configure.ac

   1 dnl == autoconf source for the Glasgow FP tools ==
   2 dnl (run "grep '^dnl \*' configure.ac | sed -e 's/dnl / /g; s/\*\*/   +/g;'"
   3 dnl  (or some such) to see the outline of this file)
   4 dnl
   5 #
   6 # (c) The University of Glasgow 1994-2004
   7 #
   8 # Configure script template for GHC
   9 #
  10 # Process with 'autoreconf' to get a working configure script.
  11 #
  12 # For the generated configure script, do "./configure --help" to
  13 # see what flags are available. (Better yet, read the documentation!)
  14 #
  15
  16 AC_INIT([The Glorious Glasgow Haskell Compilation System], [7.1], [glasgow-haskell-bugs@haskell.org], [ghc])
  17
  18 # Set this to YES for a released version, otherwise NO
  19 : ${RELEASE=NO}
  20
  21 # The primary version (e.g. 6.7, 6.6.1) is set in the AC_INIT line
  22 # above.  If this is not a released version, then we will append the
  23 # date to the version number (e.g. 6.7.20070204).  The date is
  24 # constructed by finding the date of the most recent patch in the
  25 # darcs repository.  If this is a source distribution (not a darcs
  26 # checkout), then we ship a file 'VERSION' containing the full version
  27 # when the source distribution was created.
  28
  29 if test ! -f mk/config.h.in; then
  30    echo "mk/config.h.in doesn't exist: perhaps you haven't run 'perl boot'?"
  31    exit 1
  32 fi
  33
  34 AC_SUBST([CONFIGURE_ARGS], [$ac_configure_args])
  35
  36 dnl ----------------------------------------------------------
  37 dnl ** Find unixy sort and find commands,
  38 dnl ** which are needed by FP_SETUP_PROJECT_VERSION
  39
  40 dnl ** Find find command (for Win32's benefit)
  41 FP_PROG_FIND
  42
  43 dnl ** Find sort command (for the benefit of Win32 environs)
  44 FP_PROG_SORT
  45
  46 dnl ----------------------------------------------------------
  47 FP_SETUP_PROJECT_VERSION
  48
  49 # Hmmm, we fix the RPM release number to 1 here... Is this convenient?
  50 AC_SUBST([release], [1])
  51
  52 # First off, a distrib sanity check..
  53 AC_CONFIG_SRCDIR([mk/config.mk.in])
  54
  55 dnl * We require autoconf version 2.52
  56 dnl We need 2.50 due to the use of AC_SYS_LARGEFILE and AC_MSG_NOTICE.
  57 dnl We need 2.52 due to the use of AS_TR_CPP and AS_TR_SH.
  58 AC_PREREQ([2.52])
  59
  60 # -------------------------------------------------------------------------
  61 # Prepare to generate the following header files
  62 #
  63 #
  64 AC_CONFIG_HEADER(mk/config.h)
  65
  66 # No, semi-sadly, we don't do `--srcdir'...
  67 if test x"$srcdir" != 'x.' ; then
  68     echo "This configuration does not support the \`--srcdir' option.."
  69     exit 1
  70 fi
  71
  72 dnl --------------------------------------------------------------
  73 dnl * Project specific configuration options
  74 dnl --------------------------------------------------------------
  75 dnl What follows is a bunch of options that can either be configured
  76 dnl through command line options to the configure script or by
  77 dnl supplying defns in the build tree's mk/build.mk. Having the option to
  78 dnl use either is considered a Feature.
  79
  80 dnl ** What command to use to compile compiler sources ?
  81 dnl --------------------------------------------------------------
  82
  83 AC_ARG_WITH([ghc],
  84 [AC_HELP_STRING([--with-ghc=ARG],
  85   [Use ARG as the path to GHC  [default=autodetect]])],
  86   [WithGhc="$withval"],
  87   [if test "$GHC" = ""; then
  88     AC_PATH_PROG([GHC], [ghc])
  89   fi
  90   WithGhc="$GHC"])
  91
  92 dnl ** Booting from .hc files?
  93 dnl --------------------------------------------------------------
  94 AC_ARG_ENABLE(hc-boot,
  95 [AC_HELP_STRING([--enable-hc-boot],
  96 [Boot the Glasgow Haskell Compiler from intermediate .hc files.
  97  (This option is mostly of interest to porters.) [default=no]])],
  98 [ if test x"$enableval" = x"yes"; then
  99         BootingFromHc=YES
 100   else
 101         BootingFromHc=NO
 102   fi
 103 ],
 104 [BootingFromHc=NO]
 105 )
 106 AC_SUBST(BootingFromHc)
 107
 108 AC_ARG_ENABLE(bootstrap-with-devel-snapshot,
 109 [AC_HELP_STRING([--enable-bootstrap-with-devel-snapshot],
 110                 [Allow bootstrapping using a development snapshot of GHC.  This is not guaranteed to work.])],
 111         EnableBootstrapWithDevelSnaphost=YES,
 112         EnableBootstrapWithDevelSnaphost=NO
 113 )
 114
 115 if test "$WithGhc" != ""; then
 116   FPTOOLS_GHC_VERSION([GhcVersion], [GhcMajVersion], [GhcMinVersion], [GhcPatchLevel])dnl
 117
 118   if test "$GhcMajVersion" = "unknown" -o "$GhcMinVersion" = "unknown"; then
 119      AC_MSG_ERROR([Cannot determine the version of $WithGhc.  Is it really GHC?])
 120   fi
 121
 122   AC_SUBST(GhcVersion)dnl
 123   AC_SUBST(GhcMajVersion)dnl
 124   AC_SUBST(GhcMinVersion)dnl
 125   AC_SUBST(GhcPatchLevel)dnl
 126   GhcMinVersion2=`echo "$GhcMinVersion" | sed 's/^\\(.\\)$/0\\1/'`
 127   GhcCanonVersion="$GhcMajVersion$GhcMinVersion2"
 128   FP_COMPARE_VERSIONS($GhcVersion,[-ge],[6.10.2],
 129                       [ghc_ge_6102=YES], [ghc_ge_6102=NO])
 130   if test $GhcCanonVersion -ge 611; then ghc_ge_611=YES; else ghc_ge_611=NO; fi
 131   if test $GhcCanonVersion -ge 613; then ghc_ge_613=YES; else ghc_ge_613=NO; fi
 132   AC_SUBST(ghc_ge_6102)dnl
 133   AC_SUBST(ghc_ge_611)dnl
 134   AC_SUBST(ghc_ge_613)dnl
 135 fi
 136
 137 dnl ** Must have GHC to build GHC, unless --enable-hc-boot is on
 138 if test "$BootingFromHc" = "NO" -a -d "$srcdir/compiler"; then
 139   if test "$WithGhc" = ""; then
 140      AC_MSG_ERROR([GHC is required unless bootstrapping from .hc files.])
 141   fi
 142   FP_COMPARE_VERSIONS([$GhcVersion],[-lt],[6.10],
 143     [AC_MSG_ERROR([GHC version 6.10 or later is required to compile GHC.])])dnl
 144
 145   if test `expr $GhcMinVersion % 2` = "1"; then
 146      if test "$EnableBootstrapWithDevelSnaphost" = "NO"; then
 147         AC_MSG_ERROR([
 148      $WithGhc is a development snapshot of GHC, version $GhcVersion.
 149      Bootstrapping using this version of GHC is not supported, and may not
 150      work.  Use --enable-bootstrap-with-devel-snapshot to try it anyway,
 151      or --with-ghc to specify a different GHC to use.])
 152      fi
 153   fi
 154 fi;
 155
 156 # GHC is passed to Cabal, so we need a native path
 157 if test "${WithGhc}" != ""
 158 then
 159     ghc_host=`"${WithGhc}" +RTS --info | grep 'Host platform' | sed -e 's/.*, "//' -e 's/")//'`
 160
 161     if test "$ghc_host" = "i386-unknown-mingw32"
 162     then
 163         if test "${OSTYPE}" = "msys"
 164         then
 165             WithGhc=`echo "${WithGhc}" | sed "s#^/\([a-zA-Z]\)/#\1:/#"`
 166         else
 167             # Canonicalise to <drive>:/path/to/ghc
 168             WithGhc=`cygpath -m "${WithGhc}"`
 169         fi
 170         echo "GHC path canonicalised to: ${WithGhc}"
 171     fi
 172 fi
 173 AC_SUBST([WithGhc])
 174
 175 dnl ** Without optimization some INLINE trickery fails for GHCi
 176 SRC_CC_OPTS="-O"
 177
 178 FP_ICONV
 179 FP_GMP
 180
 181 dnl--------------------------------------------------------------------
 182 dnl * Choose host(/target/build) platform
 183 dnl--------------------------------------------------------------------
 184 dnl If we aren't explicitly told what values to use with configure flags,
 185 dnl we ask the bootstrapping compiler what platform it is for
 186
 187 if test "${WithGhc}" != ""
 188 then
 189         bootstrap_host=`"${WithGhc}" +RTS --info | grep '^ ,("Host platform"' | sed -e 's/.*, "//' -e 's/")//' | tr -d '\r'`
 190         bootstrap_target=`"${WithGhc}" +RTS --info | grep '^ ,("Target platform"' | sed -e 's/.*, "//' -e 's/")//' | tr -d '\r'`
 191         if test "$bootstrap_host" != "$bootstrap_target"
 192         then
 193                 echo "Bootstrapping GHC is a cross compiler. This probably isn't going to work"
 194         fi
 195 fi
 196
 197 # We have to run these unconditionally, but we may discard their
 198 # results in the following code
 199 AC_CANONICAL_BUILD
 200 AC_CANONICAL_HOST
 201 AC_CANONICAL_TARGET
 202
 203 # If no argument was given for a configuration variable, then discard
 204 # the guessed canonical system and use the configuration of the
 205 # bootstrapping ghc. If an argument was given, map it from gnu format
 206 # to ghc format.
 207 #
 208 # For why we do it this way, see: #3637, #1717, #2951
 209
 210 if test "$build_alias" = ""
 211 then
 212     if test "${WithGhc}" != ""
 213     then
 214         build=$bootstrap_target
 215         echo "Build platform inferred as: $build"
 216     else
 217         echo "Can't work out build platform"
 218         exit 1
 219     fi
 220
 221     BuildArch=`echo "$build" | sed 's/-.*//'`
 222     BuildVendor=`echo "$build" | sed -e 's/.*-\(.*\)-.*/\1/'`
 223     BuildOS=`echo "$build" | sed 's/.*-//'`
 224 else
 225     GHC_CONVERT_CPU([$build_cpu], [BuildArch])
 226     GHC_CONVERT_VENDOR([$build_vendor], [BuildVendor])
 227     GHC_CONVERT_OS([$build_os], [BuildOS])
 228 fi
 229
 230 if test "$host_alias" = ""
 231 then
 232     if test "${WithGhc}" != ""
 233     then
 234         host=$bootstrap_target
 235         echo "Host platform inferred as: $host"
 236     else
 237         echo "Can't work out host platform"
 238         exit 1
 239     fi
 240
 241     HostArch=`echo "$host" | sed 's/-.*//'`
 242     HostVendor=`echo "$host" | sed -e 's/.*-\(.*\)-.*/\1/'`
 243     HostOS=`echo "$host" | sed 's/.*-//'`
 244 else
 245     GHC_CONVERT_CPU([$host_cpu], [HostArch])
 246     GHC_CONVERT_VENDOR([$host_vendor], [HostVendor])
 247     GHC_CONVERT_OS([$host_os], [HostOS])
 248 fi
 249
 250 if test "$target_alias" = ""
 251 then
 252     if test "${WithGhc}" != ""
 253     then
 254         target=$bootstrap_target
 255         echo "Target platform inferred as: $target"
 256     else
 257         echo "Can't work out target platform"
 258         exit 1
 259     fi
 260
 261     TargetArch=`echo "$target" | sed 's/-.*//'`
 262     TargetVendor=`echo "$target" | sed -e 's/.*-\(.*\)-.*/\1/'`
 263     TargetOS=`echo "$target" | sed 's/.*-//'`
 264 else
 265     GHC_CONVERT_CPU([$target_cpu], [TargetArch])
 266     GHC_CONVERT_VENDOR([$target_vendor], [TargetVendor])
 267     GHC_CONVERT_OS([$target_os], [TargetOS])
 268 fi
 269
 270 exeext=''
 271 soext='.so'
 272 case $host in
 273 *-unknown-cygwin32)
 274     AC_MSG_WARN([GHC does not support the Cygwin target at the moment])
 275     AC_MSG_WARN([I'm assuming you wanted to build for i386-unknown-mingw32])
 276     exit 1
 277     ;;
 278 *-unknown-mingw32)
 279     exeext='.exe'
 280     soext='.dll'
 281     ;;
 282 i386-apple-darwin|powerpc-apple-darwin)
 283     soext='.dylib'
 284     ;;
 285 x86_64-apple-darwin)
 286     soext='.dylib'
 287     ;;
 288 esac
 289
 290 checkArch() {
 291     case $1 in
 292     alpha|arm|hppa|hppa1_1|i386|ia64|m68k|mips|mipseb|mipsel|powerpc|powerpc64|rs6000|s390|sparc|sparc64|vax|x86_64)
 293         ;;
 294     *)
 295         echo "Unknown arch $1"
 296         exit 1
 297         ;;
 298     esac
 299 }
 300
 301 checkVendor() {
 302     case $1 in
 303     dec|unknown|hp|apple|next|sun|sgi|ibm)
 304         ;;
 305     *)
 306         echo "Unknown vendor $1"
 307         exit 1
 308         ;;
 309     esac
 310 }
 311
 312 checkOS() {
 313     case $1 in
 314     linux|freebsd|netbsd|openbsd|dragonfly|osf1|osf3|hpux|linuxaout|kfreebsdgnu|freebsd2|solaris2|cygwin32|mingw32|darwin|gnu|nextstep2|nextstep3|sunos4|ultrix|irix|aix|haiku)
 315         ;;
 316     *)
 317         echo "Unknown OS '$1'"
 318         exit 1
 319         ;;
 320     esac
 321 }
 322
 323 BuildPlatform="$BuildArch-$BuildVendor-$BuildOS"
 324 BuildPlatform_CPP=`echo "$BuildPlatform" | sed -e 's/\./_/g' -e 's/-/_/g'`
 325 BuildArch_CPP=`    echo "$BuildArch"     | sed -e 's/\./_/g' -e 's/-/_/g'`
 326 BuildVendor_CPP=`  echo "$BuildVendor"   | sed -e 's/\./_/g' -e 's/-/_/g'`
 327 BuildOS_CPP=`      echo "$BuildOS"       | sed -e 's/\./_/g' -e 's/-/_/g'`
 328
 329 checkArch "$BuildArch"
 330 checkVendor "$BuildVendor"
 331 checkOS "$BuildOS"
 332
 333 HostPlatform="$HostArch-$HostVendor-$HostOS"
 334 HostPlatform_CPP=`echo "$HostPlatform" | sed -e 's/\./_/g' -e 's/-/_/g'`
 335 HostArch_CPP=`    echo "$HostArch"     | sed -e 's/\./_/g' -e 's/-/_/g'`
 336 HostVendor_CPP=`  echo "$HostVendor"   | sed -e 's/\./_/g' -e 's/-/_/g'`
 337 HostOS_CPP=`      echo "$HostOS"       | sed -e 's/\./_/g' -e 's/-/_/g'`
 338
 339 checkArch "$HostArch"
 340 checkVendor "$HostVendor"
 341 checkOS "$HostOS"
 342
 343 TargetPlatform="$TargetArch-$TargetVendor-$TargetOS"
 344 TargetPlatform_CPP=`echo "$TargetPlatform" | sed -e 's/\./_/g' -e 's/-/_/g'`
 345 TargetArch_CPP=`    echo "$TargetArch"     | sed -e 's/\./_/g' -e 's/-/_/g'`
 346 TargetVendor_CPP=`  echo "$TargetVendor"   | sed -e 's/\./_/g' -e 's/-/_/g'`
 347 TargetOS_CPP=`      echo "$TargetOS"       | sed -e 's/\./_/g' -e 's/-/_/g'`
 348
 349 checkArch "$TargetArch"
 350 checkVendor "$TargetVendor"
 351 checkOS "$TargetOS"
 352
 353 AC_SUBST(BuildPlatform)
 354 AC_SUBST(HostPlatform)
 355 AC_SUBST(TargetPlatform)
 356 AC_SUBST(HostPlatform_CPP)
 357 AC_SUBST(BuildPlatform_CPP)
 358 AC_SUBST(TargetPlatform_CPP)
 359
 360 AC_SUBST(HostArch_CPP)
 361 AC_SUBST(BuildArch_CPP)
 362 AC_SUBST(TargetArch_CPP)
 363
 364 AC_SUBST(HostOS_CPP)
 365 AC_SUBST(BuildOS_CPP)
 366 AC_SUBST(TargetOS_CPP)
 367
 368 AC_SUBST(HostVendor_CPP)
 369 AC_SUBST(BuildVendor_CPP)
 370 AC_SUBST(TargetVendor_CPP)
 371
 372 AC_SUBST(exeext)
 373 AC_SUBST(soext)
 374
 375 AC_ARG_WITH(hc,
 376 [AC_HELP_STRING([--with-hc=ARG],
 377         [Use ARG as the path to the compiler for compiling ordinary
 378          Haskell code  (default= value of --with-ghc)])],
 379 [WithHc="$withval"],
 380 [WithHc=$WithGhc]
 381 )
 382 AC_SUBST(WithHc)
 383
 384 # This uses GHC, so put it after the "GHC is required" check above:
 385 FP_INTREE_GHC_PWD
 386 FP_FIND_ROOT
 387
 388 if test "$HostOS" = "mingw32"
 389 then
 390     CC="$hardtop/inplace/mingw/bin/gcc.exe"
 391     LD="$hardtop/inplace/mingw/bin/ld.exe"
 392     NM="$hardtop/inplace/mingw/bin/nm.exe"
 393     fp_prog_ar_raw="$hardtop/inplace/mingw/bin/ar.exe"
 394     if ! test -d inplace/mingw ||
 395          test inplace/mingw -ot ghc-tarballs/mingw/binutils*.tar.lzma  ||
 396          test inplace/mingw -ot ghc-tarballs/mingw/gcc-core*.tar.lzma  ||
 397          test inplace/mingw -ot ghc-tarballs/mingw/gcc-c++*.tar.lzma   ||
 398          test inplace/mingw -ot ghc-tarballs/mingw/libgmp*.tar.gz      ||
 399          test inplace/mingw -ot ghc-tarballs/mingw/libmpc*.tar.gz      ||
 400          test inplace/mingw -ot ghc-tarballs/mingw/libmpfr*.tar.gz     ||
 401          test inplace/mingw -ot ghc-tarballs/mingw/mingwrt*-dev.tar.gz ||
 402          test inplace/mingw -ot ghc-tarballs/mingw/mingwrt*-dll.tar.gz ||
 403          test inplace/mingw -ot ghc-tarballs/mingw/w32api*.tar.lzma
 404     then
 405         AC_MSG_NOTICE([Making in-tree mingw tree])
 406         rm -rf inplace/mingw
 407         test -d inplace || mkdir inplace
 408         mkdir inplace/mingw
 409         (
 410             cd inplace/mingw &&
 411             tar --lzma -xf ../../ghc-tarballs/mingw/binutils*.tar.lzma  &&
 412             tar --lzma -xf ../../ghc-tarballs/mingw/gcc-core*.tar.lzma  &&
 413             tar --lzma -xf ../../ghc-tarballs/mingw/gcc-c++*.tar.lzma   &&
 414             tar --lzma -xf ../../ghc-tarballs/mingw/libgmp*.tar.lzma    &&
 415             tar --lzma -xf ../../ghc-tarballs/mingw/libmpc*.tar.lzma    &&
 416             tar --lzma -xf ../../ghc-tarballs/mingw/libmpfr*.tar.lzma   &&
 417             tar -z     -xf ../../ghc-tarballs/mingw/mingwrt*-dev.tar.gz &&
 418             tar -z     -xf ../../ghc-tarballs/mingw/mingwrt*-dll.tar.gz &&
 419             tar --lzma -xf ../../ghc-tarballs/mingw/w32api*.tar.lzma    &&
 420             mv bin/gcc.exe bin/realgcc.exe
 421         )
 422         PATH=`pwd`/inplace/mingw/bin:$PATH inplace/mingw/bin/realgcc.exe driver/gcc/gcc.c driver/utils/cwrapper.c driver/utils/getLocation.c -Idriver/utils -o inplace/mingw/bin/gcc.exe
 423         if ! test -e inplace/mingw/bin/gcc.exe
 424         then
 425             AC_MSG_ERROR([GHC is required unless bootstrapping from .hc files.])
 426         fi
 427         AC_MSG_NOTICE([In-tree mingw tree created])
 428     fi
 429     if ! test -d inplace/perl ||
 430          test inplace/perl -ot ghc-tarballs/perl/ghc-perl*.tar.gz
 431     then
 432         AC_MSG_NOTICE([Making in-tree perl tree])
 433         rm -rf inplace/perl
 434         mkdir inplace
 435         mkdir inplace/perl
 436         (
 437             cd inplace/perl &&
 438             tar -zxf ../../ghc-tarballs/perl/ghc-perl*.tar.gz
 439         )
 440         AC_MSG_NOTICE([In-tree perl tree created])
 441     fi
 442 fi
 443
 444 dnl ** Which gcc to use?
 445 dnl --------------------------------------------------------------
 446 FP_ARG_WITH_PATH_GNU_PROG([CC], [gcc])
 447 export CC
 448 WhatGccIsCalled="$CC"
 449 AC_SUBST(WhatGccIsCalled)
 450
 451 dnl ** Which ld to use?
 452 dnl --------------------------------------------------------------
 453 FP_ARG_WITH_PATH_GNU_PROG([LD], [ld])
 454 LdCmd="$LD"
 455 AC_SUBST([LdCmd])
 456
 457 dnl ** Which nm to use?
 458 dnl --------------------------------------------------------------
 459 FP_ARG_WITH_PATH_GNU_PROG([NM], [nm])
 460 NmCmd="$NM"
 461 AC_SUBST([NmCmd])
 462
 463 dnl ** Mac OS X: explicit deployment target
 464 dnl --------------------------------------------------------------
 465 AC_ARG_WITH([macosx-deployment-target],
 466 [AC_HELP_STRING([--with-macosx-deployment-target=VERSION],
 467         [Build for Mac OS VERSION and higher  (default= version of build host)])],
 468 [FP_MACOSX_DEPLOYMENT_TARGET="$withval"
 469  if test "x$TargetOS_CPP-$TargetVendor_CPP" != "xdarwin-apple"; then
 470    # ignore everywhere, but on Mac OS
 471    AC_MSG_WARN([--macosx-deployment-target is only available on Mac OS X])
 472    FP_MACOSX_DEPLOYMENT_TARGET=none
 473  fi],
 474 [FP_MACOSX_DEPLOYMENT_TARGET=none]
 475 )
 476 FP_CHECK_MACOSX_DEPLOYMENT_TARGET
 477 AC_SUBST(MACOSX_DEPLOYMENT_VERSION)
 478 AC_SUBST(MACOSX_DEPLOYMENT_SDK)
 479
 480 dnl --------------------------------------------------------------
 481 dnl End of configure script option section
 482 dnl --------------------------------------------------------------
 483
 484
 485 dnl --------------------------------------------------------------
 486 dnl * General configuration checks
 487 dnl --------------------------------------------------------------
 488
 489 dnl ** Can the unix package be built?
 490 dnl --------------------------------------------------------------
 491
 492 if test x"$TargetPlatform" = x"i386-unknown-mingw32"; then
 493    GhcLibsWithUnix=NO
 494 else
 495    GhcLibsWithUnix=YES
 496 fi
 497 AC_SUBST([GhcLibsWithUnix])
 498
 499 dnl ** does #! work?
 500 AC_SYS_INTERPRETER()
 501
 502 dnl ** look for `perl'
 503 case $HostOS_CPP in
 504 cygwin32|mingw32)
 505     PerlCmd=$hardtop/inplace/perl/perl
 506     ;;
 507 *)
 508     AC_PATH_PROG(PerlCmd,perl)
 509     if test -z "$PerlCmd"
 510     then
 511         echo "You must install perl before you can continue"
 512         echo "Perhaps it is already installed, but not in your PATH?"
 513         exit 1
 514     else
 515         FPTOOLS_CHECK_PERL_VERSION
 516     fi
 517     ;;
 518 esac
 519
 520 dnl ** does #! path/to/perl work? (sometimes it's too long...)
 521 FPTOOLS_SHEBANG_PERL
 522
 523 dnl ** check for Python
 524 AC_PATH_PROG(PythonCmd,python)
 525
 526 dnl ** look for GCC and find out which version
 527 dnl     Figure out which C compiler to use.  Gcc is preferred.
 528 dnl     If gcc, make sure it's at least 2.1
 529 dnl
 530 FP_HAVE_GCC
 531
 532 FPTOOLS_SET_C_LD_FLAGS([target],[CFLAGS],[LDFLAGS])
 533 FPTOOLS_SET_C_LD_FLAGS([build],[CONF_CC_OPTS_STAGE0],[CONF_LD_OPTS_STAGE0])
 534 FPTOOLS_SET_C_LD_FLAGS([target],[CONF_CC_OPTS_STAGE1],[CONF_LD_OPTS_STAGE1])
 535 # Stage 3 won't be supported by cross-compilation
 536 FPTOOLS_SET_C_LD_FLAGS([target],[CONF_CC_OPTS_STAGE2],[CONF_LD_OPTS_STAGE2])
 537
 538 FP_GCC_EXTRA_FLAGS
 539
 540 dnl ** figure out how to invoke cpp directly (gcc -E is no good)
 541 AC_PROG_CPP
 542
 543 AC_SUBST(CONF_CC_OPTS_STAGE0)
 544 AC_SUBST(CONF_CC_OPTS_STAGE1)
 545 AC_SUBST(CONF_CC_OPTS_STAGE2)
 546 AC_SUBST(CONF_LD_OPTS_STAGE0)
 547 AC_SUBST(CONF_LD_OPTS_STAGE1)
 548 AC_SUBST(CONF_LD_OPTS_STAGE2)
 549
 550 dnl ** figure out how to do context diffs
 551 FP_PROG_CONTEXT_DIFF
 552
 553 dnl Let's make sure install-sh is executable here.  If we got it from
 554 dnl a darcs repo, it might not be (see bug #978).
 555 chmod +x install-sh
 556 dnl ** figure out how to do a BSD-ish install
 557 AC_PROG_INSTALL
 558
 559 dnl If you can run configure, you certainly have /bin/sh
 560 AC_DEFINE([HAVE_BIN_SH], [1], [Define to 1 if you have /bin/sh.])
 561
 562 dnl ** how to invoke `ar' and `ranlib'
 563 FP_PROG_AR_SUPPORTS_ATFILE
 564 FP_PROG_AR_NEEDS_RANLIB
 565 FP_PROG_AR_SUPPORTS_INPUT
 566
 567 dnl ** Check to see whether ln -s works
 568 AC_PROG_LN_S
 569
 570
 571 dnl ** Find the path to sed
 572 AC_PATH_PROGS(SedCmd,gsed sed,sed)
 573
 574
 575 dnl ** check for time command
 576 AC_PATH_PROG(TimeCmd,time)
 577
 578 dnl ** check for tar
 579 dnl   if GNU tar is named gtar, look for it first.
 580 AC_PATH_PROGS(TarCmd,gnutar gtar tar,tar)
 581
 582 dnl ** check for patch
 583 dnl if GNU patch is named gpatch, look for it first
 584 AC_PATH_PROGS(PatchCmd,gpatch patch, patch)
 585
 586 dnl ** check for dtrace (currently only implemented for Mac OS X)
 587 HaveDtrace=NO
 588 AC_PATH_PROG(DtraceCmd,dtrace)
 589 if test -n "$DtraceCmd"; then
 590   if test "x$TargetOS_CPP-$TargetVendor_CPP" == "xdarwin-apple"; then
 591     HaveDtrace=YES
 592   fi
 593 fi
 594 AC_SUBST(HaveDtrace)
 595
 596 AC_PATH_PROG(HSCOLOUR,HsColour)
 597 # HsColour is passed to Cabal, so we need a native path
 598 if test "x$HostPlatform"  = "xi386-unknown-mingw32" && \
 599    test "${OSTYPE}"      != "msys"                  && \
 600    test "${HSCOLOUR}"    != ""
 601 then
 602     # Canonicalise to <drive>:/path/to/gcc
 603     HSCOLOUR=`cygpath -m ${HSCOLOUR}`
 604 fi
 605
 606 dnl ** check for DocBook toolchain
 607 FP_CHECK_DOCBOOK_DTD
 608 FP_DOCBOOK_XSL
 609 FP_PROG_DBLATEX
 610
 611 FP_PROG_HSTAGS
 612
 613 dnl ** check for ghc-pkg command
 614 FP_PROG_GHC_PKG
 615
 616 dnl ** check for installed happy binary + version
 617 dnl    (don't do it if we're booting from .hc files though.)
 618 if test "$BootingFromHc" = "NO"; then
 619 FPTOOLS_HAPPY
 620 fi;
 621
 622 dnl ** check for installed alex binary + version
 623 dnl    (don't do it if we're booting from .hc files though.)
 624 if test "$BootingFromHc" = "NO"; then
 625 FPTOOLS_ALEX
 626 fi;
 627
 628 dnl --------------------------------------------------
 629 dnl ### program checking section ends here ###
 630 dnl --------------------------------------------------
 631
 632 dnl --------------------------------------------------
 633 dnl * Platform header file and syscall feature tests
 634 dnl ### checking the state of the local header files and syscalls ###
 635
 636 dnl ** check for full ANSI header (.h) files
 637 AC_HEADER_STDC
 638
 639 dnl ** Enable large file support.  NB. do this before testing the type of
 640 dnl    off_t, because it will affect the result of that test.
 641 AC_SYS_LARGEFILE
 642
 643 dnl ** check for specific header (.h) files that we are interested in
 644 AC_CHECK_HEADERS([bfd.h ctype.h dirent.h dlfcn.h errno.h fcntl.h grp.h limits.h locale.h nlist.h pthread.h pwd.h signal.h sys/cpuset.h sys/mman.h sys/resource.h sys/select.h sys/time.h sys/timeb.h sys/timers.h sys/times.h sys/utsname.h sys/wait.h termios.h time.h utime.h windows.h winsock.h sched.h])
 645
 646 dnl ** check if it is safe to include both <time.h> and <sys/time.h>
 647 AC_HEADER_TIME
 648
 649 dnl ** do we have long longs?
 650 AC_CHECK_TYPES([long long])
 651
 652 dnl ** what are the sizes of various types
 653 AC_CHECK_SIZEOF(char,               1)
 654 AC_CHECK_SIZEOF(double,             8)
 655 AC_CHECK_SIZEOF(float,              4)
 656 AC_CHECK_SIZEOF(int,                4)
 657 AC_CHECK_SIZEOF(long,               4)
 658 if test "$ac_cv_type_long_long" = yes; then
 659 AC_CHECK_SIZEOF(long long,          8)
 660 fi
 661 AC_CHECK_SIZEOF(short,              2)
 662 AC_CHECK_SIZEOF(unsigned char,      1)
 663 AC_CHECK_SIZEOF(unsigned int,       4)
 664 AC_CHECK_SIZEOF(unsigned long,      4)
 665 if test "$ac_cv_type_long_long" = yes; then
 666 AC_CHECK_SIZEOF(unsigned long long, 8)
 667 fi
 668 AC_CHECK_SIZEOF(unsigned short,     2)
 669 AC_CHECK_SIZEOF(void *,             4)
 670
 671 dnl ** what are alignment constraints on various types
 672 FP_CHECK_ALIGNMENT(char)
 673 FP_CHECK_ALIGNMENT(double)
 674 FP_CHECK_ALIGNMENT(float)
 675 FP_CHECK_ALIGNMENT(int)
 676 FP_CHECK_ALIGNMENT(long)
 677 if test "$ac_cv_type_long_long" = yes; then
 678 FP_CHECK_ALIGNMENT(long long)
 679 fi
 680 FP_CHECK_ALIGNMENT(short)
 681 FP_CHECK_ALIGNMENT(unsigned char)
 682 FP_CHECK_ALIGNMENT(unsigned int)
 683 FP_CHECK_ALIGNMENT(unsigned long)
 684 if test "$ac_cv_type_long_long" = yes; then
 685 FP_CHECK_ALIGNMENT(unsigned long long)
 686 fi
 687 FP_CHECK_ALIGNMENT(unsigned short)
 688 FP_CHECK_ALIGNMENT(void *)
 689
 690 FP_CHECK_FUNC([WinExec],
 691   [@%:@include <windows.h>], [WinExec("",0)])
 692
 693 FP_CHECK_FUNC([GetModuleFileName],
 694   [@%:@include <windows.h>], [GetModuleFileName((HMODULE)0,(LPTSTR)0,0)])
 695
 696 dnl ** check return type of signal handlers
 697 dnl Foo: assumes we can use prototypes.
 698 dnl On BCC, signal handlers have type "int(void)", elsewhere its "void(int)".
 699 dnl AC_CACHE_CHECK([type of signal handlers], ac_cv_type_signal_handler,
 700 dnl [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 701 dnl #include <signal.h>
 702 dnl #ifdef signal
 703 dnl #undef signal
 704 dnl #endif
 705 dnl void (*signal (int, void (*)(int)))(int);
 706 dnl ]],
 707 dnl [[int i;]])],
 708 dnl [ac_cv_type_signal_handler=void_int],
 709 dnl [ac_cv_type_signal_handler=int_void])])
 710 dnl if test "$ac_cv_type_signal_handler" = void_int; then
 711 dnl AC_DEFINE(VOID_INT_SIGNALS)
 712 dnl fi
 713
 714 dnl On BCC, signal handlers have type "int(void)", elsewhere its "void(int)".
 715 AC_TYPE_SIGNAL
 716 if test "$ac_cv_type_signal" = void; then
 717   AC_DEFINE([VOID_INT_SIGNALS], [1], [Define to 1 if signal handlers have type void (*)(int). Otherwise, they're assumed to have type int (*)(void).])
 718 fi
 719
 720 dnl ** check for more functions
 721 dnl ** The following have been verified to be used in ghc/, but might be used somewhere else, too.
 722 AC_CHECK_FUNCS([getclock getrusage gettimeofday setitimer siginterrupt sysconf times ctime_r sched_setaffinity setlocale])
 723
 724 AC_TRY_RUN([
 725 #include <sys/types.h>
 726 #include <sys/time.h>
 727 int main(void) {
 728   struct itimerval tval;
 729   tval.it_value.tv_sec = 1;
 730   tval.it_value.tv_usec = 0;
 731   tval.it_interval = tval.it_value;
 732   return setitimer(ITIMER_VIRTUAL, &tval, (void*)0) != 0;
 733 }
 734 ],[AC_DEFINE([HAVE_SETITIMER_VIRTUAL], [1], [Define to 1 if setitimer accepts ITIMER_VIRTUAL, 0 else.])])
 735
 736 dnl ** On OS X 10.4 (at least), time.h doesn't declare ctime_r if
 737 dnl ** _POSIX_C_SOURCE is defined
 738 AC_CHECK_DECLS([ctime_r], , ,
 739 [#define _POSIX_SOURCE 1
 740 #define _POSIX_C_SOURCE 199506L
 741 #include <time.h>])
 742
 743 dnl ** check for mingwex library
 744 AC_CHECK_LIB(mingwex, closedir, HaveLibMingwEx=YES, HaveLibMingwEx=NO)
 745 AC_SUBST(HaveLibMingwEx)
 746
 747 if test $HaveLibMingwEx = YES ; then
 748   AC_DEFINE([HAVE_MINGWEX], [1], [Define to 1 if you have the mingwex library.])
 749 fi
 750
 751 dnl ** check for math library
 752 dnl    Keep that check as early as possible.
 753 dnl    as we need to know whether we need libm
 754 dnl    for math functions or not
 755 dnl    (see http://hackage.haskell.org/trac/ghc/ticket/3730)
 756 AC_CHECK_LIB(m, atan, HaveLibM=YES, HaveLibM=NO)
 757 if test $HaveLibM = YES
 758 then
 759   AC_DEFINE([HAVE_LIBM], [1], [Define to 1 if you need to link with libm])
 760 fi
 761
 762 dnl ** check whether this machine has BFD and liberty installed (used for debugging)
 763 dnl    the order of these tests matters: bfd needs liberty
 764 AC_CHECK_LIB(iberty, xmalloc)
 765 AC_CHECK_LIB(bfd,    bfd_init)
 766
 767 dnl ################################################################
 768 dnl Check for libraries
 769 dnl ################################################################
 770
 771 dnl ** check whether we need -ldl to get dlopen()
 772
 773 AC_CHECK_LIB(dl, dlopen,
 774     [HaveLibDL=YES
 775      AC_DEFINE([HAVE_LIBDL], [1], [Define to 1 if you need -ldl to get dlopen().])
 776      LIBS="$LIBS -ldl"],
 777     [HaveLibDL=NO])
 778 AC_SUBST(HaveLibDL)
 779
 780 dnl --------------------------------------------------
 781 dnl * Miscellaneous feature tests
 782 dnl --------------------------------------------------
 783
 784 dnl ** can we get alloca?
 785 AC_FUNC_ALLOCA
 786
 787 dnl ** Working vfork?
 788 AC_FUNC_FORK
 789
 790 dnl ** determine whether or not const works
 791 AC_C_CONST
 792
 793 dnl ** are we big endian?
 794 AC_C_BIGENDIAN
 795 FPTOOLS_FLOAT_WORD_ORDER_BIGENDIAN
 796
 797 dnl ** check for leading underscores in symbol names
 798 FP_LEADING_UNDERSCORE
 799
 800 dnl ** check for ld, whether it has an -x option, and if it is GNU ld
 801 FP_PROG_LD_X
 802 FP_PROG_LD_IS_GNU
 803
 804 dnl ** check for Apple-style dead-stripping support
 805 dnl    (.subsections-via-symbols assembler directive)
 806
 807
 808 AC_MSG_CHECKING(for .subsections_via_symbols)
 809 AC_COMPILE_IFELSE(
 810     [AC_LANG_PROGRAM([], [__asm__ (".subsections_via_symbols");])],
 811     [AC_MSG_RESULT(yes)
 812      AC_DEFINE([HAVE_SUBSECTIONS_VIA_SYMBOLS],[1],
 813                [Define to 1 if Apple-style dead-stripping is supported.])
 814     ],
 815     [AC_MSG_RESULT(no)])
 816
 817 dnl *** check for GNU non-executable stack note support (ELF only)
 818 dnl     (.section .note.GNU-stack,"",@progbits)
 819
 820 dnl This test doesn't work with "gcc -g" in gcc 4.4 (GHC trac #3889:
 821 dnl     Error: can't resolve `.note.GNU-stack' {.note.GNU-stack section} - `.Ltext0' {.text section}
 822 dnl so we empty CFLAGS while running this test
 823 CFLAGS2="$CFLAGS"
 824 CFLAGS=
 825 AC_MSG_CHECKING(for GNU non-executable stack support)
 826 AC_COMPILE_IFELSE(
 827     [AC_LANG_PROGRAM([__asm__ (".section .note.GNU-stack,\"\",@progbits");], [0])],
 828     [AC_MSG_RESULT(yes)
 829      AC_DEFINE([HAVE_GNU_NONEXEC_STACK],[1],
 830                [Define to 1 if GNU non-executable stack notes are supported.])
 831     ],
 832     [AC_MSG_RESULT(no)])
 833 CFLAGS="$CFLAGS2"
 834
 835 FP_VISIBILITY_HIDDEN
 836
 837 dnl ** check for librt
 838 AC_CHECK_LIB(rt, clock_gettime)
 839 AC_CHECK_FUNCS(clock_gettime timer_create timer_settime)
 840 FP_CHECK_TIMER_CREATE
 841
 842 dnl ** check for Apple's "interesting" long double compatibility scheme
 843 AC_MSG_CHECKING(for printf\$LDBLStub)
 844 AC_TRY_LINK_FUNC(printf\$LDBLStub,
 845     [
 846         AC_MSG_RESULT(yes)
 847         AC_DEFINE([HAVE_PRINTF_LDBLSTUB],[1],
 848             [Define to 1 if we have printf$LDBLStub (Apple Mac OS >= 10.4, PPC).])
 849     ],
 850     [
 851         AC_MSG_RESULT(no)
 852         AC_DEFINE([HAVE_PRINTF_LDBLSTUB],[0],
 853             [Define to 1 if we have printf$LDBLStub (Apple Mac OS >= 10.4, PPC).])
 854     ])
 855
 856 dnl ** check for eventfd which is needed by the I/O manager
 857 AC_CHECK_HEADERS([sys/eventfd.h])
 858 AC_CHECK_FUNCS([eventfd])
 859
 860 # test for GTK+
 861 AC_PATH_PROGS([GTK_CONFIG], [pkg-config])
 862 if test -n "$GTK_CONFIG"; then
 863   if $GTK_CONFIG gtk+-2.0 --atleast-version=2.0; then
 864     GTK_CONFIG="$GTK_CONFIG gtk+-2.0"
 865   else
 866     AC_MSG_WARN([GTK+ not usable, need at least version 2.0])
 867     GTK_CONFIG=
 868   fi
 869 fi
 870 AC_SUBST([GTK_CONFIG])
 871
 872 #Checking for PAPI
 873 AC_CHECK_LIB(papi, PAPI_library_init, HavePapiLib=YES, HavePapiLib=NO)
 874 AC_CHECK_HEADER([papi.h], [HavePapiHeader=YES], [HavePapiHeader=NO])
 875 AC_SUBST(HavePapiLib)
 876 AC_SUBST(HavePapiHeader)
 877
 878 AC_CHECK_FUNCS(__mingw_vfprintf)
 879
 880 if test "$HavePapiLib" = "YES" -a "$HavePapiHeader" = "YES"; then
 881    HavePapi=YES
 882 else
 883    HavePapi=NO
 884 fi
 885 AC_SUBST(HavePapi)
 886
 887 if test "$HAVE_DOCBOOK_XSL" = "NO" ||
 888    test "$XsltprocCmd" = ""
 889 then
 890     BUILD_DOCBOOK_HTML=NO
 891 else
 892     BUILD_DOCBOOK_HTML=YES
 893 fi
 894 AC_SUBST(BUILD_DOCBOOK_HTML)
 895
 896 if test "$DblatexCmd" = ""
 897 then
 898     BUILD_DOCBOOK_PS=NO
 899     BUILD_DOCBOOK_PDF=NO
 900 else
 901     BUILD_DOCBOOK_PS=YES
 902     BUILD_DOCBOOK_PDF=YES
 903 fi
 904 AC_SUBST(BUILD_DOCBOOK_PS)
 905 AC_SUBST(BUILD_DOCBOOK_PDF)
 906
 907 LIBRARY_VERSION(base)
 908 LIBRARY_VERSION(Cabal)
 909 LIBRARY_VERSION(ghc-prim)
 910 LIBRARY_ghc_VERSION="$ProjectVersion"
 911 AC_SUBST(LIBRARY_ghc_VERSION)
 912
 913 if grep '       ' compiler/ghc.cabal.in 2>&1 >/dev/null; then
 914    AC_MSG_ERROR([compiler/ghc.cabal.in contains tab characters; please remove them])
 915 fi
 916
 917 AC_CONFIG_FILES([mk/config.mk mk/install.mk mk/project.mk compiler/ghc.cabal ghc/ghc-bin.cabal utils/runghc/runghc.cabal ghc.spec extra-gcc-opts docs/users_guide/ug-book.xml docs/users_guide/ug-ent.xml docs/index.html libraries/prologue.txt distrib/ghc.iss distrib/configure.ac distrib/MacOS/installer-scripts/create-links distrib/MacOS/installer-scripts/Uninstaller distrib/MacOS/GHC-system.pmdoc/index.xml])
 918 AC_CONFIG_COMMANDS([mk/stamp-h],[echo timestamp > mk/stamp-h])
 919 AC_OUTPUT
 920
 921 # We get caught by
 922 #     http://savannah.gnu.org/bugs/index.php?1516
 923 #     $(eval ...) inside conditionals causes errors
 924 # with make 3.80, so warn the user if it looks like they're about to
 925 # try to use it.
 926 # We would use "grep -q" here, but Solaris's grep doesn't support it.
 927 checkMake380() {
 928     if $1 --version 2>&1 | head -1 | grep 'GNU Make 3\.80' > /dev/null
 929     then
 930         echo
 931         echo "WARNING: It looks like \"$1\" is GNU make 3.80."
 932         echo "This version cannot be used to build GHC."
 933         echo "Please use GNU make >= 3.81."
 934     fi
 935 }
 936
 937 checkMake380 make
 938 checkMake380 gmake
 939
 940 echo ["
 941 ----------------------------------------------------------------------
 942 Configure completed successfully.
 943
 944    Building GHC version  : $ProjectVersion
 945
 946    Build platform        : $BuildPlatform
 947    Host platform         : $HostPlatform
 948    Target platform       : $TargetPlatform
 949 "]
 950
 951 if test "$BootingFromHc" = "YES"; then
 952 echo ["\
 953    Bootstrapping from HC files.
 954 "]
 955 else
 956 echo ["\
 957    Bootstrapping using   : $WithGhc
 958       which is version   : $GhcVersion
 959 "]
 960 fi
 961
 962 echo ["\
 963    Using GCC             : $WhatGccIsCalled
 964       which is version   : $GccVersion
 965
 966    ld       : $LdCmd
 967    Happy    : $HappyCmd ($HappyVersion)
 968    Alex     : $AlexCmd ($AlexVersion)
 969    Python   : $PythonCmd
 970    Perl     : $PerlCmd
 971    dblatex  : $DblatexCmd
 972    xsltproc : $XsltprocCmd"]
 973
 974 if test "$HSCOLOUR" = ""; then
 975 echo ["
 976    HsColour was not found; documentation will not contain source links
 977 "]
 978 else
 979 echo ["\
 980    HsColour : $HSCOLOUR
 981 "]
 982 fi
 983
 984 echo ["\
 985    Building DocBook HTML documentation : $BUILD_DOCBOOK_HTML
 986    Building DocBook PS documentation   : $BUILD_DOCBOOK_PS
 987    Building DocBook PDF documentation  : $BUILD_DOCBOOK_PDF"]
 988
 989 echo ["----------------------------------------------------------------------
 990 "]
 991
 992 echo "\
 993 For a standard build of GHC (fully optimised with profiling), type (g)make.
 994
 995 To make changes to the default build configuration, copy the file
 996 mk/build.mk.sample to mk/build.mk, and edit the settings in there.
 997
 998 For more information on how to configure your GHC build, see
 999    http://hackage.haskell.org/trac/ghc/wiki/Building
1000 "