configure.ac

   1 dnl == autoconf source for the Glasgow FP tools ==
   2 dnl (run "grep '^dnl \*' configure.ac | sed -e 's/dnl / /g; s/\*\*/   +/g;'"
   3 dnl  (or some such) to see the outline of this file)
   4 dnl
   5 #
   6 # (c) The University of Glasgow 1994-2004
   7 #
   8 # Configure script template for GHC
   9 #
  10 # Process with 'autoreconf' to get a working configure script.
  11 #
  12 # For the generated configure script, do "./configure --help" to
  13 # see what flags are available. (Better yet, read the documentation!)
  14 #
  15
  16 AC_INIT([The Glorious Glasgow Haskell Compilation System], [7.1], [glasgow-haskell-bugs@haskell.org], [ghc])
  17
  18 # Set this to YES for a released version, otherwise NO
  19 : ${RELEASE=NO}
  20
  21 # The primary version (e.g. 6.7, 6.6.1) is set in the AC_INIT line
  22 # above.  If this is not a released version, then we will append the
  23 # date to the version number (e.g. 6.7.20070204).  The date is
  24 # constructed by finding the date of the most recent patch in the
  25 # darcs repository.  If this is a source distribution (not a darcs
  26 # checkout), then we ship a file 'VERSION' containing the full version
  27 # when the source distribution was created.
  28
  29 if test ! -f mk/config.h.in; then
  30    echo "mk/config.h.in doesn't exist: perhaps you haven't run 'perl boot'?"
  31    exit 1
  32 fi
  33
  34 AC_SUBST([CONFIGURE_ARGS], [$ac_configure_args])
  35
  36 dnl ----------------------------------------------------------
  37 dnl ** Find unixy sort and find commands,
  38 dnl ** which are needed by FP_SETUP_PROJECT_VERSION
  39
  40 dnl ** Find find command (for Win32's benefit)
  41 FP_PROG_FIND
  42
  43 dnl ** Find sort command (for the benefit of Win32 environs)
  44 FP_PROG_SORT
  45
  46 dnl ----------------------------------------------------------
  47 FP_SETUP_PROJECT_VERSION
  48
  49 # Hmmm, we fix the RPM release number to 1 here... Is this convenient?
  50 AC_SUBST([release], [1])
  51
  52 # First off, a distrib sanity check..
  53 AC_CONFIG_SRCDIR([mk/config.mk.in])
  54
  55 dnl * We require autoconf version 2.52
  56 dnl We need 2.50 due to the use of AC_SYS_LARGEFILE and AC_MSG_NOTICE.
  57 dnl We need 2.52 due to the use of AS_TR_CPP and AS_TR_SH.
  58 AC_PREREQ([2.52])
  59
  60 # -------------------------------------------------------------------------
  61 # Prepare to generate the following header files
  62 #
  63 #
  64 AC_CONFIG_HEADER(mk/config.h)
  65
  66 # No, semi-sadly, we don't do `--srcdir'...
  67 if test x"$srcdir" != 'x.' ; then
  68     echo "This configuration does not support the \`--srcdir' option.."
  69     exit 1
  70 fi
  71
  72 dnl --------------------------------------------------------------
  73 dnl * Project specific configuration options
  74 dnl --------------------------------------------------------------
  75 dnl What follows is a bunch of options that can either be configured
  76 dnl through command line options to the configure script or by
  77 dnl supplying defns in the build tree's mk/build.mk. Having the option to
  78 dnl use either is considered a Feature.
  79
  80 dnl ** What command to use to compile compiler sources ?
  81 dnl --------------------------------------------------------------
  82
  83 AC_ARG_WITH([ghc],
  84 [AC_HELP_STRING([--with-ghc=ARG],
  85   [Use ARG as the path to GHC  [default=autodetect]])],
  86   [WithGhc="$withval"],
  87   [if test "$GHC" = ""; then
  88     AC_PATH_PROG([GHC], [ghc])
  89   fi
  90   WithGhc="$GHC"])
  91
  92
  93 dnl ** Tell the make system which OS we are using
  94 dnl $OSTYPE is set by the operating system to "msys" or "cygwin" or something
  95 AC_SUBST(OSTYPE)
  96
  97 dnl ** Booting from .hc files?
  98 dnl --------------------------------------------------------------
  99 AC_ARG_ENABLE(hc-boot,
 100 [AC_HELP_STRING([--enable-hc-boot],
 101 [Boot the Glasgow Haskell Compiler from intermediate .hc files.
 102  (This option is mostly of interest to porters.) [default=no]])],
 103 [ if test x"$enableval" = x"yes"; then
 104         BootingFromHc=YES
 105   else
 106         BootingFromHc=NO
 107   fi
 108 ],
 109 [BootingFromHc=NO]
 110 )
 111 AC_SUBST(BootingFromHc)
 112
 113 AC_ARG_ENABLE(bootstrap-with-devel-snapshot,
 114 [AC_HELP_STRING([--enable-bootstrap-with-devel-snapshot],
 115                 [Allow bootstrapping using a development snapshot of GHC.  This is not guaranteed to work.])],
 116         EnableBootstrapWithDevelSnaphost=YES,
 117         EnableBootstrapWithDevelSnaphost=NO
 118 )
 119
 120 if test "$WithGhc" != ""; then
 121   FPTOOLS_GHC_VERSION([GhcVersion], [GhcMajVersion], [GhcMinVersion], [GhcPatchLevel])dnl
 122
 123   if test "$GhcMajVersion" = "unknown" -o "$GhcMinVersion" = "unknown"; then
 124      AC_MSG_ERROR([Cannot determine the version of $WithGhc.  Is it really GHC?])
 125   fi
 126
 127   AC_SUBST(GhcVersion)dnl
 128   AC_SUBST(GhcMajVersion)dnl
 129   AC_SUBST(GhcMinVersion)dnl
 130   AC_SUBST(GhcPatchLevel)dnl
 131   GhcMinVersion2=`echo "$GhcMinVersion" | sed 's/^\\(.\\)$/0\\1/'`
 132   GhcCanonVersion="$GhcMajVersion$GhcMinVersion2"
 133   if test $GhcCanonVersion -ge 613; then ghc_ge_613=YES; else ghc_ge_613=NO; fi
 134   AC_SUBST(ghc_ge_613)dnl
 135
 136   BOOTSTRAPPING_GHC_INFO_FIELD([CC_STAGE0],[C compiler command],['$(CC)'])
 137   BOOTSTRAPPING_GHC_INFO_FIELD([AR_STAGE0],[ar command],['$(AR)'])
 138   BOOTSTRAPPING_GHC_INFO_FIELD([AR_OPTS_STAGE0],[ar flags],['$(AR_OPTS)'])
 139   BOOTSTRAPPING_GHC_INFO_FIELD([ArSupportsAtFile_STAGE0],[ar supports at file],['$(ArSupportsAtFile)'])
 140 fi
 141
 142 dnl ** Must have GHC to build GHC, unless --enable-hc-boot is on
 143 if test "$BootingFromHc" = "NO"; then
 144   if test "$WithGhc" = ""; then
 145      AC_MSG_ERROR([GHC is required unless bootstrapping from .hc files.])
 146   fi
 147   FP_COMPARE_VERSIONS([$GhcVersion],[-lt],[6.12],
 148     [AC_MSG_ERROR([GHC version 6.12 or later is required to compile GHC.])])dnl
 149
 150   if test `expr $GhcMinVersion % 2` = "1"; then
 151      if test "$EnableBootstrapWithDevelSnaphost" = "NO"; then
 152         AC_MSG_ERROR([
 153      $WithGhc is a development snapshot of GHC, version $GhcVersion.
 154      Bootstrapping using this version of GHC is not supported, and may not
 155      work.  Use --enable-bootstrap-with-devel-snapshot to try it anyway,
 156      or --with-ghc to specify a different GHC to use.])
 157      fi
 158   fi
 159 fi;
 160
 161 # GHC is passed to Cabal, so we need a native path
 162 if test "${WithGhc}" != ""
 163 then
 164     ghc_host=`"${WithGhc}" +RTS --info | grep 'Host platform' | sed -e 's/.*, "//' -e 's/")//'`
 165
 166     if test "$ghc_host" = "i386-unknown-mingw32"
 167     then
 168         if test "${OSTYPE}" = "msys"
 169         then
 170             WithGhc=`echo "${WithGhc}" | sed "s#^/\([a-zA-Z]\)/#\1:/#"`
 171         else
 172             # Canonicalise to <drive>:/path/to/ghc
 173             WithGhc=`cygpath -m "${WithGhc}"`
 174         fi
 175         echo "GHC path canonicalised to: ${WithGhc}"
 176     fi
 177 fi
 178 AC_SUBST([WithGhc])
 179
 180 dnl ** Without optimization some INLINE trickery fails for GHCi
 181 SRC_CC_OPTS="-O"
 182
 183 FP_ICONV
 184 FP_GMP
 185
 186 dnl--------------------------------------------------------------------
 187 dnl * Choose host(/target/build) platform
 188 dnl--------------------------------------------------------------------
 189 dnl If we aren't explicitly told what values to use with configure flags,
 190 dnl we ask the bootstrapping compiler what platform it is for
 191
 192 if test "${WithGhc}" != ""
 193 then
 194         bootstrap_host=`"${WithGhc}" +RTS --info | grep '^ ,("Host platform"' | sed -e 's/.*, "//' -e 's/")//' | tr -d '\r'`
 195         bootstrap_target=`"${WithGhc}" +RTS --info | grep '^ ,("Target platform"' | sed -e 's/.*, "//' -e 's/")//' | tr -d '\r'`
 196         if test "$bootstrap_host" != "$bootstrap_target"
 197         then
 198                 echo "Bootstrapping GHC is a cross compiler. This probably isn't going to work"
 199         fi
 200 fi
 201
 202 # We have to run these unconditionally, but we may discard their
 203 # results in the following code
 204 AC_CANONICAL_BUILD
 205 AC_CANONICAL_HOST
 206 AC_CANONICAL_TARGET
 207
 208 FPTOOLS_SET_PLATFORM_VARS
 209
 210 exeext=''
 211 soext='.so'
 212 case $host in
 213 *-unknown-cygwin32)
 214     AC_MSG_WARN([GHC does not support the Cygwin target at the moment])
 215     AC_MSG_WARN([I'm assuming you wanted to build for i386-unknown-mingw32])
 216     exit 1
 217     ;;
 218 *-unknown-mingw32)
 219     exeext='.exe'
 220     soext='.dll'
 221     ;;
 222 i386-apple-darwin|powerpc-apple-darwin)
 223     soext='.dylib'
 224     ;;
 225 x86_64-apple-darwin)
 226     soext='.dylib'
 227     ;;
 228 esac
 229
 230 # Testing if we shall enable shared libs support on Solaris.
 231 # Anything older than SunOS 5.11 aka Solaris 11 (Express) is broken.
 232
 233 SOLARIS_BROKEN_SHLD=NO
 234
 235 case $host in
 236      i386-*-solaris2)
 237      # here we go with the test
 238      MINOR=`uname -r|cut -d '.' -f 2-`
 239      if test "$MINOR" -lt "11"; then
 240         SOLARIS_BROKEN_SHLD=YES
 241      fi
 242      ;;
 243 esac
 244
 245 # Sync this with cTargetArch in compiler/ghc.mk
 246 checkArch() {
 247     case $1 in
 248     alpha|arm|hppa|hppa1_1|i386|ia64|m68k|mips|mipseb|mipsel|powerpc|powerpc64|rs6000|s390|sparc|sparc64|vax|x86_64)
 249         ;;
 250     *)
 251         echo "Unknown arch $1"
 252         exit 1
 253         ;;
 254     esac
 255 }
 256
 257 checkVendor() {
 258     case $1 in
 259     dec|unknown|hp|apple|next|sun|sgi|ibm)
 260         ;;
 261     *)
 262         echo "Unknown vendor $1"
 263         exit 1
 264         ;;
 265     esac
 266 }
 267
 268 checkOS() {
 269     case $1 in
 270     linux|freebsd|netbsd|openbsd|dragonfly|osf1|osf3|hpux|linuxaout|kfreebsdgnu|freebsd2|solaris2|cygwin32|mingw32|darwin|gnu|nextstep2|nextstep3|sunos4|ultrix|irix|aix|haiku)
 271         ;;
 272     *)
 273         echo "Unknown OS '$1'"
 274         exit 1
 275         ;;
 276     esac
 277 }
 278
 279 BuildPlatform="$BuildArch-$BuildVendor-$BuildOS"
 280 BuildPlatform_CPP=`echo "$BuildPlatform" | sed -e 's/\./_/g' -e 's/-/_/g'`
 281 BuildArch_CPP=`    echo "$BuildArch"     | sed -e 's/\./_/g' -e 's/-/_/g'`
 282 BuildVendor_CPP=`  echo "$BuildVendor"   | sed -e 's/\./_/g' -e 's/-/_/g'`
 283 BuildOS_CPP=`      echo "$BuildOS"       | sed -e 's/\./_/g' -e 's/-/_/g'`
 284
 285 checkArch "$BuildArch"
 286 checkVendor "$BuildVendor"
 287 checkOS "$BuildOS"
 288
 289 HostPlatform="$HostArch-$HostVendor-$HostOS"
 290 HostPlatform_CPP=`echo "$HostPlatform" | sed -e 's/\./_/g' -e 's/-/_/g'`
 291 HostArch_CPP=`    echo "$HostArch"     | sed -e 's/\./_/g' -e 's/-/_/g'`
 292 HostVendor_CPP=`  echo "$HostVendor"   | sed -e 's/\./_/g' -e 's/-/_/g'`
 293 HostOS_CPP=`      echo "$HostOS"       | sed -e 's/\./_/g' -e 's/-/_/g'`
 294
 295 checkArch "$HostArch"
 296 checkVendor "$HostVendor"
 297 checkOS "$HostOS"
 298
 299 TargetPlatform="$TargetArch-$TargetVendor-$TargetOS"
 300 TargetPlatform_CPP=`echo "$TargetPlatform" | sed -e 's/\./_/g' -e 's/-/_/g'`
 301 TargetArch_CPP=`    echo "$TargetArch"     | sed -e 's/\./_/g' -e 's/-/_/g'`
 302 TargetVendor_CPP=`  echo "$TargetVendor"   | sed -e 's/\./_/g' -e 's/-/_/g'`
 303 TargetOS_CPP=`      echo "$TargetOS"       | sed -e 's/\./_/g' -e 's/-/_/g'`
 304
 305 checkArch "$TargetArch"
 306 checkVendor "$TargetVendor"
 307 checkOS "$TargetOS"
 308
 309 # Verify that the installed (bootstrap) GHC is capable of generating
 310 # code for the requested build platform.
 311 if test "$BootingFromHc" = "NO"
 312 then
 313     if test "$BuildPlatform" != "$bootstrap_target"
 314     then
 315         echo "This GHC (${WithGhc}) does not generate code for the build platform"
 316         echo "   GHC target platform    : $bootstrap_target"
 317         echo "   Desired build platform : $BuildPlatform"
 318         exit 1
 319     fi
 320 fi
 321
 322 echo "GHC build  : $BuildPlatform"
 323 echo "GHC host   : $HostPlatform"
 324 echo "GHC target : $TargetPlatform"
 325
 326 AC_SUBST(BuildPlatform)
 327 AC_SUBST(HostPlatform)
 328 AC_SUBST(TargetPlatform)
 329 AC_SUBST(HostPlatform_CPP)
 330 AC_SUBST(BuildPlatform_CPP)
 331 AC_SUBST(TargetPlatform_CPP)
 332
 333 AC_SUBST(HostArch_CPP)
 334 AC_SUBST(BuildArch_CPP)
 335 AC_SUBST(TargetArch_CPP)
 336
 337 AC_SUBST(HostOS_CPP)
 338 AC_SUBST(BuildOS_CPP)
 339 AC_SUBST(TargetOS_CPP)
 340
 341 AC_SUBST(HostVendor_CPP)
 342 AC_SUBST(BuildVendor_CPP)
 343 AC_SUBST(TargetVendor_CPP)
 344
 345 AC_SUBST(exeext)
 346 AC_SUBST(soext)
 347
 348 AC_SUBST(SOLARIS_BROKEN_SHLD)
 349
 350 AC_ARG_WITH(hc,
 351 [AC_HELP_STRING([--with-hc=ARG],
 352         [Use ARG as the path to the compiler for compiling ordinary
 353          Haskell code  (default= value of --with-ghc)])],
 354 [WithHc="$withval"],
 355 [WithHc=$WithGhc]
 356 )
 357 AC_SUBST(WithHc)
 358
 359 # This uses GHC, so put it after the "GHC is required" check above:
 360 FP_INTREE_GHC_PWD
 361 FP_FIND_ROOT
 362
 363 if test "$HostOS" = "mingw32"
 364 then
 365     test -d inplace || mkdir inplace
 366
 367     CC="$hardtop/inplace/mingw/bin/gcc.exe"
 368     LD="$hardtop/inplace/mingw/bin/ld.exe"
 369     NM="$hardtop/inplace/mingw/bin/nm.exe"
 370     fp_prog_ar_raw="$hardtop/inplace/mingw/bin/ar.exe"
 371
 372     # NB. If you update the tarbballs to a new version of gcc, don't
 373     # forget to tweak the paths in driver/gcc/gcc.c.
 374     if ! test -d inplace/mingw ||
 375          test inplace/mingw -ot ghc-tarballs/mingw/binutils*.tar.lzma  ||
 376          test inplace/mingw -ot ghc-tarballs/mingw/gcc-core*.tar.lzma  ||
 377          test inplace/mingw -ot ghc-tarballs/mingw/gcc-c++*.tar.lzma   ||
 378          test inplace/mingw -ot ghc-tarballs/mingw/libgcc*.tar.gz      ||
 379          test inplace/mingw -ot ghc-tarballs/mingw/libgmp*.tar.gz      ||
 380          test inplace/mingw -ot ghc-tarballs/mingw/libmpc*.tar.gz      ||
 381          test inplace/mingw -ot ghc-tarballs/mingw/libmpfr*.tar.gz     ||
 382          test inplace/mingw -ot ghc-tarballs/mingw/libstdc*.tar.lzma   ||
 383          test inplace/mingw -ot ghc-tarballs/mingw/mingwrt*-dev.tar.gz ||
 384          test inplace/mingw -ot ghc-tarballs/mingw/mingwrt*-dll.tar.gz ||
 385          test inplace/mingw -ot ghc-tarballs/mingw/w32api*.tar.lzma
 386     then
 387         AC_MSG_NOTICE([Making in-tree mingw tree])
 388         rm -rf inplace/mingw
 389         mkdir inplace/mingw
 390         (
 391             cd inplace/mingw &&
 392             tar --lzma -xf ../../ghc-tarballs/mingw/binutils*.tar.lzma  &&
 393             tar --lzma -xf ../../ghc-tarballs/mingw/gcc-core*.tar.lzma  &&
 394             tar --lzma -xf ../../ghc-tarballs/mingw/gcc-c++*.tar.lzma   &&
 395             tar --lzma -xf ../../ghc-tarballs/mingw/libgcc*.tar.lzma    &&
 396             tar --lzma -xf ../../ghc-tarballs/mingw/libgmp*.tar.lzma    &&
 397             tar --lzma -xf ../../ghc-tarballs/mingw/libmpc*.tar.lzma    &&
 398             tar --lzma -xf ../../ghc-tarballs/mingw/libmpfr*.tar.lzma   &&
 399             tar --lzma -xf ../../ghc-tarballs/mingw/libstdc*.tar.lzma   &&
 400             tar -z     -xf ../../ghc-tarballs/mingw/mingwrt*-dev.tar.gz &&
 401             tar -z     -xf ../../ghc-tarballs/mingw/mingwrt*-dll.tar.gz &&
 402             tar --lzma -xf ../../ghc-tarballs/mingw/w32api*.tar.lzma    &&
 403             mv bin/gcc.exe bin/realgcc.exe
 404         )
 405         PATH=`pwd`/inplace/mingw/bin:$PATH inplace/mingw/bin/realgcc.exe driver/gcc/gcc.c driver/utils/cwrapper.c driver/utils/getLocation.c -Idriver/utils -o inplace/mingw/bin/gcc.exe
 406         if ! test -e inplace/mingw/bin/gcc.exe
 407         then
 408             AC_MSG_ERROR([GHC is required unless bootstrapping from .hc files.])
 409         fi
 410         AC_MSG_NOTICE([In-tree mingw tree created])
 411     fi
 412     if ! test -d inplace/perl ||
 413          test inplace/perl -ot ghc-tarballs/perl/ghc-perl*.tar.gz
 414     then
 415         AC_MSG_NOTICE([Making in-tree perl tree])
 416         rm -rf inplace/perl
 417         mkdir inplace
 418         mkdir inplace/perl
 419         (
 420             cd inplace/perl &&
 421             tar -zxf ../../ghc-tarballs/perl/ghc-perl*.tar.gz
 422         )
 423         AC_MSG_NOTICE([In-tree perl tree created])
 424     fi
 425 fi
 426
 427 dnl ** Which gcc to use?
 428 dnl --------------------------------------------------------------
 429 FP_ARG_WITH_PATH_GNU_PROG([CC], [gcc])
 430 export CC
 431 WhatGccIsCalled="$CC"
 432 AC_SUBST(WhatGccIsCalled)
 433
 434 dnl ** Which ld to use?
 435 dnl --------------------------------------------------------------
 436 FP_ARG_WITH_PATH_GNU_PROG([LD], [ld])
 437 LdCmd="$LD"
 438 AC_SUBST([LdCmd])
 439
 440 dnl ** Which nm to use?
 441 dnl --------------------------------------------------------------
 442 FP_ARG_WITH_PATH_GNU_PROG([NM], [nm])
 443 NmCmd="$NM"
 444 AC_SUBST([NmCmd])
 445
 446 SplitObjsBroken=NO
 447 if test "$TargetOS_CPP" = "darwin"
 448 then
 449     AC_MSG_CHECKING(XCode version)
 450     XCodeVersion=`xcodebuild -version | grep Xcode | sed "s/Xcode //"`
 451     # Old XCode versions don't actually give the XCode version
 452     if test "$XCodeVersion" = ""
 453     then
 454         AC_MSG_RESULT(not found (too old?))
 455         SplitObjsBroken=YES
 456     else
 457         AC_MSG_RESULT($XCodeVersion)
 458         XCodeVersion1=`echo "$XCodeVersion" | sed 's/\..*//'`
 459 changequote(, )dnl
 460         XCodeVersion2=`echo "$XCodeVersion" | sed 's/[^.]*\.\([^.]*\).*/\1/'`
 461 changequote([, ])dnl
 462         AC_MSG_NOTICE(XCode version component 1: $XCodeVersion1)
 463         AC_MSG_NOTICE(XCode version component 2: $XCodeVersion2)
 464         # Split objects is broken (#4013) with XCode < 3.2
 465         if test "$XCodeVersion1" -lt 3
 466         then
 467             SplitObjsBroken=YES
 468         else
 469             if test "$XCodeVersion1" -eq 3
 470             then
 471                 if test "$XCodeVersion2" -lt 2
 472                 then
 473                     SplitObjsBroken=YES
 474                 fi
 475             fi
 476         fi
 477     fi
 478 fi
 479 AC_SUBST([SplitObjsBroken])
 480
 481 dnl ** Mac OS X: explicit deployment target
 482 dnl --------------------------------------------------------------
 483 AC_ARG_WITH([macosx-deployment-target],
 484 [AC_HELP_STRING([--with-macosx-deployment-target=VERSION],
 485         [Build for Mac OS VERSION and higher  (default= version of build host)])],
 486 [FP_MACOSX_DEPLOYMENT_TARGET="$withval"
 487  if test "x$TargetOS_CPP-$TargetVendor_CPP" != "xdarwin-apple"; then
 488    # ignore everywhere, but on Mac OS
 489    AC_MSG_WARN([--macosx-deployment-target is only available on Mac OS X])
 490    FP_MACOSX_DEPLOYMENT_TARGET=none
 491  fi],
 492 [FP_MACOSX_DEPLOYMENT_TARGET=none]
 493 )
 494 FP_CHECK_MACOSX_DEPLOYMENT_TARGET
 495 AC_SUBST(MACOSX_DEPLOYMENT_VERSION)
 496 AC_SUBST(MACOSX_DEPLOYMENT_SDK)
 497
 498 dnl --------------------------------------------------------------
 499 dnl End of configure script option section
 500 dnl --------------------------------------------------------------
 501
 502
 503 dnl --------------------------------------------------------------
 504 dnl * General configuration checks
 505 dnl --------------------------------------------------------------
 506
 507 dnl ** Can the unix package be built?
 508 dnl --------------------------------------------------------------
 509
 510 if test x"$TargetPlatform" = x"i386-unknown-mingw32"; then
 511    GhcLibsWithUnix=NO
 512 else
 513    GhcLibsWithUnix=YES
 514 fi
 515 AC_SUBST([GhcLibsWithUnix])
 516
 517 dnl ** does #! work?
 518 AC_SYS_INTERPRETER()
 519
 520 dnl ** look for `perl'
 521 case $HostOS_CPP in
 522 cygwin32|mingw32)
 523     PerlCmd=$hardtop/inplace/perl/perl
 524     ;;
 525 *)
 526     AC_PATH_PROG(PerlCmd,perl)
 527     if test -z "$PerlCmd"
 528     then
 529         echo "You must install perl before you can continue"
 530         echo "Perhaps it is already installed, but not in your PATH?"
 531         exit 1
 532     else
 533         FPTOOLS_CHECK_PERL_VERSION
 534     fi
 535     ;;
 536 esac
 537
 538 dnl ** does #! path/to/perl work? (sometimes it's too long...)
 539 FPTOOLS_SHEBANG_PERL
 540
 541 dnl ** check for Python
 542 AC_PATH_PROG(PythonCmd,python)
 543
 544 dnl ** look for GCC and find out which version
 545 dnl     Figure out which C compiler to use.  Gcc is preferred.
 546 dnl     If gcc, make sure it's at least 2.1
 547 dnl
 548 FP_GCC_VERSION
 549
 550 FPTOOLS_SET_C_LD_FLAGS([target],[CFLAGS],[LDFLAGS],[IGNORE_LINKER_LD_FLAGS],[CPPFLAGS])
 551 FPTOOLS_SET_C_LD_FLAGS([build],[CONF_CC_OPTS_STAGE0],[CONF_GCC_LINKER_OPTS_STAGE0],[CONF_LD_LINKER_OPTS_STAGE0],[CONF_CPP_OPTS_STAGE0])
 552 FPTOOLS_SET_C_LD_FLAGS([target],[CONF_CC_OPTS_STAGE1],[CONF_GCC_LINKER_OPTS_STAGE1],[CONF_LD_LINKER_OPTS_STAGE1],[CONF_CPP_OPTS_STAGE1])
 553 # Stage 3 won't be supported by cross-compilation
 554 FPTOOLS_SET_C_LD_FLAGS([target],[CONF_CC_OPTS_STAGE2],[CONF_GCC_LINKER_OPTS_STAGE2],[CONF_LD_LINKER_OPTS_STAGE2],[CONF_CPP_OPTS_STAGE2])
 555
 556 FP_GCC_EXTRA_FLAGS
 557
 558 dnl ** figure out how to invoke cpp directly (gcc -E is no good)
 559 AC_PROG_CPP
 560
 561 AC_SUBST(CONF_CC_OPTS_STAGE0)
 562 AC_SUBST(CONF_CC_OPTS_STAGE1)
 563 AC_SUBST(CONF_CC_OPTS_STAGE2)
 564 AC_SUBST(CONF_GCC_LINKER_OPTS_STAGE0)
 565 AC_SUBST(CONF_GCC_LINKER_OPTS_STAGE1)
 566 AC_SUBST(CONF_GCC_LINKER_OPTS_STAGE2)
 567 AC_SUBST(CONF_LD_LINKER_OPTS_STAGE0)
 568 AC_SUBST(CONF_LD_LINKER_OPTS_STAGE1)
 569 AC_SUBST(CONF_LD_LINKER_OPTS_STAGE2)
 570 AC_SUBST(CONF_CPP_OPTS_STAGE0)
 571 AC_SUBST(CONF_CPP_OPTS_STAGE1)
 572 AC_SUBST(CONF_CPP_OPTS_STAGE2)
 573
 574 dnl ** figure out how to do context diffs
 575 FP_PROG_CONTEXT_DIFF
 576
 577 dnl Let's make sure install-sh is executable here.  If we got it from
 578 dnl a darcs repo, it might not be (see bug #978).
 579 chmod +x install-sh
 580 dnl ** figure out how to do a BSD-ish install
 581 AC_PROG_INSTALL
 582
 583 dnl If you can run configure, you certainly have /bin/sh
 584 AC_DEFINE([HAVE_BIN_SH], [1], [Define to 1 if you have /bin/sh.])
 585
 586 dnl ** how to invoke `ar' and `ranlib'
 587 FP_PROG_AR_SUPPORTS_ATFILE
 588 FP_PROG_AR_NEEDS_RANLIB
 589
 590 dnl ** Check to see whether ln -s works
 591 AC_PROG_LN_S
 592
 593
 594 dnl ** Find the path to sed
 595 AC_PATH_PROGS(SedCmd,gsed sed,sed)
 596
 597
 598 dnl ** check for time command
 599 AC_PATH_PROG(TimeCmd,time)
 600
 601 dnl ** check for tar
 602 dnl   if GNU tar is named gtar, look for it first.
 603 AC_PATH_PROGS(TarCmd,gnutar gtar tar,tar)
 604
 605 dnl ** check for patch
 606 dnl if GNU patch is named gpatch, look for it first
 607 AC_PATH_PROGS(PatchCmd,gpatch patch, patch)
 608
 609 dnl ** check for dtrace (currently only implemented for Mac OS X)
 610 HaveDtrace=NO
 611 AC_PATH_PROG(DtraceCmd,dtrace)
 612 if test -n "$DtraceCmd"; then
 613   if test "x$TargetOS_CPP-$TargetVendor_CPP" == "xdarwin-apple" -o "x$TargetOS_CPP-$TargetVendor_CPP" == "xsolaris2-unknown"; then
 614     HaveDtrace=YES
 615   fi
 616 fi
 617 AC_SUBST(HaveDtrace)
 618
 619 AC_PATH_PROG(HSCOLOUR,HsColour)
 620 # HsColour is passed to Cabal, so we need a native path
 621 if test "x$HostPlatform"  = "xi386-unknown-mingw32" && \
 622    test "${OSTYPE}"      != "msys"                  && \
 623    test "${HSCOLOUR}"    != ""
 624 then
 625     # Canonicalise to <drive>:/path/to/gcc
 626     HSCOLOUR=`cygpath -m ${HSCOLOUR}`
 627 fi
 628
 629 dnl ** check for DocBook toolchain
 630 FP_CHECK_DOCBOOK_DTD
 631 FP_DOCBOOK_XSL
 632 FP_PROG_DBLATEX
 633
 634 FP_PROG_HSTAGS
 635
 636 dnl ** check for ghc-pkg command
 637 FP_PROG_GHC_PKG
 638
 639 dnl ** check for installed happy binary + version
 640 dnl    (don't do it if we're booting from .hc files though.)
 641 if test "$BootingFromHc" = "NO"; then
 642 FPTOOLS_HAPPY
 643 fi;
 644
 645 dnl ** check for installed alex binary + version
 646 dnl    (don't do it if we're booting from .hc files though.)
 647 if test "$BootingFromHc" = "NO"; then
 648 FPTOOLS_ALEX
 649 fi;
 650
 651 dnl --------------------------------------------------
 652 dnl ### program checking section ends here ###
 653 dnl --------------------------------------------------
 654
 655 dnl --------------------------------------------------
 656 dnl * Platform header file and syscall feature tests
 657 dnl ### checking the state of the local header files and syscalls ###
 658
 659 dnl ** check for full ANSI header (.h) files
 660 AC_HEADER_STDC
 661
 662 dnl ** Enable large file support.  NB. do this before testing the type of
 663 dnl    off_t, because it will affect the result of that test.
 664 AC_SYS_LARGEFILE
 665
 666 dnl ** check for specific header (.h) files that we are interested in
 667 AC_CHECK_HEADERS([bfd.h ctype.h dirent.h dlfcn.h errno.h fcntl.h grp.h limits.h locale.h nlist.h pthread.h pwd.h signal.h sys/cpuset.h sys/mman.h sys/resource.h sys/select.h sys/time.h sys/timeb.h sys/timers.h sys/times.h sys/utsname.h sys/wait.h termios.h time.h utime.h windows.h winsock.h sched.h])
 668
 669 dnl ** check if it is safe to include both <time.h> and <sys/time.h>
 670 AC_HEADER_TIME
 671
 672 dnl ** do we have long longs?
 673 AC_CHECK_TYPES([long long])
 674
 675 dnl ** what are the sizes of various types
 676 AC_CHECK_SIZEOF(char,               1)
 677 AC_CHECK_SIZEOF(double,             8)
 678 AC_CHECK_SIZEOF(float,              4)
 679 AC_CHECK_SIZEOF(int,                4)
 680 AC_CHECK_SIZEOF(long,               4)
 681 if test "$ac_cv_type_long_long" = yes; then
 682 AC_CHECK_SIZEOF(long long,          8)
 683 fi
 684 AC_CHECK_SIZEOF(short,              2)
 685 AC_CHECK_SIZEOF(unsigned char,      1)
 686 AC_CHECK_SIZEOF(unsigned int,       4)
 687 AC_CHECK_SIZEOF(unsigned long,      4)
 688 if test "$ac_cv_type_long_long" = yes; then
 689 AC_CHECK_SIZEOF(unsigned long long, 8)
 690 fi
 691 AC_CHECK_SIZEOF(unsigned short,     2)
 692 AC_CHECK_SIZEOF(void *,             4)
 693
 694 dnl ** what are alignment constraints on various types
 695 FP_CHECK_ALIGNMENT(char)
 696 FP_CHECK_ALIGNMENT(double)
 697 FP_CHECK_ALIGNMENT(float)
 698 FP_CHECK_ALIGNMENT(int)
 699 FP_CHECK_ALIGNMENT(long)
 700 if test "$ac_cv_type_long_long" = yes; then
 701 FP_CHECK_ALIGNMENT(long long)
 702 fi
 703 FP_CHECK_ALIGNMENT(short)
 704 FP_CHECK_ALIGNMENT(unsigned char)
 705 FP_CHECK_ALIGNMENT(unsigned int)
 706 FP_CHECK_ALIGNMENT(unsigned long)
 707 if test "$ac_cv_type_long_long" = yes; then
 708 FP_CHECK_ALIGNMENT(unsigned long long)
 709 fi
 710 FP_CHECK_ALIGNMENT(unsigned short)
 711 FP_CHECK_ALIGNMENT(void *)
 712
 713 FP_CHECK_FUNC([WinExec],
 714   [@%:@include <windows.h>], [WinExec("",0)])
 715
 716 FP_CHECK_FUNC([GetModuleFileName],
 717   [@%:@include <windows.h>], [GetModuleFileName((HMODULE)0,(LPTSTR)0,0)])
 718
 719 dnl ** check return type of signal handlers
 720 dnl Foo: assumes we can use prototypes.
 721 dnl On BCC, signal handlers have type "int(void)", elsewhere its "void(int)".
 722 dnl AC_CACHE_CHECK([type of signal handlers], ac_cv_type_signal_handler,
 723 dnl [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 724 dnl #include <signal.h>
 725 dnl #ifdef signal
 726 dnl #undef signal
 727 dnl #endif
 728 dnl void (*signal (int, void (*)(int)))(int);
 729 dnl ]],
 730 dnl [[int i;]])],
 731 dnl [ac_cv_type_signal_handler=void_int],
 732 dnl [ac_cv_type_signal_handler=int_void])])
 733 dnl if test "$ac_cv_type_signal_handler" = void_int; then
 734 dnl AC_DEFINE(VOID_INT_SIGNALS)
 735 dnl fi
 736
 737 dnl On BCC, signal handlers have type "int(void)", elsewhere its "void(int)".
 738 AC_TYPE_SIGNAL
 739 if test "$ac_cv_type_signal" = void; then
 740   AC_DEFINE([VOID_INT_SIGNALS], [1], [Define to 1 if signal handlers have type void (*)(int). Otherwise, they're assumed to have type int (*)(void).])
 741 fi
 742
 743 dnl ** check for more functions
 744 dnl ** The following have been verified to be used in ghc/, but might be used somewhere else, too.
 745 AC_CHECK_FUNCS([getclock getrusage gettimeofday setitimer siginterrupt sysconf times ctime_r sched_setaffinity setlocale])
 746
 747 AC_TRY_RUN([
 748 #include <sys/types.h>
 749 #include <sys/time.h>
 750 int main(void) {
 751   struct itimerval tval;
 752   tval.it_value.tv_sec = 1;
 753   tval.it_value.tv_usec = 0;
 754   tval.it_interval = tval.it_value;
 755   return setitimer(ITIMER_VIRTUAL, &tval, (void*)0) != 0;
 756 }
 757 ],[AC_DEFINE([HAVE_SETITIMER_VIRTUAL], [1], [Define to 1 if setitimer accepts ITIMER_VIRTUAL, 0 else.])])
 758
 759 dnl ** On OS X 10.4 (at least), time.h doesn't declare ctime_r if
 760 dnl ** _POSIX_C_SOURCE is defined
 761 AC_CHECK_DECLS([ctime_r], , ,
 762 [#define _POSIX_SOURCE 1
 763 #define _POSIX_C_SOURCE 199506L
 764 #include <time.h>])
 765
 766 dnl ** check for mingwex library
 767 AC_CHECK_LIB(mingwex, closedir, HaveLibMingwEx=YES, HaveLibMingwEx=NO)
 768 AC_SUBST(HaveLibMingwEx)
 769
 770 if test $HaveLibMingwEx = YES ; then
 771   AC_DEFINE([HAVE_MINGWEX], [1], [Define to 1 if you have the mingwex library.])
 772 fi
 773
 774 dnl ** check for math library
 775 dnl    Keep that check as early as possible.
 776 dnl    as we need to know whether we need libm
 777 dnl    for math functions or not
 778 dnl    (see http://hackage.haskell.org/trac/ghc/ticket/3730)
 779 AC_CHECK_LIB(m, atan, HaveLibM=YES, HaveLibM=NO)
 780 if test $HaveLibM = YES
 781 then
 782   AC_DEFINE([HAVE_LIBM], [1], [Define to 1 if you need to link with libm])
 783 fi
 784
 785 dnl ** check whether this machine has BFD and liberty installed (used for debugging)
 786 dnl    the order of these tests matters: bfd needs liberty
 787 AC_CHECK_LIB(iberty, xmalloc)
 788 AC_CHECK_LIB(bfd,    bfd_init)
 789
 790 dnl ################################################################
 791 dnl Check for libraries
 792 dnl ################################################################
 793
 794 dnl ** check whether we need -ldl to get dlopen()
 795
 796 AC_CHECK_LIB(dl, dlopen,
 797     [HaveLibDL=YES
 798      AC_DEFINE([HAVE_LIBDL], [1], [Define to 1 if you need -ldl to get dlopen().])
 799      LIBS="$LIBS -ldl"],
 800     [HaveLibDL=NO])
 801 AC_SUBST(HaveLibDL)
 802
 803 dnl --------------------------------------------------
 804 dnl * Miscellaneous feature tests
 805 dnl --------------------------------------------------
 806
 807 dnl ** can we get alloca?
 808 AC_FUNC_ALLOCA
 809
 810 dnl ** Working vfork?
 811 AC_FUNC_FORK
 812
 813 dnl ** determine whether or not const works
 814 AC_C_CONST
 815
 816 dnl ** are we big endian?
 817 AC_C_BIGENDIAN
 818 FPTOOLS_FLOAT_WORD_ORDER_BIGENDIAN
 819
 820 dnl ** check for leading underscores in symbol names
 821 FP_LEADING_UNDERSCORE
 822
 823 dnl ** check for ld, whether it has an -x option, and if it is GNU ld
 824 FP_PROG_LD_X
 825 FP_PROG_LD_IS_GNU
 826 FP_PROG_LD_BUILD_ID
 827
 828 dnl ** check for Apple-style dead-stripping support
 829 dnl    (.subsections-via-symbols assembler directive)
 830
 831
 832 AC_MSG_CHECKING(for .subsections_via_symbols)
 833 AC_COMPILE_IFELSE(
 834     [AC_LANG_PROGRAM([], [__asm__ (".subsections_via_symbols");])],
 835     [AC_MSG_RESULT(yes)
 836      AC_DEFINE([HAVE_SUBSECTIONS_VIA_SYMBOLS],[1],
 837                [Define to 1 if Apple-style dead-stripping is supported.])
 838     ],
 839     [AC_MSG_RESULT(no)])
 840
 841 dnl *** check for GNU non-executable stack note support (ELF only)
 842 dnl     (.section .note.GNU-stack,"",@progbits)
 843
 844 dnl This test doesn't work with "gcc -g" in gcc 4.4 (GHC trac #3889:
 845 dnl     Error: can't resolve `.note.GNU-stack' {.note.GNU-stack section} - `.Ltext0' {.text section}
 846 dnl so we empty CFLAGS while running this test
 847 CFLAGS2="$CFLAGS"
 848 CFLAGS=
 849 AC_MSG_CHECKING(for GNU non-executable stack support)
 850 AC_COMPILE_IFELSE(
 851     [AC_LANG_PROGRAM([__asm__ (".section .note.GNU-stack,\"\",@progbits");], [0])],
 852     [AC_MSG_RESULT(yes)
 853      AC_DEFINE([HAVE_GNU_NONEXEC_STACK],[1],
 854                [Define to 1 if GNU non-executable stack notes are supported.])
 855     ],
 856     [AC_MSG_RESULT(no)])
 857 CFLAGS="$CFLAGS2"
 858
 859 FP_VISIBILITY_HIDDEN
 860
 861 dnl ** check for librt
 862 AC_CHECK_LIB(rt, clock_gettime)
 863 AC_CHECK_FUNCS(clock_gettime timer_create timer_settime)
 864 FP_CHECK_TIMER_CREATE
 865
 866 dnl ** check for Apple's "interesting" long double compatibility scheme
 867 AC_MSG_CHECKING(for printf\$LDBLStub)
 868 AC_TRY_LINK_FUNC(printf\$LDBLStub,
 869     [
 870         AC_MSG_RESULT(yes)
 871         AC_DEFINE([HAVE_PRINTF_LDBLSTUB],[1],
 872             [Define to 1 if we have printf$LDBLStub (Apple Mac OS >= 10.4, PPC).])
 873     ],
 874     [
 875         AC_MSG_RESULT(no)
 876         AC_DEFINE([HAVE_PRINTF_LDBLSTUB],[0],
 877             [Define to 1 if we have printf$LDBLStub (Apple Mac OS >= 10.4, PPC).])
 878     ])
 879
 880 dnl ** check for eventfd which is needed by the I/O manager
 881 AC_CHECK_HEADERS([sys/eventfd.h])
 882 AC_CHECK_FUNCS([eventfd])
 883
 884 # test for GTK+
 885 AC_PATH_PROGS([GTK_CONFIG], [pkg-config])
 886 if test -n "$GTK_CONFIG"; then
 887   if $GTK_CONFIG gtk+-2.0 --atleast-version=2.0; then
 888     GTK_CONFIG="$GTK_CONFIG gtk+-2.0"
 889   else
 890     AC_MSG_WARN([GTK+ not usable, need at least version 2.0])
 891     GTK_CONFIG=
 892   fi
 893 fi
 894 AC_SUBST([GTK_CONFIG])
 895
 896 #Checking for PAPI
 897 AC_CHECK_LIB(papi, PAPI_library_init, HavePapiLib=YES, HavePapiLib=NO)
 898 AC_CHECK_HEADER([papi.h], [HavePapiHeader=YES], [HavePapiHeader=NO])
 899 AC_SUBST(HavePapiLib)
 900 AC_SUBST(HavePapiHeader)
 901
 902 AC_CHECK_FUNCS(__mingw_vfprintf)
 903
 904 if test "$HavePapiLib" = "YES" -a "$HavePapiHeader" = "YES"; then
 905    HavePapi=YES
 906 else
 907    HavePapi=NO
 908 fi
 909 AC_SUBST(HavePapi)
 910
 911 if test "$HAVE_DOCBOOK_XSL" = "NO" ||
 912    test "$XsltprocCmd" = ""
 913 then
 914     BUILD_DOCBOOK_HTML=NO
 915 else
 916     BUILD_DOCBOOK_HTML=YES
 917 fi
 918 AC_SUBST(BUILD_DOCBOOK_HTML)
 919
 920 if test "$DblatexCmd" = ""
 921 then
 922     BUILD_DOCBOOK_PS=NO
 923     BUILD_DOCBOOK_PDF=NO
 924 else
 925     BUILD_DOCBOOK_PS=YES
 926     BUILD_DOCBOOK_PDF=YES
 927 fi
 928 AC_SUBST(BUILD_DOCBOOK_PS)
 929 AC_SUBST(BUILD_DOCBOOK_PDF)
 930
 931 LIBRARY_VERSION(base)
 932 LIBRARY_VERSION(Cabal)
 933 LIBRARY_VERSION(ghc-prim)
 934 LIBRARY_ghc_VERSION="$ProjectVersion"
 935 AC_SUBST(LIBRARY_ghc_VERSION)
 936
 937 if grep '       ' compiler/ghc.cabal.in 2>&1 >/dev/null; then
 938    AC_MSG_ERROR([compiler/ghc.cabal.in contains tab characters; please remove them])
 939 fi
 940
 941 AC_CONFIG_FILES([mk/config.mk mk/install.mk mk/project.mk compiler/ghc.cabal ghc/ghc-bin.cabal utils/runghc/runghc.cabal ghc.spec settings docs/users_guide/ug-book.xml docs/users_guide/ug-ent.xml docs/index.html libraries/prologue.txt distrib/ghc.iss distrib/configure.ac])
 942 AC_CONFIG_COMMANDS([mk/stamp-h],[echo timestamp > mk/stamp-h])
 943 AC_OUTPUT
 944
 945 # We get caught by
 946 #     http://savannah.gnu.org/bugs/index.php?1516
 947 #     $(eval ...) inside conditionals causes errors
 948 # with make 3.80, so warn the user if it looks like they're about to
 949 # try to use it.
 950 # We would use "grep -q" here, but Solaris's grep doesn't support it.
 951 checkMake380() {
 952     if $1 --version 2>&1 | head -1 | grep 'GNU Make 3\.80' > /dev/null
 953     then
 954         echo
 955         echo "WARNING: It looks like \"$1\" is GNU make 3.80."
 956         echo "This version cannot be used to build GHC."
 957         echo "Please use GNU make >= 3.81."
 958     fi
 959 }
 960
 961 checkMake380 make
 962 checkMake380 gmake
 963
 964 echo ["
 965 ----------------------------------------------------------------------
 966 Configure completed successfully.
 967
 968    Building GHC version  : $ProjectVersion
 969
 970    Build platform        : $BuildPlatform
 971    Host platform         : $HostPlatform
 972    Target platform       : $TargetPlatform
 973 "]
 974
 975 if test "$BootingFromHc" = "YES"; then
 976 echo ["\
 977    Bootstrapping from HC files.
 978 "]
 979 else
 980 echo ["\
 981    Bootstrapping using   : $WithGhc
 982       which is version   : $GhcVersion
 983 "]
 984 fi
 985
 986 echo ["\
 987    Using GCC             : $WhatGccIsCalled
 988       which is version   : $GccVersion
 989
 990    ld       : $LdCmd
 991    Happy    : $HappyCmd ($HappyVersion)
 992    Alex     : $AlexCmd ($AlexVersion)
 993    Python   : $PythonCmd
 994    Perl     : $PerlCmd
 995    dblatex  : $DblatexCmd
 996    xsltproc : $XsltprocCmd"]
 997
 998 if test "$HSCOLOUR" = ""; then
 999 echo ["
1000    HsColour was not found; documentation will not contain source links
1001 "]
1002 else
1003 echo ["\
1004    HsColour : $HSCOLOUR
1005 "]
1006 fi
1007
1008 echo ["\
1009    Building DocBook HTML documentation : $BUILD_DOCBOOK_HTML
1010    Building DocBook PS documentation   : $BUILD_DOCBOOK_PS
1011    Building DocBook PDF documentation  : $BUILD_DOCBOOK_PDF"]
1012
1013 echo ["----------------------------------------------------------------------
1014 "]
1015
1016 echo "\
1017 For a standard build of GHC (fully optimised with profiling), type (g)make.
1018
1019 To make changes to the default build configuration, copy the file
1020 mk/build.mk.sample to mk/build.mk, and edit the settings in there.
1021
1022 For more information on how to configure your GHC build, see
1023    http://hackage.haskell.org/trac/ghc/wiki/Building
1024 "