configure.ac

   1 dnl == autoconf source for the Glasgow FP tools ==
   2 dnl (run "grep '^dnl \*' configure.ac | sed -e 's/dnl / /g; s/\*\*/   +/g;'"
   3 dnl  (or some such) to see the outline of this file)
   4 dnl
   5 #
   6 # (c) The University of Glasgow 1994-2004
   7 #
   8 # Configure script template for GHC
   9 #
  10 # Process with 'autoreconf' to get a working configure script.
  11 #
  12 # For the generated configure script, do "./configure --help" to
  13 # see what flags are available. (Better yet, read the documentation!)
  14 #
  15
  16 AC_INIT([The Glorious Glasgow Haskell Compilation System], [6.13], [glasgow-haskell-bugs@haskell.org], [ghc])
  17
  18 # Set this to YES for a released version, otherwise NO
  19 : ${RELEASE=NO}
  20
  21 # The primary version (e.g. 6.7, 6.6.1) is set in the AC_INIT line
  22 # above.  If this is not a released version, then we will append the
  23 # date to the version number (e.g. 6.7.20070204).  The date is
  24 # constructed by finding the date of the most recent patch in the
  25 # darcs repository.  If this is a source distribution (not a darcs
  26 # checkout), then we ship a file 'VERSION' containing the full version
  27 # when the source distribution was created.
  28
  29 if test ! -f mk/config.h.in; then
  30    echo "mk/config.h.in doesn't exist: perhaps you haven't run 'perl boot'?"
  31    exit 1
  32 fi
  33
  34 AC_SUBST([CONFIGURE_ARGS], [$ac_configure_args])
  35
  36 dnl ----------------------------------------------------------
  37 dnl ** Find unixy sort and find commands,
  38 dnl ** which are needed by FP_SETUP_PROJECT_VERSION
  39
  40 dnl ** Find find command (for Win32's benefit)
  41 FP_PROG_FIND
  42
  43 dnl ** Find sort command (for the benefit of Win32 environs)
  44 FP_PROG_SORT
  45
  46 dnl ----------------------------------------------------------
  47 FP_SETUP_PROJECT_VERSION
  48
  49 # Hmmm, we fix the RPM release number to 1 here... Is this convenient?
  50 AC_SUBST([release], [1])
  51
  52 # First off, a distrib sanity check..
  53 AC_CONFIG_SRCDIR([mk/config.mk.in])
  54
  55 dnl * We require autoconf version 2.52
  56 dnl We need 2.50 due to the use of AC_SYS_LARGEFILE and AC_MSG_NOTICE.
  57 dnl We need 2.52 due to the use of AS_TR_CPP and AS_TR_SH.
  58 AC_PREREQ([2.52])
  59
  60 # -------------------------------------------------------------------------
  61 # Prepare to generate the following header files
  62 #
  63 #
  64 AC_CONFIG_HEADER(mk/config.h)
  65
  66 # No, semi-sadly, we don't do `--srcdir'...
  67 if test x"$srcdir" != 'x.' ; then
  68     echo "This configuration does not support the \`--srcdir' option.."
  69     exit 1
  70 fi
  71
  72 dnl --------------------------------------------------------------
  73 dnl * Project specific configuration options
  74 dnl --------------------------------------------------------------
  75 dnl What follows is a bunch of options that can either be configured
  76 dnl through command line options to the configure script or by
  77 dnl supplying defns in the build tree's mk/build.mk. Having the option to
  78 dnl use either is considered a Feature.
  79
  80 dnl ** What command to use to compile compiler sources ?
  81 dnl --------------------------------------------------------------
  82
  83 AC_ARG_WITH([ghc],
  84 [AC_HELP_STRING([--with-ghc=ARG],
  85   [Use ARG as the path to GHC  [default=autodetect]])],
  86   [WithGhc="$withval"],
  87   [if test "$GHC" = ""; then
  88     AC_PATH_PROG([GHC], [ghc])
  89   fi
  90   WithGhc="$GHC"])
  91
  92 dnl ** Booting from .hc files?
  93 dnl --------------------------------------------------------------
  94 AC_ARG_ENABLE(hc-boot,
  95 [AC_HELP_STRING([--enable-hc-boot],
  96 [Boot the Glasgow Haskell Compiler from intermediate .hc files.
  97  (This option is mostly of interest to porters.) [default=no]])],
  98 [ if test x"$enableval" = x"yes"; then
  99         BootingFromHc=YES
 100   else
 101         BootingFromHc=NO
 102   fi
 103 ],
 104 [BootingFromHc=NO]
 105 )
 106 AC_SUBST(BootingFromHc)
 107
 108 AC_ARG_ENABLE(bootstrap-with-devel-snapshot,
 109 [AC_HELP_STRING([--enable-bootstrap-with-devel-snapshot],
 110                 [Allow bootstrapping using a development snapshot of GHC.  This is not guaranteed to work.])],
 111         EnableBootstrapWithDevelSnaphost=YES,
 112         EnableBootstrapWithDevelSnaphost=NO
 113 )
 114
 115 if test "$WithGhc" != ""; then
 116   FPTOOLS_GHC_VERSION([GhcVersion], [GhcMajVersion], [GhcMinVersion], [GhcPatchLevel])dnl
 117
 118   if test "$GhcMajVersion" = "unknown" -o "$GhcMinVersion" = "unknown"; then
 119      AC_MSG_ERROR([Cannot determine the version of $WithGhc.  Is it really GHC?])
 120   fi
 121
 122   AC_SUBST(GhcVersion)dnl
 123   AC_SUBST(GhcMajVersion)dnl
 124   AC_SUBST(GhcMinVersion)dnl
 125   AC_SUBST(GhcPatchLevel)dnl
 126   GhcMinVersion2=`echo "$GhcMinVersion" | sed 's/^\\(.\\)$/0\\1/'`
 127   GhcCanonVersion="$GhcMajVersion$GhcMinVersion2"
 128   FP_COMPARE_VERSIONS($GhcVersion,[-ge],[6.10.2],
 129                       [ghc_ge_6102=YES], [ghc_ge_6102=NO])
 130   if test $GhcCanonVersion -ge 611; then ghc_ge_611=YES; else ghc_ge_611=NO; fi
 131   if test $GhcCanonVersion -ge 613; then ghc_ge_613=YES; else ghc_ge_613=NO; fi
 132   AC_SUBST(ghc_ge_6102)dnl
 133   AC_SUBST(ghc_ge_611)dnl
 134   AC_SUBST(ghc_ge_613)dnl
 135 fi
 136
 137 dnl ** Must have GHC to build GHC, unless --enable-hc-boot is on
 138 if test "$BootingFromHc" = "NO" -a -d "$srcdir/compiler"; then
 139   if test "$WithGhc" = ""; then
 140      AC_MSG_ERROR([GHC is required unless bootstrapping from .hc files.])
 141   fi
 142   FP_COMPARE_VERSIONS([$GhcVersion],[-lt],[6.10],
 143     [AC_MSG_ERROR([GHC version 6.10 or later is required to compile GHC.])])dnl
 144
 145   if test `expr $GhcMinVersion % 2` = "1"; then
 146      if test "$EnableBootstrapWithDevelSnaphost" = "NO"; then
 147         AC_MSG_ERROR([
 148      $WithGhc is a development snapshot of GHC, version $GhcVersion.
 149      Bootstrapping using this version of GHC is not supported, and may not
 150      work.  Use --enable-bootstrap-with-devel-snapshot to try it anyway,
 151      or --with-ghc to specify a different GHC to use.])
 152      fi
 153   fi
 154 fi;
 155
 156 # GHC is passed to Cabal, so we need a native path
 157 if test "${WithGhc}" != ""
 158 then
 159     ghc_host=`"${WithGhc}" +RTS --info | grep 'Host platform' | sed -e 's/.*, "//' -e 's/")//'`
 160
 161     if test "$ghc_host" = "i386-unknown-mingw32"
 162     then
 163         if test "${OSTYPE}" = "msys"
 164         then
 165             WithGhc=`echo "${WithGhc}" | sed "s#^/\([a-zA-Z]\)/#\1:/#"`
 166         else
 167             # Canonicalise to <drive>:/path/to/ghc
 168             WithGhc=`cygpath -m "${WithGhc}"`
 169         fi
 170         echo "GHC path canonicalised to: ${WithGhc}"
 171     fi
 172 fi
 173 AC_SUBST([WithGhc])
 174
 175 dnl ** Without optimization some INLINE trickery fails for GHCi
 176 SRC_CC_OPTS="-O"
 177
 178 dnl Allow to specify iconv options to the toplevel configure script
 179 dnl so they can be properly passed to sub-builds.
 180 dnl Note: ICONV_LIB_DIRS and ICONV_INCLUDE_DIRS are not predefined
 181 dnl to the empty string to allow them to be overridden from the
 182 dnl environment.
 183
 184 AC_ARG_WITH([iconv-includes],
 185   [AC_HELP_STRING([--with-iconv-includes],
 186     [directory containing iconv.h])],
 187     [ICONV_INCLUDE_DIRS=$withval])
 188
 189 AC_ARG_WITH([iconv-libraries],
 190   [AC_HELP_STRING([--with-iconv-libraries],
 191     [directory containing iconv library])],
 192     [ICONV_LIB_DIRS=$withval])
 193
 194 AC_SUBST(ICONV_INCLUDE_DIRS)
 195 AC_SUBST(ICONV_LIB_DIRS)
 196
 197 dnl Allow to specify gmp options to the toplevel configure script
 198 dnl so they can be properly passed to sub-builds.
 199
 200 AC_ARG_WITH([gmp-includes],
 201   [AC_HELP_STRING([--with-gmp-includes],
 202     [directory containing gmp.h])],
 203     [GMP_INCLUDE_DIRS=$withval])
 204
 205 AC_ARG_WITH([gmp-libraries],
 206   [AC_HELP_STRING([--with-gmp-libraries],
 207     [directory containing gmp library])],
 208     [GMP_LIB_DIRS=$withval])
 209
 210 AC_SUBST(GMP_INCLUDE_DIRS)
 211 AC_SUBST(GMP_LIB_DIRS)
 212
 213 dnl--------------------------------------------------------------------
 214 dnl * Choose host(/target/build) platform
 215 dnl--------------------------------------------------------------------
 216 dnl If we aren't explicitly told what values to use with configure flags,
 217 dnl we ask the bootstrapping compiler what platform it is for
 218
 219 if test "${WithGhc}" != ""
 220 then
 221         bootstrap_host=`"${WithGhc}" +RTS --info | grep '^ ,("Host platform"' | sed -e 's/.*, "//' -e 's/")//' | tr -d '\r'`
 222         bootstrap_target=`"${WithGhc}" +RTS --info | grep '^ ,("Target platform"' | sed -e 's/.*, "//' -e 's/")//' | tr -d '\r'`
 223         if test "$bootstrap_host" != "$bootstrap_target"
 224         then
 225                 echo "Bootstrapping GHC is a cross compiler. This probably isn't going to work"
 226         fi
 227 fi
 228
 229 # We have to run these unconditionally, but we may discard their
 230 # results in the following code
 231 AC_CANONICAL_BUILD
 232 AC_CANONICAL_HOST
 233 AC_CANONICAL_TARGET
 234
 235 # If no argument was given for a configuration variable, then discard
 236 # the guessed canonical system and use the configuration of the
 237 # bootstrapping ghc. If an argument was given, map it from gnu format
 238 # to ghc format.
 239 #
 240 # For why we do it this way, see: #3637, #1717, #2951
 241
 242 if test "$build_alias" = ""
 243 then
 244     if test "${WithGhc}" != ""
 245     then
 246         build=$bootstrap_target
 247         echo "Build platform inferred as: $build"
 248     else
 249         echo "Can't work out build platform"
 250         exit 1
 251     fi
 252
 253     BuildArch=`echo "$build" | sed 's/-.*//'`
 254     BuildVendor=`echo "$build" | sed -e 's/.*-\(.*\)-.*/\1/'`
 255     BuildOS=`echo "$build" | sed 's/.*-//'`
 256 else
 257     GHC_CONVERT_CPU([$build_cpu], [BuildArch])
 258     GHC_CONVERT_VENDOR([$build_vendor], [BuildVendor])
 259     GHC_CONVERT_OS([$build_os], [BuildOS])
 260 fi
 261
 262 if test "$host_alias" = ""
 263 then
 264     if test "${WithGhc}" != ""
 265     then
 266         host=$bootstrap_target
 267         echo "Host platform inferred as: $host"
 268     else
 269         echo "Can't work out host platform"
 270         exit 1
 271     fi
 272
 273     HostArch=`echo "$host" | sed 's/-.*//'`
 274     HostVendor=`echo "$host" | sed -e 's/.*-\(.*\)-.*/\1/'`
 275     HostOS=`echo "$host" | sed 's/.*-//'`
 276 else
 277     GHC_CONVERT_CPU([$host_cpu], [HostArch])
 278     GHC_CONVERT_VENDOR([$host_vendor], [HostVendor])
 279     GHC_CONVERT_OS([$host_os], [HostOS])
 280 fi
 281
 282 if test "$target_alias" = ""
 283 then
 284     if test "${WithGhc}" != ""
 285     then
 286         target=$bootstrap_target
 287         echo "Target platform inferred as: $target"
 288     else
 289         echo "Can't work out target platform"
 290         exit 1
 291     fi
 292
 293     TargetArch=`echo "$target" | sed 's/-.*//'`
 294     TargetVendor=`echo "$target" | sed -e 's/.*-\(.*\)-.*/\1/'`
 295     TargetOS=`echo "$target" | sed 's/.*-//'`
 296 else
 297     GHC_CONVERT_CPU([$target_cpu], [TargetArch])
 298     GHC_CONVERT_VENDOR([$target_vendor], [TargetVendor])
 299     GHC_CONVERT_OS([$target_os], [TargetOS])
 300 fi
 301
 302 exeext=''
 303 soext='.so'
 304 case $host in
 305 *-unknown-cygwin32)
 306     AC_MSG_WARN([GHC does not support the Cygwin target at the moment])
 307     AC_MSG_WARN([I'm assuming you wanted to build for i386-unknown-mingw32])
 308     exit 1
 309     ;;
 310 *-unknown-mingw32)
 311     exeext='.exe'
 312     soext='.dll'
 313     ;;
 314 i386-apple-darwin|powerpc-apple-darwin)
 315     soext='.dylib'
 316     ;;
 317 x86_64-apple-darwin)
 318     soext='.dylib'
 319     ;;
 320 esac
 321
 322 checkArch() {
 323     case $1 in
 324     alpha|arm|hppa|hppa1_1|i386|ia64|m68k|mips|mipseb|mipsel|powerpc|powerpc64|rs6000|s390|sparc|sparc64|vax|x86_64)
 325         ;;
 326     *)
 327         echo "Unknown arch $1"
 328         exit 1
 329         ;;
 330     esac
 331 }
 332
 333 checkVendor() {
 334     case $1 in
 335     dec|unknown|hp|apple|next|sun|sgi|ibm)
 336         ;;
 337     *)
 338         echo "Unknown vendor $1"
 339         exit 1
 340         ;;
 341     esac
 342 }
 343
 344 checkOS() {
 345     case $1 in
 346     linux|freebsd|netbsd|openbsd|dragonfly|osf1|osf3|hpux|linuxaout|kfreebsdgnu|freebsd2|solaris2|cygwin32|mingw32|darwin|gnu|nextstep2|nextstep3|sunos4|ultrix|irix|aix|haiku)
 347         ;;
 348     *)
 349         echo "Unknown OS '$1'"
 350         exit 1
 351         ;;
 352     esac
 353 }
 354
 355 BuildPlatform="$BuildArch-$BuildVendor-$BuildOS"
 356 BuildPlatform_CPP=`echo "$BuildPlatform" | sed -e 's/\./_/g' -e 's/-/_/g'`
 357 BuildArch_CPP=`    echo "$BuildArch"     | sed -e 's/\./_/g' -e 's/-/_/g'`
 358 BuildVendor_CPP=`  echo "$BuildVendor"   | sed -e 's/\./_/g' -e 's/-/_/g'`
 359 BuildOS_CPP=`      echo "$BuildOS"       | sed -e 's/\./_/g' -e 's/-/_/g'`
 360
 361 checkArch "$BuildArch"
 362 checkVendor "$BuildVendor"
 363 checkOS "$BuildOS"
 364
 365 HostPlatform="$HostArch-$HostVendor-$HostOS"
 366 HostPlatform_CPP=`echo "$HostPlatform" | sed -e 's/\./_/g' -e 's/-/_/g'`
 367 HostArch_CPP=`    echo "$HostArch"     | sed -e 's/\./_/g' -e 's/-/_/g'`
 368 HostVendor_CPP=`  echo "$HostVendor"   | sed -e 's/\./_/g' -e 's/-/_/g'`
 369 HostOS_CPP=`      echo "$HostOS"       | sed -e 's/\./_/g' -e 's/-/_/g'`
 370
 371 checkArch "$HostArch"
 372 checkVendor "$HostVendor"
 373 checkOS "$HostOS"
 374
 375 TargetPlatform="$TargetArch-$TargetVendor-$TargetOS"
 376 TargetPlatform_CPP=`echo "$TargetPlatform" | sed -e 's/\./_/g' -e 's/-/_/g'`
 377 TargetArch_CPP=`    echo "$TargetArch"     | sed -e 's/\./_/g' -e 's/-/_/g'`
 378 TargetVendor_CPP=`  echo "$TargetVendor"   | sed -e 's/\./_/g' -e 's/-/_/g'`
 379 TargetOS_CPP=`      echo "$TargetOS"       | sed -e 's/\./_/g' -e 's/-/_/g'`
 380
 381 checkArch "$TargetArch"
 382 checkVendor "$TargetVendor"
 383 checkOS "$TargetOS"
 384
 385 AC_SUBST(BuildPlatform)
 386 AC_SUBST(HostPlatform)
 387 AC_SUBST(TargetPlatform)
 388 AC_SUBST(HostPlatform_CPP)
 389 AC_SUBST(BuildPlatform_CPP)
 390 AC_SUBST(TargetPlatform_CPP)
 391
 392 AC_SUBST(HostArch_CPP)
 393 AC_SUBST(BuildArch_CPP)
 394 AC_SUBST(TargetArch_CPP)
 395
 396 AC_SUBST(HostOS_CPP)
 397 AC_SUBST(BuildOS_CPP)
 398 AC_SUBST(TargetOS_CPP)
 399
 400 AC_SUBST(HostVendor_CPP)
 401 AC_SUBST(BuildVendor_CPP)
 402 AC_SUBST(TargetVendor_CPP)
 403
 404 AC_SUBST(exeext)
 405 AC_SUBST(soext)
 406
 407 AC_ARG_WITH(hc,
 408 [AC_HELP_STRING([--with-hc=ARG],
 409         [Use ARG as the path to the compiler for compiling ordinary
 410          Haskell code  (default= value of --with-ghc)])],
 411 [WithHc="$withval"],
 412 [WithHc=$WithGhc]
 413 )
 414 AC_SUBST(WithHc)
 415
 416 AC_PATH_PROGS(NHC,nhc nhc98)
 417 AC_PATH_PROG(HBC,hbc)
 418
 419 # This uses GHC, so put it after the "GHC is required" check above:
 420 FP_FIND_ROOT
 421
 422 if test "$HostOS" = "mingw32"
 423 then
 424     CC="$hardtop/inplace/mingw/bin/gcc.exe"
 425     LD="$hardtop/inplace/mingw/bin/ld.exe"
 426     NM="$hardtop/inplace/mingw/bin/nm.exe"
 427     fp_prog_ar_raw="$hardtop/inplace/mingw/bin/ar.exe"
 428     if ! test -d inplace/mingw ||
 429          test inplace/mingw -ot ghc-tarballs/mingw/binutils*.tar.lzma ||
 430          test inplace/mingw -ot ghc-tarballs/mingw/gcc-core*.tar.lzma ||
 431          test inplace/mingw -ot ghc-tarballs/mingw/gcc-c++*.tar.lzma  ||
 432          test inplace/mingw -ot ghc-tarballs/mingw/mingwrt*.tar.gz    ||
 433          test inplace/mingw -ot ghc-tarballs/mingw/w32api*.tar.lzma
 434     then
 435         AC_MSG_NOTICE([Making in-tree mingw tree])
 436         rm -rf inplace/mingw
 437         mkdir inplace
 438         mkdir inplace/mingw
 439         (
 440             cd inplace/mingw &&
 441             tar --lzma -xf ../../ghc-tarballs/mingw/binutils*.tar.lzma &&
 442             tar --lzma -xf ../../ghc-tarballs/mingw/gcc-core*.tar.lzma &&
 443             tar --lzma -xf ../../ghc-tarballs/mingw/gcc-c++*.tar.lzma  &&
 444             tar -z     -xf ../../ghc-tarballs/mingw/mingwrt*.tar.gz    &&
 445             tar --lzma -xf ../../ghc-tarballs/mingw/w32api*.tar.lzma   &&
 446             mv bin/gcc.exe bin/realgcc.exe
 447         )
 448         inplace/mingw/bin/realgcc.exe driver/gcc/gcc.c driver/utils/cwrapper.c driver/utils/getLocation.c -Idriver/utils -o inplace/mingw/bin/gcc.exe
 449         AC_MSG_NOTICE([In-tree mingw tree created])
 450     fi
 451     if ! test -d inplace/perl ||
 452          test inplace/perl -ot ghc-tarballs/perl/ghc-perl*.tar.gz
 453     then
 454         AC_MSG_NOTICE([Making in-tree perl tree])
 455         rm -rf inplace/perl
 456         mkdir inplace
 457         mkdir inplace/perl
 458         (
 459             cd inplace/perl &&
 460             tar -zxf ../../ghc-tarballs/perl/ghc-perl*.tar.gz
 461         )
 462         AC_MSG_NOTICE([In-tree perl tree created])
 463     fi
 464 fi
 465
 466 dnl ** Which gcc to use?
 467 dnl --------------------------------------------------------------
 468 FP_ARG_WITH_PATH_GNU_PROG([CC], [gcc])
 469 export CC
 470 WhatGccIsCalled="$CC"
 471 AC_SUBST(WhatGccIsCalled)
 472
 473 dnl ** Which ld to use?
 474 dnl --------------------------------------------------------------
 475 FP_ARG_WITH_PATH_GNU_PROG([LD], [ld])
 476 LdCmd="$LD"
 477 AC_SUBST([LdCmd])
 478
 479 dnl ** Which nm to use?
 480 dnl --------------------------------------------------------------
 481 FP_ARG_WITH_PATH_GNU_PROG([NM], [nm])
 482 NmCmd="$NM"
 483 AC_SUBST([NmCmd])
 484
 485 dnl ** Mac OS X: explicit deployment target
 486 dnl --------------------------------------------------------------
 487 AC_ARG_WITH([macosx-deployment-target],
 488 [AC_HELP_STRING([--with-macosx-deployment-target=VERSION],
 489         [Build for Mac OS VERSION and higher  (default= version of build host)])],
 490 [FP_MACOSX_DEPLOYMENT_TARGET="$withval"
 491  if test "x$TargetOS_CPP-$TargetVendor_CPP" != "xdarwin-apple"; then
 492    # ignore everywhere, but on Mac OS
 493    AC_MSG_WARN([--macosx-deployment-target is only available on Mac OS X])
 494    FP_MACOSX_DEPLOYMENT_TARGET=none
 495  fi],
 496 [FP_MACOSX_DEPLOYMENT_TARGET=none]
 497 )
 498 FP_CHECK_MACOSX_DEPLOYMENT_TARGET
 499 AC_SUBST(MACOSX_DEPLOYMENT_VERSION)
 500 AC_SUBST(MACOSX_DEPLOYMENT_SDK)
 501
 502 dnl --------------------------------------------------------------
 503 dnl End of configure script option section
 504 dnl --------------------------------------------------------------
 505
 506
 507 dnl --------------------------------------------------------------
 508 dnl * General configuration checks
 509 dnl --------------------------------------------------------------
 510
 511 dnl ** Can the unix package be built?
 512 dnl --------------------------------------------------------------
 513
 514 if test x"$TargetPlatform" = x"i386-unknown-mingw32"; then
 515    GhcLibsWithUnix=NO
 516 else
 517    GhcLibsWithUnix=YES
 518 fi
 519 AC_SUBST([GhcLibsWithUnix])
 520
 521 dnl ** does #! work?
 522 AC_SYS_INTERPRETER()
 523
 524 dnl ** look for `perl', but only in /bin on Windows
 525 case $HostOS_CPP in
 526 cygwin32|mingw32)
 527       AC_CHECK_PROG(PerlCmd,perl,/bin/perl,,/bin)
 528       if test -z "$PerlCmd"; then
 529          echo "You must install the version of Perl shipped with GHC"
 530          echo "(or a compatible one) in /bin."
 531          exit 1
 532       fi
 533    ;;
 534 *)
 535    AC_PATH_PROG(PerlCmd,perl)
 536    if test -z "$PerlCmd"; then
 537       echo "You must install perl before you can continue"
 538       echo "Perhaps it is already installed, but not in your PATH?"
 539       exit 1
 540    else
 541    FPTOOLS_CHECK_PERL_VERSION
 542    fi
 543    ;;
 544 esac
 545
 546 dnl ** does #! path/to/perl work? (sometimes it's too long...)
 547 FPTOOLS_SHEBANG_PERL
 548
 549 dnl ** check for Python
 550 AC_PATH_PROG(PythonCmd,python)
 551
 552 dnl ** look for GCC and find out which version
 553 dnl     Figure out which C compiler to use.  Gcc is preferred.
 554 dnl     If gcc, make sure it's at least 2.1
 555 dnl
 556 FP_HAVE_GCC
 557
 558 FPTOOLS_SET_C_LD_FLAGS([target],[CFLAGS],[LDFLAGS])
 559 FPTOOLS_SET_C_LD_FLAGS([build],[CONF_CC_OPTS_STAGE0],[CONF_LD_OPTS_STAGE0])
 560 FPTOOLS_SET_C_LD_FLAGS([target],[CONF_CC_OPTS_STAGE1],[CONF_LD_OPTS_STAGE1])
 561 # Stage 3 won't be supported by cross-compilation
 562 FPTOOLS_SET_C_LD_FLAGS([target],[CONF_CC_OPTS_STAGE2],[CONF_LD_OPTS_STAGE2])
 563
 564 FP_GCC_EXTRA_FLAGS
 565
 566 dnl ** figure out how to invoke cpp directly (gcc -E is no good)
 567 AC_PROG_CPP
 568
 569 AC_SUBST(CONF_CC_OPTS_STAGE0)
 570 AC_SUBST(CONF_CC_OPTS_STAGE1)
 571 AC_SUBST(CONF_CC_OPTS_STAGE2)
 572 AC_SUBST(CONF_LD_OPTS_STAGE0)
 573 AC_SUBST(CONF_LD_OPTS_STAGE1)
 574 AC_SUBST(CONF_LD_OPTS_STAGE2)
 575
 576 dnl ** figure out how to do context diffs
 577 FP_PROG_CONTEXT_DIFF
 578
 579 dnl Let's make sure install-sh is executable here.  If we got it from
 580 dnl a darcs repo, it might not be (see bug #978).
 581 chmod +x install-sh
 582 dnl ** figure out how to do a BSD-ish install
 583 AC_PROG_INSTALL
 584
 585 dnl If you can run configure, you certainly have /bin/sh
 586 AC_DEFINE([HAVE_BIN_SH], [1], [Define to 1 if you have /bin/sh.])
 587
 588 dnl ** how to invoke `ar' and `ranlib'
 589 FP_PROG_AR_SUPPORTS_ATFILE
 590 FP_PROG_AR_NEEDS_RANLIB
 591 FP_PROG_AR_SUPPORTS_INPUT
 592
 593 dnl ** Check to see whether ln -s works
 594 AC_PROG_LN_S
 595
 596
 597 dnl ** Find the path to sed
 598 AC_PATH_PROGS(SedCmd,gsed sed,sed)
 599
 600
 601 dnl ** check for time command
 602 AC_PATH_PROG(TimeCmd,time)
 603
 604 dnl ** check for tar
 605 dnl   if GNU tar is named gtar, look for it first.
 606 AC_PATH_PROGS(TarCmd,gnutar gtar tar,tar)
 607
 608 dnl ** check for patch
 609 dnl if GNU patch is named gpatch, look for it first
 610 AC_PATH_PROGS(PatchCmd,gpatch patch, patch)
 611
 612 dnl ** check for dtrace (currently only implemented for Mac OS X)
 613 HaveDtrace=NO
 614 AC_PATH_PROG(DtraceCmd,dtrace)
 615 if test -n "$DtraceCmd"; then
 616   if test "x$TargetOS_CPP-$TargetVendor_CPP" == "xdarwin-apple"; then
 617     HaveDtrace=YES
 618   fi
 619 fi
 620 AC_SUBST(HaveDtrace)
 621
 622 AC_PATH_PROG(HSCOLOUR,HsColour)
 623 # HsColour is passed to Cabal, so we need a native path
 624 if test "x$HostPlatform"  = "xi386-unknown-mingw32" && \
 625    test "${OSTYPE}"      != "msys"                  && \
 626    test "${HSCOLOUR}"    != ""
 627 then
 628     # Canonicalise to <drive>:/path/to/gcc
 629     HSCOLOUR=`cygpath -m ${HSCOLOUR}`
 630 fi
 631
 632 dnl ** check for DocBook toolchain
 633 FP_CHECK_DOCBOOK_DTD
 634 FP_DOCBOOK_XSL
 635 FP_PROG_DBLATEX
 636
 637 FP_PROG_HSTAGS
 638
 639 dnl ** check for ghc-pkg command
 640 FP_PROG_GHC_PKG
 641
 642 dnl ** check for installed happy binary + version
 643 dnl    (don't do it if we're booting from .hc files though.)
 644 if test "$BootingFromHc" = "NO"; then
 645 FPTOOLS_HAPPY
 646 fi;
 647
 648 dnl ** check for installed alex binary + version
 649 dnl    (don't do it if we're booting from .hc files though.)
 650 if test "$BootingFromHc" = "NO"; then
 651 FPTOOLS_ALEX
 652 fi;
 653
 654 dnl --------------------------------------------------
 655 dnl ### program checking section ends here ###
 656 dnl --------------------------------------------------
 657
 658 dnl --------------------------------------------------
 659 dnl * Platform header file and syscall feature tests
 660 dnl ### checking the state of the local header files and syscalls ###
 661
 662 dnl ** check for full ANSI header (.h) files
 663 AC_HEADER_STDC
 664
 665 dnl ** Enable large file support.  NB. do this before testing the type of
 666 dnl    off_t, because it will affect the result of that test.
 667 AC_SYS_LARGEFILE
 668
 669 dnl ** check for specific header (.h) files that we are interested in
 670 AC_CHECK_HEADERS([bfd.h ctype.h dirent.h dlfcn.h errno.h fcntl.h grp.h limits.h locale.h nlist.h pthread.h pwd.h signal.h sys/cpuset.h sys/mman.h sys/resource.h sys/select.h sys/time.h sys/timeb.h sys/timers.h sys/times.h sys/utsname.h sys/wait.h termios.h time.h utime.h windows.h winsock.h sched.h])
 671
 672 dnl ** check if it is safe to include both <time.h> and <sys/time.h>
 673 AC_HEADER_TIME
 674
 675 dnl ** do we have long longs?
 676 AC_CHECK_TYPES([long long])
 677
 678 dnl ** what are the sizes of various types
 679 AC_CHECK_SIZEOF(char,               1)
 680 AC_CHECK_SIZEOF(double,             8)
 681 AC_CHECK_SIZEOF(float,              4)
 682 AC_CHECK_SIZEOF(int,                4)
 683 AC_CHECK_SIZEOF(long,               4)
 684 if test "$ac_cv_type_long_long" = yes; then
 685 AC_CHECK_SIZEOF(long long,          8)
 686 fi
 687 AC_CHECK_SIZEOF(short,              2)
 688 AC_CHECK_SIZEOF(unsigned char,      1)
 689 AC_CHECK_SIZEOF(unsigned int,       4)
 690 AC_CHECK_SIZEOF(unsigned long,      4)
 691 if test "$ac_cv_type_long_long" = yes; then
 692 AC_CHECK_SIZEOF(unsigned long long, 8)
 693 fi
 694 AC_CHECK_SIZEOF(unsigned short,     2)
 695 AC_CHECK_SIZEOF(void *,             4)
 696
 697 dnl ** what are alignment constraints on various types
 698 FP_CHECK_ALIGNMENT(char)
 699 FP_CHECK_ALIGNMENT(double)
 700 FP_CHECK_ALIGNMENT(float)
 701 FP_CHECK_ALIGNMENT(int)
 702 FP_CHECK_ALIGNMENT(long)
 703 if test "$ac_cv_type_long_long" = yes; then
 704 FP_CHECK_ALIGNMENT(long long)
 705 fi
 706 FP_CHECK_ALIGNMENT(short)
 707 FP_CHECK_ALIGNMENT(unsigned char)
 708 FP_CHECK_ALIGNMENT(unsigned int)
 709 FP_CHECK_ALIGNMENT(unsigned long)
 710 if test "$ac_cv_type_long_long" = yes; then
 711 FP_CHECK_ALIGNMENT(unsigned long long)
 712 fi
 713 FP_CHECK_ALIGNMENT(unsigned short)
 714 FP_CHECK_ALIGNMENT(void *)
 715
 716 FP_CHECK_FUNC([WinExec],
 717   [@%:@include <windows.h>], [WinExec("",0)])
 718
 719 FP_CHECK_FUNC([GetModuleFileName],
 720   [@%:@include <windows.h>], [GetModuleFileName((HMODULE)0,(LPTSTR)0,0)])
 721
 722 dnl ** check return type of signal handlers
 723 dnl Foo: assumes we can use prototypes.
 724 dnl On BCC, signal handlers have type "int(void)", elsewhere its "void(int)".
 725 dnl AC_CACHE_CHECK([type of signal handlers], ac_cv_type_signal_handler,
 726 dnl [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 727 dnl #include <signal.h>
 728 dnl #ifdef signal
 729 dnl #undef signal
 730 dnl #endif
 731 dnl void (*signal (int, void (*)(int)))(int);
 732 dnl ]],
 733 dnl [[int i;]])],
 734 dnl [ac_cv_type_signal_handler=void_int],
 735 dnl [ac_cv_type_signal_handler=int_void])])
 736 dnl if test "$ac_cv_type_signal_handler" = void_int; then
 737 dnl AC_DEFINE(VOID_INT_SIGNALS)
 738 dnl fi
 739
 740 dnl On BCC, signal handlers have type "int(void)", elsewhere its "void(int)".
 741 AC_TYPE_SIGNAL
 742 if test "$ac_cv_type_signal" = void; then
 743   AC_DEFINE([VOID_INT_SIGNALS], [1], [Define to 1 if signal handlers have type void (*)(int). Otherwise, they're assumed to have type int (*)(void).])
 744 fi
 745
 746 dnl ** check for more functions
 747 dnl ** The following have been verified to be used in ghc/, but might be used somewhere else, too.
 748 AC_CHECK_FUNCS([getclock getrusage gettimeofday setitimer siginterrupt sysconf times ctime_r sched_setaffinity setlocale])
 749
 750 AC_TRY_RUN([
 751 #include <sys/types.h>
 752 #include <sys/time.h>
 753 int main(void) {
 754   struct itimerval tval;
 755   tval.it_value.tv_sec = 1;
 756   tval.it_value.tv_usec = 0;
 757   tval.it_interval = tval.it_value;
 758   return setitimer(ITIMER_VIRTUAL, &tval, (void*)0) != 0;
 759 }
 760 ],[AC_DEFINE([HAVE_SETITIMER_VIRTUAL], [1], [Define to 1 if setitimer accepts ITIMER_VIRTUAL, 0 else.])])
 761
 762 dnl ** On OS X 10.4 (at least), time.h doesn't declare ctime_r if
 763 dnl ** _POSIX_C_SOURCE is defined
 764 AC_CHECK_DECLS([ctime_r], , ,
 765 [#define _POSIX_SOURCE 1
 766 #define _POSIX_C_SOURCE 199506L
 767 #include <time.h>])
 768
 769 dnl ** check for mingwex library
 770 AC_CHECK_LIB(mingwex, closedir, HaveLibMingwEx=YES, HaveLibMingwEx=NO)
 771 AC_SUBST(HaveLibMingwEx)
 772
 773 if test $HaveLibMingwEx = YES ; then
 774   AC_DEFINE([HAVE_MINGWEX], [1], [Define to 1 if you have the mingwex library.])
 775 fi
 776
 777 dnl ** check for math library
 778 dnl    Keep that check as early as possible.
 779 dnl    as we need to know whether we need libm
 780 dnl    for math functions or not
 781 dnl    (see http://hackage.haskell.org/trac/ghc/ticket/3730)
 782 AC_CHECK_LIB(m, atan, HaveLibM=YES, HaveLibM=NO)
 783 if test $HaveLibM = YES
 784 then
 785   AC_DEFINE([HAVE_LIBM], [1], [Define to 1 if you need to link with libm])
 786 fi
 787
 788 dnl ** check whether this machine has BFD and liberty installed (used for debugging)
 789 dnl    the order of these tests matters: bfd needs liberty
 790 AC_CHECK_LIB(iberty, xmalloc)
 791 AC_CHECK_LIB(bfd,    bfd_init)
 792
 793 dnl ################################################################
 794 dnl Check for libraries
 795 dnl ################################################################
 796
 797 dnl ** check whether we need -ldl to get dlopen()
 798
 799 AC_CHECK_LIB(dl, dlopen,
 800     [HaveLibDL=YES
 801      AC_DEFINE([HAVE_LIBDL], [1], [Define to 1 if you need -ldl to get dlopen().])
 802      LIBS="$LIBS -ldl"],
 803     [HaveLibDL=NO])
 804 AC_SUBST(HaveLibDL)
 805
 806 dnl --------------------------------------------------
 807 dnl * Miscellaneous feature tests
 808 dnl --------------------------------------------------
 809
 810 dnl ** can we get alloca?
 811 AC_FUNC_ALLOCA
 812
 813 dnl ** Working vfork?
 814 AC_FUNC_FORK
 815
 816 dnl ** determine whether or not const works
 817 AC_C_CONST
 818
 819 dnl ** are we big endian?
 820 AC_C_BIGENDIAN
 821 FPTOOLS_FLOAT_WORD_ORDER_BIGENDIAN
 822
 823 dnl ** check for leading underscores in symbol names
 824 FP_LEADING_UNDERSCORE
 825
 826 dnl ** check for ld, whether it has an -x option, and if it is GNU ld
 827 FP_PROG_LD_X
 828 FP_PROG_LD_IS_GNU
 829
 830 dnl ** check for Apple-style dead-stripping support
 831 dnl    (.subsections-via-symbols assembler directive)
 832
 833
 834 AC_MSG_CHECKING(for .subsections_via_symbols)
 835 AC_COMPILE_IFELSE(
 836     [AC_LANG_PROGRAM([], [__asm__ (".subsections_via_symbols");])],
 837     [AC_MSG_RESULT(yes)
 838      AC_DEFINE([HAVE_SUBSECTIONS_VIA_SYMBOLS],[1],
 839                [Define to 1 if Apple-style dead-stripping is supported.])
 840     ],
 841     [AC_MSG_RESULT(no)])
 842
 843 dnl *** check for GNU non-executable stack note support (ELF only)
 844 dnl     (.section .note.GNU-stack,"",@progbits)
 845
 846 dnl This test doesn't work with "gcc -g" in gcc 4.4 (GHC trac #3889:
 847 dnl     Error: can't resolve `.note.GNU-stack' {.note.GNU-stack section} - `.Ltext0' {.text section}
 848 dnl so we empty CFLAGS while running this test
 849 CFLAGS2="$CFLAGS"
 850 CFLAGS=
 851 AC_MSG_CHECKING(for GNU non-executable stack support)
 852 AC_COMPILE_IFELSE(
 853     [AC_LANG_PROGRAM([__asm__ (".section .note.GNU-stack,\"\",@progbits");], [0])],
 854     [AC_MSG_RESULT(yes)
 855      AC_DEFINE([HAVE_GNU_NONEXEC_STACK],[1],
 856                [Define to 1 if GNU non-executable stack notes are supported.])
 857     ],
 858     [AC_MSG_RESULT(no)])
 859 CFLAGS="$CFLAGS2"
 860
 861 dnl ** check for librt
 862 AC_CHECK_LIB(rt, clock_gettime)
 863 AC_CHECK_FUNCS(clock_gettime timer_create timer_settime)
 864 FP_CHECK_TIMER_CREATE
 865
 866 dnl ** check for Apple's "interesting" long double compatibility scheme
 867 AC_MSG_CHECKING(for printf\$LDBLStub)
 868 AC_TRY_LINK_FUNC(printf\$LDBLStub,
 869     [
 870         AC_MSG_RESULT(yes)
 871         AC_DEFINE([HAVE_PRINTF_LDBLSTUB],[1],
 872             [Define to 1 if we have printf$LDBLStub (Apple Mac OS >= 10.4, PPC).])
 873     ],
 874     [
 875         AC_MSG_RESULT(no)
 876         AC_DEFINE([HAVE_PRINTF_LDBLSTUB],[0],
 877             [Define to 1 if we have printf$LDBLStub (Apple Mac OS >= 10.4, PPC).])
 878     ])
 879
 880 dnl ** check for eventfd which is needed by the I/O manager
 881 AC_CHECK_HEADERS([sys/eventfd.h])
 882 AC_CHECK_FUNCS([eventfd])
 883
 884 # test for GTK+
 885 AC_PATH_PROGS([GTK_CONFIG], [pkg-config])
 886 if test -n "$GTK_CONFIG"; then
 887   if $GTK_CONFIG gtk+-2.0 --atleast-version=2.0; then
 888     GTK_CONFIG="$GTK_CONFIG gtk+-2.0"
 889   else
 890     AC_MSG_WARN([GTK+ not usable, need at least version 2.0])
 891     GTK_CONFIG=
 892   fi
 893 fi
 894 AC_SUBST([GTK_CONFIG])
 895
 896 #Checking for PAPI
 897 AC_CHECK_LIB(papi, PAPI_library_init, HavePapiLib=YES, HavePapiLib=NO)
 898 AC_CHECK_HEADER([papi.h], [HavePapiHeader=YES], [HavePapiHeader=NO])
 899 AC_SUBST(HavePapiLib)
 900 AC_SUBST(HavePapiHeader)
 901
 902 AC_CHECK_FUNCS(__mingw_vfprintf)
 903
 904 if test "$HavePapiLib" = "YES" -a "$HavePapiHeader" = "YES"; then
 905    HavePapi=YES
 906 else
 907    HavePapi=NO
 908 fi
 909 AC_SUBST(HavePapi)
 910
 911 if test "$HAVE_DOCBOOK_XSL" = "NO" ||
 912    test "$XsltprocCmd" = ""
 913 then
 914     BUILD_DOCBOOK_HTML=NO
 915 else
 916     BUILD_DOCBOOK_HTML=YES
 917 fi
 918 AC_SUBST(BUILD_DOCBOOK_HTML)
 919
 920 if test "$DblatexCmd" = ""
 921 then
 922     BUILD_DOCBOOK_PS=NO
 923     BUILD_DOCBOOK_PDF=NO
 924 else
 925     BUILD_DOCBOOK_PS=YES
 926     BUILD_DOCBOOK_PDF=YES
 927 fi
 928 AC_SUBST(BUILD_DOCBOOK_PS)
 929 AC_SUBST(BUILD_DOCBOOK_PDF)
 930
 931 LIBRARY_VERSION(base)
 932 LIBRARY_VERSION(Cabal)
 933 LIBRARY_VERSION(ghc-prim)
 934 LIBRARY_ghc_VERSION="$ProjectVersion"
 935 AC_SUBST(LIBRARY_ghc_VERSION)
 936
 937 if grep '       ' compiler/ghc.cabal.in 2>&1 >/dev/null; then
 938    AC_MSG_ERROR([compiler/ghc.cabal.in contains tab characters; please remove them])
 939 fi
 940
 941 AC_CONFIG_FILES([mk/config.mk mk/install.mk mk/project.mk compiler/ghc.cabal ghc/ghc-bin.cabal ghc.spec extra-gcc-opts docs/users_guide/ug-book.xml docs/users_guide/ug-ent.xml docs/index.html libraries/prologue.txt distrib/ghc.iss distrib/configure.ac])
 942 AC_CONFIG_COMMANDS([mk/stamp-h],[echo timestamp > mk/stamp-h])
 943 AC_OUTPUT
 944
 945 # We get caught by
 946 #     http://savannah.gnu.org/bugs/index.php?1516
 947 #     $(eval ...) inside conditionals causes errors
 948 # with make 3.80, so warn the user if it looks like they're about to
 949 # try to use it.
 950 # We would use "grep -q" here, but Solaris's grep doesn't support it.
 951 checkMake380() {
 952     if $1 --version 2>&1 | head -1 | grep 'GNU Make 3\.80' > /dev/null
 953     then
 954         echo
 955         echo "WARNING: It looks like \"$1\" is GNU make 3.80."
 956         echo "This version cannot be used to build GHC."
 957         echo "Please use GNU make >= 3.81."
 958     fi
 959 }
 960
 961 checkMake380 make
 962 checkMake380 gmake
 963
 964 echo ["
 965 ----------------------------------------------------------------------
 966 Configure completed successfully.
 967
 968    Building GHC version  : $ProjectVersion
 969
 970    Build platform        : $BuildPlatform
 971    Host platform         : $HostPlatform
 972    Target platform       : $TargetPlatform
 973 "]
 974
 975 if test "$BootingFromHc" = "YES"; then
 976 echo ["\
 977    Bootstrapping from HC files.
 978 "]
 979 else
 980 echo ["\
 981    Bootstrapping using   : $WithGhc
 982       which is version   : $GhcVersion
 983 "]
 984 fi
 985
 986 echo ["\
 987    Using GCC             : $WhatGccIsCalled
 988       which is version   : $GccVersion
 989
 990    ld       : $LdCmd
 991    Happy    : $HappyCmd ($HappyVersion)
 992    Alex     : $AlexCmd ($AlexVersion)
 993    Python   : $PythonCmd
 994    Perl     : $PerlCmd
 995    dblatex  : $DblatexCmd
 996    xsltproc : $XsltprocCmd"]
 997
 998 if test "$HSCOLOUR" = ""; then
 999 echo ["
1000    HsColour was not found; documentation will not contain source links
1001 "]
1002 else
1003 echo ["\
1004    HsColour : $HSCOLOUR
1005 "]
1006 fi
1007
1008 echo ["\
1009    Building DocBook HTML documentation : $BUILD_DOCBOOK_HTML
1010    Building DocBook PS documentation   : $BUILD_DOCBOOK_PS
1011    Building DocBook PDF documentation  : $BUILD_DOCBOOK_PDF"]
1012
1013 echo ["----------------------------------------------------------------------
1014 "]
1015
1016 echo "\
1017 For a standard build of GHC (fully optimised with profiling), type (g)make.
1018
1019 To make changes to the default build configuration, copy the file
1020 mk/build.mk.sample to mk/build.mk, and edit the settings in there.
1021
1022 For more information on how to configure your GHC build, see
1023    http://hackage.haskell.org/trac/ghc/wiki/Building
1024 "