configure.ac

   1 dnl == autoconf source for the Glasgow FP tools ==
   2 dnl (run "grep '^dnl \*' configure.ac | sed -e 's/dnl / /g; s/\*\*/   +/g;'"
   3 dnl  (or some such) to see the outline of this file)
   4 dnl
   5 #
   6 # (c) The University of Glasgow 1994-2004
   7 #
   8 # Configure script template for GHC
   9 #
  10 # Process with 'autoreconf' to get a working configure script.
  11 #
  12 # For the generated configure script, do "./configure --help" to
  13 # see what flags are available. (Better yet, read the documentation!)
  14 #
  15
  16 AC_INIT([The Glorious Glasgow Haskell Compilation System], [7.1], [glasgow-haskell-bugs@haskell.org], [ghc])
  17
  18 # Set this to YES for a released version, otherwise NO
  19 : ${RELEASE=NO}
  20
  21 # The primary version (e.g. 6.7, 6.6.1) is set in the AC_INIT line
  22 # above.  If this is not a released version, then we will append the
  23 # date to the version number (e.g. 6.7.20070204).  The date is
  24 # constructed by finding the date of the most recent patch in the
  25 # darcs repository.  If this is a source distribution (not a darcs
  26 # checkout), then we ship a file 'VERSION' containing the full version
  27 # when the source distribution was created.
  28
  29 if test ! -f mk/config.h.in; then
  30    echo "mk/config.h.in doesn't exist: perhaps you haven't run 'perl boot'?"
  31    exit 1
  32 fi
  33
  34 AC_SUBST([CONFIGURE_ARGS], [$ac_configure_args])
  35
  36 dnl ----------------------------------------------------------
  37 dnl ** Find unixy sort and find commands,
  38 dnl ** which are needed by FP_SETUP_PROJECT_VERSION
  39
  40 dnl ** Find find command (for Win32's benefit)
  41 FP_PROG_FIND
  42
  43 dnl ** Find sort command (for the benefit of Win32 environs)
  44 FP_PROG_SORT
  45
  46 dnl ----------------------------------------------------------
  47 FP_SETUP_PROJECT_VERSION
  48
  49 # Hmmm, we fix the RPM release number to 1 here... Is this convenient?
  50 AC_SUBST([release], [1])
  51
  52 # First off, a distrib sanity check..
  53 AC_CONFIG_SRCDIR([mk/config.mk.in])
  54
  55 dnl * We require autoconf version 2.52
  56 dnl We need 2.50 due to the use of AC_SYS_LARGEFILE and AC_MSG_NOTICE.
  57 dnl We need 2.52 due to the use of AS_TR_CPP and AS_TR_SH.
  58 AC_PREREQ([2.52])
  59
  60 # -------------------------------------------------------------------------
  61 # Prepare to generate the following header files
  62 #
  63 #
  64 AC_CONFIG_HEADER(mk/config.h)
  65
  66 # No, semi-sadly, we don't do `--srcdir'...
  67 if test x"$srcdir" != 'x.' ; then
  68     echo "This configuration does not support the \`--srcdir' option.."
  69     exit 1
  70 fi
  71
  72 dnl --------------------------------------------------------------
  73 dnl * Project specific configuration options
  74 dnl --------------------------------------------------------------
  75 dnl What follows is a bunch of options that can either be configured
  76 dnl through command line options to the configure script or by
  77 dnl supplying defns in the build tree's mk/build.mk. Having the option to
  78 dnl use either is considered a Feature.
  79
  80 dnl ** What command to use to compile compiler sources ?
  81 dnl --------------------------------------------------------------
  82
  83 AC_ARG_WITH([ghc],
  84 [AC_HELP_STRING([--with-ghc=ARG],
  85   [Use ARG as the path to GHC  [default=autodetect]])],
  86   [WithGhc="$withval"],
  87   [if test "$GHC" = ""; then
  88     AC_PATH_PROG([GHC], [ghc])
  89   fi
  90   WithGhc="$GHC"])
  91
  92 dnl ** Booting from .hc files?
  93 dnl --------------------------------------------------------------
  94 AC_ARG_ENABLE(hc-boot,
  95 [AC_HELP_STRING([--enable-hc-boot],
  96 [Boot the Glasgow Haskell Compiler from intermediate .hc files.
  97  (This option is mostly of interest to porters.) [default=no]])],
  98 [ if test x"$enableval" = x"yes"; then
  99         BootingFromHc=YES
 100   else
 101         BootingFromHc=NO
 102   fi
 103 ],
 104 [BootingFromHc=NO]
 105 )
 106 AC_SUBST(BootingFromHc)
 107
 108 AC_ARG_ENABLE(bootstrap-with-devel-snapshot,
 109 [AC_HELP_STRING([--enable-bootstrap-with-devel-snapshot],
 110                 [Allow bootstrapping using a development snapshot of GHC.  This is not guaranteed to work.])],
 111         EnableBootstrapWithDevelSnaphost=YES,
 112         EnableBootstrapWithDevelSnaphost=NO
 113 )
 114
 115 if test "$WithGhc" != ""; then
 116   FPTOOLS_GHC_VERSION([GhcVersion], [GhcMajVersion], [GhcMinVersion], [GhcPatchLevel])dnl
 117
 118   if test "$GhcMajVersion" = "unknown" -o "$GhcMinVersion" = "unknown"; then
 119      AC_MSG_ERROR([Cannot determine the version of $WithGhc.  Is it really GHC?])
 120   fi
 121
 122   AC_SUBST(GhcVersion)dnl
 123   AC_SUBST(GhcMajVersion)dnl
 124   AC_SUBST(GhcMinVersion)dnl
 125   AC_SUBST(GhcPatchLevel)dnl
 126   GhcMinVersion2=`echo "$GhcMinVersion" | sed 's/^\\(.\\)$/0\\1/'`
 127   GhcCanonVersion="$GhcMajVersion$GhcMinVersion2"
 128   FP_COMPARE_VERSIONS($GhcVersion,[-ge],[6.10.2],
 129                       [ghc_ge_6102=YES], [ghc_ge_6102=NO])
 130   if test $GhcCanonVersion -ge 611; then ghc_ge_611=YES; else ghc_ge_611=NO; fi
 131   if test $GhcCanonVersion -ge 613; then ghc_ge_613=YES; else ghc_ge_613=NO; fi
 132   AC_SUBST(ghc_ge_6102)dnl
 133   AC_SUBST(ghc_ge_611)dnl
 134   AC_SUBST(ghc_ge_613)dnl
 135 fi
 136
 137 dnl ** Must have GHC to build GHC, unless --enable-hc-boot is on
 138 if test "$BootingFromHc" = "NO" -a -d "$srcdir/compiler"; then
 139   if test "$WithGhc" = ""; then
 140      AC_MSG_ERROR([GHC is required unless bootstrapping from .hc files.])
 141   fi
 142   FP_COMPARE_VERSIONS([$GhcVersion],[-lt],[6.10],
 143     [AC_MSG_ERROR([GHC version 6.10 or later is required to compile GHC.])])dnl
 144
 145   if test `expr $GhcMinVersion % 2` = "1"; then
 146      if test "$EnableBootstrapWithDevelSnaphost" = "NO"; then
 147         AC_MSG_ERROR([
 148      $WithGhc is a development snapshot of GHC, version $GhcVersion.
 149      Bootstrapping using this version of GHC is not supported, and may not
 150      work.  Use --enable-bootstrap-with-devel-snapshot to try it anyway,
 151      or --with-ghc to specify a different GHC to use.])
 152      fi
 153   fi
 154 fi;
 155
 156 # GHC is passed to Cabal, so we need a native path
 157 if test "${WithGhc}" != ""
 158 then
 159     ghc_host=`"${WithGhc}" +RTS --info | grep 'Host platform' | sed -e 's/.*, "//' -e 's/")//'`
 160
 161     if test "$ghc_host" = "i386-unknown-mingw32"
 162     then
 163         if test "${OSTYPE}" = "msys"
 164         then
 165             WithGhc=`echo "${WithGhc}" | sed "s#^/\([a-zA-Z]\)/#\1:/#"`
 166         else
 167             # Canonicalise to <drive>:/path/to/ghc
 168             WithGhc=`cygpath -m "${WithGhc}"`
 169         fi
 170         echo "GHC path canonicalised to: ${WithGhc}"
 171     fi
 172 fi
 173 AC_SUBST([WithGhc])
 174
 175 dnl ** Without optimization some INLINE trickery fails for GHCi
 176 SRC_CC_OPTS="-O"
 177
 178 FP_ICONV
 179 FP_GMP
 180
 181 dnl--------------------------------------------------------------------
 182 dnl * Choose host(/target/build) platform
 183 dnl--------------------------------------------------------------------
 184 dnl If we aren't explicitly told what values to use with configure flags,
 185 dnl we ask the bootstrapping compiler what platform it is for
 186
 187 if test "${WithGhc}" != ""
 188 then
 189         bootstrap_host=`"${WithGhc}" +RTS --info | grep '^ ,("Host platform"' | sed -e 's/.*, "//' -e 's/")//' | tr -d '\r'`
 190         bootstrap_target=`"${WithGhc}" +RTS --info | grep '^ ,("Target platform"' | sed -e 's/.*, "//' -e 's/")//' | tr -d '\r'`
 191         if test "$bootstrap_host" != "$bootstrap_target"
 192         then
 193                 echo "Bootstrapping GHC is a cross compiler. This probably isn't going to work"
 194         fi
 195 fi
 196
 197 # We have to run these unconditionally, but we may discard their
 198 # results in the following code
 199 AC_CANONICAL_BUILD
 200 AC_CANONICAL_HOST
 201 AC_CANONICAL_TARGET
 202
 203 # If no argument was given for a configuration variable, then discard
 204 # the guessed canonical system and use the configuration of the
 205 # bootstrapping ghc. If an argument was given, map it from gnu format
 206 # to ghc format.
 207 #
 208 # For why we do it this way, see: #3637, #1717, #2951
 209
 210 if test "$build_alias" = ""
 211 then
 212     if test "${WithGhc}" != ""
 213     then
 214         build=$bootstrap_target
 215         echo "Build platform inferred as: $build"
 216     else
 217         echo "Can't work out build platform"
 218         exit 1
 219     fi
 220
 221     BuildArch=`echo "$build" | sed 's/-.*//'`
 222     BuildVendor=`echo "$build" | sed -e 's/.*-\(.*\)-.*/\1/'`
 223     BuildOS=`echo "$build" | sed 's/.*-//'`
 224 else
 225     GHC_CONVERT_CPU([$build_cpu], [BuildArch])
 226     GHC_CONVERT_VENDOR([$build_vendor], [BuildVendor])
 227     GHC_CONVERT_OS([$build_os], [BuildOS])
 228 fi
 229
 230 if test "$host_alias" = ""
 231 then
 232     if test "${WithGhc}" != ""
 233     then
 234         host=$bootstrap_target
 235         echo "Host platform inferred as: $host"
 236     else
 237         echo "Can't work out host platform"
 238         exit 1
 239     fi
 240
 241     HostArch=`echo "$host" | sed 's/-.*//'`
 242     HostVendor=`echo "$host" | sed -e 's/.*-\(.*\)-.*/\1/'`
 243     HostOS=`echo "$host" | sed 's/.*-//'`
 244 else
 245     GHC_CONVERT_CPU([$host_cpu], [HostArch])
 246     GHC_CONVERT_VENDOR([$host_vendor], [HostVendor])
 247     GHC_CONVERT_OS([$host_os], [HostOS])
 248 fi
 249
 250 if test "$target_alias" = ""
 251 then
 252     if test "${WithGhc}" != ""
 253     then
 254         target=$bootstrap_target
 255         echo "Target platform inferred as: $target"
 256     else
 257         echo "Can't work out target platform"
 258         exit 1
 259     fi
 260
 261     TargetArch=`echo "$target" | sed 's/-.*//'`
 262     TargetVendor=`echo "$target" | sed -e 's/.*-\(.*\)-.*/\1/'`
 263     TargetOS=`echo "$target" | sed 's/.*-//'`
 264 else
 265     GHC_CONVERT_CPU([$target_cpu], [TargetArch])
 266     GHC_CONVERT_VENDOR([$target_vendor], [TargetVendor])
 267     GHC_CONVERT_OS([$target_os], [TargetOS])
 268 fi
 269
 270 exeext=''
 271 soext='.so'
 272 case $host in
 273 *-unknown-cygwin32)
 274     AC_MSG_WARN([GHC does not support the Cygwin target at the moment])
 275     AC_MSG_WARN([I'm assuming you wanted to build for i386-unknown-mingw32])
 276     exit 1
 277     ;;
 278 *-unknown-mingw32)
 279     exeext='.exe'
 280     soext='.dll'
 281     ;;
 282 i386-apple-darwin|powerpc-apple-darwin)
 283     soext='.dylib'
 284     ;;
 285 x86_64-apple-darwin)
 286     soext='.dylib'
 287     ;;
 288 esac
 289
 290 checkArch() {
 291     case $1 in
 292     alpha|arm|hppa|hppa1_1|i386|ia64|m68k|mips|mipseb|mipsel|powerpc|powerpc64|rs6000|s390|sparc|sparc64|vax|x86_64)
 293         ;;
 294     *)
 295         echo "Unknown arch $1"
 296         exit 1
 297         ;;
 298     esac
 299 }
 300
 301 checkVendor() {
 302     case $1 in
 303     dec|unknown|hp|apple|next|sun|sgi|ibm)
 304         ;;
 305     *)
 306         echo "Unknown vendor $1"
 307         exit 1
 308         ;;
 309     esac
 310 }
 311
 312 checkOS() {
 313     case $1 in
 314     linux|freebsd|netbsd|openbsd|dragonfly|osf1|osf3|hpux|linuxaout|kfreebsdgnu|freebsd2|solaris2|cygwin32|mingw32|darwin|gnu|nextstep2|nextstep3|sunos4|ultrix|irix|aix|haiku)
 315         ;;
 316     *)
 317         echo "Unknown OS '$1'"
 318         exit 1
 319         ;;
 320     esac
 321 }
 322
 323 BuildPlatform="$BuildArch-$BuildVendor-$BuildOS"
 324 BuildPlatform_CPP=`echo "$BuildPlatform" | sed -e 's/\./_/g' -e 's/-/_/g'`
 325 BuildArch_CPP=`    echo "$BuildArch"     | sed -e 's/\./_/g' -e 's/-/_/g'`
 326 BuildVendor_CPP=`  echo "$BuildVendor"   | sed -e 's/\./_/g' -e 's/-/_/g'`
 327 BuildOS_CPP=`      echo "$BuildOS"       | sed -e 's/\./_/g' -e 's/-/_/g'`
 328
 329 checkArch "$BuildArch"
 330 checkVendor "$BuildVendor"
 331 checkOS "$BuildOS"
 332
 333 HostPlatform="$HostArch-$HostVendor-$HostOS"
 334 HostPlatform_CPP=`echo "$HostPlatform" | sed -e 's/\./_/g' -e 's/-/_/g'`
 335 HostArch_CPP=`    echo "$HostArch"     | sed -e 's/\./_/g' -e 's/-/_/g'`
 336 HostVendor_CPP=`  echo "$HostVendor"   | sed -e 's/\./_/g' -e 's/-/_/g'`
 337 HostOS_CPP=`      echo "$HostOS"       | sed -e 's/\./_/g' -e 's/-/_/g'`
 338
 339 checkArch "$HostArch"
 340 checkVendor "$HostVendor"
 341 checkOS "$HostOS"
 342
 343 TargetPlatform="$TargetArch-$TargetVendor-$TargetOS"
 344 TargetPlatform_CPP=`echo "$TargetPlatform" | sed -e 's/\./_/g' -e 's/-/_/g'`
 345 TargetArch_CPP=`    echo "$TargetArch"     | sed -e 's/\./_/g' -e 's/-/_/g'`
 346 TargetVendor_CPP=`  echo "$TargetVendor"   | sed -e 's/\./_/g' -e 's/-/_/g'`
 347 TargetOS_CPP=`      echo "$TargetOS"       | sed -e 's/\./_/g' -e 's/-/_/g'`
 348
 349 checkArch "$TargetArch"
 350 checkVendor "$TargetVendor"
 351 checkOS "$TargetOS"
 352
 353 AC_SUBST(BuildPlatform)
 354 AC_SUBST(HostPlatform)
 355 AC_SUBST(TargetPlatform)
 356 AC_SUBST(HostPlatform_CPP)
 357 AC_SUBST(BuildPlatform_CPP)
 358 AC_SUBST(TargetPlatform_CPP)
 359
 360 AC_SUBST(HostArch_CPP)
 361 AC_SUBST(BuildArch_CPP)
 362 AC_SUBST(TargetArch_CPP)
 363
 364 AC_SUBST(HostOS_CPP)
 365 AC_SUBST(BuildOS_CPP)
 366 AC_SUBST(TargetOS_CPP)
 367
 368 AC_SUBST(HostVendor_CPP)
 369 AC_SUBST(BuildVendor_CPP)
 370 AC_SUBST(TargetVendor_CPP)
 371
 372 AC_SUBST(exeext)
 373 AC_SUBST(soext)
 374
 375 AC_ARG_WITH(hc,
 376 [AC_HELP_STRING([--with-hc=ARG],
 377         [Use ARG as the path to the compiler for compiling ordinary
 378          Haskell code  (default= value of --with-ghc)])],
 379 [WithHc="$withval"],
 380 [WithHc=$WithGhc]
 381 )
 382 AC_SUBST(WithHc)
 383
 384 # This uses GHC, so put it after the "GHC is required" check above:
 385 FP_INTREE_GHC_PWD
 386 FP_FIND_ROOT
 387
 388 if test "$HostOS" = "mingw32"
 389 then
 390     test -d inplace || mkdir inplace
 391
 392     CC="$hardtop/inplace/mingw/bin/gcc.exe"
 393     LD="$hardtop/inplace/mingw/bin/ld.exe"
 394     NM="$hardtop/inplace/mingw/bin/nm.exe"
 395     fp_prog_ar_raw="$hardtop/inplace/mingw/bin/ar.exe"
 396     if ! test -d inplace/mingw ||
 397          test inplace/mingw -ot ghc-tarballs/mingw/binutils*.tar.lzma  ||
 398          test inplace/mingw -ot ghc-tarballs/mingw/gcc-core*.tar.lzma  ||
 399          test inplace/mingw -ot ghc-tarballs/mingw/gcc-c++*.tar.lzma   ||
 400          test inplace/mingw -ot ghc-tarballs/mingw/libgmp*.tar.gz      ||
 401          test inplace/mingw -ot ghc-tarballs/mingw/libmpc*.tar.gz      ||
 402          test inplace/mingw -ot ghc-tarballs/mingw/libmpfr*.tar.gz     ||
 403          test inplace/mingw -ot ghc-tarballs/mingw/mingwrt*-dev.tar.gz ||
 404          test inplace/mingw -ot ghc-tarballs/mingw/mingwrt*-dll.tar.gz ||
 405          test inplace/mingw -ot ghc-tarballs/mingw/w32api*.tar.lzma
 406     then
 407         AC_MSG_NOTICE([Making in-tree mingw tree])
 408         rm -rf inplace/mingw
 409         mkdir inplace/mingw
 410         (
 411             cd inplace/mingw &&
 412             tar --lzma -xf ../../ghc-tarballs/mingw/binutils*.tar.lzma  &&
 413             tar --lzma -xf ../../ghc-tarballs/mingw/gcc-core*.tar.lzma  &&
 414             tar --lzma -xf ../../ghc-tarballs/mingw/gcc-c++*.tar.lzma   &&
 415             tar --lzma -xf ../../ghc-tarballs/mingw/libgmp*.tar.lzma    &&
 416             tar --lzma -xf ../../ghc-tarballs/mingw/libmpc*.tar.lzma    &&
 417             tar --lzma -xf ../../ghc-tarballs/mingw/libmpfr*.tar.lzma   &&
 418             tar -z     -xf ../../ghc-tarballs/mingw/mingwrt*-dev.tar.gz &&
 419             tar -z     -xf ../../ghc-tarballs/mingw/mingwrt*-dll.tar.gz &&
 420             tar --lzma -xf ../../ghc-tarballs/mingw/w32api*.tar.lzma    &&
 421             mv bin/gcc.exe bin/realgcc.exe
 422         )
 423         PATH=`pwd`/inplace/mingw/bin:$PATH inplace/mingw/bin/realgcc.exe driver/gcc/gcc.c driver/utils/cwrapper.c driver/utils/getLocation.c -Idriver/utils -o inplace/mingw/bin/gcc.exe
 424         if ! test -e inplace/mingw/bin/gcc.exe
 425         then
 426             AC_MSG_ERROR([GHC is required unless bootstrapping from .hc files.])
 427         fi
 428         AC_MSG_NOTICE([In-tree mingw tree created])
 429     fi
 430     if ! test -d inplace/perl ||
 431          test inplace/perl -ot ghc-tarballs/perl/ghc-perl*.tar.gz
 432     then
 433         AC_MSG_NOTICE([Making in-tree perl tree])
 434         rm -rf inplace/perl
 435         mkdir inplace
 436         mkdir inplace/perl
 437         (
 438             cd inplace/perl &&
 439             tar -zxf ../../ghc-tarballs/perl/ghc-perl*.tar.gz
 440         )
 441         AC_MSG_NOTICE([In-tree perl tree created])
 442     fi
 443 fi
 444
 445 dnl ** Which gcc to use?
 446 dnl --------------------------------------------------------------
 447 FP_ARG_WITH_PATH_GNU_PROG([CC], [gcc])
 448 export CC
 449 WhatGccIsCalled="$CC"
 450 AC_SUBST(WhatGccIsCalled)
 451
 452 dnl ** Which ld to use?
 453 dnl --------------------------------------------------------------
 454 FP_ARG_WITH_PATH_GNU_PROG([LD], [ld])
 455 LdCmd="$LD"
 456 AC_SUBST([LdCmd])
 457
 458 dnl ** Which nm to use?
 459 dnl --------------------------------------------------------------
 460 FP_ARG_WITH_PATH_GNU_PROG([NM], [nm])
 461 NmCmd="$NM"
 462 AC_SUBST([NmCmd])
 463
 464 dnl ** Mac OS X: explicit deployment target
 465 dnl --------------------------------------------------------------
 466 AC_ARG_WITH([macosx-deployment-target],
 467 [AC_HELP_STRING([--with-macosx-deployment-target=VERSION],
 468         [Build for Mac OS VERSION and higher  (default= version of build host)])],
 469 [FP_MACOSX_DEPLOYMENT_TARGET="$withval"
 470  if test "x$TargetOS_CPP-$TargetVendor_CPP" != "xdarwin-apple"; then
 471    # ignore everywhere, but on Mac OS
 472    AC_MSG_WARN([--macosx-deployment-target is only available on Mac OS X])
 473    FP_MACOSX_DEPLOYMENT_TARGET=none
 474  fi],
 475 [FP_MACOSX_DEPLOYMENT_TARGET=none]
 476 )
 477 FP_CHECK_MACOSX_DEPLOYMENT_TARGET
 478 AC_SUBST(MACOSX_DEPLOYMENT_VERSION)
 479 AC_SUBST(MACOSX_DEPLOYMENT_SDK)
 480
 481 dnl --------------------------------------------------------------
 482 dnl End of configure script option section
 483 dnl --------------------------------------------------------------
 484
 485
 486 dnl --------------------------------------------------------------
 487 dnl * General configuration checks
 488 dnl --------------------------------------------------------------
 489
 490 dnl ** Can the unix package be built?
 491 dnl --------------------------------------------------------------
 492
 493 if test x"$TargetPlatform" = x"i386-unknown-mingw32"; then
 494    GhcLibsWithUnix=NO
 495 else
 496    GhcLibsWithUnix=YES
 497 fi
 498 AC_SUBST([GhcLibsWithUnix])
 499
 500 dnl ** does #! work?
 501 AC_SYS_INTERPRETER()
 502
 503 dnl ** look for `perl'
 504 case $HostOS_CPP in
 505 cygwin32|mingw32)
 506     PerlCmd=$hardtop/inplace/perl/perl
 507     ;;
 508 *)
 509     AC_PATH_PROG(PerlCmd,perl)
 510     if test -z "$PerlCmd"
 511     then
 512         echo "You must install perl before you can continue"
 513         echo "Perhaps it is already installed, but not in your PATH?"
 514         exit 1
 515     else
 516         FPTOOLS_CHECK_PERL_VERSION
 517     fi
 518     ;;
 519 esac
 520
 521 dnl ** does #! path/to/perl work? (sometimes it's too long...)
 522 FPTOOLS_SHEBANG_PERL
 523
 524 dnl ** check for Python
 525 AC_PATH_PROG(PythonCmd,python)
 526
 527 dnl ** look for GCC and find out which version
 528 dnl     Figure out which C compiler to use.  Gcc is preferred.
 529 dnl     If gcc, make sure it's at least 2.1
 530 dnl
 531 FP_HAVE_GCC
 532
 533 FPTOOLS_SET_C_LD_FLAGS([target],[CFLAGS],[LDFLAGS])
 534 FPTOOLS_SET_C_LD_FLAGS([build],[CONF_CC_OPTS_STAGE0],[CONF_LD_OPTS_STAGE0])
 535 FPTOOLS_SET_C_LD_FLAGS([target],[CONF_CC_OPTS_STAGE1],[CONF_LD_OPTS_STAGE1])
 536 # Stage 3 won't be supported by cross-compilation
 537 FPTOOLS_SET_C_LD_FLAGS([target],[CONF_CC_OPTS_STAGE2],[CONF_LD_OPTS_STAGE2])
 538
 539 FP_GCC_EXTRA_FLAGS
 540
 541 dnl ** figure out how to invoke cpp directly (gcc -E is no good)
 542 AC_PROG_CPP
 543
 544 AC_SUBST(CONF_CC_OPTS_STAGE0)
 545 AC_SUBST(CONF_CC_OPTS_STAGE1)
 546 AC_SUBST(CONF_CC_OPTS_STAGE2)
 547 AC_SUBST(CONF_LD_OPTS_STAGE0)
 548 AC_SUBST(CONF_LD_OPTS_STAGE1)
 549 AC_SUBST(CONF_LD_OPTS_STAGE2)
 550
 551 dnl ** figure out how to do context diffs
 552 FP_PROG_CONTEXT_DIFF
 553
 554 dnl Let's make sure install-sh is executable here.  If we got it from
 555 dnl a darcs repo, it might not be (see bug #978).
 556 chmod +x install-sh
 557 dnl ** figure out how to do a BSD-ish install
 558 AC_PROG_INSTALL
 559
 560 dnl If you can run configure, you certainly have /bin/sh
 561 AC_DEFINE([HAVE_BIN_SH], [1], [Define to 1 if you have /bin/sh.])
 562
 563 dnl ** how to invoke `ar' and `ranlib'
 564 FP_PROG_AR_SUPPORTS_ATFILE
 565 FP_PROG_AR_NEEDS_RANLIB
 566 FP_PROG_AR_SUPPORTS_INPUT
 567
 568 dnl ** Check to see whether ln -s works
 569 AC_PROG_LN_S
 570
 571
 572 dnl ** Find the path to sed
 573 AC_PATH_PROGS(SedCmd,gsed sed,sed)
 574
 575
 576 dnl ** check for time command
 577 AC_PATH_PROG(TimeCmd,time)
 578
 579 dnl ** check for tar
 580 dnl   if GNU tar is named gtar, look for it first.
 581 AC_PATH_PROGS(TarCmd,gnutar gtar tar,tar)
 582
 583 dnl ** check for patch
 584 dnl if GNU patch is named gpatch, look for it first
 585 AC_PATH_PROGS(PatchCmd,gpatch patch, patch)
 586
 587 dnl ** check for dtrace (currently only implemented for Mac OS X)
 588 HaveDtrace=NO
 589 AC_PATH_PROG(DtraceCmd,dtrace)
 590 if test -n "$DtraceCmd"; then
 591   if test "x$TargetOS_CPP-$TargetVendor_CPP" == "xdarwin-apple"; then
 592     HaveDtrace=YES
 593   fi
 594 fi
 595 AC_SUBST(HaveDtrace)
 596
 597 AC_PATH_PROG(HSCOLOUR,HsColour)
 598 # HsColour is passed to Cabal, so we need a native path
 599 if test "x$HostPlatform"  = "xi386-unknown-mingw32" && \
 600    test "${OSTYPE}"      != "msys"                  && \
 601    test "${HSCOLOUR}"    != ""
 602 then
 603     # Canonicalise to <drive>:/path/to/gcc
 604     HSCOLOUR=`cygpath -m ${HSCOLOUR}`
 605 fi
 606
 607 dnl ** check for DocBook toolchain
 608 FP_CHECK_DOCBOOK_DTD
 609 FP_DOCBOOK_XSL
 610 FP_PROG_DBLATEX
 611
 612 FP_PROG_HSTAGS
 613
 614 dnl ** check for ghc-pkg command
 615 FP_PROG_GHC_PKG
 616
 617 dnl ** check for installed happy binary + version
 618 dnl    (don't do it if we're booting from .hc files though.)
 619 if test "$BootingFromHc" = "NO"; then
 620 FPTOOLS_HAPPY
 621 fi;
 622
 623 dnl ** check for installed alex binary + version
 624 dnl    (don't do it if we're booting from .hc files though.)
 625 if test "$BootingFromHc" = "NO"; then
 626 FPTOOLS_ALEX
 627 fi;
 628
 629 dnl --------------------------------------------------
 630 dnl ### program checking section ends here ###
 631 dnl --------------------------------------------------
 632
 633 dnl --------------------------------------------------
 634 dnl * Platform header file and syscall feature tests
 635 dnl ### checking the state of the local header files and syscalls ###
 636
 637 dnl ** check for full ANSI header (.h) files
 638 AC_HEADER_STDC
 639
 640 dnl ** Enable large file support.  NB. do this before testing the type of
 641 dnl    off_t, because it will affect the result of that test.
 642 AC_SYS_LARGEFILE
 643
 644 dnl ** check for specific header (.h) files that we are interested in
 645 AC_CHECK_HEADERS([bfd.h ctype.h dirent.h dlfcn.h errno.h fcntl.h grp.h limits.h locale.h nlist.h pthread.h pwd.h signal.h sys/cpuset.h sys/mman.h sys/resource.h sys/select.h sys/time.h sys/timeb.h sys/timers.h sys/times.h sys/utsname.h sys/wait.h termios.h time.h utime.h windows.h winsock.h sched.h])
 646
 647 dnl ** check if it is safe to include both <time.h> and <sys/time.h>
 648 AC_HEADER_TIME
 649
 650 dnl ** do we have long longs?
 651 AC_CHECK_TYPES([long long])
 652
 653 dnl ** what are the sizes of various types
 654 AC_CHECK_SIZEOF(char,               1)
 655 AC_CHECK_SIZEOF(double,             8)
 656 AC_CHECK_SIZEOF(float,              4)
 657 AC_CHECK_SIZEOF(int,                4)
 658 AC_CHECK_SIZEOF(long,               4)
 659 if test "$ac_cv_type_long_long" = yes; then
 660 AC_CHECK_SIZEOF(long long,          8)
 661 fi
 662 AC_CHECK_SIZEOF(short,              2)
 663 AC_CHECK_SIZEOF(unsigned char,      1)
 664 AC_CHECK_SIZEOF(unsigned int,       4)
 665 AC_CHECK_SIZEOF(unsigned long,      4)
 666 if test "$ac_cv_type_long_long" = yes; then
 667 AC_CHECK_SIZEOF(unsigned long long, 8)
 668 fi
 669 AC_CHECK_SIZEOF(unsigned short,     2)
 670 AC_CHECK_SIZEOF(void *,             4)
 671
 672 dnl ** what are alignment constraints on various types
 673 FP_CHECK_ALIGNMENT(char)
 674 FP_CHECK_ALIGNMENT(double)
 675 FP_CHECK_ALIGNMENT(float)
 676 FP_CHECK_ALIGNMENT(int)
 677 FP_CHECK_ALIGNMENT(long)
 678 if test "$ac_cv_type_long_long" = yes; then
 679 FP_CHECK_ALIGNMENT(long long)
 680 fi
 681 FP_CHECK_ALIGNMENT(short)
 682 FP_CHECK_ALIGNMENT(unsigned char)
 683 FP_CHECK_ALIGNMENT(unsigned int)
 684 FP_CHECK_ALIGNMENT(unsigned long)
 685 if test "$ac_cv_type_long_long" = yes; then
 686 FP_CHECK_ALIGNMENT(unsigned long long)
 687 fi
 688 FP_CHECK_ALIGNMENT(unsigned short)
 689 FP_CHECK_ALIGNMENT(void *)
 690
 691 FP_CHECK_FUNC([WinExec],
 692   [@%:@include <windows.h>], [WinExec("",0)])
 693
 694 FP_CHECK_FUNC([GetModuleFileName],
 695   [@%:@include <windows.h>], [GetModuleFileName((HMODULE)0,(LPTSTR)0,0)])
 696
 697 dnl ** check return type of signal handlers
 698 dnl Foo: assumes we can use prototypes.
 699 dnl On BCC, signal handlers have type "int(void)", elsewhere its "void(int)".
 700 dnl AC_CACHE_CHECK([type of signal handlers], ac_cv_type_signal_handler,
 701 dnl [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 702 dnl #include <signal.h>
 703 dnl #ifdef signal
 704 dnl #undef signal
 705 dnl #endif
 706 dnl void (*signal (int, void (*)(int)))(int);
 707 dnl ]],
 708 dnl [[int i;]])],
 709 dnl [ac_cv_type_signal_handler=void_int],
 710 dnl [ac_cv_type_signal_handler=int_void])])
 711 dnl if test "$ac_cv_type_signal_handler" = void_int; then
 712 dnl AC_DEFINE(VOID_INT_SIGNALS)
 713 dnl fi
 714
 715 dnl On BCC, signal handlers have type "int(void)", elsewhere its "void(int)".
 716 AC_TYPE_SIGNAL
 717 if test "$ac_cv_type_signal" = void; then
 718   AC_DEFINE([VOID_INT_SIGNALS], [1], [Define to 1 if signal handlers have type void (*)(int). Otherwise, they're assumed to have type int (*)(void).])
 719 fi
 720
 721 dnl ** check for more functions
 722 dnl ** The following have been verified to be used in ghc/, but might be used somewhere else, too.
 723 AC_CHECK_FUNCS([getclock getrusage gettimeofday setitimer siginterrupt sysconf times ctime_r sched_setaffinity setlocale])
 724
 725 AC_TRY_RUN([
 726 #include <sys/types.h>
 727 #include <sys/time.h>
 728 int main(void) {
 729   struct itimerval tval;
 730   tval.it_value.tv_sec = 1;
 731   tval.it_value.tv_usec = 0;
 732   tval.it_interval = tval.it_value;
 733   return setitimer(ITIMER_VIRTUAL, &tval, (void*)0) != 0;
 734 }
 735 ],[AC_DEFINE([HAVE_SETITIMER_VIRTUAL], [1], [Define to 1 if setitimer accepts ITIMER_VIRTUAL, 0 else.])])
 736
 737 dnl ** On OS X 10.4 (at least), time.h doesn't declare ctime_r if
 738 dnl ** _POSIX_C_SOURCE is defined
 739 AC_CHECK_DECLS([ctime_r], , ,
 740 [#define _POSIX_SOURCE 1
 741 #define _POSIX_C_SOURCE 199506L
 742 #include <time.h>])
 743
 744 dnl ** check for mingwex library
 745 AC_CHECK_LIB(mingwex, closedir, HaveLibMingwEx=YES, HaveLibMingwEx=NO)
 746 AC_SUBST(HaveLibMingwEx)
 747
 748 if test $HaveLibMingwEx = YES ; then
 749   AC_DEFINE([HAVE_MINGWEX], [1], [Define to 1 if you have the mingwex library.])
 750 fi
 751
 752 dnl ** check for math library
 753 dnl    Keep that check as early as possible.
 754 dnl    as we need to know whether we need libm
 755 dnl    for math functions or not
 756 dnl    (see http://hackage.haskell.org/trac/ghc/ticket/3730)
 757 AC_CHECK_LIB(m, atan, HaveLibM=YES, HaveLibM=NO)
 758 if test $HaveLibM = YES
 759 then
 760   AC_DEFINE([HAVE_LIBM], [1], [Define to 1 if you need to link with libm])
 761 fi
 762
 763 dnl ** check whether this machine has BFD and liberty installed (used for debugging)
 764 dnl    the order of these tests matters: bfd needs liberty
 765 AC_CHECK_LIB(iberty, xmalloc)
 766 AC_CHECK_LIB(bfd,    bfd_init)
 767
 768 dnl ################################################################
 769 dnl Check for libraries
 770 dnl ################################################################
 771
 772 dnl ** check whether we need -ldl to get dlopen()
 773
 774 AC_CHECK_LIB(dl, dlopen,
 775     [HaveLibDL=YES
 776      AC_DEFINE([HAVE_LIBDL], [1], [Define to 1 if you need -ldl to get dlopen().])
 777      LIBS="$LIBS -ldl"],
 778     [HaveLibDL=NO])
 779 AC_SUBST(HaveLibDL)
 780
 781 dnl --------------------------------------------------
 782 dnl * Miscellaneous feature tests
 783 dnl --------------------------------------------------
 784
 785 dnl ** can we get alloca?
 786 AC_FUNC_ALLOCA
 787
 788 dnl ** Working vfork?
 789 AC_FUNC_FORK
 790
 791 dnl ** determine whether or not const works
 792 AC_C_CONST
 793
 794 dnl ** are we big endian?
 795 AC_C_BIGENDIAN
 796 FPTOOLS_FLOAT_WORD_ORDER_BIGENDIAN
 797
 798 dnl ** check for leading underscores in symbol names
 799 FP_LEADING_UNDERSCORE
 800
 801 dnl ** check for ld, whether it has an -x option, and if it is GNU ld
 802 FP_PROG_LD_X
 803 FP_PROG_LD_IS_GNU
 804
 805 dnl ** check for Apple-style dead-stripping support
 806 dnl    (.subsections-via-symbols assembler directive)
 807
 808
 809 AC_MSG_CHECKING(for .subsections_via_symbols)
 810 AC_COMPILE_IFELSE(
 811     [AC_LANG_PROGRAM([], [__asm__ (".subsections_via_symbols");])],
 812     [AC_MSG_RESULT(yes)
 813      AC_DEFINE([HAVE_SUBSECTIONS_VIA_SYMBOLS],[1],
 814                [Define to 1 if Apple-style dead-stripping is supported.])
 815     ],
 816     [AC_MSG_RESULT(no)])
 817
 818 dnl *** check for GNU non-executable stack note support (ELF only)
 819 dnl     (.section .note.GNU-stack,"",@progbits)
 820
 821 dnl This test doesn't work with "gcc -g" in gcc 4.4 (GHC trac #3889:
 822 dnl     Error: can't resolve `.note.GNU-stack' {.note.GNU-stack section} - `.Ltext0' {.text section}
 823 dnl so we empty CFLAGS while running this test
 824 CFLAGS2="$CFLAGS"
 825 CFLAGS=
 826 AC_MSG_CHECKING(for GNU non-executable stack support)
 827 AC_COMPILE_IFELSE(
 828     [AC_LANG_PROGRAM([__asm__ (".section .note.GNU-stack,\"\",@progbits");], [0])],
 829     [AC_MSG_RESULT(yes)
 830      AC_DEFINE([HAVE_GNU_NONEXEC_STACK],[1],
 831                [Define to 1 if GNU non-executable stack notes are supported.])
 832     ],
 833     [AC_MSG_RESULT(no)])
 834 CFLAGS="$CFLAGS2"
 835
 836 FP_VISIBILITY_HIDDEN
 837
 838 dnl ** check for librt
 839 AC_CHECK_LIB(rt, clock_gettime)
 840 AC_CHECK_FUNCS(clock_gettime timer_create timer_settime)
 841 FP_CHECK_TIMER_CREATE
 842
 843 dnl ** check for Apple's "interesting" long double compatibility scheme
 844 AC_MSG_CHECKING(for printf\$LDBLStub)
 845 AC_TRY_LINK_FUNC(printf\$LDBLStub,
 846     [
 847         AC_MSG_RESULT(yes)
 848         AC_DEFINE([HAVE_PRINTF_LDBLSTUB],[1],
 849             [Define to 1 if we have printf$LDBLStub (Apple Mac OS >= 10.4, PPC).])
 850     ],
 851     [
 852         AC_MSG_RESULT(no)
 853         AC_DEFINE([HAVE_PRINTF_LDBLSTUB],[0],
 854             [Define to 1 if we have printf$LDBLStub (Apple Mac OS >= 10.4, PPC).])
 855     ])
 856
 857 dnl ** check for eventfd which is needed by the I/O manager
 858 AC_CHECK_HEADERS([sys/eventfd.h])
 859 AC_CHECK_FUNCS([eventfd])
 860
 861 # test for GTK+
 862 AC_PATH_PROGS([GTK_CONFIG], [pkg-config])
 863 if test -n "$GTK_CONFIG"; then
 864   if $GTK_CONFIG gtk+-2.0 --atleast-version=2.0; then
 865     GTK_CONFIG="$GTK_CONFIG gtk+-2.0"
 866   else
 867     AC_MSG_WARN([GTK+ not usable, need at least version 2.0])
 868     GTK_CONFIG=
 869   fi
 870 fi
 871 AC_SUBST([GTK_CONFIG])
 872
 873 #Checking for PAPI
 874 AC_CHECK_LIB(papi, PAPI_library_init, HavePapiLib=YES, HavePapiLib=NO)
 875 AC_CHECK_HEADER([papi.h], [HavePapiHeader=YES], [HavePapiHeader=NO])
 876 AC_SUBST(HavePapiLib)
 877 AC_SUBST(HavePapiHeader)
 878
 879 AC_CHECK_FUNCS(__mingw_vfprintf)
 880
 881 if test "$HavePapiLib" = "YES" -a "$HavePapiHeader" = "YES"; then
 882    HavePapi=YES
 883 else
 884    HavePapi=NO
 885 fi
 886 AC_SUBST(HavePapi)
 887
 888 if test "$HAVE_DOCBOOK_XSL" = "NO" ||
 889    test "$XsltprocCmd" = ""
 890 then
 891     BUILD_DOCBOOK_HTML=NO
 892 else
 893     BUILD_DOCBOOK_HTML=YES
 894 fi
 895 AC_SUBST(BUILD_DOCBOOK_HTML)
 896
 897 if test "$DblatexCmd" = ""
 898 then
 899     BUILD_DOCBOOK_PS=NO
 900     BUILD_DOCBOOK_PDF=NO
 901 else
 902     BUILD_DOCBOOK_PS=YES
 903     BUILD_DOCBOOK_PDF=YES
 904 fi
 905 AC_SUBST(BUILD_DOCBOOK_PS)
 906 AC_SUBST(BUILD_DOCBOOK_PDF)
 907
 908 LIBRARY_VERSION(base)
 909 LIBRARY_VERSION(Cabal)
 910 LIBRARY_VERSION(ghc-prim)
 911 LIBRARY_ghc_VERSION="$ProjectVersion"
 912 AC_SUBST(LIBRARY_ghc_VERSION)
 913
 914 if grep '       ' compiler/ghc.cabal.in 2>&1 >/dev/null; then
 915    AC_MSG_ERROR([compiler/ghc.cabal.in contains tab characters; please remove them])
 916 fi
 917
 918 AC_CONFIG_FILES([mk/config.mk mk/install.mk mk/project.mk compiler/ghc.cabal ghc/ghc-bin.cabal utils/runghc/runghc.cabal ghc.spec extra-gcc-opts docs/users_guide/ug-book.xml docs/users_guide/ug-ent.xml docs/index.html libraries/prologue.txt distrib/ghc.iss distrib/configure.ac distrib/MacOS/installer-scripts/create-links distrib/MacOS/installer-scripts/Uninstaller distrib/MacOS/GHC-system.pmdoc/index.xml])
 919 AC_CONFIG_COMMANDS([mk/stamp-h],[echo timestamp > mk/stamp-h])
 920 AC_OUTPUT
 921
 922 # We get caught by
 923 #     http://savannah.gnu.org/bugs/index.php?1516
 924 #     $(eval ...) inside conditionals causes errors
 925 # with make 3.80, so warn the user if it looks like they're about to
 926 # try to use it.
 927 # We would use "grep -q" here, but Solaris's grep doesn't support it.
 928 checkMake380() {
 929     if $1 --version 2>&1 | head -1 | grep 'GNU Make 3\.80' > /dev/null
 930     then
 931         echo
 932         echo "WARNING: It looks like \"$1\" is GNU make 3.80."
 933         echo "This version cannot be used to build GHC."
 934         echo "Please use GNU make >= 3.81."
 935     fi
 936 }
 937
 938 checkMake380 make
 939 checkMake380 gmake
 940
 941 echo ["
 942 ----------------------------------------------------------------------
 943 Configure completed successfully.
 944
 945    Building GHC version  : $ProjectVersion
 946
 947    Build platform        : $BuildPlatform
 948    Host platform         : $HostPlatform
 949    Target platform       : $TargetPlatform
 950 "]
 951
 952 if test "$BootingFromHc" = "YES"; then
 953 echo ["\
 954    Bootstrapping from HC files.
 955 "]
 956 else
 957 echo ["\
 958    Bootstrapping using   : $WithGhc
 959       which is version   : $GhcVersion
 960 "]
 961 fi
 962
 963 echo ["\
 964    Using GCC             : $WhatGccIsCalled
 965       which is version   : $GccVersion
 966
 967    ld       : $LdCmd
 968    Happy    : $HappyCmd ($HappyVersion)
 969    Alex     : $AlexCmd ($AlexVersion)
 970    Python   : $PythonCmd
 971    Perl     : $PerlCmd
 972    dblatex  : $DblatexCmd
 973    xsltproc : $XsltprocCmd"]
 974
 975 if test "$HSCOLOUR" = ""; then
 976 echo ["
 977    HsColour was not found; documentation will not contain source links
 978 "]
 979 else
 980 echo ["\
 981    HsColour : $HSCOLOUR
 982 "]
 983 fi
 984
 985 echo ["\
 986    Building DocBook HTML documentation : $BUILD_DOCBOOK_HTML
 987    Building DocBook PS documentation   : $BUILD_DOCBOOK_PS
 988    Building DocBook PDF documentation  : $BUILD_DOCBOOK_PDF"]
 989
 990 echo ["----------------------------------------------------------------------
 991 "]
 992
 993 echo "\
 994 For a standard build of GHC (fully optimised with profiling), type (g)make.
 995
 996 To make changes to the default build configuration, copy the file
 997 mk/build.mk.sample to mk/build.mk, and edit the settings in there.
 998
 999 For more information on how to configure your GHC build, see
1000    http://hackage.haskell.org/trac/ghc/wiki/Building
1001 "