configure.ac

   1 dnl == autoconf source for the Glasgow FP tools ==
   2 dnl (run "grep '^dnl \*' configure.ac | sed -e 's/dnl / /g; s/\*\*/   +/g;'"
   3 dnl  (or some such) to see the outline of this file)
   4 dnl
   5 #
   6 # (c) The University of Glasgow 1994-2004
   7 #
   8 # Configure script template for GHC
   9 #
  10 # Process with 'autoreconf' to get a working configure script.
  11 #
  12 # For the generated configure script, do "./configure --help" to
  13 # see what flags are available. (Better yet, read the documentation!)
  14 #
  15
  16 AC_INIT([The Glorious Glasgow Haskell Compilation System], [7.1], [glasgow-haskell-bugs@haskell.org], [ghc])
  17
  18 # Set this to YES for a released version, otherwise NO
  19 : ${RELEASE=NO}
  20
  21 # The primary version (e.g. 6.7, 6.6.1) is set in the AC_INIT line
  22 # above.  If this is not a released version, then we will append the
  23 # date to the version number (e.g. 6.7.20070204).  The date is
  24 # constructed by finding the date of the most recent patch in the
  25 # darcs repository.  If this is a source distribution (not a darcs
  26 # checkout), then we ship a file 'VERSION' containing the full version
  27 # when the source distribution was created.
  28
  29 if test ! -f mk/config.h.in; then
  30    echo "mk/config.h.in doesn't exist: perhaps you haven't run 'perl boot'?"
  31    exit 1
  32 fi
  33
  34 AC_SUBST([CONFIGURE_ARGS], [$ac_configure_args])
  35
  36 dnl ----------------------------------------------------------
  37 dnl ** Find unixy sort and find commands,
  38 dnl ** which are needed by FP_SETUP_PROJECT_VERSION
  39
  40 dnl ** Find find command (for Win32's benefit)
  41 FP_PROG_FIND
  42
  43 dnl ** Find sort command (for the benefit of Win32 environs)
  44 FP_PROG_SORT
  45
  46 dnl ----------------------------------------------------------
  47 FP_SETUP_PROJECT_VERSION
  48
  49 # Hmmm, we fix the RPM release number to 1 here... Is this convenient?
  50 AC_SUBST([release], [1])
  51
  52 # First off, a distrib sanity check..
  53 AC_CONFIG_SRCDIR([mk/config.mk.in])
  54
  55 dnl * We require autoconf version 2.52
  56 dnl We need 2.50 due to the use of AC_SYS_LARGEFILE and AC_MSG_NOTICE.
  57 dnl We need 2.52 due to the use of AS_TR_CPP and AS_TR_SH.
  58 AC_PREREQ([2.52])
  59
  60 # -------------------------------------------------------------------------
  61 # Prepare to generate the following header files
  62 #
  63 #
  64 AC_CONFIG_HEADER(mk/config.h)
  65
  66 # No, semi-sadly, we don't do `--srcdir'...
  67 if test x"$srcdir" != 'x.' ; then
  68     echo "This configuration does not support the \`--srcdir' option.."
  69     exit 1
  70 fi
  71
  72 dnl --------------------------------------------------------------
  73 dnl * Project specific configuration options
  74 dnl --------------------------------------------------------------
  75 dnl What follows is a bunch of options that can either be configured
  76 dnl through command line options to the configure script or by
  77 dnl supplying defns in the build tree's mk/build.mk. Having the option to
  78 dnl use either is considered a Feature.
  79
  80 dnl ** What command to use to compile compiler sources ?
  81 dnl --------------------------------------------------------------
  82
  83 AC_ARG_WITH([ghc],
  84 [AC_HELP_STRING([--with-ghc=ARG],
  85   [Use ARG as the path to GHC  [default=autodetect]])],
  86   [WithGhc="$withval"],
  87   [if test "$GHC" = ""; then
  88     AC_PATH_PROG([GHC], [ghc])
  89   fi
  90   WithGhc="$GHC"])
  91
  92
  93 dnl ** Tell the make system which OS we are using
  94 dnl $OSTYPE is set by the operating system to "msys" or "cygwin" or something
  95 AC_SUBST(OSTYPE)
  96
  97 dnl ** Booting from .hc files?
  98 dnl --------------------------------------------------------------
  99 AC_ARG_ENABLE(hc-boot,
 100 [AC_HELP_STRING([--enable-hc-boot],
 101 [Boot the Glasgow Haskell Compiler from intermediate .hc files.
 102  (This option is mostly of interest to porters.) [default=no]])],
 103 [ if test x"$enableval" = x"yes"; then
 104         BootingFromHc=YES
 105   else
 106         BootingFromHc=NO
 107   fi
 108 ],
 109 [BootingFromHc=NO]
 110 )
 111 AC_SUBST(BootingFromHc)
 112
 113 AC_ARG_ENABLE(bootstrap-with-devel-snapshot,
 114 [AC_HELP_STRING([--enable-bootstrap-with-devel-snapshot],
 115                 [Allow bootstrapping using a development snapshot of GHC.  This is not guaranteed to work.])],
 116         EnableBootstrapWithDevelSnaphost=YES,
 117         EnableBootstrapWithDevelSnaphost=NO
 118 )
 119
 120 if test "$WithGhc" != ""; then
 121   FPTOOLS_GHC_VERSION([GhcVersion], [GhcMajVersion], [GhcMinVersion], [GhcPatchLevel])dnl
 122
 123   if test "$GhcMajVersion" = "unknown" -o "$GhcMinVersion" = "unknown"; then
 124      AC_MSG_ERROR([Cannot determine the version of $WithGhc.  Is it really GHC?])
 125   fi
 126
 127   AC_SUBST(GhcVersion)dnl
 128   AC_SUBST(GhcMajVersion)dnl
 129   AC_SUBST(GhcMinVersion)dnl
 130   AC_SUBST(GhcPatchLevel)dnl
 131   GhcMinVersion2=`echo "$GhcMinVersion" | sed 's/^\\(.\\)$/0\\1/'`
 132   GhcCanonVersion="$GhcMajVersion$GhcMinVersion2"
 133   if test $GhcCanonVersion -ge 613; then ghc_ge_613=YES; else ghc_ge_613=NO; fi
 134   AC_SUBST(ghc_ge_613)dnl
 135 fi
 136
 137 dnl ** Must have GHC to build GHC, unless --enable-hc-boot is on
 138 if test "$BootingFromHc" = "NO" -a -d "$srcdir/compiler"; then
 139   if test "$WithGhc" = ""; then
 140      AC_MSG_ERROR([GHC is required unless bootstrapping from .hc files.])
 141   fi
 142   FP_COMPARE_VERSIONS([$GhcVersion],[-lt],[6.12],
 143     [AC_MSG_ERROR([GHC version 6.12 or later is required to compile GHC.])])dnl
 144
 145   if test `expr $GhcMinVersion % 2` = "1"; then
 146      if test "$EnableBootstrapWithDevelSnaphost" = "NO"; then
 147         AC_MSG_ERROR([
 148      $WithGhc is a development snapshot of GHC, version $GhcVersion.
 149      Bootstrapping using this version of GHC is not supported, and may not
 150      work.  Use --enable-bootstrap-with-devel-snapshot to try it anyway,
 151      or --with-ghc to specify a different GHC to use.])
 152      fi
 153   fi
 154 fi;
 155
 156 # GHC is passed to Cabal, so we need a native path
 157 if test "${WithGhc}" != ""
 158 then
 159     ghc_host=`"${WithGhc}" +RTS --info | grep 'Host platform' | sed -e 's/.*, "//' -e 's/")//'`
 160
 161     if test "$ghc_host" = "i386-unknown-mingw32"
 162     then
 163         if test "${OSTYPE}" = "msys"
 164         then
 165             WithGhc=`echo "${WithGhc}" | sed "s#^/\([a-zA-Z]\)/#\1:/#"`
 166         else
 167             # Canonicalise to <drive>:/path/to/ghc
 168             WithGhc=`cygpath -m "${WithGhc}"`
 169         fi
 170         echo "GHC path canonicalised to: ${WithGhc}"
 171     fi
 172 fi
 173 AC_SUBST([WithGhc])
 174
 175 dnl ** Without optimization some INLINE trickery fails for GHCi
 176 SRC_CC_OPTS="-O"
 177
 178 FP_ICONV
 179 FP_GMP
 180
 181 dnl--------------------------------------------------------------------
 182 dnl * Choose host(/target/build) platform
 183 dnl--------------------------------------------------------------------
 184 dnl If we aren't explicitly told what values to use with configure flags,
 185 dnl we ask the bootstrapping compiler what platform it is for
 186
 187 if test "${WithGhc}" != ""
 188 then
 189         bootstrap_host=`"${WithGhc}" +RTS --info | grep '^ ,("Host platform"' | sed -e 's/.*, "//' -e 's/")//' | tr -d '\r'`
 190         bootstrap_target=`"${WithGhc}" +RTS --info | grep '^ ,("Target platform"' | sed -e 's/.*, "//' -e 's/")//' | tr -d '\r'`
 191         if test "$bootstrap_host" != "$bootstrap_target"
 192         then
 193                 echo "Bootstrapping GHC is a cross compiler. This probably isn't going to work"
 194         fi
 195 fi
 196
 197 # We have to run these unconditionally, but we may discard their
 198 # results in the following code
 199 AC_CANONICAL_BUILD
 200 AC_CANONICAL_HOST
 201 AC_CANONICAL_TARGET
 202
 203 FPTOOLS_SET_PLATFORM_VARS
 204
 205 exeext=''
 206 soext='.so'
 207 case $host in
 208 *-unknown-cygwin32)
 209     AC_MSG_WARN([GHC does not support the Cygwin target at the moment])
 210     AC_MSG_WARN([I'm assuming you wanted to build for i386-unknown-mingw32])
 211     exit 1
 212     ;;
 213 *-unknown-mingw32)
 214     exeext='.exe'
 215     soext='.dll'
 216     ;;
 217 i386-apple-darwin|powerpc-apple-darwin)
 218     soext='.dylib'
 219     ;;
 220 x86_64-apple-darwin)
 221     soext='.dylib'
 222     ;;
 223 esac
 224
 225 # Testing if we shall enable shared libs support on Solaris.
 226 # Anything older than SunOS 5.11 aka Solaris 11 (Express) is broken.
 227
 228 SOLARIS_BROKEN_SHLD=NO
 229
 230 case $host in
 231      i386-*-solaris2)
 232      # here we go with the test
 233      MINOR=`uname -r|cut -d '.' -f 2-`
 234      if test "$MINOR" -lt "11"; then
 235         SOLARIS_BROKEN_SHLD=YES
 236      fi
 237      ;;
 238 esac
 239
 240 # Sync this with cTargetArch in compiler/ghc.mk
 241 checkArch() {
 242     case $1 in
 243     alpha|arm|hppa|hppa1_1|i386|ia64|m68k|mips|mipseb|mipsel|powerpc|powerpc64|rs6000|s390|sparc|sparc64|vax|x86_64)
 244         ;;
 245     *)
 246         echo "Unknown arch $1"
 247         exit 1
 248         ;;
 249     esac
 250 }
 251
 252 checkVendor() {
 253     case $1 in
 254     dec|unknown|hp|apple|next|sun|sgi|ibm)
 255         ;;
 256     *)
 257         echo "Unknown vendor $1"
 258         exit 1
 259         ;;
 260     esac
 261 }
 262
 263 checkOS() {
 264     case $1 in
 265     linux|freebsd|netbsd|openbsd|dragonfly|osf1|osf3|hpux|linuxaout|kfreebsdgnu|freebsd2|solaris2|cygwin32|mingw32|darwin|gnu|nextstep2|nextstep3|sunos4|ultrix|irix|aix|haiku)
 266         ;;
 267     *)
 268         echo "Unknown OS '$1'"
 269         exit 1
 270         ;;
 271     esac
 272 }
 273
 274 BuildPlatform="$BuildArch-$BuildVendor-$BuildOS"
 275 BuildPlatform_CPP=`echo "$BuildPlatform" | sed -e 's/\./_/g' -e 's/-/_/g'`
 276 BuildArch_CPP=`    echo "$BuildArch"     | sed -e 's/\./_/g' -e 's/-/_/g'`
 277 BuildVendor_CPP=`  echo "$BuildVendor"   | sed -e 's/\./_/g' -e 's/-/_/g'`
 278 BuildOS_CPP=`      echo "$BuildOS"       | sed -e 's/\./_/g' -e 's/-/_/g'`
 279
 280 checkArch "$BuildArch"
 281 checkVendor "$BuildVendor"
 282 checkOS "$BuildOS"
 283
 284 HostPlatform="$HostArch-$HostVendor-$HostOS"
 285 HostPlatform_CPP=`echo "$HostPlatform" | sed -e 's/\./_/g' -e 's/-/_/g'`
 286 HostArch_CPP=`    echo "$HostArch"     | sed -e 's/\./_/g' -e 's/-/_/g'`
 287 HostVendor_CPP=`  echo "$HostVendor"   | sed -e 's/\./_/g' -e 's/-/_/g'`
 288 HostOS_CPP=`      echo "$HostOS"       | sed -e 's/\./_/g' -e 's/-/_/g'`
 289
 290 checkArch "$HostArch"
 291 checkVendor "$HostVendor"
 292 checkOS "$HostOS"
 293
 294 TargetPlatform="$TargetArch-$TargetVendor-$TargetOS"
 295 TargetPlatform_CPP=`echo "$TargetPlatform" | sed -e 's/\./_/g' -e 's/-/_/g'`
 296 TargetArch_CPP=`    echo "$TargetArch"     | sed -e 's/\./_/g' -e 's/-/_/g'`
 297 TargetVendor_CPP=`  echo "$TargetVendor"   | sed -e 's/\./_/g' -e 's/-/_/g'`
 298 TargetOS_CPP=`      echo "$TargetOS"       | sed -e 's/\./_/g' -e 's/-/_/g'`
 299
 300 checkArch "$TargetArch"
 301 checkVendor "$TargetVendor"
 302 checkOS "$TargetOS"
 303
 304 # Verify that the installed (bootstrap) GHC is capable of generating
 305 # code for the requested build platform.
 306 if test "$BuildPlatform" != "$bootstrap_target"
 307 then
 308     echo "This GHC (${WithGhc}) does not generate code for the build platform"
 309     echo "   GHC target platform    : $bootstrap_target"
 310     echo "   Desired build platform : $BuildPlatform"
 311     exit 1
 312 fi
 313
 314 echo "GHC build  : $BuildPlatform"
 315 echo "GHC host   : $HostPlatform"
 316 echo "GHC target : $TargetPlatform"
 317
 318 AC_SUBST(BuildPlatform)
 319 AC_SUBST(HostPlatform)
 320 AC_SUBST(TargetPlatform)
 321 AC_SUBST(HostPlatform_CPP)
 322 AC_SUBST(BuildPlatform_CPP)
 323 AC_SUBST(TargetPlatform_CPP)
 324
 325 AC_SUBST(HostArch_CPP)
 326 AC_SUBST(BuildArch_CPP)
 327 AC_SUBST(TargetArch_CPP)
 328
 329 AC_SUBST(HostOS_CPP)
 330 AC_SUBST(BuildOS_CPP)
 331 AC_SUBST(TargetOS_CPP)
 332
 333 AC_SUBST(HostVendor_CPP)
 334 AC_SUBST(BuildVendor_CPP)
 335 AC_SUBST(TargetVendor_CPP)
 336
 337 AC_SUBST(exeext)
 338 AC_SUBST(soext)
 339
 340 AC_SUBST(SOLARIS_BROKEN_SHLD)
 341
 342 AC_ARG_WITH(hc,
 343 [AC_HELP_STRING([--with-hc=ARG],
 344         [Use ARG as the path to the compiler for compiling ordinary
 345          Haskell code  (default= value of --with-ghc)])],
 346 [WithHc="$withval"],
 347 [WithHc=$WithGhc]
 348 )
 349 AC_SUBST(WithHc)
 350
 351 # This uses GHC, so put it after the "GHC is required" check above:
 352 FP_INTREE_GHC_PWD
 353 FP_FIND_ROOT
 354
 355 if test "$HostOS" = "mingw32"
 356 then
 357     test -d inplace || mkdir inplace
 358
 359     CC="$hardtop/inplace/mingw/bin/gcc.exe"
 360     LD="$hardtop/inplace/mingw/bin/ld.exe"
 361     NM="$hardtop/inplace/mingw/bin/nm.exe"
 362     fp_prog_ar_raw="$hardtop/inplace/mingw/bin/ar.exe"
 363
 364     # NB. If you update the tarbballs to a new version of gcc, don't
 365     # forget to tweak the paths in driver/gcc/gcc.c.
 366     if ! test -d inplace/mingw ||
 367          test inplace/mingw -ot ghc-tarballs/mingw/binutils*.tar.lzma  ||
 368          test inplace/mingw -ot ghc-tarballs/mingw/gcc-core*.tar.lzma  ||
 369          test inplace/mingw -ot ghc-tarballs/mingw/gcc-c++*.tar.lzma   ||
 370          test inplace/mingw -ot ghc-tarballs/mingw/libgcc*.tar.gz      ||
 371          test inplace/mingw -ot ghc-tarballs/mingw/libgmp*.tar.gz      ||
 372          test inplace/mingw -ot ghc-tarballs/mingw/libmpc*.tar.gz      ||
 373          test inplace/mingw -ot ghc-tarballs/mingw/libmpfr*.tar.gz     ||
 374          test inplace/mingw -ot ghc-tarballs/mingw/libstdc*.tar.lzma   ||
 375          test inplace/mingw -ot ghc-tarballs/mingw/mingwrt*-dev.tar.gz ||
 376          test inplace/mingw -ot ghc-tarballs/mingw/mingwrt*-dll.tar.gz ||
 377          test inplace/mingw -ot ghc-tarballs/mingw/w32api*.tar.lzma
 378     then
 379         AC_MSG_NOTICE([Making in-tree mingw tree])
 380         rm -rf inplace/mingw
 381         mkdir inplace/mingw
 382         (
 383             cd inplace/mingw &&
 384             tar --lzma -xf ../../ghc-tarballs/mingw/binutils*.tar.lzma  &&
 385             tar --lzma -xf ../../ghc-tarballs/mingw/gcc-core*.tar.lzma  &&
 386             tar --lzma -xf ../../ghc-tarballs/mingw/gcc-c++*.tar.lzma   &&
 387             tar --lzma -xf ../../ghc-tarballs/mingw/libgcc*.tar.lzma    &&
 388             tar --lzma -xf ../../ghc-tarballs/mingw/libgmp*.tar.lzma    &&
 389             tar --lzma -xf ../../ghc-tarballs/mingw/libmpc*.tar.lzma    &&
 390             tar --lzma -xf ../../ghc-tarballs/mingw/libmpfr*.tar.lzma   &&
 391             tar --lzma -xf ../../ghc-tarballs/mingw/libstdc*.tar.lzma   &&
 392             tar -z     -xf ../../ghc-tarballs/mingw/mingwrt*-dev.tar.gz &&
 393             tar -z     -xf ../../ghc-tarballs/mingw/mingwrt*-dll.tar.gz &&
 394             tar --lzma -xf ../../ghc-tarballs/mingw/w32api*.tar.lzma    &&
 395             mv bin/gcc.exe bin/realgcc.exe
 396         )
 397         PATH=`pwd`/inplace/mingw/bin:$PATH inplace/mingw/bin/realgcc.exe driver/gcc/gcc.c driver/utils/cwrapper.c driver/utils/getLocation.c -Idriver/utils -o inplace/mingw/bin/gcc.exe
 398         if ! test -e inplace/mingw/bin/gcc.exe
 399         then
 400             AC_MSG_ERROR([GHC is required unless bootstrapping from .hc files.])
 401         fi
 402         AC_MSG_NOTICE([In-tree mingw tree created])
 403     fi
 404     if ! test -d inplace/perl ||
 405          test inplace/perl -ot ghc-tarballs/perl/ghc-perl*.tar.gz
 406     then
 407         AC_MSG_NOTICE([Making in-tree perl tree])
 408         rm -rf inplace/perl
 409         mkdir inplace
 410         mkdir inplace/perl
 411         (
 412             cd inplace/perl &&
 413             tar -zxf ../../ghc-tarballs/perl/ghc-perl*.tar.gz
 414         )
 415         AC_MSG_NOTICE([In-tree perl tree created])
 416     fi
 417 fi
 418
 419 dnl ** Which gcc to use?
 420 dnl --------------------------------------------------------------
 421 FP_ARG_WITH_PATH_GNU_PROG([CC], [gcc])
 422 export CC
 423 WhatGccIsCalled="$CC"
 424 AC_SUBST(WhatGccIsCalled)
 425
 426 dnl ** Which ld to use?
 427 dnl --------------------------------------------------------------
 428 FP_ARG_WITH_PATH_GNU_PROG([LD], [ld])
 429 LdCmd="$LD"
 430 AC_SUBST([LdCmd])
 431
 432 dnl ** Which nm to use?
 433 dnl --------------------------------------------------------------
 434 FP_ARG_WITH_PATH_GNU_PROG([NM], [nm])
 435 NmCmd="$NM"
 436 AC_SUBST([NmCmd])
 437
 438 SplitObjsBroken=NO
 439 if test "$TargetOS_CPP" = "darwin"
 440 then
 441     AC_MSG_CHECKING(XCode version)
 442     XCodeVersion=`xcodebuild -version | grep Xcode | sed "s/Xcode //"`
 443     # Old XCode versions don't actually give the XCode version
 444     if test "$XCodeVersion" = ""
 445     then
 446         AC_MSG_RESULT(not found (too old?))
 447         SplitObjsBroken=YES
 448     else
 449         AC_MSG_RESULT($XCodeVersion)
 450         XCodeVersion1=`echo "$XCodeVersion" | sed 's/\..*//'`
 451 changequote(, )dnl
 452         XCodeVersion2=`echo "$XCodeVersion" | sed 's/[^.]*\.\([^.]*\).*/\1/'`
 453 changequote([, ])dnl
 454         AC_MSG_NOTICE(XCode version component 1: $XCodeVersion1)
 455         AC_MSG_NOTICE(XCode version component 2: $XCodeVersion2)
 456         # Split objects is broken (#4013) with XCode < 3.2
 457         if test "$XCodeVersion1" -lt 3
 458         then
 459             SplitObjsBroken=YES
 460         else
 461             if test "$XCodeVersion1" -eq 3
 462             then
 463                 if test "$XCodeVersion2" -lt 2
 464                 then
 465                     SplitObjsBroken=YES
 466                 fi
 467             fi
 468         fi
 469     fi
 470 fi
 471 AC_SUBST([SplitObjsBroken])
 472
 473 dnl ** Mac OS X: explicit deployment target
 474 dnl --------------------------------------------------------------
 475 AC_ARG_WITH([macosx-deployment-target],
 476 [AC_HELP_STRING([--with-macosx-deployment-target=VERSION],
 477         [Build for Mac OS VERSION and higher  (default= version of build host)])],
 478 [FP_MACOSX_DEPLOYMENT_TARGET="$withval"
 479  if test "x$TargetOS_CPP-$TargetVendor_CPP" != "xdarwin-apple"; then
 480    # ignore everywhere, but on Mac OS
 481    AC_MSG_WARN([--macosx-deployment-target is only available on Mac OS X])
 482    FP_MACOSX_DEPLOYMENT_TARGET=none
 483  fi],
 484 [FP_MACOSX_DEPLOYMENT_TARGET=none]
 485 )
 486 FP_CHECK_MACOSX_DEPLOYMENT_TARGET
 487 AC_SUBST(MACOSX_DEPLOYMENT_VERSION)
 488 AC_SUBST(MACOSX_DEPLOYMENT_SDK)
 489
 490 dnl --------------------------------------------------------------
 491 dnl End of configure script option section
 492 dnl --------------------------------------------------------------
 493
 494
 495 dnl --------------------------------------------------------------
 496 dnl * General configuration checks
 497 dnl --------------------------------------------------------------
 498
 499 dnl ** Can the unix package be built?
 500 dnl --------------------------------------------------------------
 501
 502 if test x"$TargetPlatform" = x"i386-unknown-mingw32"; then
 503    GhcLibsWithUnix=NO
 504 else
 505    GhcLibsWithUnix=YES
 506 fi
 507 AC_SUBST([GhcLibsWithUnix])
 508
 509 dnl ** does #! work?
 510 AC_SYS_INTERPRETER()
 511
 512 dnl ** look for `perl'
 513 case $HostOS_CPP in
 514 cygwin32|mingw32)
 515     PerlCmd=$hardtop/inplace/perl/perl
 516     ;;
 517 *)
 518     AC_PATH_PROG(PerlCmd,perl)
 519     if test -z "$PerlCmd"
 520     then
 521         echo "You must install perl before you can continue"
 522         echo "Perhaps it is already installed, but not in your PATH?"
 523         exit 1
 524     else
 525         FPTOOLS_CHECK_PERL_VERSION
 526     fi
 527     ;;
 528 esac
 529
 530 dnl ** does #! path/to/perl work? (sometimes it's too long...)
 531 FPTOOLS_SHEBANG_PERL
 532
 533 dnl ** check for Python
 534 AC_PATH_PROG(PythonCmd,python)
 535
 536 dnl ** look for GCC and find out which version
 537 dnl     Figure out which C compiler to use.  Gcc is preferred.
 538 dnl     If gcc, make sure it's at least 2.1
 539 dnl
 540 FP_HAVE_GCC
 541
 542 FPTOOLS_SET_C_LD_FLAGS([target],[CFLAGS],[LDFLAGS],[IGNORE_LINKER_LD_FLAGS],[CPPFLAGS])
 543 FPTOOLS_SET_C_LD_FLAGS([build],[CONF_CC_OPTS_STAGE0],[CONF_GCC_LINKER_OPTS_STAGE0],[CONF_LD_LINKER_OPTS_STAGE0],[CONF_CPP_OPTS_STAGE0])
 544 FPTOOLS_SET_C_LD_FLAGS([target],[CONF_CC_OPTS_STAGE1],[CONF_GCC_LINKER_OPTS_STAGE1],[CONF_LD_LINKER_OPTS_STAGE1],[CONF_CPP_OPTS_STAGE1])
 545 # Stage 3 won't be supported by cross-compilation
 546 FPTOOLS_SET_C_LD_FLAGS([target],[CONF_CC_OPTS_STAGE2],[CONF_GCC_LINKER_OPTS_STAGE2],[CONF_LD_LINKER_OPTS_STAGE2],[CONF_CPP_OPTS_STAGE2])
 547
 548 FP_GCC_EXTRA_FLAGS
 549
 550 dnl ** figure out how to invoke cpp directly (gcc -E is no good)
 551 AC_PROG_CPP
 552
 553 AC_SUBST(CONF_CC_OPTS_STAGE0)
 554 AC_SUBST(CONF_CC_OPTS_STAGE1)
 555 AC_SUBST(CONF_CC_OPTS_STAGE2)
 556 AC_SUBST(CONF_GCC_LINKER_OPTS_STAGE0)
 557 AC_SUBST(CONF_GCC_LINKER_OPTS_STAGE1)
 558 AC_SUBST(CONF_GCC_LINKER_OPTS_STAGE2)
 559 AC_SUBST(CONF_LD_LINKER_OPTS_STAGE0)
 560 AC_SUBST(CONF_LD_LINKER_OPTS_STAGE1)
 561 AC_SUBST(CONF_LD_LINKER_OPTS_STAGE2)
 562 AC_SUBST(CONF_CPP_OPTS_STAGE0)
 563 AC_SUBST(CONF_CPP_OPTS_STAGE1)
 564 AC_SUBST(CONF_CPP_OPTS_STAGE2)
 565
 566 dnl ** figure out how to do context diffs
 567 FP_PROG_CONTEXT_DIFF
 568
 569 dnl Let's make sure install-sh is executable here.  If we got it from
 570 dnl a darcs repo, it might not be (see bug #978).
 571 chmod +x install-sh
 572 dnl ** figure out how to do a BSD-ish install
 573 AC_PROG_INSTALL
 574
 575 dnl If you can run configure, you certainly have /bin/sh
 576 AC_DEFINE([HAVE_BIN_SH], [1], [Define to 1 if you have /bin/sh.])
 577
 578 dnl ** how to invoke `ar' and `ranlib'
 579 FP_PROG_AR_SUPPORTS_ATFILE
 580 FP_PROG_AR_NEEDS_RANLIB
 581 FP_PROG_AR_SUPPORTS_INPUT
 582
 583 dnl ** Check to see whether ln -s works
 584 AC_PROG_LN_S
 585
 586
 587 dnl ** Find the path to sed
 588 AC_PATH_PROGS(SedCmd,gsed sed,sed)
 589
 590
 591 dnl ** check for time command
 592 AC_PATH_PROG(TimeCmd,time)
 593
 594 dnl ** check for tar
 595 dnl   if GNU tar is named gtar, look for it first.
 596 AC_PATH_PROGS(TarCmd,gnutar gtar tar,tar)
 597
 598 dnl ** check for patch
 599 dnl if GNU patch is named gpatch, look for it first
 600 AC_PATH_PROGS(PatchCmd,gpatch patch, patch)
 601
 602 dnl ** check for dtrace (currently only implemented for Mac OS X)
 603 HaveDtrace=NO
 604 AC_PATH_PROG(DtraceCmd,dtrace)
 605 if test -n "$DtraceCmd"; then
 606   if test "x$TargetOS_CPP-$TargetVendor_CPP" == "xdarwin-apple" -o "x$TargetOS_CPP-$TargetVendor_CPP" == "xsolaris2-unknown"; then
 607     HaveDtrace=YES
 608   fi
 609 fi
 610 AC_SUBST(HaveDtrace)
 611
 612 AC_PATH_PROG(HSCOLOUR,HsColour)
 613 # HsColour is passed to Cabal, so we need a native path
 614 if test "x$HostPlatform"  = "xi386-unknown-mingw32" && \
 615    test "${OSTYPE}"      != "msys"                  && \
 616    test "${HSCOLOUR}"    != ""
 617 then
 618     # Canonicalise to <drive>:/path/to/gcc
 619     HSCOLOUR=`cygpath -m ${HSCOLOUR}`
 620 fi
 621
 622 dnl ** check for DocBook toolchain
 623 FP_CHECK_DOCBOOK_DTD
 624 FP_DOCBOOK_XSL
 625 FP_PROG_DBLATEX
 626
 627 FP_PROG_HSTAGS
 628
 629 dnl ** check for ghc-pkg command
 630 FP_PROG_GHC_PKG
 631
 632 dnl ** check for installed happy binary + version
 633 dnl    (don't do it if we're booting from .hc files though.)
 634 if test "$BootingFromHc" = "NO"; then
 635 FPTOOLS_HAPPY
 636 fi;
 637
 638 dnl ** check for installed alex binary + version
 639 dnl    (don't do it if we're booting from .hc files though.)
 640 if test "$BootingFromHc" = "NO"; then
 641 FPTOOLS_ALEX
 642 fi;
 643
 644 dnl --------------------------------------------------
 645 dnl ### program checking section ends here ###
 646 dnl --------------------------------------------------
 647
 648 dnl --------------------------------------------------
 649 dnl * Platform header file and syscall feature tests
 650 dnl ### checking the state of the local header files and syscalls ###
 651
 652 dnl ** check for full ANSI header (.h) files
 653 AC_HEADER_STDC
 654
 655 dnl ** Enable large file support.  NB. do this before testing the type of
 656 dnl    off_t, because it will affect the result of that test.
 657 AC_SYS_LARGEFILE
 658
 659 dnl ** check for specific header (.h) files that we are interested in
 660 AC_CHECK_HEADERS([bfd.h ctype.h dirent.h dlfcn.h errno.h fcntl.h grp.h limits.h locale.h nlist.h pthread.h pwd.h signal.h sys/cpuset.h sys/mman.h sys/resource.h sys/select.h sys/time.h sys/timeb.h sys/timers.h sys/times.h sys/utsname.h sys/wait.h termios.h time.h utime.h windows.h winsock.h sched.h])
 661
 662 dnl ** check if it is safe to include both <time.h> and <sys/time.h>
 663 AC_HEADER_TIME
 664
 665 dnl ** do we have long longs?
 666 AC_CHECK_TYPES([long long])
 667
 668 dnl ** what are the sizes of various types
 669 AC_CHECK_SIZEOF(char,               1)
 670 AC_CHECK_SIZEOF(double,             8)
 671 AC_CHECK_SIZEOF(float,              4)
 672 AC_CHECK_SIZEOF(int,                4)
 673 AC_CHECK_SIZEOF(long,               4)
 674 if test "$ac_cv_type_long_long" = yes; then
 675 AC_CHECK_SIZEOF(long long,          8)
 676 fi
 677 AC_CHECK_SIZEOF(short,              2)
 678 AC_CHECK_SIZEOF(unsigned char,      1)
 679 AC_CHECK_SIZEOF(unsigned int,       4)
 680 AC_CHECK_SIZEOF(unsigned long,      4)
 681 if test "$ac_cv_type_long_long" = yes; then
 682 AC_CHECK_SIZEOF(unsigned long long, 8)
 683 fi
 684 AC_CHECK_SIZEOF(unsigned short,     2)
 685 AC_CHECK_SIZEOF(void *,             4)
 686
 687 dnl ** what are alignment constraints on various types
 688 FP_CHECK_ALIGNMENT(char)
 689 FP_CHECK_ALIGNMENT(double)
 690 FP_CHECK_ALIGNMENT(float)
 691 FP_CHECK_ALIGNMENT(int)
 692 FP_CHECK_ALIGNMENT(long)
 693 if test "$ac_cv_type_long_long" = yes; then
 694 FP_CHECK_ALIGNMENT(long long)
 695 fi
 696 FP_CHECK_ALIGNMENT(short)
 697 FP_CHECK_ALIGNMENT(unsigned char)
 698 FP_CHECK_ALIGNMENT(unsigned int)
 699 FP_CHECK_ALIGNMENT(unsigned long)
 700 if test "$ac_cv_type_long_long" = yes; then
 701 FP_CHECK_ALIGNMENT(unsigned long long)
 702 fi
 703 FP_CHECK_ALIGNMENT(unsigned short)
 704 FP_CHECK_ALIGNMENT(void *)
 705
 706 FP_CHECK_FUNC([WinExec],
 707   [@%:@include <windows.h>], [WinExec("",0)])
 708
 709 FP_CHECK_FUNC([GetModuleFileName],
 710   [@%:@include <windows.h>], [GetModuleFileName((HMODULE)0,(LPTSTR)0,0)])
 711
 712 dnl ** check return type of signal handlers
 713 dnl Foo: assumes we can use prototypes.
 714 dnl On BCC, signal handlers have type "int(void)", elsewhere its "void(int)".
 715 dnl AC_CACHE_CHECK([type of signal handlers], ac_cv_type_signal_handler,
 716 dnl [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 717 dnl #include <signal.h>
 718 dnl #ifdef signal
 719 dnl #undef signal
 720 dnl #endif
 721 dnl void (*signal (int, void (*)(int)))(int);
 722 dnl ]],
 723 dnl [[int i;]])],
 724 dnl [ac_cv_type_signal_handler=void_int],
 725 dnl [ac_cv_type_signal_handler=int_void])])
 726 dnl if test "$ac_cv_type_signal_handler" = void_int; then
 727 dnl AC_DEFINE(VOID_INT_SIGNALS)
 728 dnl fi
 729
 730 dnl On BCC, signal handlers have type "int(void)", elsewhere its "void(int)".
 731 AC_TYPE_SIGNAL
 732 if test "$ac_cv_type_signal" = void; then
 733   AC_DEFINE([VOID_INT_SIGNALS], [1], [Define to 1 if signal handlers have type void (*)(int). Otherwise, they're assumed to have type int (*)(void).])
 734 fi
 735
 736 dnl ** check for more functions
 737 dnl ** The following have been verified to be used in ghc/, but might be used somewhere else, too.
 738 AC_CHECK_FUNCS([getclock getrusage gettimeofday setitimer siginterrupt sysconf times ctime_r sched_setaffinity setlocale])
 739
 740 AC_TRY_RUN([
 741 #include <sys/types.h>
 742 #include <sys/time.h>
 743 int main(void) {
 744   struct itimerval tval;
 745   tval.it_value.tv_sec = 1;
 746   tval.it_value.tv_usec = 0;
 747   tval.it_interval = tval.it_value;
 748   return setitimer(ITIMER_VIRTUAL, &tval, (void*)0) != 0;
 749 }
 750 ],[AC_DEFINE([HAVE_SETITIMER_VIRTUAL], [1], [Define to 1 if setitimer accepts ITIMER_VIRTUAL, 0 else.])])
 751
 752 dnl ** On OS X 10.4 (at least), time.h doesn't declare ctime_r if
 753 dnl ** _POSIX_C_SOURCE is defined
 754 AC_CHECK_DECLS([ctime_r], , ,
 755 [#define _POSIX_SOURCE 1
 756 #define _POSIX_C_SOURCE 199506L
 757 #include <time.h>])
 758
 759 dnl ** check for mingwex library
 760 AC_CHECK_LIB(mingwex, closedir, HaveLibMingwEx=YES, HaveLibMingwEx=NO)
 761 AC_SUBST(HaveLibMingwEx)
 762
 763 if test $HaveLibMingwEx = YES ; then
 764   AC_DEFINE([HAVE_MINGWEX], [1], [Define to 1 if you have the mingwex library.])
 765 fi
 766
 767 dnl ** check for math library
 768 dnl    Keep that check as early as possible.
 769 dnl    as we need to know whether we need libm
 770 dnl    for math functions or not
 771 dnl    (see http://hackage.haskell.org/trac/ghc/ticket/3730)
 772 AC_CHECK_LIB(m, atan, HaveLibM=YES, HaveLibM=NO)
 773 if test $HaveLibM = YES
 774 then
 775   AC_DEFINE([HAVE_LIBM], [1], [Define to 1 if you need to link with libm])
 776 fi
 777
 778 dnl ** check whether this machine has BFD and liberty installed (used for debugging)
 779 dnl    the order of these tests matters: bfd needs liberty
 780 AC_CHECK_LIB(iberty, xmalloc)
 781 AC_CHECK_LIB(bfd,    bfd_init)
 782
 783 dnl ################################################################
 784 dnl Check for libraries
 785 dnl ################################################################
 786
 787 dnl ** check whether we need -ldl to get dlopen()
 788
 789 AC_CHECK_LIB(dl, dlopen,
 790     [HaveLibDL=YES
 791      AC_DEFINE([HAVE_LIBDL], [1], [Define to 1 if you need -ldl to get dlopen().])
 792      LIBS="$LIBS -ldl"],
 793     [HaveLibDL=NO])
 794 AC_SUBST(HaveLibDL)
 795
 796 dnl --------------------------------------------------
 797 dnl * Miscellaneous feature tests
 798 dnl --------------------------------------------------
 799
 800 dnl ** can we get alloca?
 801 AC_FUNC_ALLOCA
 802
 803 dnl ** Working vfork?
 804 AC_FUNC_FORK
 805
 806 dnl ** determine whether or not const works
 807 AC_C_CONST
 808
 809 dnl ** are we big endian?
 810 AC_C_BIGENDIAN
 811 FPTOOLS_FLOAT_WORD_ORDER_BIGENDIAN
 812
 813 dnl ** check for leading underscores in symbol names
 814 FP_LEADING_UNDERSCORE
 815
 816 dnl ** check for ld, whether it has an -x option, and if it is GNU ld
 817 FP_PROG_LD_X
 818 FP_PROG_LD_IS_GNU
 819 FP_PROG_LD_BUILD_ID
 820
 821 dnl ** check for Apple-style dead-stripping support
 822 dnl    (.subsections-via-symbols assembler directive)
 823
 824
 825 AC_MSG_CHECKING(for .subsections_via_symbols)
 826 AC_COMPILE_IFELSE(
 827     [AC_LANG_PROGRAM([], [__asm__ (".subsections_via_symbols");])],
 828     [AC_MSG_RESULT(yes)
 829      AC_DEFINE([HAVE_SUBSECTIONS_VIA_SYMBOLS],[1],
 830                [Define to 1 if Apple-style dead-stripping is supported.])
 831     ],
 832     [AC_MSG_RESULT(no)])
 833
 834 dnl *** check for GNU non-executable stack note support (ELF only)
 835 dnl     (.section .note.GNU-stack,"",@progbits)
 836
 837 dnl This test doesn't work with "gcc -g" in gcc 4.4 (GHC trac #3889:
 838 dnl     Error: can't resolve `.note.GNU-stack' {.note.GNU-stack section} - `.Ltext0' {.text section}
 839 dnl so we empty CFLAGS while running this test
 840 CFLAGS2="$CFLAGS"
 841 CFLAGS=
 842 AC_MSG_CHECKING(for GNU non-executable stack support)
 843 AC_COMPILE_IFELSE(
 844     [AC_LANG_PROGRAM([__asm__ (".section .note.GNU-stack,\"\",@progbits");], [0])],
 845     [AC_MSG_RESULT(yes)
 846      AC_DEFINE([HAVE_GNU_NONEXEC_STACK],[1],
 847                [Define to 1 if GNU non-executable stack notes are supported.])
 848     ],
 849     [AC_MSG_RESULT(no)])
 850 CFLAGS="$CFLAGS2"
 851
 852 FP_VISIBILITY_HIDDEN
 853
 854 dnl ** check for librt
 855 AC_CHECK_LIB(rt, clock_gettime)
 856 AC_CHECK_FUNCS(clock_gettime timer_create timer_settime)
 857 FP_CHECK_TIMER_CREATE
 858
 859 dnl ** check for Apple's "interesting" long double compatibility scheme
 860 AC_MSG_CHECKING(for printf\$LDBLStub)
 861 AC_TRY_LINK_FUNC(printf\$LDBLStub,
 862     [
 863         AC_MSG_RESULT(yes)
 864         AC_DEFINE([HAVE_PRINTF_LDBLSTUB],[1],
 865             [Define to 1 if we have printf$LDBLStub (Apple Mac OS >= 10.4, PPC).])
 866     ],
 867     [
 868         AC_MSG_RESULT(no)
 869         AC_DEFINE([HAVE_PRINTF_LDBLSTUB],[0],
 870             [Define to 1 if we have printf$LDBLStub (Apple Mac OS >= 10.4, PPC).])
 871     ])
 872
 873 dnl ** check for eventfd which is needed by the I/O manager
 874 AC_CHECK_HEADERS([sys/eventfd.h])
 875 AC_CHECK_FUNCS([eventfd])
 876
 877 # test for GTK+
 878 AC_PATH_PROGS([GTK_CONFIG], [pkg-config])
 879 if test -n "$GTK_CONFIG"; then
 880   if $GTK_CONFIG gtk+-2.0 --atleast-version=2.0; then
 881     GTK_CONFIG="$GTK_CONFIG gtk+-2.0"
 882   else
 883     AC_MSG_WARN([GTK+ not usable, need at least version 2.0])
 884     GTK_CONFIG=
 885   fi
 886 fi
 887 AC_SUBST([GTK_CONFIG])
 888
 889 #Checking for PAPI
 890 AC_CHECK_LIB(papi, PAPI_library_init, HavePapiLib=YES, HavePapiLib=NO)
 891 AC_CHECK_HEADER([papi.h], [HavePapiHeader=YES], [HavePapiHeader=NO])
 892 AC_SUBST(HavePapiLib)
 893 AC_SUBST(HavePapiHeader)
 894
 895 AC_CHECK_FUNCS(__mingw_vfprintf)
 896
 897 if test "$HavePapiLib" = "YES" -a "$HavePapiHeader" = "YES"; then
 898    HavePapi=YES
 899 else
 900    HavePapi=NO
 901 fi
 902 AC_SUBST(HavePapi)
 903
 904 if test "$HAVE_DOCBOOK_XSL" = "NO" ||
 905    test "$XsltprocCmd" = ""
 906 then
 907     BUILD_DOCBOOK_HTML=NO
 908 else
 909     BUILD_DOCBOOK_HTML=YES
 910 fi
 911 AC_SUBST(BUILD_DOCBOOK_HTML)
 912
 913 if test "$DblatexCmd" = ""
 914 then
 915     BUILD_DOCBOOK_PS=NO
 916     BUILD_DOCBOOK_PDF=NO
 917 else
 918     BUILD_DOCBOOK_PS=YES
 919     BUILD_DOCBOOK_PDF=YES
 920 fi
 921 AC_SUBST(BUILD_DOCBOOK_PS)
 922 AC_SUBST(BUILD_DOCBOOK_PDF)
 923
 924 LIBRARY_VERSION(base)
 925 LIBRARY_VERSION(Cabal)
 926 LIBRARY_VERSION(ghc-prim)
 927 LIBRARY_ghc_VERSION="$ProjectVersion"
 928 AC_SUBST(LIBRARY_ghc_VERSION)
 929
 930 if grep '       ' compiler/ghc.cabal.in 2>&1 >/dev/null; then
 931    AC_MSG_ERROR([compiler/ghc.cabal.in contains tab characters; please remove them])
 932 fi
 933
 934 AC_CONFIG_FILES([mk/config.mk mk/install.mk mk/project.mk compiler/ghc.cabal ghc/ghc-bin.cabal utils/runghc/runghc.cabal ghc.spec settings docs/users_guide/ug-book.xml docs/users_guide/ug-ent.xml docs/index.html libraries/prologue.txt distrib/ghc.iss distrib/configure.ac])
 935 AC_CONFIG_COMMANDS([mk/stamp-h],[echo timestamp > mk/stamp-h])
 936 AC_OUTPUT
 937
 938 # We get caught by
 939 #     http://savannah.gnu.org/bugs/index.php?1516
 940 #     $(eval ...) inside conditionals causes errors
 941 # with make 3.80, so warn the user if it looks like they're about to
 942 # try to use it.
 943 # We would use "grep -q" here, but Solaris's grep doesn't support it.
 944 checkMake380() {
 945     if $1 --version 2>&1 | head -1 | grep 'GNU Make 3\.80' > /dev/null
 946     then
 947         echo
 948         echo "WARNING: It looks like \"$1\" is GNU make 3.80."
 949         echo "This version cannot be used to build GHC."
 950         echo "Please use GNU make >= 3.81."
 951     fi
 952 }
 953
 954 checkMake380 make
 955 checkMake380 gmake
 956
 957 echo ["
 958 ----------------------------------------------------------------------
 959 Configure completed successfully.
 960
 961    Building GHC version  : $ProjectVersion
 962
 963    Build platform        : $BuildPlatform
 964    Host platform         : $HostPlatform
 965    Target platform       : $TargetPlatform
 966 "]
 967
 968 if test "$BootingFromHc" = "YES"; then
 969 echo ["\
 970    Bootstrapping from HC files.
 971 "]
 972 else
 973 echo ["\
 974    Bootstrapping using   : $WithGhc
 975       which is version   : $GhcVersion
 976 "]
 977 fi
 978
 979 echo ["\
 980    Using GCC             : $WhatGccIsCalled
 981       which is version   : $GccVersion
 982
 983    ld       : $LdCmd
 984    Happy    : $HappyCmd ($HappyVersion)
 985    Alex     : $AlexCmd ($AlexVersion)
 986    Python   : $PythonCmd
 987    Perl     : $PerlCmd
 988    dblatex  : $DblatexCmd
 989    xsltproc : $XsltprocCmd"]
 990
 991 if test "$HSCOLOUR" = ""; then
 992 echo ["
 993    HsColour was not found; documentation will not contain source links
 994 "]
 995 else
 996 echo ["\
 997    HsColour : $HSCOLOUR
 998 "]
 999 fi
1000
1001 echo ["\
1002    Building DocBook HTML documentation : $BUILD_DOCBOOK_HTML
1003    Building DocBook PS documentation   : $BUILD_DOCBOOK_PS
1004    Building DocBook PDF documentation  : $BUILD_DOCBOOK_PDF"]
1005
1006 echo ["----------------------------------------------------------------------
1007 "]
1008
1009 echo "\
1010 For a standard build of GHC (fully optimised with profiling), type (g)make.
1011
1012 To make changes to the default build configuration, copy the file
1013 mk/build.mk.sample to mk/build.mk, and edit the settings in there.
1014
1015 For more information on how to configure your GHC build, see
1016    http://hackage.haskell.org/trac/ghc/wiki/Building
1017 "