configure.ac

   1 dnl == autoconf source for the Glasgow FP tools ==
   2 dnl (run "grep '^dnl \*' configure.ac | sed -e 's/dnl / /g; s/\*\*/   +/g;'"
   3 dnl  (or some such) to see the outline of this file)
   4 dnl
   5 #
   6 # (c) The University of Glasgow 1994-2004
   7 #
   8 # Configure script template for GHC
   9 #
  10 # Process with 'autoreconf' to get a working configure script.
  11 #
  12 # For the generated configure script, do "./configure --help" to
  13 # see what flags are available. (Better yet, read the documentation!)
  14 #
  15
  16 AC_INIT([The Glorious Glasgow Haskell Compilation System], [6.13], [glasgow-haskell-bugs@haskell.org], [ghc])
  17
  18 # Set this to YES for a released version, otherwise NO
  19 : ${RELEASE=NO}
  20
  21 # The primary version (e.g. 6.7, 6.6.1) is set in the AC_INIT line
  22 # above.  If this is not a released version, then we will append the
  23 # date to the version number (e.g. 6.7.20070204).  The date is
  24 # constructed by finding the date of the most recent patch in the
  25 # darcs repository.  If this is a source distribution (not a darcs
  26 # checkout), then we ship a file 'VERSION' containing the full version
  27 # when the source distribution was created.
  28
  29 if test ! -f mk/config.h.in; then
  30    echo "mk/config.h.in doesn't exist: perhaps you haven't run 'sh boot'?"
  31    exit 1
  32 fi
  33
  34 AC_SUBST([CONFIGURE_ARGS], [$ac_configure_args])
  35
  36 dnl ----------------------------------------------------------
  37 dnl ** Find unixy sort and find commands,
  38 dnl ** which are needed by FP_SETUP_PROJECT_VERSION
  39
  40 dnl ** Find find command (for Win32's benefit)
  41 FP_PROG_FIND
  42
  43 dnl ** Find sort command (for the benefit of Win32 environs)
  44 FP_PROG_SORT
  45
  46 dnl ----------------------------------------------------------
  47 FP_SETUP_PROJECT_VERSION
  48
  49 # Hmmm, we fix the RPM release number to 1 here... Is this convenient?
  50 AC_SUBST([release], [1])
  51
  52 # First off, a distrib sanity check..
  53 AC_CONFIG_SRCDIR([mk/config.mk.in])
  54
  55 dnl * We require autoconf version 2.52
  56 dnl We need 2.50 due to the use of AC_SYS_LARGEFILE and AC_MSG_NOTICE.
  57 dnl We need 2.52 due to the use of AS_TR_CPP and AS_TR_SH.
  58 AC_PREREQ([2.52])
  59
  60 # -------------------------------------------------------------------------
  61 # Prepare to generate the following header files
  62 #
  63 #
  64 AC_CONFIG_HEADER(mk/config.h)
  65
  66 # No, semi-sadly, we don't do `--srcdir'...
  67 if test x"$srcdir" != 'x.' ; then
  68     echo "This configuration does not support the \`--srcdir' option.."
  69     exit 1
  70 fi
  71
  72 dnl --------------------------------------------------------------
  73 dnl * Project specific configuration options
  74 dnl --------------------------------------------------------------
  75 dnl What follows is a bunch of options that can either be configured
  76 dnl through command line options to the configure script or by
  77 dnl supplying defns in the build tree's mk/build.mk. Having the option to
  78 dnl use either is considered a Feature.
  79
  80 dnl ** What command to use to compile compiler sources ?
  81 dnl --------------------------------------------------------------
  82
  83 AC_ARG_WITH([ghc],
  84 [AC_HELP_STRING([--with-ghc=ARG],
  85   [Use ARG as the path to GHC  [default=autodetect]])],
  86   [WithGhc="$withval"],
  87   [if test "$GHC" = ""; then
  88     AC_PATH_PROG([GHC], [ghc])
  89   fi
  90   WithGhc="$GHC"])
  91
  92 dnl ** Booting from .hc files?
  93 dnl --------------------------------------------------------------
  94 AC_ARG_ENABLE(hc-boot,
  95 [AC_HELP_STRING([--enable-hc-boot],
  96 [Boot the Glasgow Haskell Compiler from intermediate .hc files.
  97  (This option is mostly of interest to porters.) [default=no]])],
  98 [ if test x"$enableval" = x"yes"; then
  99         BootingFromHc=YES
 100   else
 101         BootingFromHc=NO
 102   fi
 103 ],
 104 [BootingFromHc=NO]
 105 )
 106 AC_SUBST(BootingFromHc)
 107
 108 AC_ARG_ENABLE(bootstrap-with-devel-snapshot,
 109 [AC_HELP_STRING([--enable-bootstrap-with-devel-snapshot],
 110                 [Allow bootstrapping using a development snapshot of GHC.  This is not guaranteed to work.])],
 111         EnableBootstrapWithDevelSnaphost=YES,
 112         EnableBootstrapWithDevelSnaphost=NO
 113 )
 114
 115 if test "$WithGhc" != ""; then
 116   FPTOOLS_GHC_VERSION([GhcVersion], [GhcMajVersion], [GhcMinVersion], [GhcPatchLevel])dnl
 117
 118   if test "$GhcMajVersion" = "unknown" -o "$GhcMinVersion" = "unknown"; then
 119      AC_MSG_ERROR([Cannot determine the version of $WithGhc.  Is it really GHC?])
 120   fi
 121
 122   AC_SUBST(GhcVersion)dnl
 123   AC_SUBST(GhcMajVersion)dnl
 124   AC_SUBST(GhcMinVersion)dnl
 125   AC_SUBST(GhcPatchLevel)dnl
 126   GhcMinVersion2=`echo "$GhcMinVersion" | sed 's/^\\(.\\)$/0\\1/'`
 127   GhcCanonVersion="$GhcMajVersion$GhcMinVersion2"
 128   if test $GhcCanonVersion -ge 609; then ghc_ge_609=YES; else ghc_ge_609=NO; fi
 129   FP_COMPARE_VERSIONS($GhcVersion,[-ge],[6.10.2],
 130                       [ghc_ge_6102=YES], [ghc_ge_6102=NO])
 131   if test $GhcCanonVersion -ge 611; then ghc_ge_611=YES; else ghc_ge_611=NO; fi
 132   if test $GhcCanonVersion -ge 613; then ghc_ge_613=YES; else ghc_ge_613=NO; fi
 133   AC_SUBST(ghc_ge_609)dnl
 134   AC_SUBST(ghc_ge_6102)dnl
 135   AC_SUBST(ghc_ge_611)dnl
 136   AC_SUBST(ghc_ge_613)dnl
 137 fi
 138
 139 dnl ** Must have GHC to build GHC, unless --enable-hc-boot is on
 140 if test "$BootingFromHc" = "NO" -a -d "$srcdir/compiler"; then
 141   if test "$WithGhc" = ""; then
 142      AC_MSG_ERROR([GHC is required unless bootstrapping from .hc files.])
 143   fi
 144   FP_COMPARE_VERSIONS([$GhcVersion],[-lt],[6.8],
 145     [AC_MSG_ERROR([GHC version 6.8 or later is required to compile GHC.])])dnl
 146
 147   if test `expr $GhcMinVersion % 2` = "1"; then
 148      if test "$EnableBootstrapWithDevelSnaphost" = "NO"; then
 149         AC_MSG_ERROR([
 150      $WithGhc is a development snapshot of GHC, version $GhcVersion.
 151      Bootstrapping using this version of GHC is not supported, and may not
 152      work.  Use --enable-bootstrap-with-devel-snapshot to try it anyway,
 153      or --with-ghc to specify a different GHC to use.])
 154      fi
 155   fi
 156 fi;
 157
 158 # GHC is passed to Cabal, so we need a native path
 159 if test "${WithGhc}" != ""
 160 then
 161     ghc_host=`"${WithGhc}" +RTS --info | grep 'Host platform' | sed -e 's/.*, "//' -e 's/")//'`
 162
 163     if test "$ghc_host" = "i386-unknown-mingw32"
 164     then
 165         if test "${OSTYPE}" = "msys"
 166         then
 167             WithGhc=`echo "${WithGhc}" | sed "s#^/\([a-zA-Z]\)/#\1:/#"`
 168         else
 169             # Canonicalise to <drive>:/path/to/ghc
 170             WithGhc=`cygpath -m "${WithGhc}"`
 171         fi
 172         echo "GHC path canonicalised to: ${WithGhc}"
 173     fi
 174 fi
 175 AC_SUBST([WithGhc])
 176
 177 dnl ** Without optimization some INLINE trickery fails for GHCi
 178 SRC_CC_OPTS="-O"
 179
 180 dnl Allow to specify iconv options to the toplevel configure script
 181 dnl so they can be properly passed to sub-builds.
 182 dnl Note: ICONV_LIB_DIRS and ICONV_INCLUDE_DIRS are not predefined
 183 dnl to the empty string to allow them to be overridden from the
 184 dnl environment.
 185
 186 AC_ARG_WITH([iconv-includes],
 187   [AC_HELP_STRING([--with-iconv-includes],
 188     [directory containing iconv.h])],
 189     [ICONV_INCLUDE_DIRS=$withval])
 190
 191 AC_ARG_WITH([iconv-libraries],
 192   [AC_HELP_STRING([--with-iconv-libraries],
 193     [directory containing iconv library])],
 194     [ICONV_LIB_DIRS=$withval])
 195
 196 AC_SUBST(ICONV_INCLUDE_DIRS)
 197 AC_SUBST(ICONV_LIB_DIRS)
 198
 199 dnl--------------------------------------------------------------------
 200 dnl * Choose host(/target/build) platform
 201 dnl--------------------------------------------------------------------
 202 dnl We don't use the standard autoconf macros for this, but instead
 203 dnl ask the bootstrapping compiler what platform it is for
 204
 205 dnl Guess host/target/build platform(s) if necessary.
 206 m4_divert_once([HELP_CANON],
 207 [[
 208 System types:
 209   --build=BUILD     configure for building on BUILD [guessed]
 210   --host=HOST       cross-compile to build programs to run on HOST [guessed]
 211   --target=TARGET   configure for building compilers for TARGET [guessed]]])dnl
 212
 213 if test "${WithGhc}" != ""
 214 then
 215         bootstrap_host=`"${WithGhc}" +RTS --info | grep '^ ,("Host platform"' | sed -e 's/.*, "//' -e 's/")//' | tr -d '\r'`
 216         bootstrap_target=`"${WithGhc}" +RTS --info | grep '^ ,("Target platform"' | sed -e 's/.*, "//' -e 's/")//' | tr -d '\r'`
 217         if test "$bootstrap_host" != "$bootstrap_target"
 218         then
 219                 echo "Bootstrapping GHC is a cross compiler. This probably isn't going to work"
 220         fi
 221 fi
 222
 223 # We have to run these unconditionally, but we may discard their
 224 # results in the following code
 225 AC_CANONICAL_BUILD
 226 AC_CANONICAL_HOST
 227 AC_CANONICAL_TARGET
 228
 229 # If no argument was given for a configuration variable, then discard
 230 # the guessed canonical system and use the configuration of the
 231 # bootstrapping ghc. If an argument was given, map it from gnu format
 232 # to ghc format.
 233 #
 234 # For why we do it this way, see: #3637, #1717, #2951
 235
 236 if test "$build_alias" = ""
 237 then
 238     if test "${WithGhc}" != ""
 239     then
 240         build=$bootstrap_target
 241         echo "Build platform inferred as: $build"
 242     else
 243         echo "Can't work out build platform"
 244         exit 1
 245     fi
 246
 247     BuildArch=`echo "$build" | sed 's/-.*//'`
 248     BuildVendor=`echo "$build" | sed -e 's/.*-\(.*\)-.*/\1/'`
 249     BuildOS=`echo "$build" | sed 's/.*-//'`
 250 else
 251     GHC_CONVERT_CPU([$build_cpu], [BuildArch])
 252     GHC_CONVERT_VENDOR([$build_vendor], [BuildVendor])
 253     GHC_CONVERT_OS([$build_os], [BuildOS])
 254 fi
 255
 256 if test "$host_alias" = ""
 257 then
 258     if test "${WithGhc}" != ""
 259     then
 260         host=$bootstrap_target
 261         echo "Host platform inferred as: $host"
 262     else
 263         echo "Can't work out host platform"
 264         exit 1
 265     fi
 266
 267     HostArch=`echo "$host" | sed 's/-.*//'`
 268     HostVendor=`echo "$host" | sed -e 's/.*-\(.*\)-.*/\1/'`
 269     HostOS=`echo "$host" | sed 's/.*-//'`
 270 else
 271     GHC_CONVERT_CPU([$host_cpu], [HostArch])
 272     GHC_CONVERT_VENDOR([$host_vendor], [HostVendor])
 273     GHC_CONVERT_OS([$host_os], [HostOS])
 274 fi
 275
 276 if test "$target_alias" = ""
 277 then
 278     if test "${WithGhc}" != ""
 279     then
 280         target=$bootstrap_target
 281         echo "Target platform inferred as: $target"
 282     else
 283         echo "Can't work out target platform"
 284         exit 1
 285     fi
 286
 287     TargetArch=`echo "$target" | sed 's/-.*//'`
 288     TargetVendor=`echo "$target" | sed -e 's/.*-\(.*\)-.*/\1/'`
 289     TargetOS=`echo "$target" | sed 's/.*-//'`
 290 else
 291     GHC_CONVERT_CPU([$target_cpu], [TargetArch])
 292     GHC_CONVERT_VENDOR([$target_vendor], [TargetVendor])
 293     GHC_CONVERT_OS([$target_os], [TargetOS])
 294 fi
 295
 296 exeext=''
 297 soext='.so'
 298 case $host in
 299 *-unknown-cygwin32)
 300     AC_MSG_WARN([GHC does not support the Cygwin target at the moment])
 301     AC_MSG_WARN([I'm assuming you wanted to build for i386-unknown-mingw32])
 302     exit 1
 303     ;;
 304 *-unknown-mingw32)
 305     exeext='.exe'
 306     soext='.dll'
 307     ;;
 308 i386-apple-darwin|powerpc-apple-darwin)
 309     soext='.dylib'
 310     CFLAGS="$CFLAGS -m32"
 311     LDFLAGS="$LDFLAGS -m32"
 312     CONF_CC_OPTS="$CONF_CC_OPTS -m32"
 313     CONF_LD_OPTS="$CONF_LD_OPTS -m32"
 314     ;;
 315 x86_64-apple-darwin)
 316     soext='.dylib'
 317     CFLAGS="$CFLAGS -m64"
 318     LDFLAGS="$LDFLAGS -m64"
 319     CONF_CC_OPTS="$CONF_CC_OPTS -m64"
 320     CONF_LD_OPTS="$CONF_LD_OPTS -m64"
 321     ;;
 322 esac
 323
 324 checkArch() {
 325     case $1 in
 326     alpha|arm|hppa|hppa1_1|i386|ia64|m68k|mips|mipseb|mipsel|powerpc|powerpc64|rs6000|s390|sparc|sparc64|vax|x86_64)
 327         ;;
 328     *)
 329         echo "Unknown arch $1"
 330         exit 1
 331         ;;
 332     esac
 333 }
 334
 335 checkVendor() {
 336     case $1 in
 337     dec|unknown|hp|apple|next|sun|sgi|ibm)
 338         ;;
 339     *)
 340         echo "Unknown vendor $1"
 341         exit 1
 342         ;;
 343     esac
 344 }
 345
 346 checkOS() {
 347     case $1 in
 348     linux|freebsd|netbsd|openbsd|dragonfly|osf1|osf3|hpux|linuxaout|kfreebsdgnu|freebsd2|solaris2|cygwin32|mingw32|darwin|gnu|nextstep2|nextstep3|sunos4|ultrix|irix|aix|haiku)
 349         ;;
 350     *)
 351         echo "Unknown OS '$1'"
 352         exit 1
 353         ;;
 354     esac
 355 }
 356
 357 BuildPlatform="$BuildArch-$BuildVendor-$BuildOS"
 358 BuildPlatform_CPP=`echo "$BuildPlatform" | sed -e 's/\./_/g' -e 's/-/_/g'`
 359 BuildArch_CPP=`    echo "$BuildArch"     | sed -e 's/\./_/g' -e 's/-/_/g'`
 360 BuildVendor_CPP=`  echo "$BuildVendor"   | sed -e 's/\./_/g' -e 's/-/_/g'`
 361 BuildOS_CPP=`      echo "$BuildOS"       | sed -e 's/\./_/g' -e 's/-/_/g'`
 362
 363 checkArch "$BuildArch"
 364 checkVendor "$BuildVendor"
 365 checkOS "$BuildOS"
 366
 367 HostPlatform="$HostArch-$HostVendor-$HostOS"
 368 HostPlatform_CPP=`echo "$HostPlatform" | sed -e 's/\./_/g' -e 's/-/_/g'`
 369 HostArch_CPP=`    echo "$HostArch"     | sed -e 's/\./_/g' -e 's/-/_/g'`
 370 HostVendor_CPP=`  echo "$HostVendor"   | sed -e 's/\./_/g' -e 's/-/_/g'`
 371 HostOS_CPP=`      echo "$HostOS"       | sed -e 's/\./_/g' -e 's/-/_/g'`
 372
 373 checkArch "$HostArch"
 374 checkVendor "$HostVendor"
 375 checkOS "$HostOS"
 376
 377 TargetPlatform="$TargetArch-$TargetVendor-$TargetOS"
 378 TargetPlatform_CPP=`echo "$TargetPlatform" | sed -e 's/\./_/g' -e 's/-/_/g'`
 379 TargetArch_CPP=`    echo "$TargetArch"     | sed -e 's/\./_/g' -e 's/-/_/g'`
 380 TargetVendor_CPP=`  echo "$TargetVendor"   | sed -e 's/\./_/g' -e 's/-/_/g'`
 381 TargetOS_CPP=`      echo "$TargetOS"       | sed -e 's/\./_/g' -e 's/-/_/g'`
 382
 383 checkArch "$TargetArch"
 384 checkVendor "$TargetVendor"
 385 checkOS "$TargetOS"
 386
 387 AC_SUBST(BuildPlatform)
 388 AC_SUBST(HostPlatform)
 389 AC_SUBST(TargetPlatform)
 390 AC_SUBST(HostPlatform_CPP)
 391 AC_SUBST(BuildPlatform_CPP)
 392 AC_SUBST(TargetPlatform_CPP)
 393
 394 AC_SUBST(HostArch_CPP)
 395 AC_SUBST(BuildArch_CPP)
 396 AC_SUBST(TargetArch_CPP)
 397
 398 AC_SUBST(HostOS_CPP)
 399 AC_SUBST(BuildOS_CPP)
 400 AC_SUBST(TargetOS_CPP)
 401
 402 AC_SUBST(HostVendor_CPP)
 403 AC_SUBST(BuildVendor_CPP)
 404 AC_SUBST(TargetVendor_CPP)
 405
 406 AC_SUBST(exeext)
 407 AC_SUBST(soext)
 408
 409 AC_ARG_WITH(hc,
 410 [AC_HELP_STRING([--with-hc=ARG],
 411         [Use ARG as the path to the compiler for compiling ordinary
 412          Haskell code  (default= value of --with-ghc)])],
 413 [WithHc="$withval"],
 414 [WithHc=$WithGhc]
 415 )
 416 AC_SUBST(WithHc)
 417
 418 AC_PATH_PROGS(NHC,nhc nhc98)
 419 AC_PATH_PROG(HBC,hbc)
 420
 421 # This uses GHC, so put it after the "GHC is required" check above:
 422 FP_FIND_ROOT
 423
 424 if test "$HostOS" = "mingw32"
 425 then
 426     CC="$hardtop/inplace/mingw/bin/gcc.exe"
 427     LD="$hardtop/inplace/mingw/bin/ld.exe"
 428     NM="$hardtop/inplace/mingw/bin/nm.exe"
 429     if ! test -d inplace/mingw ||
 430          test inplace/mingw -ot ghc-tarballs/mingw/binutils*.tar.gz ||
 431          test inplace/mingw -ot ghc-tarballs/mingw/gcc-core*.tar.gz ||
 432          test inplace/mingw -ot ghc-tarballs/mingw/gcc-g++*.tar.gz ||
 433          test inplace/mingw -ot ghc-tarballs/mingw/libcrypt*.tar.bz2 ||
 434          test inplace/mingw -ot ghc-tarballs/mingw/mingw-runtime*.tar.gz ||
 435          test inplace/mingw -ot ghc-tarballs/mingw/w32api*.tar.gz
 436     then
 437         AC_MSG_NOTICE([Making in-tree mingw tree])
 438         rm -rf inplace/mingw
 439         mkdir inplace
 440         mkdir inplace/mingw
 441         (
 442             cd inplace/mingw &&
 443             tar -zxf ../../ghc-tarballs/mingw/binutils*.tar.gz &&
 444             tar -zxf ../../ghc-tarballs/mingw/gcc-core*.tar.gz &&
 445             tar -zxf ../../ghc-tarballs/mingw/gcc-g++*.tar.gz &&
 446             tar -jxf ../../ghc-tarballs/mingw/libcrypt*.tar.bz2 &&
 447             tar -zxf ../../ghc-tarballs/mingw/mingw-runtime*.tar.gz &&
 448             tar -zxf ../../ghc-tarballs/mingw/w32api*.tar.gz &&
 449             mv bin/gcc.exe bin/realgcc.exe
 450         )
 451         inplace/mingw/bin/realgcc.exe driver/gcc/gcc.c driver/utils/cwrapper.c driver/utils/getLocation.c -Idriver/utils -o inplace/mingw/bin/gcc.exe
 452         AC_MSG_NOTICE([In-tree mingw tree created])
 453     fi
 454     if ! test -d inplace/perl ||
 455          test inplace/perl -ot ghc-tarballs/perl/ghc-perl*.tar.gz
 456     then
 457         AC_MSG_NOTICE([Making in-tree perl tree])
 458         rm -rf inplace/perl
 459         mkdir inplace
 460         mkdir inplace/perl
 461         (
 462             cd inplace/perl &&
 463             tar -zxf ../../ghc-tarballs/perl/ghc-perl*.tar.gz
 464         )
 465         AC_MSG_NOTICE([In-tree perl tree created])
 466     fi
 467 fi
 468
 469 dnl ** Which gcc to use?
 470 dnl --------------------------------------------------------------
 471 FP_ARG_WITH_PATH_GNU_PROG([CC], [gcc])
 472 export CC
 473 WhatGccIsCalled="$CC"
 474 AC_SUBST(WhatGccIsCalled)
 475
 476 dnl ** Which ld to use?
 477 dnl --------------------------------------------------------------
 478 FP_ARG_WITH_PATH_GNU_PROG([LD], [ld])
 479 LdCmd="$LD"
 480 AC_SUBST([LdCmd])
 481
 482 dnl ** Which nm to use?
 483 dnl --------------------------------------------------------------
 484 FP_ARG_WITH_PATH_GNU_PROG([NM], [nm])
 485 NmCmd="$NM"
 486 AC_SUBST([NmCmd])
 487
 488 dnl ** Mac OS X: explicit deployment target
 489 dnl --------------------------------------------------------------
 490 AC_ARG_WITH([macosx-deployment-target],
 491 [AC_HELP_STRING([--with-macosx-deployment-target=VERSION],
 492         [Build for Mac OS VERSION and higher  (default= version of build host)])],
 493 [FP_MACOSX_DEPLOYMENT_TARGET="$withval"
 494  if test "x$TargetOS_CPP-$TargetVendor_CPP" != "xdarwin-apple"; then
 495    # ignore everywhere, but on Mac OS
 496    AC_MSG_WARN([--macosx-deployment-target is only available on Mac OS X])
 497    FP_MACOSX_DEPLOYMENT_TARGET=none
 498  fi],
 499 [FP_MACOSX_DEPLOYMENT_TARGET=none]
 500 )
 501 FP_CHECK_MACOSX_DEPLOYMENT_TARGET
 502 AC_SUBST(MACOSX_DEPLOYMENT_VERSION)
 503 AC_SUBST(MACOSX_DEPLOYMENT_SDK)
 504
 505 dnl --------------------------------------------------------------
 506 dnl End of configure script option section
 507 dnl --------------------------------------------------------------
 508
 509
 510 dnl --------------------------------------------------------------
 511 dnl * General configuration checks
 512 dnl --------------------------------------------------------------
 513
 514 dnl ** Can the unix package be built?
 515 dnl --------------------------------------------------------------
 516
 517 if test x"$TargetPlatform" = x"i386-unknown-mingw32"; then
 518    GhcLibsWithUnix=NO
 519 else
 520    GhcLibsWithUnix=YES
 521 fi
 522 AC_SUBST([GhcLibsWithUnix])
 523
 524 dnl ** does #! work?
 525 AC_SYS_INTERPRETER()
 526
 527 dnl ** look for `perl', but only in /bin on Windows
 528 case $HostOS_CPP in
 529 cygwin32|mingw32)
 530       AC_CHECK_PROG(PerlCmd,perl,/bin/perl,,/bin)
 531       if test -z "$PerlCmd"; then
 532          echo "You must install the version of Perl shipped with GHC"
 533          echo "(or a compatible one) in /bin."
 534          exit 1
 535       fi
 536    ;;
 537 *)
 538    AC_PATH_PROG(PerlCmd,perl)
 539    if test -z "$PerlCmd"; then
 540       echo "You must install perl before you can continue"
 541       echo "Perhaps it is already installed, but not in your PATH?"
 542       exit 1
 543    else
 544    FPTOOLS_CHECK_PERL_VERSION
 545    fi
 546    ;;
 547 esac
 548
 549 dnl ** does #! path/to/perl work? (sometimes it's too long...)
 550 FPTOOLS_SHEBANG_PERL
 551
 552 dnl ** check for Python
 553 AC_PATH_PROG(PythonCmd,python)
 554
 555 dnl ** look for GCC and find out which version
 556 dnl     Figure out which C compiler to use.  Gcc is preferred.
 557 dnl     If gcc, make sure it's at least 2.1
 558 dnl
 559 FP_HAVE_GCC
 560 FP_GCC_EXTRA_FLAGS
 561
 562 dnl ** figure out how to invoke cpp directly (gcc -E is no good)
 563 AC_PROG_CPP
 564
 565 AC_SUBST(CONF_CC_OPTS)
 566 AC_SUBST(CONF_LD_OPTS)
 567
 568 dnl ** figure out how to do context diffs
 569 FP_PROG_CONTEXT_DIFF
 570
 571 dnl Let's make sure install-sh is executable here.  If we got it from
 572 dnl a darcs repo, it might not be (see bug #978).
 573 chmod +x install-sh
 574 dnl ** figure out how to do a BSD-ish install
 575 AC_PROG_INSTALL
 576
 577 dnl If you can run configure, you certainly have /bin/sh
 578 AC_DEFINE([HAVE_BIN_SH], [1], [Define to 1 if you have /bin/sh.])
 579
 580 dnl ** how to invoke `ar' and `ranlib'
 581 FP_PROG_AR_SUPPORTS_ATFILE
 582 FP_PROG_AR_NEEDS_RANLIB
 583 FP_PROG_AR_SUPPORTS_INPUT
 584
 585 dnl ** Check to see whether ln -s works
 586 AC_PROG_LN_S
 587
 588
 589 dnl ** Find the path to sed
 590 AC_PATH_PROGS(SedCmd,gsed sed,sed)
 591
 592
 593 dnl ** check for time command
 594 AC_PATH_PROG(TimeCmd,time)
 595
 596 dnl ** check for tar
 597 dnl   if GNU tar is named gtar, look for it first.
 598 AC_PATH_PROGS(TarCmd,gnutar gtar tar,tar)
 599
 600 dnl ** check for patch
 601 dnl if GNU patch is named gpatch, look for it first
 602 AC_PATH_PROGS(PatchCmd,gpatch patch, patch)
 603
 604 dnl ** check for dtrace (currently only implemented for Mac OS X)
 605 HaveDtrace=NO
 606 AC_PATH_PROG(DtraceCmd,dtrace)
 607 if test -n "$DtraceCmd"; then
 608   if test "x$TargetOS_CPP-$TargetVendor_CPP" == "xdarwin-apple"; then
 609     HaveDtrace=YES
 610   fi
 611 fi
 612 AC_SUBST(HaveDtrace)
 613
 614 AC_PATH_PROG(HSCOLOUR,HsColour)
 615 # HsColour is passed to Cabal, so we need a native path
 616 if test "x$HostPlatform"  = "xi386-unknown-mingw32" && \
 617    test "${OSTYPE}"      != "msys"                  && \
 618    test "${HSCOLOUR}"    != ""
 619 then
 620     # Canonicalise to <drive>:/path/to/gcc
 621     HSCOLOUR=`cygpath -m ${HSCOLOUR}`
 622 fi
 623
 624 dnl ** check for DocBook toolchain
 625 FP_CHECK_DOCBOOK_DTD
 626 FP_DOCBOOK_XSL
 627 FP_PROG_DBLATEX
 628
 629 FP_PROG_HSTAGS
 630
 631 dnl ** check for ghc-pkg command
 632 FP_PROG_GHC_PKG
 633
 634 dnl ** check for installed happy binary + version
 635 dnl    (don't do it if we're booting from .hc files though.)
 636 if test "$BootingFromHc" = "NO"; then
 637 FPTOOLS_HAPPY
 638 fi;
 639
 640 dnl ** check for installed alex binary + version
 641 dnl    (don't do it if we're booting from .hc files though.)
 642 if test "$BootingFromHc" = "NO"; then
 643 FPTOOLS_ALEX
 644 fi;
 645
 646 dnl --------------------------------------------------
 647 dnl ### program checking section ends here ###
 648 dnl --------------------------------------------------
 649
 650 dnl --------------------------------------------------
 651 dnl * Platform header file and syscall feature tests
 652 dnl ### checking the state of the local header files and syscalls ###
 653
 654 dnl ** check for full ANSI header (.h) files
 655 AC_HEADER_STDC
 656
 657 dnl ** Enable large file support.  NB. do this before testing the type of
 658 dnl    off_t, because it will affect the result of that test.
 659 AC_SYS_LARGEFILE
 660
 661 dnl ** check for specific header (.h) files that we are interested in
 662 AC_CHECK_HEADERS([bfd.h ctype.h dirent.h dlfcn.h errno.h fcntl.h grp.h limits.h locale.h nlist.h pthread.h pwd.h signal.h sys/mman.h sys/resource.h sys/select.h sys/time.h sys/timeb.h sys/timers.h sys/times.h sys/utsname.h sys/wait.h termios.h time.h utime.h windows.h winsock.h sched.h])
 663
 664 dnl ** check if it is safe to include both <time.h> and <sys/time.h>
 665 AC_HEADER_TIME
 666
 667 dnl ** do we have long longs?
 668 AC_CHECK_TYPES([long long])
 669
 670 dnl ** what are the sizes of various types
 671 AC_CHECK_SIZEOF(char,               1)
 672 AC_CHECK_SIZEOF(double,             8)
 673 AC_CHECK_SIZEOF(float,              4)
 674 AC_CHECK_SIZEOF(int,                4)
 675 AC_CHECK_SIZEOF(long,               4)
 676 if test "$ac_cv_type_long_long" = yes; then
 677 AC_CHECK_SIZEOF(long long,          8)
 678 fi
 679 AC_CHECK_SIZEOF(short,              2)
 680 AC_CHECK_SIZEOF(unsigned char,      1)
 681 AC_CHECK_SIZEOF(unsigned int,       4)
 682 AC_CHECK_SIZEOF(unsigned long,      4)
 683 if test "$ac_cv_type_long_long" = yes; then
 684 AC_CHECK_SIZEOF(unsigned long long, 8)
 685 fi
 686 AC_CHECK_SIZEOF(unsigned short,     2)
 687 AC_CHECK_SIZEOF(void *,             4)
 688
 689 dnl ** what are alignment constraints on various types
 690 FP_CHECK_ALIGNMENT(char)
 691 FP_CHECK_ALIGNMENT(double)
 692 FP_CHECK_ALIGNMENT(float)
 693 FP_CHECK_ALIGNMENT(int)
 694 FP_CHECK_ALIGNMENT(long)
 695 if test "$ac_cv_type_long_long" = yes; then
 696 FP_CHECK_ALIGNMENT(long long)
 697 fi
 698 FP_CHECK_ALIGNMENT(short)
 699 FP_CHECK_ALIGNMENT(unsigned char)
 700 FP_CHECK_ALIGNMENT(unsigned int)
 701 FP_CHECK_ALIGNMENT(unsigned long)
 702 if test "$ac_cv_type_long_long" = yes; then
 703 FP_CHECK_ALIGNMENT(unsigned long long)
 704 fi
 705 FP_CHECK_ALIGNMENT(unsigned short)
 706 FP_CHECK_ALIGNMENT(void *)
 707
 708 FP_CHECK_FUNC([WinExec],
 709   [@%:@include <windows.h>], [WinExec("",0)])
 710
 711 FP_CHECK_FUNC([GetModuleFileName],
 712   [@%:@include <windows.h>], [GetModuleFileName((HMODULE)0,(LPTSTR)0,0)])
 713
 714 dnl ** check return type of signal handlers
 715 dnl Foo: assumes we can use prototypes.
 716 dnl On BCC, signal handlers have type "int(void)", elsewhere its "void(int)".
 717 dnl AC_CACHE_CHECK([type of signal handlers], ac_cv_type_signal_handler,
 718 dnl [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 719 dnl #include <signal.h>
 720 dnl #ifdef signal
 721 dnl #undef signal
 722 dnl #endif
 723 dnl void (*signal (int, void (*)(int)))(int);
 724 dnl ]],
 725 dnl [[int i;]])],
 726 dnl [ac_cv_type_signal_handler=void_int],
 727 dnl [ac_cv_type_signal_handler=int_void])])
 728 dnl if test "$ac_cv_type_signal_handler" = void_int; then
 729 dnl AC_DEFINE(VOID_INT_SIGNALS)
 730 dnl fi
 731
 732 dnl On BCC, signal handlers have type "int(void)", elsewhere its "void(int)".
 733 AC_TYPE_SIGNAL
 734 if test "$ac_cv_type_signal" = void; then
 735   AC_DEFINE([VOID_INT_SIGNALS], [1], [Define to 1 if signal handlers have type void (*)(int). Otherwise, they're assumed to have type int (*)(void).])
 736 fi
 737
 738 dnl ** check for more functions
 739 dnl ** The following have been verified to be used in ghc/, but might be used somewhere else, too.
 740 AC_CHECK_FUNCS([getclock getrusage gettimeofday setitimer siginterrupt sysconf times ctime_r sched_setaffinity setlocale])
 741
 742 AC_TRY_RUN([
 743 #include <sys/types.h>
 744 #include <sys/time.h>
 745 int main(void) {
 746   struct itimerval tval;
 747   tval.it_value.tv_sec = 1;
 748   tval.it_value.tv_usec = 0;
 749   tval.it_interval = tval.it_value;
 750   return setitimer(ITIMER_VIRTUAL, &tval, (void*)0) != 0;
 751 }
 752 ],[AC_DEFINE([HAVE_SETITIMER_VIRTUAL], [1], [Define to 1 if setitimer accepts ITIMER_VIRTUAL, 0 else.])])
 753
 754 dnl ** On OS X 10.4 (at least), time.h doesn't declare ctime_r if
 755 dnl ** _POSIX_C_SOURCE is defined
 756 AC_CHECK_DECLS([ctime_r], , ,
 757 [#define _POSIX_SOURCE 1
 758 #define _POSIX_C_SOURCE 199506L
 759 #include <time.h>])
 760
 761 dnl ** check for mingwex library
 762 AC_CHECK_LIB(mingwex, closedir, HaveLibMingwEx=YES, HaveLibMingwEx=NO)
 763 AC_SUBST(HaveLibMingwEx)
 764
 765 if test $HaveLibMingwEx = YES ; then
 766   AC_DEFINE([HAVE_MINGWEX], [1], [Define to 1 if you have the mingwex library.])
 767 fi
 768
 769 dnl ** check for math library
 770 dnl    Keep that check as early as possible.
 771 dnl    as we need to know whether we need libm
 772 dnl    for math functions or not
 773 dnl    (see http://hackage.haskell.org/trac/ghc/ticket/3730)
 774 AC_SEARCH_LIBS(atan, m,
 775   [AC_DEFINE([HAVE_LIBM], [1], [Define to 1 if you need to link with libm])])
 776
 777 dnl ** check whether this machine has BFD and liberty installed (used for debugging)
 778 dnl    the order of these tests matters: bfd needs liberty
 779 AC_CHECK_LIB(iberty, xmalloc)
 780 AC_CHECK_LIB(bfd,    bfd_init)
 781
 782 dnl ################################################################
 783 dnl Check for libraries
 784 dnl ################################################################
 785
 786 dnl ** check whether we need -ldl to get dlopen()
 787
 788 AC_CHECK_LIB(dl, dlopen,
 789     [HaveLibDL=YES
 790      AC_DEFINE([HAVE_LIBDL], [1], [Define to 1 if you need -ldl to get dlopen().])
 791      LIBS="$LIBS -ldl"],
 792     [HaveLibDL=NO])
 793 AC_SUBST(HaveLibDL)
 794
 795 dnl --------------------------------------------------
 796 dnl * Miscellaneous feature tests
 797 dnl --------------------------------------------------
 798
 799 dnl ** can we get alloca?
 800 AC_FUNC_ALLOCA
 801
 802 dnl ** Working vfork?
 803 AC_FUNC_FORK
 804
 805 dnl ** determine whether or not const works
 806 AC_C_CONST
 807
 808 dnl ** are we big endian?
 809 AC_C_BIGENDIAN
 810 FPTOOLS_FLOAT_WORD_ORDER_BIGENDIAN
 811
 812 dnl ** check for leading underscores in symbol names
 813 FP_LEADING_UNDERSCORE
 814
 815 dnl ** check for ld, whether it has an -x option, and if it is GNU ld
 816 FP_PROG_LD_X
 817 FP_PROG_LD_IS_GNU
 818
 819 dnl ** check for Apple-style dead-stripping support
 820 dnl    (.subsections-via-symbols assembler directive)
 821
 822
 823 AC_MSG_CHECKING(for .subsections_via_symbols)
 824 AC_COMPILE_IFELSE(
 825     [AC_LANG_PROGRAM([], [__asm__ (".subsections_via_symbols");])],
 826     [AC_MSG_RESULT(yes)
 827      AC_DEFINE([HAVE_SUBSECTIONS_VIA_SYMBOLS],[1],
 828                [Define to 1 if Apple-style dead-stripping is supported.])
 829     ],
 830     [AC_MSG_RESULT(no)])
 831
 832 dnl *** check for GNU non-executable stack note support (ELF only)
 833 dnl     (.section .note.GNU-stack,"",@progbits)
 834
 835 AC_MSG_CHECKING(for GNU non-executable stack support)
 836 AC_COMPILE_IFELSE(
 837     [AC_LANG_PROGRAM([__asm__ (".section .note.GNU-stack,\"\",@progbits");], [0])],
 838     [AC_MSG_RESULT(yes)
 839      AC_DEFINE([HAVE_GNU_NONEXEC_STACK],[1],
 840                [Define to 1 if GNU non-executable stack notes are supported.])
 841     ],
 842     [AC_MSG_RESULT(no)])
 843
 844 dnl ** check for librt
 845 AC_CHECK_LIB(rt, clock_gettime)
 846 AC_CHECK_FUNCS(clock_gettime timer_create timer_settime)
 847 FP_CHECK_TIMER_CREATE
 848
 849 dnl ** check for Apple's "interesting" long double compatibility scheme
 850 AC_MSG_CHECKING(for printf\$LDBLStub)
 851 AC_TRY_LINK_FUNC(printf\$LDBLStub,
 852     [
 853         AC_MSG_RESULT(yes)
 854         AC_DEFINE([HAVE_PRINTF_LDBLSTUB],[1],
 855             [Define to 1 if we have printf$LDBLStub (Apple Mac OS >= 10.4, PPC).])
 856     ],
 857     [
 858         AC_MSG_RESULT(no)
 859         AC_DEFINE([HAVE_PRINTF_LDBLSTUB],[0],
 860             [Define to 1 if we have printf$LDBLStub (Apple Mac OS >= 10.4, PPC).])
 861     ])
 862
 863 # test for GTK+
 864 AC_PATH_PROGS([GTK_CONFIG], [pkg-config])
 865 if test -n "$GTK_CONFIG"; then
 866   if $GTK_CONFIG gtk+-2.0 --atleast-version=2.0; then
 867     GTK_CONFIG="$GTK_CONFIG gtk+-2.0"
 868   else
 869     AC_MSG_WARN([GTK+ not usable, need at least version 2.0])
 870     GTK_CONFIG=
 871   fi
 872 fi
 873 AC_SUBST([GTK_CONFIG])
 874
 875 #Checking for PAPI
 876 AC_CHECK_LIB(papi, PAPI_library_init, HavePapiLib=YES, HavePapiLib=NO)
 877 AC_CHECK_HEADER([papi.h], [HavePapiHeader=YES], [HavePapiHeader=NO])
 878 AC_SUBST(HavePapiLib)
 879 AC_SUBST(HavePapiHeader)
 880
 881 AC_CHECK_FUNCS(__mingw_vfprintf)
 882
 883 if test "$HavePapiLib" = "YES" -a "$HavePapiHeader" = "YES"; then
 884    HavePapi=YES
 885 else
 886    HavePapi=NO
 887 fi
 888 AC_SUBST(HavePapi)
 889
 890 if test "$HAVE_DOCBOOK_XSL" = "NO" ||
 891    test "$XsltprocCmd" = ""
 892 then
 893     BUILD_DOCBOOK_HTML=NO
 894 else
 895     BUILD_DOCBOOK_HTML=YES
 896 fi
 897 AC_SUBST(BUILD_DOCBOOK_HTML)
 898
 899 if test "$DblatexCmd" = ""
 900 then
 901     BUILD_DOCBOOK_PS=NO
 902     BUILD_DOCBOOK_PDF=NO
 903 else
 904     BUILD_DOCBOOK_PS=YES
 905     BUILD_DOCBOOK_PDF=YES
 906 fi
 907 AC_SUBST(BUILD_DOCBOOK_PS)
 908 AC_SUBST(BUILD_DOCBOOK_PDF)
 909
 910 LIBRARY_VERSION(base)
 911 LIBRARY_VERSION(Cabal)
 912 LIBRARY_VERSION(ghc-prim)
 913 LIBRARY_ghc_VERSION="$ProjectVersion"
 914 AC_SUBST(LIBRARY_ghc_VERSION)
 915
 916 if grep '       ' compiler/ghc.cabal.in 2>&1 >/dev/null; then
 917    AC_MSG_ERROR([compiler/ghc.cabal.in contains tab characters; please remove them])
 918 fi
 919
 920 AC_CONFIG_FILES([mk/config.mk mk/install.mk mk/project.mk compiler/ghc.cabal ghc/ghc-bin.cabal ghc.spec extra-gcc-opts docs/users_guide/ug-book.xml docs/users_guide/ug-ent.xml libraries/prologue.txt distrib/ghc.iss distrib/configure.ac])
 921 AC_CONFIG_COMMANDS([mk/stamp-h],[echo timestamp > mk/stamp-h])
 922 AC_OUTPUT
 923
 924 # We get caught by
 925 #     http://savannah.gnu.org/bugs/index.php?1516
 926 #     $(eval ...) inside conditionals causes errors
 927 # with make 3.80, so warn the user if it looks like they're about to
 928 # try to use it.
 929 # We would use "grep -q" here, but Solaris's grep doesn't support it.
 930 checkMake380() {
 931     if $1 --version 2>&1 | head -1 | grep 'GNU Make 3\.80' > /dev/null
 932     then
 933         echo
 934         echo "WARNING: It looks like \"$1\" is GNU make 3.80."
 935         echo "This version cannot be used to build GHC."
 936         echo "Please use GNU make >= 3.81."
 937     fi
 938 }
 939
 940 checkMake380 make
 941 checkMake380 gmake
 942
 943 echo ["
 944 ----------------------------------------------------------------------
 945 Configure completed successfully.
 946
 947    Building GHC version  : $ProjectVersion
 948
 949    Build platform        : $BuildPlatform
 950    Host platform         : $HostPlatform
 951    Target platform       : $TargetPlatform
 952 "]
 953
 954 if test "$BootingFromHc" = "YES"; then
 955 echo ["\
 956    Bootstrapping from HC files.
 957 "]
 958 else
 959 echo ["\
 960    Bootstrapping using   : $WithGhc
 961       which is version   : $GhcVersion
 962 "]
 963 fi
 964
 965 echo ["\
 966    Using GCC             : $WhatGccIsCalled
 967       which is version   : $GccVersion
 968
 969    ld       : $LdCmd
 970    Happy    : $HappyCmd ($HappyVersion)
 971    Alex     : $AlexCmd ($AlexVersion)
 972    Python   : $PythonCmd
 973    Perl     : $PerlCmd
 974    dblatex  : $DblatexCmd
 975    xsltproc : $XsltprocCmd"]
 976
 977 if test "$HSCOLOUR" = ""; then
 978 echo ["
 979    HsColour was not found; documentation will not contain source links
 980 "]
 981 else
 982 echo ["\
 983    HsColour : $HSCOLOUR
 984 "]
 985 fi
 986
 987 echo ["\
 988    Building DocBook HTML documentation : $BUILD_DOCBOOK_HTML
 989    Building DocBook PS documentation   : $BUILD_DOCBOOK_PS
 990    Building DocBook PDF documentation  : $BUILD_DOCBOOK_PDF"]
 991
 992 echo ["----------------------------------------------------------------------
 993 "]
 994
 995 echo "\
 996 For a standard build of GHC (fully optimised with profiling), type (g)make.
 997
 998 To make changes to the default build configuration, copy the file
 999 mk/build.mk.sample to mk/build.mk, and edit the settings in there.
1000
1001 For more information on how to configure your GHC build, see
1002    http://hackage.haskell.org/trac/ghc/wiki/Building
1003 "