ghc/compiler/stranal/WorkWrap.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1993-1998
   3 %
   4 \section[WorkWrap]{Worker/wrapper-generating back-end of strictness analyser}
   5
   6 \begin{code}
   7 module WorkWrap ( wwTopBinds, mkWrapper ) where
   8
   9 #include "HsVersions.h"
  10
  11 import CoreSyn
  12 import CoreUnfold       ( certainlyWillInline )
  13 import CoreLint         ( showPass, endPass )
  14 import CoreUtils        ( exprType, exprIsHNF )
  15 import Id               ( Id, idType, isOneShotLambda,
  16                           setIdNewStrictness, mkWorkerId,
  17                           setIdWorkerInfo, setInlinePragma,
  18                           idInfo )
  19 import MkId             ( lazyIdKey, lazyIdUnfolding )
  20 import Type             ( Type )
  21 import IdInfo           ( WorkerInfo(..), arityInfo,
  22                           newDemandInfo, newStrictnessInfo, unfoldingInfo, inlinePragInfo
  23                         )
  24 import NewDemand        ( Demand(..), StrictSig(..), DmdType(..), DmdResult(..),
  25                           Demands(..), mkTopDmdType, isBotRes, returnsCPR, topSig, isAbsent
  26                         )
  27 import UniqSupply       ( UniqSupply, initUs_, returnUs, thenUs, mapUs, getUniqueUs, UniqSM )
  28 import Unique           ( hasKey )
  29 import BasicTypes       ( RecFlag(..), isNonRec, Activation(..) )
  30 import VarEnv           ( isEmptyVarEnv )
  31 import Maybes           ( orElse )
  32 import DynFlags
  33 import WwLib
  34 import Util             ( lengthIs, notNull )
  35 import Outputable
  36 \end{code}
  37
  38 We take Core bindings whose binders have:
  39
  40 \begin{enumerate}
  41
  42 \item Strictness attached (by the front-end of the strictness
  43 analyser), and / or
  44
  45 \item Constructed Product Result information attached by the CPR
  46 analysis pass.
  47
  48 \end{enumerate}
  49
  50 and we return some ``plain'' bindings which have been
  51 worker/wrapper-ified, meaning:
  52
  53 \begin{enumerate}
  54
  55 \item Functions have been split into workers and wrappers where
  56 appropriate.  If a function has both strictness and CPR properties
  57 then only one worker/wrapper doing both transformations is produced;
  58
  59 \item Binders' @IdInfos@ have been updated to reflect the existence of
  60 these workers/wrappers (this is where we get STRICTNESS and CPR pragma
  61 info for exported values).
  62 \end{enumerate}
  63
  64 \begin{code}
  65
  66 wwTopBinds :: DynFlags
  67            -> UniqSupply
  68            -> [CoreBind]
  69            -> IO [CoreBind]
  70
  71 wwTopBinds dflags us binds
  72   = do {
  73         showPass dflags "Worker Wrapper binds";
  74
  75         -- Create worker/wrappers, and mark binders with their
  76         -- "strictness info" [which encodes their worker/wrapper-ness]
  77         let { binds' = workersAndWrappers us binds };
  78
  79         endPass dflags "Worker Wrapper binds"
  80                 Opt_D_dump_worker_wrapper binds'
  81     }
  82 \end{code}
  83
  84
  85 \begin{code}
  86 workersAndWrappers :: UniqSupply -> [CoreBind] -> [CoreBind]
  87
  88 workersAndWrappers us top_binds
  89   = initUs_ us $
  90     mapUs wwBind top_binds `thenUs` \ top_binds' ->
  91     returnUs (concat top_binds')
  92 \end{code}
  93
  94 %************************************************************************
  95 %*                                                                      *
  96 \subsection[wwBind-wwExpr]{@wwBind@ and @wwExpr@}
  97 %*                                                                      *
  98 %************************************************************************
  99
 100 @wwBind@ works on a binding, trying each \tr{(binder, expr)} pair in
 101 turn.  Non-recursive case first, then recursive...
 102
 103 \begin{code}
 104 wwBind  :: CoreBind
 105         -> UniqSM [CoreBind]    -- returns a WwBinding intermediate form;
 106                                 -- the caller will convert to Expr/Binding,
 107                                 -- as appropriate.
 108
 109 wwBind (NonRec binder rhs)
 110   = wwExpr rhs                          `thenUs` \ new_rhs ->
 111     tryWW NonRecursive binder new_rhs   `thenUs` \ new_pairs ->
 112     returnUs [NonRec b e | (b,e) <- new_pairs]
 113       -- Generated bindings must be non-recursive
 114       -- because the original binding was.
 115
 116 wwBind (Rec pairs)
 117   = mapUs do_one pairs          `thenUs` \ new_pairs ->
 118     returnUs [Rec (concat new_pairs)]
 119   where
 120     do_one (binder, rhs) = wwExpr rhs   `thenUs` \ new_rhs ->
 121                            tryWW Recursive binder new_rhs
 122 \end{code}
 123
 124 @wwExpr@ basically just walks the tree, looking for appropriate
 125 annotations that can be used. Remember it is @wwBind@ that does the
 126 matching by looking for strict arguments of the correct type.
 127 @wwExpr@ is a version that just returns the ``Plain'' Tree.
 128
 129 \begin{code}
 130 wwExpr :: CoreExpr -> UniqSM CoreExpr
 131
 132 wwExpr e@(Type _)             = returnUs e
 133 wwExpr e@(Lit _)              = returnUs e
 134 wwExpr e@(Note InlineMe expr) = returnUs e
 135         -- Don't w/w inside InlineMe's
 136
 137 wwExpr e@(Var v)
 138   | v `hasKey` lazyIdKey = returnUs lazyIdUnfolding
 139   | otherwise            = returnUs e
 140         -- Inline 'lazy' after strictness analysis
 141         -- (but not inside InlineMe's)
 142
 143 wwExpr (Lam binder expr)
 144   = wwExpr expr                 `thenUs` \ new_expr ->
 145     returnUs (Lam binder new_expr)
 146
 147 wwExpr (App f a)
 148   = wwExpr f                    `thenUs` \ new_f ->
 149     wwExpr a                    `thenUs` \ new_a ->
 150     returnUs (App new_f new_a)
 151
 152 wwExpr (Note note expr)
 153   = wwExpr expr                 `thenUs` \ new_expr ->
 154     returnUs (Note note new_expr)
 155
 156 wwExpr (Let bind expr)
 157   = wwBind bind                 `thenUs` \ intermediate_bind ->
 158     wwExpr expr                 `thenUs` \ new_expr ->
 159     returnUs (mkLets intermediate_bind new_expr)
 160
 161 wwExpr (Case expr binder ty alts)
 162   = wwExpr expr                         `thenUs` \ new_expr ->
 163     mapUs ww_alt alts                   `thenUs` \ new_alts ->
 164     returnUs (Case new_expr binder ty new_alts)
 165   where
 166     ww_alt (con, binders, rhs)
 167       = wwExpr rhs                      `thenUs` \ new_rhs ->
 168         returnUs (con, binders, new_rhs)
 169 \end{code}
 170
 171 %************************************************************************
 172 %*                                                                      *
 173 \subsection[tryWW]{@tryWW@: attempt a worker/wrapper pair}
 174 %*                                                                      *
 175 %************************************************************************
 176
 177 @tryWW@ just accumulates arguments, converts strictness info from the
 178 front-end into the proper form, then calls @mkWwBodies@ to do
 179 the business.
 180
 181 We have to BE CAREFUL that we don't worker-wrapperize an Id that has
 182 already been w-w'd!  (You can end up with several liked-named Ids
 183 bouncing around at the same time---absolute mischief.)  So the
 184 criterion we use is: if an Id already has an unfolding (for whatever
 185 reason), then we don't w-w it.
 186
 187 The only reason this is monadised is for the unique supply.
 188
 189 \begin{code}
 190 tryWW   :: RecFlag
 191         -> Id                           -- The fn binder
 192         -> CoreExpr                     -- The bound rhs; its innards
 193                                         --   are already ww'd
 194         -> UniqSM [(Id, CoreExpr)]      -- either *one* or *two* pairs;
 195                                         -- if one, then no worker (only
 196                                         -- the orig "wrapper" lives on);
 197                                         -- if two, then a worker and a
 198                                         -- wrapper.
 199 tryWW is_rec fn_id rhs
 200   |  isNonRec is_rec && certainlyWillInline unfolding
 201         -- No point in worker/wrappering a function that is going to be
 202         -- INLINEd wholesale anyway.  If the strictness analyser is run
 203         -- twice, this test also prevents wrappers (which are INLINEd)
 204         -- from being re-done.
 205         --
 206         -- It's very important to refrain from w/w-ing an INLINE function
 207         -- If we do so by mistake we transform
 208         --      f = __inline (\x -> E)
 209         -- into
 210         --      f = __inline (\x -> case x of (a,b) -> fw E)
 211         --      fw = \ab -> (__inline (\x -> E)) (a,b)
 212         -- and the original __inline now vanishes, so E is no longer
 213         -- inside its __inline wrapper.  Death!  Disaster!
 214   = returnUs [ (new_fn_id, rhs) ]
 215
 216   | is_thunk && worthSplittingThunk maybe_fn_dmd res_info
 217   = ASSERT2( isNonRec is_rec, ppr new_fn_id )   -- The thunk must be non-recursive
 218     splitThunk new_fn_id rhs
 219
 220   | is_fun && worthSplittingFun wrap_dmds res_info
 221   = splitFun new_fn_id fn_info wrap_dmds res_info inline_prag rhs
 222
 223   | otherwise
 224   = returnUs [ (new_fn_id, rhs) ]
 225
 226   where
 227     fn_info      = idInfo fn_id
 228     maybe_fn_dmd = newDemandInfo fn_info
 229     unfolding    = unfoldingInfo fn_info
 230     inline_prag  = inlinePragInfo fn_info
 231
 232         -- In practice it always will have a strictness
 233         -- signature, even if it's a uninformative one
 234     strict_sig  = newStrictnessInfo fn_info `orElse` topSig
 235     StrictSig (DmdType env wrap_dmds res_info) = strict_sig
 236
 237         -- new_fn_id has the DmdEnv zapped.
 238         --      (a) it is never used again
 239         --      (b) it wastes space
 240         --      (c) it becomes incorrect as things are cloned, because
 241         --          we don't push the substitution into it
 242     new_fn_id | isEmptyVarEnv env = fn_id
 243               | otherwise         = fn_id `setIdNewStrictness`
 244                                      StrictSig (mkTopDmdType wrap_dmds res_info)
 245
 246     is_fun    = notNull wrap_dmds
 247     is_thunk  = not is_fun && not (exprIsHNF rhs)
 248
 249 ---------------------
 250 splitFun fn_id fn_info wrap_dmds res_info inline_prag rhs
 251   = WARN( not (wrap_dmds `lengthIs` arity), ppr fn_id <+> (ppr arity $$ ppr wrap_dmds $$ ppr res_info) )
 252         -- The arity should match the signature
 253     mkWwBodies fun_ty wrap_dmds res_info one_shots      `thenUs` \ (work_demands, wrap_fn, work_fn) ->
 254     getUniqueUs                                         `thenUs` \ work_uniq ->
 255     let
 256         work_rhs = work_fn rhs
 257         work_id  = mkWorkerId work_uniq fn_id (exprType work_rhs)
 258                         `setInlinePragma` inline_prag
 259                         `setIdNewStrictness` StrictSig (mkTopDmdType work_demands work_res_info)
 260                                 -- Even though we may not be at top level,
 261                                 -- it's ok to give it an empty DmdEnv
 262
 263         wrap_rhs = wrap_fn work_id
 264         wrap_id  = fn_id `setIdWorkerInfo` HasWorker work_id arity
 265                          `setInlinePragma` AlwaysActive -- Zap any inline pragma;
 266                                                         -- Put it on the worker instead
 267     in
 268     returnUs ([(work_id, work_rhs), (wrap_id, wrap_rhs)])
 269         -- Worker first, because wrapper mentions it
 270         -- mkWwBodies has already built a wrap_rhs with an INLINE pragma wrapped around it
 271   where
 272     fun_ty = idType fn_id
 273
 274     arity  = arityInfo fn_info  -- The arity is set by the simplifier using exprEtaExpandArity
 275                                 -- So it may be more than the number of top-level-visible lambdas
 276
 277     work_res_info | isBotRes res_info = BotRes  -- Cpr stuff done by wrapper
 278                   | otherwise         = TopRes
 279
 280     one_shots = get_one_shots rhs
 281
 282 -- If the original function has one-shot arguments, it is important to
 283 -- make the wrapper and worker have corresponding one-shot arguments too.
 284 -- Otherwise we spuriously float stuff out of case-expression join points,
 285 -- which is very annoying.
 286 get_one_shots (Lam b e)
 287   | isId b    = isOneShotLambda b : get_one_shots e
 288   | otherwise = get_one_shots e
 289 get_one_shots (Note _ e) = get_one_shots e
 290 get_one_shots other      = noOneShotInfo
 291 \end{code}
 292
 293 Thunk splitting
 294 ~~~~~~~~~~~~~~~
 295 Suppose x is used strictly (never mind whether it has the CPR
 296 property).
 297
 298       let
 299         x* = x-rhs
 300       in body
 301
 302 splitThunk transforms like this:
 303
 304       let
 305         x* = case x-rhs of { I# a -> I# a }
 306       in body
 307
 308 Now simplifier will transform to
 309
 310       case x-rhs of
 311         I# a -> let x* = I# b
 312                 in body
 313
 314 which is what we want. Now suppose x-rhs is itself a case:
 315
 316         x-rhs = case e of { T -> I# a; F -> I# b }
 317
 318 The join point will abstract over a, rather than over (which is
 319 what would have happened before) which is fine.
 320
 321 Notice that x certainly has the CPR property now!
 322
 323 In fact, splitThunk uses the function argument w/w splitting
 324 function, so that if x's demand is deeper (say U(U(L,L),L))
 325 then the splitting will go deeper too.
 326
 327 \begin{code}
 328 -- splitThunk converts the *non-recursive* binding
 329 --      x = e
 330 -- into
 331 --      x = let x = e
 332 --          in case x of
 333 --               I# y -> let x = I# y in x }
 334 -- See comments above. Is it not beautifully short?
 335
 336 splitThunk fn_id rhs
 337   = mkWWstr [fn_id]             `thenUs` \ (_, wrap_fn, work_fn) ->
 338     returnUs [ (fn_id, Let (NonRec fn_id rhs) (wrap_fn (work_fn (Var fn_id)))) ]
 339 \end{code}
 340
 341
 342 %************************************************************************
 343 %*                                                                      *
 344 \subsection{Functions over Demands}
 345 %*                                                                      *
 346 %************************************************************************
 347
 348 \begin{code}
 349 worthSplittingFun :: [Demand] -> DmdResult -> Bool
 350                 -- True <=> the wrapper would not be an identity function
 351 worthSplittingFun ds res
 352   = any worth_it ds || returnsCPR res
 353         -- worthSplitting returns False for an empty list of demands,
 354         -- and hence do_strict_ww is False if arity is zero and there is no CPR
 355
 356         -- We used not to split if the result is bottom.
 357         -- [Justification:  there's no efficiency to be gained.]
 358         -- But it's sometimes bad not to make a wrapper.  Consider
 359         --      fw = \x# -> let x = I# x# in case e of
 360         --                                      p1 -> error_fn x
 361         --                                      p2 -> error_fn x
 362         --                                      p3 -> the real stuff
 363         -- The re-boxing code won't go away unless error_fn gets a wrapper too.
 364         -- [We don't do reboxing now, but in general it's better to pass
 365         --  an unboxed thing to f, and have it reboxed in the error cases....]
 366   where
 367     worth_it Abs              = True    -- Absent arg
 368     worth_it (Eval (Prod ds)) = True    -- Product arg to evaluate
 369     worth_it other            = False
 370
 371 worthSplittingThunk :: Maybe Demand     -- Demand on the thunk
 372                     -> DmdResult        -- CPR info for the thunk
 373                     -> Bool
 374 worthSplittingThunk maybe_dmd res
 375   = worth_it maybe_dmd || returnsCPR res
 376   where
 377         -- Split if the thing is unpacked
 378     worth_it (Just (Eval (Prod ds))) = not (all isAbsent ds)
 379     worth_it other                   = False
 380 \end{code}
 381
 382
 383
 384 %************************************************************************
 385 %*                                                                      *
 386 \subsection{The worker wrapper core}
 387 %*                                                                      *
 388 %************************************************************************
 389
 390 @mkWrapper@ is called when importing a function.  We have the type of
 391 the function and the name of its worker, and we want to make its body (the wrapper).
 392
 393 \begin{code}
 394 mkWrapper :: Type               -- Wrapper type
 395           -> StrictSig          -- Wrapper strictness info
 396           -> UniqSM (Id -> CoreExpr)    -- Wrapper body, missing worker Id
 397
 398 mkWrapper fun_ty (StrictSig (DmdType _ demands res_info))
 399   = mkWwBodies fun_ty demands res_info noOneShotInfo    `thenUs` \ (_, wrap_fn, _) ->
 400     returnUs wrap_fn
 401
 402 noOneShotInfo = repeat False
 403 \end{code}