ghc/rts/gmp/mpn/mips2/rshift.s

   1  # MIPS2 __gmpn_rshift --
   2
   3  # Copyright (C) 1995, 2000 Free Software Foundation, Inc.
   4
   5  # This file is part of the GNU MP Library.
   6
   7  # The GNU MP Library is free software; you can redistribute it and/or modify
   8  # it under the terms of the GNU Lesser General Public License as published by
   9  # the Free Software Foundation; either version 2.1 of the License, or (at your
  10  # option) any later version.
  11
  12  # The GNU MP Library is distributed in the hope that it will be useful, but
  13  # WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
  14  # or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU Lesser General Public
  15  # License for more details.
  16
  17  # You should have received a copy of the GNU Lesser General Public License
  18  # along with the GNU MP Library; see the file COPYING.LIB.  If not, write to
  19  # the Free Software Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  # MA 02111-1307, USA.
  21
  22
  23  # INPUT PARAMETERS
  24  # res_ptr      $4
  25  # src_ptr      $5
  26  # size         $6
  27  # cnt          $7
  28
  29         .text
  30         .align  2
  31         .globl  __gmpn_rshift
  32         .ent    __gmpn_rshift
  33 __gmpn_rshift:
  34         .set    noreorder
  35         .set    nomacro
  36
  37         lw      $10,0($5)       # load first limb
  38         subu    $13,$0,$7
  39         addiu   $6,$6,-1
  40         and     $9,$6,4-1       # number of limbs in first loop
  41         beq     $9,$0,.L0       # if multiple of 4 limbs, skip first loop
  42          sll    $2,$10,$13      # compute function result
  43
  44         subu    $6,$6,$9
  45
  46 .Loop0: lw      $3,4($5)
  47         addiu   $4,$4,4
  48         addiu   $5,$5,4
  49         addiu   $9,$9,-1
  50         srl     $11,$10,$7
  51         sll     $12,$3,$13
  52         move    $10,$3
  53         or      $8,$11,$12
  54         bne     $9,$0,.Loop0
  55          sw     $8,-4($4)
  56
  57 .L0:    beq     $6,$0,.Lend
  58          nop
  59
  60 .Loop:  lw      $3,4($5)
  61         addiu   $4,$4,16
  62         addiu   $6,$6,-4
  63         srl     $11,$10,$7
  64         sll     $12,$3,$13
  65
  66         lw      $10,8($5)
  67         srl     $14,$3,$7
  68         or      $8,$11,$12
  69         sw      $8,-16($4)
  70         sll     $9,$10,$13
  71
  72         lw      $3,12($5)
  73         srl     $11,$10,$7
  74         or      $8,$14,$9
  75         sw      $8,-12($4)
  76         sll     $12,$3,$13
  77
  78         lw      $10,16($5)
  79         srl     $14,$3,$7
  80         or      $8,$11,$12
  81         sw      $8,-8($4)
  82         sll     $9,$10,$13
  83
  84         addiu   $5,$5,16
  85         or      $8,$14,$9
  86         bgtz    $6,.Loop
  87          sw     $8,-4($4)
  88
  89 .Lend:  srl     $8,$10,$7
  90         j       $31
  91         sw      $8,0($4)
  92         .end    __gmpn_rshift