ghc/rts/gmp/mpn/sparc64/rshift.asm

   1 ! SPARC v9 __gmpn_rshift --
   2
   3 ! Copyright (C) 1996, 2000 Free Software Foundation, Inc.
   4
   5 ! This file is part of the GNU MP Library.
   6
   7 ! The GNU MP Library is free software; you can redistribute it and/or modify
   8 ! it under the terms of the GNU Lesser General Public License as published by
   9 ! the Free Software Foundation; either version 2.1 of the License, or (at your
  10 ! option) any later version.
  11
  12 ! The GNU MP Library is distributed in the hope that it will be useful, but
  13 ! WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
  14 ! or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU Lesser General Public
  15 ! License for more details.
  16
  17 ! You should have received a copy of the GNU Lesser General Public License
  18 ! along with the GNU MP Library; see the file COPYING.LIB.  If not, write to
  19 ! the Free Software Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20 ! MA 02111-1307, USA.
  21
  22
  23 ! INPUT PARAMETERS
  24 ! res_ptr       %o0
  25 ! src_ptr       %o1
  26 ! size          %o2
  27 ! cnt           %o3
  28
  29 include(`../config.m4')
  30
  31 ASM_START()
  32         .register       %g2,#scratch
  33         .register       %g3,#scratch
  34 PROLOGUE(mpn_rshift)
  35         ldx     [%o1],%g2       ! load first limb
  36         sub     %g0,%o3,%o5     ! negate shift count
  37         add     %o2,-1,%o2
  38         and     %o2,4-1,%g4     ! number of limbs in first loop
  39         sllx    %g2,%o5,%g1     ! compute function result
  40         brz,pn  %g4,L(0)        ! if multiple of 4 limbs, skip first loop
  41         mov     %g1,%g5
  42
  43         sub     %o2,%g4,%o2     ! adjust count for main loop
  44
  45 L(loop0):
  46         ldx     [%o1+8],%g3
  47         add     %o0,8,%o0
  48         add     %o1,8,%o1
  49         add     %g4,-1,%g4
  50         srlx    %g2,%o3,%o4
  51         sllx    %g3,%o5,%g1
  52         mov     %g3,%g2
  53         or      %o4,%g1,%o4
  54         brnz,pt %g4,L(loop0)
  55          stx    %o4,[%o0-8]
  56
  57 L(0):   brz,pn  %o2,L(end)
  58          nop
  59
  60 L(loop1):
  61         ldx     [%o1+8],%g3
  62         add     %o0,32,%o0
  63         add     %o2,-4,%o2
  64         srlx    %g2,%o3,%o4
  65         sllx    %g3,%o5,%g1
  66
  67         ldx     [%o1+16],%g2
  68         srlx    %g3,%o3,%g4
  69         or      %o4,%g1,%o4
  70         stx     %o4,[%o0-32]
  71         sllx    %g2,%o5,%g1
  72
  73         ldx     [%o1+24],%g3
  74         srlx    %g2,%o3,%o4
  75         or      %g4,%g1,%g4
  76         stx     %g4,[%o0-24]
  77         sllx    %g3,%o5,%g1
  78
  79         ldx     [%o1+32],%g2
  80         srlx    %g3,%o3,%g4
  81         or      %o4,%g1,%o4
  82         stx     %o4,[%o0-16]
  83         sllx    %g2,%o5,%g1
  84
  85         add     %o1,32,%o1
  86         or      %g4,%g1,%g4
  87         brnz    %o2,L(loop1)
  88          stx    %g4,[%o0-8]
  89
  90 L(end): srlx    %g2,%o3,%g2
  91         stx     %g2,[%o0-0]
  92         retl
  93         mov     %g5,%o0
  94 EPILOGUE(mpn_rshift)