rts/gmp/mpn/hppa/add_n.s

   1 ; HP-PA  __gmpn_add_n -- Add two limb vectors of the same length > 0 and store
   2 ; sum in a third limb vector.
   3
   4 ; Copyright (C) 1992, 1994, 2000 Free Software Foundation, Inc.
   5
   6 ; This file is part of the GNU MP Library.
   7
   8 ; The GNU MP Library is free software; you can redistribute it and/or modify
   9 ; it under the terms of the GNU Lesser General Public License as published by
  10 ; the Free Software Foundation; either version 2.1 of the License, or (at your
  11 ; option) any later version.
  12
  13 ; The GNU MP Library is distributed in the hope that it will be useful, but
  14 ; WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
  15 ; or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU Lesser General Public
  16 ; License for more details.
  17
  18 ; You should have received a copy of the GNU Lesser General Public License
  19 ; along with the GNU MP Library; see the file COPYING.LIB.  If not, write to
  20 ; the Free Software Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  21 ; MA 02111-1307, USA.
  22
  23
  24 ; INPUT PARAMETERS
  25 ; res_ptr       gr26
  26 ; s1_ptr        gr25
  27 ; s2_ptr        gr24
  28 ; size          gr23
  29
  30 ; One might want to unroll this as for other processors, but it turns
  31 ; out that the data cache contention after a store makes such
  32 ; unrolling useless.  We can't come under 5 cycles/limb anyway.
  33
  34         .code
  35         .export         __gmpn_add_n
  36 __gmpn_add_n
  37         .proc
  38         .callinfo       frame=0,no_calls
  39         .entry
  40
  41         ldws,ma         4(0,%r25),%r20
  42         ldws,ma         4(0,%r24),%r19
  43
  44         addib,=         -1,%r23,L$end   ; check for (SIZE == 1)
  45          add            %r20,%r19,%r28  ; add first limbs ignoring cy
  46
  47 L$loop  ldws,ma         4(0,%r25),%r20
  48         ldws,ma         4(0,%r24),%r19
  49         stws,ma         %r28,4(0,%r26)
  50         addib,<>        -1,%r23,L$loop
  51          addc           %r20,%r19,%r28
  52
  53 L$end   stws            %r28,0(0,%r26)
  54         bv              0(%r2)
  55          addc           %r0,%r0,%r28
  56
  57         .exit
  58         .procend