rts/gmp/mpn/hppa/hppa1_1/pa7100/rshift.s

   1 ; HP-PA  __gmpn_rshift --
   2 ; This is optimized for the PA7100, where is runs at 3.25 cycles/limb
   3
   4 ; Copyright (C) 1992, 1994, 2000 Free Software Foundation, Inc.
   5
   6 ; This file is part of the GNU MP Library.
   7
   8 ; The GNU MP Library is free software; you can redistribute it and/or modify
   9 ; it under the terms of the GNU Lesser General Public License as published by
  10 ; the Free Software Foundation; either version 2.1 of the License, or (at your
  11 ; option) any later version.
  12
  13 ; The GNU MP Library is distributed in the hope that it will be useful, but
  14 ; WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
  15 ; or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU Lesser General Public
  16 ; License for more details.
  17
  18 ; You should have received a copy of the GNU Lesser General Public License
  19 ; along with the GNU MP Library; see the file COPYING.LIB.  If not, write to
  20 ; the Free Software Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  21 ; MA 02111-1307, USA.
  22
  23
  24 ; INPUT PARAMETERS
  25 ; res_ptr       gr26
  26 ; s_ptr         gr25
  27 ; size          gr24
  28 ; cnt           gr23
  29
  30         .code
  31         .export         __gmpn_rshift
  32 __gmpn_rshift
  33         .proc
  34         .callinfo       frame=64,no_calls
  35         .entry
  36
  37         ldws,ma         4(0,%r25),%r22
  38         mtsar           %r23
  39         addib,=         -1,%r24,L$0004
  40         vshd            %r22,%r0,%r28           ; compute carry out limb
  41         ldws,ma         4(0,%r25),%r29
  42         addib,<=        -5,%r24,L$rest
  43         vshd            %r29,%r22,%r20
  44
  45 L$loop  ldws,ma         4(0,%r25),%r22
  46         stws,ma         %r20,4(0,%r26)
  47         vshd            %r22,%r29,%r20
  48         ldws,ma         4(0,%r25),%r29
  49         stws,ma         %r20,4(0,%r26)
  50         vshd            %r29,%r22,%r20
  51         ldws,ma         4(0,%r25),%r22
  52         stws,ma         %r20,4(0,%r26)
  53         vshd            %r22,%r29,%r20
  54         ldws,ma         4(0,%r25),%r29
  55         stws,ma         %r20,4(0,%r26)
  56         addib,>         -4,%r24,L$loop
  57         vshd            %r29,%r22,%r20
  58
  59 L$rest  addib,=         4,%r24,L$end1
  60         nop
  61 L$eloop ldws,ma         4(0,%r25),%r22
  62         stws,ma         %r20,4(0,%r26)
  63         addib,<=        -1,%r24,L$end2
  64         vshd            %r22,%r29,%r20
  65         ldws,ma         4(0,%r25),%r29
  66         stws,ma         %r20,4(0,%r26)
  67         addib,>         -1,%r24,L$eloop
  68         vshd            %r29,%r22,%r20
  69
  70 L$end1  stws,ma         %r20,4(0,%r26)
  71         vshd            %r0,%r29,%r20
  72         bv              0(%r2)
  73         stw             %r20,0(0,%r26)
  74 L$end2  stws,ma         %r20,4(0,%r26)
  75 L$0004  vshd            %r0,%r22,%r20
  76         bv              0(%r2)
  77         stw             %r20,0(0,%r26)
  78
  79         .exit
  80         .procend