rts/gmp/mpn/m88k/mc88110/addmul_1.s

   1 ; mc88110 __gmpn_addmul_1 -- Multiply a limb vector with a single limb and
   2 ; store the product in a second limb vector.
   3
   4 ; Copyright (C) 1996, 2000 Free Software Foundation, Inc.
   5
   6 ; This file is part of the GNU MP Library.
   7
   8 ; The GNU MP Library is free software; you can redistribute it and/or modify
   9 ; it under the terms of the GNU Lesser General Public License as published by
  10 ; the Free Software Foundation; either version 2.1 of the License, or (at your
  11 ; option) any later version.
  12
  13 ; The GNU MP Library is distributed in the hope that it will be useful, but
  14 ; WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
  15 ; or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU Lesser General Public
  16 ; License for more details.
  17
  18 ; You should have received a copy of the GNU Lesser General Public License
  19 ; along with the GNU MP Library; see the file COPYING.LIB.  If not, write to
  20 ; the Free Software Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  21 ; MA 02111-1307, USA.
  22
  23
  24 ; INPUT PARAMETERS
  25 ; res_ptr       r2
  26 ; s1_ptr        r3
  27 ; size          r4
  28 ; s2_limb       r5
  29
  30         text
  31         align   16
  32         global  ___gmpn_addmul_1
  33 ___gmpn_addmul_1:
  34         lda      r3,r3[r4]
  35         lda      r8,r2[r4]              ; RES_PTR in r8 since r2 is retval
  36         subu     r4,r0,r4
  37         addu.co  r2,r0,r0               ; r2 = cy = 0
  38
  39         ld       r6,r3[r4]
  40         addu     r4,r4,1
  41         subu     r8,r8,4
  42         bcnd.n   eq0,r4,Lend
  43          mulu.d  r10,r6,r5
  44
  45 Loop:   ld       r7,r8[r4]
  46         ld       r6,r3[r4]
  47         addu.cio r9,r11,r2
  48         addu.ci  r2,r10,r0
  49         addu.co  r9,r9,r7
  50         st       r9,r8[r4]
  51         addu     r4,r4,1
  52         mulu.d   r10,r6,r5
  53         bcnd     ne0,r4,Loop
  54
  55 Lend:   ld       r7,r8,0
  56         addu.cio r9,r11,r2
  57         addu.ci  r2,r10,r0
  58         addu.co  r9,r9,r7
  59         st       r9,r8,0
  60         jmp.n    r1
  61          addu.ci r2,r2,r0