rts/gmp/mpn/pa64w/mul_1.S

   1 ; HP-PA 2.0 64-bit __gmpn_mul_1 -- Multiply a limb vector with a limb and
   2 ; store the result in a second limb vector.
   3
   4 ; Copyright (C) 1998, 1999, 2000 Free Software Foundation, Inc.
   5
   6 ; This file is part of the GNU MP Library.
   7
   8 ; The GNU MP Library is free software; you can redistribute it and/or modify
   9 ; it under the terms of the GNU Lesser General Public License as published by
  10 ; the Free Software Foundation; either version 2.1 of the License, or (at your
  11 ; option) any later version.
  12
  13 ; The GNU MP Library is distributed in the hope that it will be useful, but
  14 ; WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
  15 ; or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU Lesser General Public
  16 ; License for more details.
  17
  18 ; You should have received a copy of the GNU Lesser General Public License
  19 ; along with the GNU MP Library; see the file COPYING.LIB.  If not, write to
  20 ; the Free Software Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  21 ; MA 02111-1307, USA.
  22
  23 ; INPUT PARAMETERS
  24 #define rptr            %r26
  25 #define sptr            %r25
  26 #define size            %r24
  27 #define s2limb          %r23
  28
  29 ; This runs at 11 cycles/limb on a PA8000.  It might be possible to make
  30 ; it faster, but the PA8000 pipeline is not publically documented and it
  31 ; is very complex to reverse engineer
  32
  33 #define t1 %r19
  34 #define rlimb %r20
  35 #define hi %r21
  36 #define lo %r22
  37 #define m0 %r28
  38 #define m1 %r3
  39 #define cylimb %r29
  40 #define t3 %r4
  41 #define t2 %r6
  42 #define t5 %r23
  43 #define t4 %r31
  44         .level  2.0w
  45         .code
  46         .export __gmpn_mul_1,entry
  47 __gmpn_mul_1
  48         .proc
  49         .callinfo frame=128,no_calls
  50         .entry
  51         std             s2limb,-56(%r30)
  52         fldd            -56(%r30),%fr5
  53         ldo             128(%r30),%r30
  54         add             %r0,%r0,cylimb          ; clear cy and cylimb
  55
  56         std             %r3,-96(%r30)
  57         std             %r4,-88(%r30)
  58         std             %r5,-80(%r30)
  59         std             %r6,-72(%r30)
  60         depdi,z         1,31,1,%r5
  61
  62         fldd            0(sptr),%fr4
  63         ldo             8(sptr),sptr
  64
  65         xmpyu           %fr5R,%fr4R,%fr6
  66         fstd            %fr6,-128(%r30)
  67         xmpyu           %fr5R,%fr4L,%fr7
  68         fstd            %fr7,-120(%r30)
  69         xmpyu           %fr5L,%fr4R,%fr8
  70         fstd            %fr8,-112(%r30)
  71         xmpyu           %fr5L,%fr4L,%fr9
  72         fstd            %fr9,-104(%r30)
  73         ldd             -128(%r30),lo           ; lo = low 64 bit of product
  74         ldd             -120(%r30),m0           ; m0 = mid0 64 bit of product
  75         ldd             -112(%r30),m1           ; m1 = mid1 64 bit of product
  76         ldd             -104(%r30),hi           ; hi = high 64 bit of product
  77         addib,=         -1,%r24,L$end1
  78         nop
  79         fldd            0(sptr),%fr4
  80         ldo             8(sptr),sptr
  81         addib,=         -1,%r24,L$end2
  82         nop
  83 L$loop
  84         xmpyu           %fr5R,%fr4R,%fr6
  85         fstd            %fr6,-128(%r30)
  86         xmpyu           %fr5R,%fr4L,%fr7
  87         fstd            %fr7,-120(%r30)
  88         xmpyu           %fr5L,%fr4R,%fr8
  89         fstd            %fr8,-112(%r30)
  90         xmpyu           %fr5L,%fr4L,%fr9
  91         fstd            %fr9,-104(%r30)
  92         extrd,u         lo,31,32,t1             ; t1 = hi32(lo)
  93         extrd,u         lo,63,32,t4             ; t4 = lo32(lo)
  94         add,l           m0,t1,t1                ; t1 += m0
  95         add,l,*nuv      m1,t1,t1                ; t1 += m1
  96          add,l          %r5,hi,hi               ; propagate carry
  97         extrd,u         t1,31,32,t2             ; t2 = hi32(t1)
  98         depd,z          t1,31,32,t5             ; t5 = lo32(t1)
  99         add,l           t5,t4,t4                ; t4 += lo32(t1)
 100         ldd             -128(%r30),lo           ; lo = low 64 bit of product
 101         add             cylimb,t4,t3
 102         ldd             -120(%r30),m0           ; m0 = mid0 64 bit of product
 103         add,dc          t2,hi,cylimb
 104         ldd             -112(%r30),m1           ; m1 = mid1 64 bit of product
 105         ldd             -104(%r30),hi           ; hi = high 64 bit of product
 106         fldd            0(sptr),%fr4
 107         ldo             8(sptr),sptr
 108         std             t3,0(rptr)
 109         addib,<>        -1,%r24,L$loop
 110         ldo             8(rptr),rptr
 111 L$end2
 112         xmpyu           %fr5R,%fr4R,%fr6
 113         fstd            %fr6,-128(%r30)
 114         xmpyu           %fr5R,%fr4L,%fr7
 115         fstd            %fr7,-120(%r30)
 116         xmpyu           %fr5L,%fr4R,%fr8
 117         fstd            %fr8,-112(%r30)
 118         xmpyu           %fr5L,%fr4L,%fr9
 119         fstd            %fr9,-104(%r30)
 120         extrd,u         lo,31,32,t1             ; t1 = hi32(lo)
 121         extrd,u         lo,63,32,t4             ; t4 = lo32(lo)
 122         add,l           m0,t1,t1                ; t1 += m0
 123         add,l,*nuv      m1,t1,t1                ; t1 += m0
 124          add,l          %r5,hi,hi               ; propagate carry
 125         extrd,u         t1,31,32,t2             ; t2 = hi32(t1)
 126         depd,z          t1,31,32,t5             ; t5 = lo32(t1)
 127         add,l           t5,t4,t4                ; t4 += lo32(t1)
 128         ldd             -128(%r30),lo           ; lo = low 64 bit of product
 129         add             cylimb,t4,t3
 130         ldd             -120(%r30),m0           ; m0 = mid0 64 bit of product
 131         add,dc          t2,hi,cylimb
 132         ldd             -112(%r30),m1           ; m1 = mid1 64 bit of product
 133         ldd             -104(%r30),hi           ; hi = high 64 bit of product
 134         std             t3,0(rptr)
 135         ldo             8(rptr),rptr
 136 L$end1
 137         extrd,u         lo,31,32,t1             ; t1 = hi32(lo)
 138         extrd,u         lo,63,32,t4             ; t2 = lo32(lo)
 139         add,l           m0,t1,t1                ; t1 += m0
 140         add,l,*nuv      m1,t1,t1                ; t1 += m0
 141          add,l          %r5,hi,hi               ; propagate carry
 142         extrd,u         t1,31,32,t2             ; t2 = hi32(t1)
 143         depd,z          t1,31,32,t5             ; t5 = lo32(t1)
 144         add,l           t5,t4,t4                ; t4 += lo32(t1)
 145         add             cylimb,t4,t3
 146         add,dc          t2,hi,cylimb
 147         std             t3,0(rptr)
 148         ldo             8(rptr),rptr
 149
 150         ldd             -96(%r30),%r3
 151         ldd             -88(%r30),%r4
 152         ldd             -80(%r30),%r5
 153         ldd             -72(%r30),%r6
 154
 155         copy            cylimb,%r28
 156         bve             (%r2)
 157         .exit
 158         ldo             -128(%r30),%r30
 159         .procend