rts/gmp/mpn/power/mul_1.s

   1 # IBM POWER __gmpn_mul_1 -- Multiply a limb vector with a limb and store
   2 # the result in a second limb vector.
   3
   4 # Copyright (C) 1992, 1994, 1999, 2000 Free Software Foundation, Inc.
   5
   6 # This file is part of the GNU MP Library.
   7
   8 # The GNU MP Library is free software; you can redistribute it and/or modify
   9 # it under the terms of the GNU Lesser General Public License as published by
  10 # the Free Software Foundation; either version 2.1 of the License, or (at your
  11 # option) any later version.
  12
  13 # The GNU MP Library is distributed in the hope that it will be useful, but
  14 # WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
  15 # or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU Lesser General Public
  16 # License for more details.
  17
  18 # You should have received a copy of the GNU Lesser General Public License
  19 # along with the GNU MP Library; see the file COPYING.LIB.  If not, write to
  20 # the Free Software Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  21 # MA 02111-1307, USA.
  22
  23
  24 # INPUT PARAMETERS
  25 # res_ptr       r3
  26 # s1_ptr        r4
  27 # size          r5
  28 # s2_limb       r6
  29
  30 # The POWER architecture has no unsigned 32x32->64 bit multiplication
  31 # instruction.  To obtain that operation, we have to use the 32x32->64 signed
  32 # multiplication instruction, and add the appropriate compensation to the high
  33 # limb of the result.  We add the multiplicand if the multiplier has its most
  34 # significant bit set, and we add the multiplier if the multiplicand has its
  35 # most significant bit set.  We need to preserve the carry flag between each
  36 # iteration, so we have to compute the compensation carefully (the natural,
  37 # srai+and doesn't work).  Since the POWER architecture has a branch unit we
  38 # can branch in zero cycles, so that's how we perform the additions.
  39
  40         .toc
  41         .globl  __gmpn_mul_1
  42         .globl  .__gmpn_mul_1
  43         .csect  __gmpn_mul_1[DS]
  44 __gmpn_mul_1:
  45         .long   .__gmpn_mul_1, TOC[tc0], 0
  46         .csect  .text[PR]
  47         .align  2
  48 .__gmpn_mul_1:
  49
  50         cal     3,-4(3)
  51         l       0,0(4)
  52         cmpi    0,6,0
  53         mtctr   5
  54         mul     9,0,6
  55         srai    7,0,31
  56         and     7,7,6
  57         mfmq    8
  58         ai      0,0,0           # reset carry
  59         cax     9,9,7
  60         blt     Lneg
  61 Lpos:   bdz     Lend
  62 Lploop: lu      0,4(4)
  63         stu     8,4(3)
  64         cmpi    0,0,0
  65         mul     10,0,6
  66         mfmq    0
  67         ae      8,0,9
  68         bge     Lp0
  69         cax     10,10,6         # adjust high limb for negative limb from s1
  70 Lp0:    bdz     Lend0
  71         lu      0,4(4)
  72         stu     8,4(3)
  73         cmpi    0,0,0
  74         mul     9,0,6
  75         mfmq    0
  76         ae      8,0,10
  77         bge     Lp1
  78         cax     9,9,6           # adjust high limb for negative limb from s1
  79 Lp1:    bdn     Lploop
  80         b       Lend
  81
  82 Lneg:   cax     9,9,0
  83         bdz     Lend
  84 Lnloop: lu      0,4(4)
  85         stu     8,4(3)
  86         cmpi    0,0,0
  87         mul     10,0,6
  88         cax     10,10,0         # adjust high limb for negative s2_limb
  89         mfmq    0
  90         ae      8,0,9
  91         bge     Ln0
  92         cax     10,10,6         # adjust high limb for negative limb from s1
  93 Ln0:    bdz     Lend0
  94         lu      0,4(4)
  95         stu     8,4(3)
  96         cmpi    0,0,0
  97         mul     9,0,6
  98         cax     9,9,0           # adjust high limb for negative s2_limb
  99         mfmq    0
 100         ae      8,0,10
 101         bge     Ln1
 102         cax     9,9,6           # adjust high limb for negative limb from s1
 103 Ln1:    bdn     Lnloop
 104         b       Lend
 105
 106 Lend0:  cal     9,0(10)
 107 Lend:   st      8,4(3)
 108         aze     3,9
 109         br