rts/gmp/mpn/powerpc32/sub_n.asm

   1 dnl PowerPC-32 mpn_sub_n -- Subtract two limb vectors of the same length > 0
   2 dnl and store difference in a third limb vector.
   3
   4 dnl Copyright (C) 1995, 1997, 2000 Free Software Foundation, Inc.
   5
   6 dnl This file is part of the GNU MP Library.
   7
   8 dnl The GNU MP Library is free software; you can redistribute it and/or modify
   9 dnl it under the terms of the GNU Lesser General Public License as published by
  10 dnl the Free Software Foundation; either version 2.1 of the License, or (at your
  11 dnl option) any later version.
  12
  13 dnl The GNU MP Library is distributed in the hope that it will be useful, but
  14 dnl WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
  15 dnl or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU Lesser General Public
  16 dnl License for more details.
  17
  18 dnl You should have received a copy of the GNU Lesser General Public License
  19 dnl along with the GNU MP Library; see the file COPYING.LIB.  If not, write to
  20 dnl the Free Software Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  21 dnl MA 02111-1307, USA.
  22
  23
  24 dnl INPUT PARAMETERS
  25 dnl res_ptr     r3
  26 dnl s1_ptr      r4
  27 dnl s2_ptr      r5
  28 dnl size        r6
  29
  30 include(`../config.m4')
  31
  32 ASM_START()
  33 PROLOGUE(mpn_sub_n)
  34         mtctr   r6              C copy size into CTR
  35         addic   r0,r6,-1        C set cy
  36         lwz     r8,0(r4)        C load least significant s1 limb
  37         lwz     r0,0(r5)        C load least significant s2 limb
  38         addi    r3,r3,-4        C offset res_ptr, it's updated before it's used
  39         bdz     .Lend           C If done, skip loop
  40 .Loop:  lwz     r9,4(r4)        C load s1 limb
  41         lwz     r10,4(r5)       C load s2 limb
  42         subfe   r7,r0,r8        C subtract limbs with cy, set cy
  43         stw     r7,4(r3)        C store result limb
  44         bdz     .Lexit          C decrement CTR and exit if done
  45         lwzu    r8,8(r4)        C load s1 limb and update s1_ptr
  46         lwzu    r0,8(r5)        C load s2 limb and update s2_ptr
  47         subfe   r7,r10,r9       C subtract limbs with cy, set cy
  48         stwu    r7,8(r3)        C store result limb and update res_ptr
  49         bdnz    .Loop           C decrement CTR and loop back
  50
  51 .Lend:  subfe   r7,r0,r8
  52         stw     r7,4(r3)        C store ultimate result limb
  53         subfe   r3,r0,r0        C load !cy into ...
  54         subfic  r3,r3,0         C ... return value register
  55         blr
  56 .Lexit: subfe   r7,r10,r9
  57         stw     r7,8(r3)
  58         subfe   r3,r0,r0        C load !cy into ...
  59         subfic  r3,r3,0         C ... return value register
  60         blr
  61 EPILOGUE(mpn_sub_n)