Reorganisation of the source tree
[ghc-hetmet.git] / rts / gmp / mpn / sparc32 / v8 / submul_1.asm
1 dnl  SPARC v8 mpn_submul_1 -- Multiply a limb vector with a limb and
2 dnl  subtract the result from a second limb vector.
3
4 dnl  Copyright (C) 1992, 1993, 1994, 2000 Free Software Foundation, Inc.
5
6 dnl  This file is part of the GNU MP Library.
7
8 dnl  The GNU MP Library is free software; you can redistribute it and/or modify
9 dnl  it under the terms of the GNU Lesser General Public License as published
10 dnl  by the Free Software Foundation; either version 2.1 of the License, or (at
11 dnl  your option) any later version.
12
13 dnl  The GNU MP Library is distributed in the hope that it will be useful, but
14 dnl  WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
15 dnl  or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU Lesser General Public
16 dnl  License for more details.
17
18 dnl  You should have received a copy of the GNU Lesser General Public License
19 dnl  along with the GNU MP Library; see the file COPYING.LIB.  If not, write to
20 dnl  the Free Software Foundation, Inc., 59 Temple Place - Suite 330, Boston,
21 dnl  MA 02111-1307, USA.
22
23
24 include(`../config.m4')
25
26 C INPUT PARAMETERS
27 C res_ptr       o0
28 C s1_ptr        o1
29 C size          o2
30 C s2_limb       o3
31
32 ASM_START()
33 PROLOGUE(mpn_submul_1)
34         sub     %g0,%o2,%o2             C negate ...
35         sll     %o2,2,%o2               C ... and scale size
36         sub     %o1,%o2,%o1             C o1 is offset s1_ptr
37         sub     %o0,%o2,%g1             C g1 is offset res_ptr
38
39         mov     0,%o0                   C clear cy_limb
40
41 L(loop):
42         ld      [%o1+%o2],%o4
43         ld      [%g1+%o2],%g2
44         umul    %o4,%o3,%o5
45         rd      %y,%g3
46         addcc   %o5,%o0,%o5
47         addx    %g3,0,%o0
48         subcc   %g2,%o5,%g2
49         addx    %o0,0,%o0
50         st      %g2,[%g1+%o2]
51
52         addcc   %o2,4,%o2
53         bne     L(loop)
54          nop
55
56         retl
57          nop
58 EPILOGUE(mpn_submul_1)