sync-all

   1 #!/usr/bin/perl -w
   2
   3 use strict;
   4 use Cwd;
   5
   6 # Usage:
   7 #
   8 # ./sync-all [-q] [-s] [--ignore-failure] [-r repo]
   9 #            [--nofib] [--testsuite] [--checked-out] cmd [git flags]
  10 #
  11 # Applies the command "cmd" to each repository in the tree.
  12 # sync-all will try to do the right thing for both git and darcs repositories.
  13 #
  14 # e.g.
  15 #      ./sync-all -r http://darcs.haskell.org/ghc get
  16 #          To get any repos which do not exist in the local tree
  17 #
  18 #      ./sync-all pull
  19 #          To pull everything from the default repos
  20 #
  21 # -------------- Flags -------------------
  22 #   -q says to be quite, and -s to be silent.
  23 #
  24 #   --ignore-failure says to ignore errors and move on to the next repository
  25 #
  26 #   -r repo says to use repo as the location of package repositories
  27 #
  28 #   --checked-out says that the remote repo is in checked-out layout, as
  29 #   opposed to the layout used for the main repo.  By default a repo on
  30 #   the local filesystem is assumed to be checked-out, and repos accessed
  31 #   via HTTP or SSH are assumed to be in the main repo layout; use
  32 #   --checked-out to override the latter.
  33 #
  34 #   --nofib, --testsuite also get the nofib and testsuite repos respectively
  35 #
  36 # ------------ Which repos to use -------------
  37 # sync-all uses the following algorithm to decide which remote repos to use
  38 #
  39 #  It always computes the remote repos from a single base, $repo_base
  40 #  How is $repo_base set?
  41 #    If you say "-r repo", then that's $repo_base
  42 #    otherwise $repo_base is set by asking git where the ghc repo came
  43 #    from, and removing the last component (e.g. /ghc.git/ of /ghc/).
  44 #
  45 #  Then sync-all iterates over the package found in the file
  46 #  ./packages; see that file for a description of the contents.
  47 #
  48 #    If $repo_base looks like a local filesystem path, or if you give
  49 #    the --checked-out flag, sync-all works on repos of form
  50 #          $repo_base/<local-path>
  51 #    otherwise sync-all works on repos of form
  52 #          $repo_base/<remote-path>
  53 #    This logic lets you say
  54 #      both    sync-all -r http://darcs.haskell.org/ghc-6.12 pull
  55 #      and     sync-all -r ../HEAD pull
  56 #    The latter is called a "checked-out tree".
  57
  58 # NB: sync-all *ignores* the defaultrepo of all repos other than the
  59 # root one.  So the remote repos must be laid out in one of the two
  60 # formats given by <local-path> and <remote-path> in the file 'packages'.
  61
  62 $| = 1; # autoflush stdout after each print, to avoid output after die
  63
  64 my $defaultrepo;
  65 my @packages;
  66 my $verbose = 2;
  67 my $ignore_failure = 0;
  68 my $want_remote_repo = 0;
  69 my $checked_out_flag = 0;
  70 my $get_mode;
  71
  72 # Flags specific to a particular command
  73 my $local_repo_unnecessary = 0;
  74
  75 my %tags;
  76
  77 # Figure out where to get the other repositories from.
  78 sub getrepo {
  79     my $basedir = ".";
  80     my $repo;
  81
  82     if (defined($defaultrepo)) {
  83         $repo = $defaultrepo;
  84         chomp $repo;
  85     } else {
  86         # Figure out where to get the other repositories from,
  87         # based on where this GHC repo came from.
  88         my $branch = `git branch | grep "\* " | sed "s/^\* //"`; chomp $branch;
  89         my $remote = `git config branch.$branch.remote`;         chomp $remote;
  90         $repo = `git config remote.$remote.url`;       chomp $repo;
  91     }
  92
  93     my $repo_base;
  94     my $checked_out_tree;
  95
  96     if ($repo =~ /^...*:/) {
  97         # HTTP or SSH
  98         # Above regex says "at least two chars before the :", to avoid
  99         # catching Win32 drives ("C:\").
 100         $repo_base = $repo;
 101
 102         # --checked-out is needed if you want to use a checked-out repo
 103         # over SSH or HTTP
 104         if ($checked_out_flag) {
 105             $checked_out_tree = 1;
 106         } else {
 107             $checked_out_tree = 0;
 108         }
 109
 110         # Don't drop the last part of the path if specified with -r, as
 111         # it expects repos of the form:
 112         #
 113         #   http://darcs.haskell.org
 114         #
 115         # rather than
 116         #
 117         #   http://darcs.haskell.org/ghc
 118         #
 119         if (!$defaultrepo) {
 120             $repo_base =~ s#/[^/]+/?$##;
 121         }
 122     }
 123     elsif ($repo =~ /^\/|\.\.\/|.:(\/|\\)/) {
 124         # Local filesystem, either absolute or relative path
 125         # (assumes a checked-out tree):
 126         $repo_base = $repo;
 127         $checked_out_tree = 1;
 128     }
 129     else {
 130         die "Couldn't work out repo";
 131     }
 132
 133     return $repo_base, $checked_out_tree;
 134 }
 135
 136 sub parsePackages {
 137     my @repos;
 138     my $lineNum;
 139
 140     open IN, "< packages" or die "Can't open packages file";
 141     @repos = <IN>;
 142     close IN;
 143
 144     @packages = ();
 145     $lineNum = 0;
 146     foreach (@repos) {
 147         chomp;
 148         $lineNum++;
 149         if (/^([^# ]+) +([^ ]+) +([^ ]+) +([^ ]+) +([^ ]+)$/) {
 150             my %line;
 151             $line{"localpath"}  = $1;
 152             $line{"tag"}        = $2;
 153             $line{"remotepath"} = $3;
 154             $line{"vcs"}        = $4;
 155             $line{"upstream"}   = $5;
 156             push @packages, \%line;
 157         }
 158         elsif (! /^(#.*)?$/) {
 159             die "Bad content on line $lineNum of packages file: $_";
 160         }
 161     }
 162 }
 163
 164 sub message {
 165     if ($verbose >= 2) {
 166         print "@_\n";
 167     }
 168 }
 169
 170 sub warning {
 171     if ($verbose >= 1) {
 172         print "warning: @_\n";
 173     }
 174 }
 175
 176 sub scm {
 177     my $dir = shift;
 178     my $scm = shift;
 179     my $pwd;
 180
 181     if ($dir eq '.') {
 182         message "== running $scm @_";
 183     } else {
 184         message "== $dir: running $scm @_";
 185         $pwd = getcwd();
 186         chdir($dir);
 187     }
 188
 189     system ($scm, @_) == 0
 190         or $ignore_failure
 191         or die "$scm failed: $?";
 192
 193     if ($dir ne '.') {
 194         chdir($pwd);
 195     }
 196 }
 197
 198 sub repoexists {
 199     my ($scm, $localpath) = @_;
 200
 201     if ($scm eq "darcs") {
 202         -d "$localpath/_darcs";
 203     }
 204     else {
 205         -d "$localpath/.git";
 206     }
 207 }
 208
 209 sub scmall {
 210     my $command = shift;
 211
 212     my $localpath;
 213     my $tag;
 214     my $remotepath;
 215     my $scm;
 216     my $upstream;
 217     my $line;
 218     my $branch_name;
 219     my $subcommand;
 220
 221     my $path;
 222     my $wd_before = getcwd;
 223
 224     my @scm_args;
 225
 226     my $pwd;
 227     my @args;
 228
 229     my ($repo_base, $checked_out_tree) = getrepo();
 230
 231     parsePackages;
 232
 233     @args = ();
 234
 235     if ($command =~ /^remote$/) {
 236         while (@_ > 0 && $_[0] =~ /^-/) {
 237             push(@args,shift);
 238         }
 239         if (@_ < 1) { help(); }
 240         $subcommand = shift;
 241         if ($subcommand ne 'add' && $subcommand ne 'rm' && $subcommand ne 'set-url') {
 242             help();
 243         }
 244         while (@_ > 0 && $_[0] =~ /^-/) {
 245             push(@args,shift);
 246         }
 247         if (($subcommand eq 'add' || $subcommand eq 'rm') && @_ < 1) {
 248             help();
 249         } elsif (@_ < 1) { # set-url
 250             $branch_name = 'origin';
 251         } else {
 252             $branch_name = shift;
 253         }
 254     } elsif ($command eq 'new' || $command eq 'fetch') {
 255         if (@_ < 1) {
 256             $branch_name = 'origin';
 257         } else {
 258             $branch_name = shift;
 259         }
 260     }
 261
 262     push(@args, @_);
 263     print "args: @args\n";
 264
 265     for $line (@packages) {
 266
 267             $localpath  = $$line{"localpath"};
 268             $tag        = $$line{"tag"};
 269             $remotepath = $$line{"remotepath"};
 270             $scm        = $$line{"vcs"};
 271             $upstream   = $$line{"upstream"};
 272
 273             # Check the SCM is OK as early as possible
 274             die "Unknown SCM: $scm" if (($scm ne "darcs") and ($scm ne "git"));
 275
 276             # Work out the path for this package in the repo we pulled from
 277             if ($checked_out_tree) {
 278                 $path = "$repo_base/$localpath";
 279             }
 280             else {
 281                 $path = "$repo_base/$remotepath";
 282             }
 283
 284             # Work out the arguments we should give to the SCM
 285             if ($command =~ /^(?:w|wh|wha|what|whats|whatsn|whatsne|whatsnew)$/) {
 286                 @scm_args = (($scm eq "darcs" and "whatsnew")
 287                           or ($scm eq "git" and "status"));
 288
 289                 # Hack around 'darcs whatsnew' failing if there are no changes
 290                 $ignore_failure = 1;
 291             }
 292             elsif ($command =~ /^(?:pus|push)$/) {
 293                 @scm_args = "push";
 294                 $want_remote_repo = 1;
 295             }
 296             elsif ($command =~ /^(?:pul|pull)$/) {
 297                 @scm_args = "pull";
 298                 $want_remote_repo = 1;
 299                 # Q: should we append the -a argument for darcs repos?
 300             }
 301             elsif ($command =~ /^(?:g|ge|get)$/) {
 302                 # Skip any repositories we have not included the tag for
 303                 if (not defined($tags{$tag})) {
 304                     next;
 305                 }
 306
 307                 if (-d $localpath) {
 308                     warning("$localpath already present; omitting") if $localpath ne ".";
 309                     next;
 310                 }
 311
 312                 # The first time round the loop, default the get-mode
 313                 if ($scm eq "darcs" && not defined($get_mode)) {
 314                     warning("adding --partial, to override use --complete");
 315                     $get_mode = "--partial";
 316                 }
 317
 318                 # The only command that doesn't need a repo
 319                 $local_repo_unnecessary = 1;
 320
 321                 if ($scm eq "darcs") {
 322                     # Note: we can only use the get-mode with darcs for now
 323                     @scm_args = ("get", $get_mode, $path, $localpath);
 324                 }
 325                 else {
 326                     @scm_args = ("clone", $path, $localpath);
 327                 }
 328             }
 329             elsif ($command =~ /^(?:s|se|sen|send)$/) {
 330                 @scm_args = (($scm eq "darcs" and "send")
 331                           or ($scm eq "git" and "send-email"));
 332                 $want_remote_repo = 1;
 333             }
 334             elsif ($command =~ /^fetch$/) {
 335                 @scm_args = ("fetch", "$branch_name");
 336             }
 337             elsif ($command =~ /^new$/) {
 338                 @scm_args = ("log", "$branch_name..");
 339             }
 340             elsif ($command =~ /^remote$/) {
 341                 if ($subcommand eq 'add') {
 342                     @scm_args = ("remote", "add", $branch_name, $path);
 343                 } elsif ($subcommand eq 'rm') {
 344                     @scm_args = ("remote", "rm", $branch_name);
 345                 } elsif ($subcommand eq 'set-url') {
 346                     @scm_args = ("remote", "set-url", $branch_name, $path);
 347                 }
 348             }
 349             else {
 350                 die "Unknown command: $command";
 351             }
 352
 353             # Actually execute the command
 354             if (repoexists ($scm, $localpath)) {
 355                 if ($want_remote_repo) {
 356                     if ($scm eq "darcs") {
 357                         scm (".", $scm, @scm_args, @args, "--repodir=$localpath", $path);
 358                     } else {
 359                         # git pull doesn't like to be used with --work-dir
 360                         # I couldn't find an alternative to chdir() here
 361                         scm ($localpath, $scm, @scm_args, @args, $path, "master");
 362                     }
 363                 } else {
 364                     # git status *must* be used with --work-dir, if we don't chdir() to the dir
 365                     scm ($localpath, $scm, @scm_args, @args);
 366                 }
 367             }
 368             elsif ($local_repo_unnecessary) {
 369                 # Don't bother to change directory in this case
 370                 scm (".", $scm, @scm_args, @args);
 371             }
 372             elsif ($tag eq "") {
 373                 message "== Required repo $localpath is missing! Skipping";
 374             }
 375             else {
 376                 message "== $localpath repo not present; skipping";
 377             }
 378     }
 379 }
 380
 381
 382 sub help()
 383 {
 384         # Get the built in help
 385         my $help = <<END;
 386 What do you want to do?
 387 Supported commands:
 388
 389  * whatsnew
 390  * push
 391  * pull
 392  * get, with options:
 393   * --<package-tag>
 394   * --complete
 395   * --partial
 396  * fetch
 397  * send
 398  * new
 399  * remote add <branch-name>
 400  * remote rm <branch-name>
 401  * remote set-url [--push] <branch-name>
 402
 403 Available package-tags are:
 404 END
 405
 406         # Collect all the tags in the packages file
 407         my %available_tags;
 408         open IN, "< packages" or die "Can't open packages file";
 409         while (<IN>) {
 410             chomp;
 411             if (/^([^# ]+) +(?:([^ ]+) +)?([^ ]+) +([^ ]+)/) {
 412                 if (defined($2) && $2 ne "-") {
 413                     $available_tags{$2} = 1;
 414                 }
 415             }
 416             elsif (! /^(#.*)?$/) {
 417                 die "Bad line: $_";
 418             }
 419         }
 420         close IN;
 421
 422         # Show those tags and the help text
 423         my @available_tags = keys %available_tags;
 424         print "$help@available_tags\n";
 425         exit 1;
 426 }
 427
 428 sub main {
 429     if (! -d ".git" || ! -d "compiler") {
 430         die "error: sync-all must be run from the top level of the ghc tree."
 431     }
 432
 433     $tags{"-"} = 1;
 434     $tags{"dph"} = 1;
 435
 436     while ($#_ ne -1) {
 437         my $arg = shift;
 438         # We handle -q here as well as lower down as we need to skip over it
 439         # if it comes before the source-control command
 440         if ($arg eq "-q") {
 441             $verbose = 1;
 442         }
 443         elsif ($arg eq "-s") {
 444             $verbose = 0;
 445         }
 446         elsif ($arg eq "-r") {
 447             $defaultrepo = shift;
 448         }
 449         elsif ($arg eq "--ignore-failure") {
 450             $ignore_failure = 1;
 451         }
 452         elsif ($arg eq "--complete" || $arg eq "--partial") {
 453             $get_mode = $arg;
 454         }
 455         # Use --checked-out if the remote repos are a checked-out tree,
 456         # rather than the master trees.
 457         elsif ($arg eq "--checked-out") {
 458             $checked_out_flag = 1;
 459         }
 460         # --<tag> says we grab the libs tagged 'tag' with
 461         # 'get'. It has no effect on the other commands.
 462         elsif ($arg =~ m/^--/) {
 463             $arg =~ s/^--//;
 464             $tags{$arg} = 1;
 465         }
 466         else {
 467             unshift @_, $arg;
 468             if (grep /^-q$/, @_) {
 469                 $verbose = 1;
 470             }
 471             last;
 472         }
 473     }
 474
 475     if ($#_ eq -1) {
 476         help();
 477     }
 478     else {
 479         # Give the command and rest of the arguments to the main loop
 480         scmall @_;
 481     }
 482 }
 483
 484 main(@ARGV);
 485