sync-all

   1 #!/usr/bin/perl -w
   2
   3 use strict;
   4 use Cwd;
   5
   6 # Usage:
   7 #
   8 # ./sync-all [-q] [-s] [--ignore-failure] [-r repo]
   9 #            [--nofib] [--testsuite] [--checked-out] cmd [git flags]
  10 #
  11 # Applies the command "cmd" to each repository in the tree.
  12 # sync-all will try to do the right thing for both git and darcs repositories.
  13 #
  14 # e.g.
  15 #      ./sync-all -r http://darcs.haskell.org/ghc get
  16 #          To get any repos which do not exist in the local tree
  17 #
  18 #      ./sync-all pull
  19 #          To pull everything from the default repos
  20 #
  21 # -------------- Flags -------------------
  22 #   -q says to be quite, and -s to be silent.
  23 #
  24 #   --ignore-failure says to ignore errors and move on to the next repository
  25 #
  26 #   -r repo says to use repo as the location of package repositories
  27 #
  28 #   --checked-out says that the remote repo is in checked-out layout, as
  29 #   opposed to the layout used for the main repo.  By default a repo on
  30 #   the local filesystem is assumed to be checked-out, and repos accessed
  31 #   via HTTP or SSH are assumed to be in the main repo layout; use
  32 #   --checked-out to override the latter.
  33 #
  34 #   --nofib, --testsuite also get the nofib and testsuite repos respectively
  35 #
  36 # ------------ Which repos to use -------------
  37 # sync-all uses the following algorithm to decide which remote repos to use
  38 #
  39 #  It always computes the remote repos from a single base, $repo_base
  40 #  How is $repo_base set?
  41 #    If you say "-r repo", then that's $repo_base
  42 #    otherwise $repo_base is set by asking git where the ghc repo came
  43 #    from, and removing the last component (e.g. /ghc.git/ of /ghc/).
  44 #
  45 #  Then sync-all iterates over the package found in the file
  46 #  ./packages; see that file for a description of the contents.
  47 #
  48 #    If $repo_base looks like a local filesystem path, or if you give
  49 #    the --checked-out flag, sync-all works on repos of form
  50 #          $repo_base/<local-path>
  51 #    otherwise sync-all works on repos of form
  52 #          $repo_base/<remote-path>
  53 #    This logic lets you say
  54 #      both    sync-all -r http://darcs.haskell.org/ghc-6.12 pull
  55 #      and     sync-all -r ../HEAD pull
  56 #    The latter is called a "checked-out tree".
  57
  58 # NB: sync-all *ignores* the defaultrepo of all repos other than the
  59 # root one.  So the remote repos must be laid out in one of the two
  60 # formats given by <local-path> and <remote-path> in the file 'packages'.
  61
  62 $| = 1; # autoflush stdout after each print, to avoid output after die
  63
  64 my $defaultrepo;
  65 my @packages;
  66 my $verbose = 2;
  67 my $ignore_failure = 0;
  68 my $want_remote_repo = 0;
  69 my $checked_out_flag = 0;
  70 my $get_mode;
  71
  72 # Flags specific to a particular command
  73 my $local_repo_unnecessary = 0;
  74
  75 my %tags;
  76
  77 # Figure out where to get the other repositories from.
  78 sub getrepo {
  79     my $basedir = ".";
  80     my $repo;
  81
  82     if (defined($defaultrepo)) {
  83         $repo = $defaultrepo;
  84         chomp $repo;
  85     } else {
  86         # Figure out where to get the other repositories from,
  87         # based on where this GHC repo came from.
  88         my $branch = `git branch | grep "\* " | sed "s/^\* //"`; chomp $branch;
  89         my $remote = `git config branch.$branch.remote`;         chomp $remote;
  90         $repo = `git config remote.$remote.url`;       chomp $repo;
  91     }
  92
  93     my $repo_base;
  94     my $checked_out_tree;
  95
  96     if ($repo =~ /^...*:/) {
  97         # HTTP or SSH
  98         # Above regex says "at least two chars before the :", to avoid
  99         # catching Win32 drives ("C:\").
 100         $repo_base = $repo;
 101
 102         # --checked-out is needed if you want to use a checked-out repo
 103         # over SSH or HTTP
 104         if ($checked_out_flag) {
 105             $checked_out_tree = 1;
 106         } else {
 107             $checked_out_tree = 0;
 108         }
 109
 110         # Don't drop the last part of the path if specified with -r, as
 111         # it expects repos of the form:
 112         #
 113         #   http://darcs.haskell.org
 114         #
 115         # rather than
 116         #
 117         #   http://darcs.haskell.org/ghc
 118         #
 119         if (!$defaultrepo) {
 120             $repo_base =~ s#/[^/]+/?$##;
 121         }
 122     }
 123     elsif ($repo =~ /^\/|\.\.\/|.:(\/|\\)/) {
 124         # Local filesystem, either absolute or relative path
 125         # (assumes a checked-out tree):
 126         $repo_base = $repo;
 127         $checked_out_tree = 1;
 128     }
 129     else {
 130         die "Couldn't work out repo";
 131     }
 132
 133     return $repo_base, $checked_out_tree;
 134 }
 135
 136 sub parsePackages {
 137     my @repos;
 138     my $lineNum;
 139
 140     open IN, "< packages" or die "Can't open packages file";
 141     @repos = <IN>;
 142     close IN;
 143
 144     @packages = ();
 145     $lineNum = 0;
 146     foreach (@repos) {
 147         chomp;
 148         $lineNum++;
 149         if (/^([^# ]+) +([^ ]+) +([^ ]+) +([^ ]+) +([^ ]+)$/) {
 150             my %line;
 151             $line{"localpath"}  = $1;
 152             $line{"tag"}        = $2;
 153             $line{"remotepath"} = $3;
 154             $line{"vcs"}        = $4;
 155             $line{"upstream"}   = $5;
 156             push @packages, \%line;
 157         }
 158         elsif (! /^(#.*)?$/) {
 159             die "Bad content on line $lineNum of packages file: $_";
 160         }
 161     }
 162 }
 163
 164 sub message {
 165     if ($verbose >= 2) {
 166         print "@_\n";
 167     }
 168 }
 169
 170 sub warning {
 171     if ($verbose >= 1) {
 172         print "warning: @_\n";
 173     }
 174 }
 175
 176 sub scm {
 177     my $dir = shift;
 178     my $scm = shift;
 179     my $pwd;
 180
 181     if ($dir eq '.') {
 182         message "== running $scm @_";
 183     } else {
 184         message "== $dir: running $scm @_";
 185         $pwd = getcwd();
 186         chdir($dir);
 187     }
 188
 189     system ($scm, @_) == 0
 190         or $ignore_failure
 191         or die "$scm failed: $?";
 192
 193     if ($dir ne '.') {
 194         chdir($pwd);
 195     }
 196 }
 197
 198 sub repoexists {
 199     my ($scm, $localpath) = @_;
 200
 201     if ($scm eq "darcs") {
 202         -d "$localpath/_darcs";
 203     }
 204     else {
 205         -d "$localpath/.git";
 206     }
 207 }
 208
 209 sub scmall {
 210     my $command = shift;
 211
 212     my $localpath;
 213     my $tag;
 214     my $remotepath;
 215     my $scm;
 216     my $upstream;
 217     my $line;
 218     my $branch_name;
 219     my $subcommand;
 220
 221     my $path;
 222     my $wd_before = getcwd;
 223
 224     my @scm_args;
 225
 226     my $pwd;
 227     my @args;
 228
 229     my ($repo_base, $checked_out_tree) = getrepo();
 230
 231     my $is_github_repo = $repo_base =~ m/(git@|git:\/\/|https:\/\/)github.com/;
 232
 233     parsePackages;
 234
 235     @args = ();
 236
 237     if ($command =~ /^remote$/) {
 238         while (@_ > 0 && $_[0] =~ /^-/) {
 239             push(@args,shift);
 240         }
 241         if (@_ < 1) { help(); }
 242         $subcommand = shift;
 243         if ($subcommand ne 'add' && $subcommand ne 'rm' && $subcommand ne 'set-url') {
 244             help();
 245         }
 246         while (@_ > 0 && $_[0] =~ /^-/) {
 247             push(@args,shift);
 248         }
 249         if (($subcommand eq 'add' || $subcommand eq 'rm') && @_ < 1) {
 250             help();
 251         } elsif (@_ < 1) { # set-url
 252             $branch_name = 'origin';
 253         } else {
 254             $branch_name = shift;
 255         }
 256     } elsif ($command eq 'new' || $command eq 'fetch') {
 257         if (@_ < 1) {
 258             $branch_name = 'origin';
 259         } else {
 260             $branch_name = shift;
 261         }
 262     }
 263
 264     push(@args, @_);
 265
 266     for $line (@packages) {
 267
 268             $localpath  = $$line{"localpath"};
 269             $tag        = $$line{"tag"};
 270             $remotepath = $$line{"remotepath"};
 271             $scm        = $$line{"vcs"};
 272             $upstream   = $$line{"upstream"};
 273
 274             # We can't create directories on GitHub, so we translate
 275             # "package/foo" into "package-foo".
 276             if ($is_github_repo) {
 277                 $remotepath =~ s/\//-/;
 278             }
 279
 280             # Check the SCM is OK as early as possible
 281             die "Unknown SCM: $scm" if (($scm ne "darcs") and ($scm ne "git"));
 282
 283             # Work out the path for this package in the repo we pulled from
 284             if ($checked_out_tree) {
 285                 $path = "$repo_base/$localpath";
 286             }
 287             else {
 288                 $path = "$repo_base/$remotepath";
 289             }
 290
 291             # Work out the arguments we should give to the SCM
 292             if ($command =~ /^(?:w|wh|wha|what|whats|whatsn|whatsne|whatsnew|status)$/) {
 293                 @scm_args = (($scm eq "darcs" and "whatsnew")
 294                           or ($scm eq "git" and "status"));
 295
 296                 # Hack around 'darcs whatsnew' failing if there are no changes
 297                 $ignore_failure = 1;
 298             }
 299             elsif ($command =~ /^commit$/) {
 300                 @scm_args = ("commit");
 301                 # git fails if there is nothing to commit, so ignore failures
 302                 $ignore_failure = 1;
 303             }
 304             elsif ($command =~ /^(?:pus|push)$/) {
 305                 @scm_args = "push";
 306                 $want_remote_repo = 1;
 307             }
 308             elsif ($command =~ /^(?:pul|pull)$/) {
 309                 @scm_args = "pull";
 310                 # Q: should we append the -a argument for darcs repos?
 311             }
 312             elsif ($command =~ /^(?:g|ge|get)$/) {
 313                 # Skip any repositories we have not included the tag for
 314                 if (not defined($tags{$tag})) {
 315                     next;
 316                 }
 317
 318                 if (-d $localpath) {
 319                     warning("$localpath already present; omitting") if $localpath ne ".";
 320                     next;
 321                 }
 322
 323                 # The first time round the loop, default the get-mode
 324                 if ($scm eq "darcs" && not defined($get_mode)) {
 325                     warning("adding --partial, to override use --complete");
 326                     $get_mode = "--partial";
 327                 }
 328
 329                 # The only command that doesn't need a repo
 330                 $local_repo_unnecessary = 1;
 331
 332                 if ($scm eq "darcs") {
 333                     # Note: we can only use the get-mode with darcs for now
 334                     @scm_args = ("get", $get_mode, $path, $localpath);
 335                 }
 336                 else {
 337                     @scm_args = ("clone", $path, $localpath);
 338                 }
 339             }
 340             elsif ($command =~ /^(?:s|se|sen|send)$/) {
 341                 @scm_args = (($scm eq "darcs" and "send")
 342                           or ($scm eq "git" and "send-email"));
 343                 $want_remote_repo = 1;
 344             }
 345             elsif ($command =~ /^fetch$/) {
 346                 @scm_args = ("fetch", "$branch_name");
 347             }
 348             elsif ($command =~ /^new$/) {
 349                 @scm_args = ("log", "$branch_name..");
 350             }
 351             elsif ($command =~ /^remote$/) {
 352                 if ($subcommand eq 'add') {
 353                     @scm_args = ("remote", "add", $branch_name, $path);
 354                 } elsif ($subcommand eq 'rm') {
 355                     @scm_args = ("remote", "rm", $branch_name);
 356                 } elsif ($subcommand eq 'set-url') {
 357                     @scm_args = ("remote", "set-url", $branch_name, $path);
 358                 }
 359             }
 360             elsif ($command =~ /^grep$/) {
 361               @scm_args = ("grep");
 362               # Hack around 'git grep' failing if there are no matches
 363               $ignore_failure = 1;
 364             }
 365             else {
 366                 die "Unknown command: $command";
 367             }
 368
 369             # Actually execute the command
 370             if (repoexists ($scm, $localpath)) {
 371                 if ($want_remote_repo) {
 372                     if ($scm eq "darcs") {
 373                         scm (".", $scm, @scm_args, @args, "--repodir=$localpath", $path);
 374                     } else {
 375                         # git pull doesn't like to be used with --work-dir
 376                         # I couldn't find an alternative to chdir() here
 377                         scm ($localpath, $scm, @scm_args, @args, $path, "master");
 378                     }
 379                 } else {
 380                     # git status *must* be used with --work-dir, if we don't chdir() to the dir
 381                     scm ($localpath, $scm, @scm_args, @args);
 382                 }
 383             }
 384             elsif ($local_repo_unnecessary) {
 385                 # Don't bother to change directory in this case
 386                 scm (".", $scm, @scm_args, @args);
 387             }
 388             elsif ($tag eq "") {
 389                 message "== Required repo $localpath is missing! Skipping";
 390             }
 391             else {
 392                 message "== $localpath repo not present; skipping";
 393             }
 394     }
 395 }
 396
 397
 398 sub help()
 399 {
 400         # Get the built in help
 401         my $help = <<END;
 402 What do you want to do?
 403 Supported commands:
 404
 405  * whatsnew
 406  * commit
 407  * push
 408  * pull
 409  * get, with options:
 410   * --<package-tag>
 411   * --complete
 412   * --partial
 413  * fetch
 414  * send
 415  * new
 416  * remote add <branch-name>
 417  * remote rm <branch-name>
 418  * remote set-url [--push] <branch-name>
 419  * grep
 420
 421 Available package-tags are:
 422 END
 423
 424         # Collect all the tags in the packages file
 425         my %available_tags;
 426         open IN, "< packages" or die "Can't open packages file";
 427         while (<IN>) {
 428             chomp;
 429             if (/^([^# ]+) +(?:([^ ]+) +)?([^ ]+) +([^ ]+)/) {
 430                 if (defined($2) && $2 ne "-") {
 431                     $available_tags{$2} = 1;
 432                 }
 433             }
 434             elsif (! /^(#.*)?$/) {
 435                 die "Bad line: $_";
 436             }
 437         }
 438         close IN;
 439
 440         # Show those tags and the help text
 441         my @available_tags = keys %available_tags;
 442         print "$help@available_tags\n";
 443         exit 1;
 444 }
 445
 446 sub main {
 447     if (! -d ".git" || ! -d "compiler") {
 448         die "error: sync-all must be run from the top level of the ghc tree."
 449     }
 450
 451     $tags{"-"} = 1;
 452     $tags{"dph"} = 1;
 453
 454     while ($#_ ne -1) {
 455         my $arg = shift;
 456         # We handle -q here as well as lower down as we need to skip over it
 457         # if it comes before the source-control command
 458         if ($arg eq "-q") {
 459             $verbose = 1;
 460         }
 461         elsif ($arg eq "-s") {
 462             $verbose = 0;
 463         }
 464         elsif ($arg eq "-r") {
 465             $defaultrepo = shift;
 466         }
 467         elsif ($arg eq "--ignore-failure") {
 468             $ignore_failure = 1;
 469         }
 470         elsif ($arg eq "--complete" || $arg eq "--partial") {
 471             $get_mode = $arg;
 472         }
 473         # Use --checked-out if the remote repos are a checked-out tree,
 474         # rather than the master trees.
 475         elsif ($arg eq "--checked-out") {
 476             $checked_out_flag = 1;
 477         }
 478         # --<tag> says we grab the libs tagged 'tag' with
 479         # 'get'. It has no effect on the other commands.
 480         elsif ($arg =~ m/^--/) {
 481             $arg =~ s/^--//;
 482             $tags{$arg} = 1;
 483         }
 484         else {
 485             unshift @_, $arg;
 486             if (grep /^-q$/, @_) {
 487                 $verbose = 1;
 488             }
 489             last;
 490         }
 491     }
 492
 493     if ($#_ eq -1) {
 494         help();
 495     }
 496     else {
 497         # Give the command and rest of the arguments to the main loop
 498         scmall @_;
 499     }
 500 }
 501
 502 main(@ARGV);
 503