utils/ghc-pkg/Main.hs

   1 {-# OPTIONS -fglasgow-exts -cpp #-}
   2 -----------------------------------------------------------------------------
   3 --
   4 -- (c) The University of Glasgow 2004.
   5 --
   6 -- Package management tool
   7 --
   8 -----------------------------------------------------------------------------
   9
  10 -- TODO:
  11 -- * validate modules
  12 -- * expanding of variables in new-style package conf
  13 -- * version manipulation (checking whether old version exists,
  14 --   hiding old version?)
  15
  16 module Main (main) where
  17
  18 import Version ( version, targetOS, targetARCH )
  19 import Distribution.InstalledPackageInfo
  20 import Distribution.Compat.ReadP
  21 import Distribution.ParseUtils
  22 import Distribution.Package
  23 import Distribution.Version
  24 import System.FilePath
  25
  26 #ifdef USING_COMPAT
  27 import Compat.Directory ( getAppUserDataDirectory, createDirectoryIfMissing )
  28 import Compat.RawSystem ( rawSystem )
  29 #else
  30 import System.Directory ( getAppUserDataDirectory, createDirectoryIfMissing )
  31 import System.Cmd       ( rawSystem )
  32 #endif
  33
  34 import Prelude
  35
  36 #include "../../includes/ghcconfig.h"
  37
  38 import System.Console.GetOpt
  39 import Text.PrettyPrint
  40 import qualified Control.Exception as Exception
  41 import Data.Maybe
  42
  43 import Data.Char ( isSpace, toLower )
  44 import Control.Monad
  45 import System.Directory ( doesDirectoryExist, getDirectoryContents,
  46                           doesFileExist, renameFile, removeFile )
  47 import System.Exit ( exitWith, ExitCode(..) )
  48 import System.Environment ( getArgs, getProgName, getEnv )
  49 import System.IO
  50 import System.IO.Error (try)
  51 import Data.List ( isPrefixOf, isSuffixOf, isInfixOf, intersperse, sortBy, nub,
  52                    unfoldr, break )
  53 import Control.Concurrent
  54
  55 #ifdef mingw32_HOST_OS
  56 import Foreign
  57 import Foreign.C.String
  58 import GHC.ConsoleHandler
  59 #else
  60 import System.Posix
  61 #endif
  62
  63 import IO ( isPermissionError, isDoesNotExistError )
  64
  65 #if defined(GLOB)
  66 import System.Process(runInteractiveCommand)
  67 import qualified System.Info(os)
  68 #endif
  69
  70 -- -----------------------------------------------------------------------------
  71 -- Entry point
  72
  73 main :: IO ()
  74 main = do
  75   args <- getArgs
  76
  77   case getOpt Permute (flags ++ deprecFlags) args of
  78         (cli,_,[]) | FlagHelp `elem` cli -> do
  79            prog <- getProgramName
  80            bye (usageInfo (usageHeader prog) flags)
  81         (cli,_,[]) | FlagVersion `elem` cli ->
  82            bye ourCopyright
  83         (cli,nonopts,[]) ->
  84            runit cli nonopts
  85         (_,_,errors) -> do
  86            prog <- getProgramName
  87            die (concat errors ++ usageInfo (usageHeader prog) flags)
  88
  89 -- -----------------------------------------------------------------------------
  90 -- Command-line syntax
  91
  92 data Flag
  93   = FlagUser
  94   | FlagGlobal
  95   | FlagHelp
  96   | FlagVersion
  97   | FlagConfig FilePath
  98   | FlagGlobalConfig FilePath
  99   | FlagForce
 100   | FlagForceFiles
 101   | FlagAutoGHCiLibs
 102   | FlagSimpleOutput
 103   | FlagNamesOnly
 104   | FlagIgnoreCase
 105   deriving Eq
 106
 107 flags :: [OptDescr Flag]
 108 flags = [
 109   Option [] ["user"] (NoArg FlagUser)
 110         "use the current user's package database",
 111   Option [] ["global"] (NoArg FlagGlobal)
 112         "use the global package database",
 113   Option ['f'] ["package-conf"] (ReqArg FlagConfig "FILE")
 114         "use the specified package config file",
 115   Option [] ["global-conf"] (ReqArg FlagGlobalConfig "FILE")
 116         "location of the global package config",
 117   Option [] ["force"] (NoArg FlagForce)
 118          "ignore missing dependencies, directories, and libraries",
 119   Option [] ["force-files"] (NoArg FlagForceFiles)
 120          "ignore missing directories and libraries only",
 121   Option ['g'] ["auto-ghci-libs"] (NoArg FlagAutoGHCiLibs)
 122         "automatically build libs for GHCi (with register)",
 123   Option ['?'] ["help"] (NoArg FlagHelp)
 124         "display this help and exit",
 125   Option ['V'] ["version"] (NoArg FlagVersion)
 126         "output version information and exit",
 127   Option [] ["simple-output"] (NoArg FlagSimpleOutput)
 128         "print output in easy-to-parse format for some commands",
 129   Option [] ["names-only"] (NoArg FlagNamesOnly)
 130         "only print package names, not versions; can only be used with list --simple-output",
 131   Option [] ["ignore-case"] (NoArg FlagIgnoreCase)
 132         "ignore case for substring matching"
 133   ]
 134
 135 deprecFlags :: [OptDescr Flag]
 136 deprecFlags = [
 137         -- put deprecated flags here
 138   ]
 139
 140 ourCopyright :: String
 141 ourCopyright = "GHC package manager version " ++ Version.version ++ "\n"
 142
 143 usageHeader :: String -> String
 144 usageHeader prog = substProg prog $
 145   "Usage:\n" ++
 146   "  $p register {filename | -}\n" ++
 147   "    Register the package using the specified installed package\n" ++
 148   "    description. The syntax for the latter is given in the $p\n" ++
 149   "    documentation.\n" ++
 150   "\n" ++
 151   "  $p update {filename | -}\n" ++
 152   "    Register the package, overwriting any other package with the\n" ++
 153   "    same name.\n" ++
 154   "\n" ++
 155   "  $p unregister {pkg-id}\n" ++
 156   "    Unregister the specified package.\n" ++
 157   "\n" ++
 158   "  $p expose {pkg-id}\n" ++
 159   "    Expose the specified package.\n" ++
 160   "\n" ++
 161   "  $p hide {pkg-id}\n" ++
 162   "    Hide the specified package.\n" ++
 163   "\n" ++
 164   "  $p list [pkg]\n" ++
 165   "    List registered packages in the global database, and also the\n" ++
 166   "    user database if --user is given. If a package name is given\n" ++
 167   "    All the registered versions will be listed in ascending order.\n" ++
 168   "    Accepts the --simple-output flag.\n" ++
 169   "\n" ++
 170   "  $p find-module {module}\n" ++
 171   "    List registered packages exposing module {module} in the global\n" ++
 172   "    database, and also the user database if --user is given. \n" ++
 173   "    All the registered versions will be listed in ascending order.\n" ++
 174   "    Accepts the --simple-output flag.\n" ++
 175   "\n" ++
 176   "  $p latest {pkg-id}\n" ++
 177   "    Prints the highest registered version of a package.\n" ++
 178   "\n" ++
 179   "  $p check\n" ++
 180   "    Check the consistency of package depenencies and list broken packages.\n" ++
 181   "    Accepts the --simple-output flag.\n" ++
 182   "\n" ++
 183   "  $p describe {pkg}\n" ++
 184   "    Give the registered description for the specified package. The\n" ++
 185   "    description is returned in precisely the syntax required by $p\n" ++
 186   "    register.\n" ++
 187   "\n" ++
 188   "  $p field {pkg} {field}\n" ++
 189   "    Extract the specified field of the package description for the\n" ++
 190   "    specified package. Accepts comma-separated multiple fields.\n" ++
 191   "\n" ++
 192   " Substring matching is supported for {module} in find-module and\n" ++
 193   " for {pkg} in list, describe, and field, where a '*' indicates\n" ++
 194   " open substring ends (prefix*, *suffix, *infix*).\n" ++
 195   "\n" ++
 196   "  When asked to modify a database (register, unregister, update,\n"++
 197   "  hide, expose, and also check), ghc-pkg modifies the global database by\n"++
 198   "  default.  Specifying --user causes it to act on the user database,\n"++
 199   "  or --package-conf can be used to act on another database\n"++
 200   "  entirely. When multiple of these options are given, the rightmost\n"++
 201   "  one is used as the database to act upon.\n"++
 202   "\n"++
 203   "  Commands that query the package database (list, latest, describe,\n"++
 204   "  field) operate on the list of databases specified by the flags\n"++
 205   "  --user, --global, and --package-conf.  If none of these flags are\n"++
 206   "  given, the default is --global --user.\n"++
 207   "\n" ++
 208   " The following optional flags are also accepted:\n"
 209
 210 substProg :: String -> String -> String
 211 substProg _ [] = []
 212 substProg prog ('$':'p':xs) = prog ++ substProg prog xs
 213 substProg prog (c:xs) = c : substProg prog xs
 214
 215 -- -----------------------------------------------------------------------------
 216 -- Do the business
 217
 218 data Force = ForceAll | ForceFiles | NoForce
 219
 220 data PackageArg = Id PackageIdentifier | Substring String (String->Bool)
 221
 222 runit :: [Flag] -> [String] -> IO ()
 223 runit cli nonopts = do
 224   installSignalHandlers -- catch ^C and clean up
 225   prog <- getProgramName
 226   let
 227         force
 228           | FlagForce `elem` cli        = ForceAll
 229           | FlagForceFiles `elem` cli   = ForceFiles
 230           | otherwise                   = NoForce
 231         auto_ghci_libs = FlagAutoGHCiLibs `elem` cli
 232         splitFields fields = unfoldr splitComma (',':fields)
 233           where splitComma "" = Nothing
 234                 splitComma fs = Just $ break (==',') (tail fs)
 235
 236         substringCheck :: String -> Maybe (String -> Bool)
 237         substringCheck ""    = Nothing
 238         substringCheck "*"   = Just (const True)
 239         substringCheck [_]   = Nothing
 240         substringCheck (h:t) =
 241           case (h, init t, last t) of
 242             ('*',s,'*') -> Just (isInfixOf (f s) . f)
 243             ('*',_, _ ) -> Just (isSuffixOf (f t) . f)
 244             ( _ ,s,'*') -> Just (isPrefixOf (f (h:s)) . f)
 245             _           -> Nothing
 246           where f | FlagIgnoreCase `elem` cli = map toLower
 247                   | otherwise                 = id
 248 #if defined(GLOB)
 249         glob x | System.Info.os=="mingw32" = do
 250           -- glob echoes its argument, after win32 filename globbing
 251           (_,o,_,_) <- runInteractiveCommand ("glob "++x)
 252           txt <- hGetContents o
 253           return (read txt)
 254         glob x | otherwise = return [x]
 255 #endif
 256   --
 257   -- first, parse the command
 258   case nonopts of
 259 #if defined(GLOB)
 260     -- dummy command to demonstrate usage and permit testing
 261     -- without messing things up; use glob to selectively enable
 262     -- windows filename globbing for file parameters
 263     -- register, update, FlagGlobalConfig, FlagConfig; others?
 264     ["glob", filename] -> do
 265         print filename
 266         glob filename >>= print
 267 #endif
 268     ["register", filename] ->
 269         registerPackage filename cli auto_ghci_libs False force
 270     ["update", filename] ->
 271         registerPackage filename cli auto_ghci_libs True force
 272     ["unregister", pkgid_str] -> do
 273         pkgid <- readGlobPkgId pkgid_str
 274         unregisterPackage pkgid cli
 275     ["expose", pkgid_str] -> do
 276         pkgid <- readGlobPkgId pkgid_str
 277         exposePackage pkgid cli
 278     ["hide",   pkgid_str] -> do
 279         pkgid <- readGlobPkgId pkgid_str
 280         hidePackage pkgid cli
 281     ["list"] -> do
 282         listPackages cli Nothing Nothing
 283     ["list", pkgid_str] ->
 284         case substringCheck pkgid_str of
 285           Nothing -> do pkgid <- readGlobPkgId pkgid_str
 286                         listPackages cli (Just (Id pkgid)) Nothing
 287           Just m -> listPackages cli (Just (Substring pkgid_str m)) Nothing
 288     ["find-module", moduleName] -> do
 289         let match = maybe (==moduleName) id (substringCheck moduleName)
 290         listPackages cli Nothing (Just match)
 291     ["latest", pkgid_str] -> do
 292         pkgid <- readGlobPkgId pkgid_str
 293         latestPackage cli pkgid
 294     ["describe", pkgid_str] ->
 295         case substringCheck pkgid_str of
 296           Nothing -> do pkgid <- readGlobPkgId pkgid_str
 297                         describePackage cli (Id pkgid)
 298           Just m -> describePackage cli (Substring pkgid_str m)
 299     ["field", pkgid_str, fields] ->
 300         case substringCheck pkgid_str of
 301           Nothing -> do pkgid <- readGlobPkgId pkgid_str
 302                         describeField cli (Id pkgid) (splitFields fields)
 303           Just m -> describeField cli (Substring pkgid_str m)
 304                                       (splitFields fields)
 305     ["check"] -> do
 306         checkConsistency cli
 307     [] -> do
 308         die ("missing command\n" ++
 309                 usageInfo (usageHeader prog) flags)
 310     (_cmd:_) -> do
 311         die ("command-line syntax error\n" ++
 312                 usageInfo (usageHeader prog) flags)
 313
 314 parseCheck :: ReadP a a -> String -> String -> IO a
 315 parseCheck parser str what =
 316   case [ x | (x,ys) <- readP_to_S parser str, all isSpace ys ] of
 317     [x] -> return x
 318     _ -> die ("cannot parse \'" ++ str ++ "\' as a " ++ what)
 319
 320 readGlobPkgId :: String -> IO PackageIdentifier
 321 readGlobPkgId str = parseCheck parseGlobPackageId str "package identifier"
 322
 323 parseGlobPackageId :: ReadP r PackageIdentifier
 324 parseGlobPackageId =
 325   parsePackageId
 326      +++
 327   (do n <- parsePackageName; string "-*"
 328       return (PackageIdentifier{ pkgName = n, pkgVersion = globVersion }))
 329
 330 -- globVersion means "all versions"
 331 globVersion :: Version
 332 globVersion = Version{ versionBranch=[], versionTags=["*"] }
 333
 334 -- -----------------------------------------------------------------------------
 335 -- Package databases
 336
 337 -- Some commands operate on a single database:
 338 --      register, unregister, expose, hide
 339 -- however these commands also check the union of the available databases
 340 -- in order to check consistency.  For example, register will check that
 341 -- dependencies exist before registering a package.
 342 --
 343 -- Some commands operate  on multiple databases, with overlapping semantics:
 344 --      list, describe, field
 345
 346 type PackageDBName  = FilePath
 347 type PackageDB      = [InstalledPackageInfo]
 348
 349 type PackageDBStack = [(PackageDBName,PackageDB)]
 350         -- A stack of package databases.  Convention: head is the topmost
 351         -- in the stack.  Earlier entries override later one.
 352
 353 getPkgDatabases :: Bool -> [Flag] -> IO PackageDBStack
 354 getPkgDatabases modify flags = do
 355   -- first we determine the location of the global package config.  On Windows,
 356   -- this is found relative to the ghc-pkg.exe binary, whereas on Unix the
 357   -- location is passed to the binary using the --global-config flag by the
 358   -- wrapper script.
 359   let err_msg = "missing --global-conf option, location of global package.conf unknown\n"
 360   global_conf <-
 361      case [ f | FlagGlobalConfig f <- flags ] of
 362         [] -> do mb_dir <- getExecDir "/bin/ghc-pkg.exe"
 363                  case mb_dir of
 364                         Nothing  -> die err_msg
 365                         Just dir -> return (dir </> "package.conf")
 366         fs -> return (last fs)
 367
 368   let global_conf_dir = global_conf ++ ".d"
 369   global_conf_dir_exists <- doesDirectoryExist global_conf_dir
 370   global_confs <-
 371     if global_conf_dir_exists
 372       then do files <- getDirectoryContents global_conf_dir
 373               return [ global_conf_dir ++ '/' : file
 374                      | file <- files
 375                      , isSuffixOf ".conf" file]
 376       else return []
 377
 378   -- get the location of the user package database, and create it if necessary
 379   appdir <- getAppUserDataDirectory "ghc"
 380
 381   let
 382         subdir = targetARCH ++ '-':targetOS ++ '-':Version.version
 383         archdir   = appdir </> subdir
 384         user_conf = archdir </> "package.conf"
 385   user_exists <- doesFileExist user_conf
 386
 387   -- If the user database doesn't exist, and this command isn't a
 388   -- "modify" command, then we won't attempt to create or use it.
 389   let sys_databases
 390         | modify || user_exists = user_conf : global_confs ++ [global_conf]
 391         | otherwise             = global_confs ++ [global_conf]
 392
 393   e_pkg_path <- try (System.Environment.getEnv "GHC_PACKAGE_PATH")
 394   let env_stack =
 395         case e_pkg_path of
 396                 Left  _ -> sys_databases
 397                 Right path
 398                   | last cs == ""  -> init cs ++ sys_databases
 399                   | otherwise      -> cs
 400                   where cs = splitSearchPath path
 401
 402         -- The "global" database is always the one at the bottom of the stack.
 403         -- This is the database we modify by default.
 404       virt_global_conf = last env_stack
 405
 406   let db_flags = [ f | Just f <- map is_db_flag flags ]
 407          where is_db_flag FlagUser       = Just user_conf
 408                is_db_flag FlagGlobal     = Just virt_global_conf
 409                is_db_flag (FlagConfig f) = Just f
 410                is_db_flag _              = Nothing
 411
 412   final_stack <-
 413      if not modify
 414         then    -- For a "read" command, we use all the databases
 415                 -- specified on the command line.  If there are no
 416                 -- command-line flags specifying databases, the default
 417                 -- is to use all the ones we know about.
 418              if null db_flags then return env_stack
 419                               else return (reverse (nub db_flags))
 420         else let
 421                 -- For a "modify" command, treat all the databases as
 422                 -- a stack, where we are modifying the top one, but it
 423                 -- can refer to packages in databases further down the
 424                 -- stack.
 425
 426                 -- -f flags on the command line add to the database
 427                 -- stack, unless any of them are present in the stack
 428                 -- already.
 429                 flag_stack = filter (`notElem` env_stack)
 430                                 [ f | FlagConfig f <- reverse flags ]
 431                                 ++ env_stack
 432
 433                 modifying f
 434                   | f `elem` flag_stack = return (dropWhile (/= f) flag_stack)
 435                   | otherwise           = die ("requesting modification of database:\n\t" ++ f ++ "\n\twhich is not in the database stack.")
 436              in
 437                 if null db_flags
 438                    then modifying virt_global_conf
 439                    else modifying (head db_flags)
 440
 441   db_stack <- mapM readParseDatabase final_stack
 442   return db_stack
 443
 444 readParseDatabase :: PackageDBName -> IO (PackageDBName,PackageDB)
 445 readParseDatabase filename = do
 446   str <- readFile filename `Exception.catch` \_ -> return emptyPackageConfig
 447   let packages = read str
 448   Exception.evaluate packages
 449     `Exception.catch` \e->
 450         die ("error while parsing " ++ filename ++ ": " ++ show e)
 451   return (filename,packages)
 452
 453 emptyPackageConfig :: String
 454 emptyPackageConfig = "[]"
 455
 456 -- -----------------------------------------------------------------------------
 457 -- Registering
 458
 459 registerPackage :: FilePath
 460                 -> [Flag]
 461                 -> Bool              -- auto_ghci_libs
 462                 -> Bool              -- update
 463                 -> Force
 464                 -> IO ()
 465 registerPackage input flags auto_ghci_libs update force = do
 466   db_stack <- getPkgDatabases True flags
 467   let
 468         db_to_operate_on = my_head "db" db_stack
 469         db_filename      = fst db_to_operate_on
 470   --
 471
 472   s <-
 473     case input of
 474       "-" -> do
 475         putStr "Reading package info from stdin ... "
 476         getContents
 477       f   -> do
 478         putStr ("Reading package info from " ++ show f ++ " ... ")
 479         readFile f
 480
 481   expanded <- expandEnvVars s force
 482
 483   pkg <- parsePackageInfo expanded
 484   putStrLn "done."
 485
 486   validatePackageConfig pkg db_stack auto_ghci_libs update force
 487   let new_details = filter not_this (snd db_to_operate_on) ++ [pkg]
 488       not_this p = package p /= package pkg
 489   savingOldConfig db_filename $
 490     writeNewConfig db_filename new_details
 491
 492 parsePackageInfo
 493         :: String
 494         -> IO InstalledPackageInfo
 495 parsePackageInfo str =
 496   case parseInstalledPackageInfo str of
 497     ParseOk _warns ok -> return ok
 498     ParseFailed err -> case locatedErrorMsg err of
 499                            (Nothing, s) -> die s
 500                            (Just l, s) -> die (show l ++ ": " ++ s)
 501
 502 -- -----------------------------------------------------------------------------
 503 -- Exposing, Hiding, Unregistering are all similar
 504
 505 exposePackage :: PackageIdentifier ->  [Flag] -> IO ()
 506 exposePackage = modifyPackage (\p -> [p{exposed=True}])
 507
 508 hidePackage :: PackageIdentifier ->  [Flag] -> IO ()
 509 hidePackage = modifyPackage (\p -> [p{exposed=False}])
 510
 511 unregisterPackage :: PackageIdentifier ->  [Flag] -> IO ()
 512 unregisterPackage = modifyPackage (\p -> [])
 513
 514 modifyPackage
 515   :: (InstalledPackageInfo -> [InstalledPackageInfo])
 516   -> PackageIdentifier
 517   -> [Flag]
 518   -> IO ()
 519 modifyPackage fn pkgid flags  = do
 520   db_stack <- getPkgDatabases True{-modify-} flags
 521   let ((db_name, pkgs) : _) = db_stack
 522   ps <- findPackages [(db_name,pkgs)] (Id pkgid)
 523   let pids = map package ps
 524   let new_config = concat (map modify pkgs)
 525       modify pkg
 526           | package pkg `elem` pids = fn pkg
 527           | otherwise               = [pkg]
 528   savingOldConfig db_name $
 529       writeNewConfig db_name new_config
 530
 531 -- -----------------------------------------------------------------------------
 532 -- Listing packages
 533
 534 listPackages ::  [Flag] -> Maybe PackageArg -> Maybe (String->Bool) -> IO ()
 535 listPackages flags mPackageName mModuleName = do
 536   let simple_output = FlagSimpleOutput `elem` flags
 537   db_stack <- getPkgDatabases False flags
 538   let db_stack_filtered -- if a package is given, filter out all other packages
 539         | Just this <- mPackageName =
 540             map (\(conf,pkgs) -> (conf, filter (this `matchesPkg`) pkgs))
 541                 db_stack
 542         | Just match <- mModuleName = -- packages which expose mModuleName
 543             map (\(conf,pkgs) -> (conf, filter (match `exposedInPkg`) pkgs))
 544                 db_stack
 545         | otherwise = db_stack
 546
 547       db_stack_sorted
 548           = [ (db, sort_pkgs pkgs) | (db,pkgs) <- db_stack_filtered ]
 549           where sort_pkgs = sortBy cmpPkgIds
 550                 cmpPkgIds pkg1 pkg2 =
 551                    case pkgName p1 `compare` pkgName p2 of
 552                         LT -> LT
 553                         GT -> GT
 554                         EQ -> pkgVersion p1 `compare` pkgVersion p2
 555                    where (p1,p2) = (package pkg1, package pkg2)
 556
 557       match `exposedInPkg` pkg = any match (exposedModules pkg)
 558
 559       pkg_map = map (\p -> (package p, p)) $ concatMap snd db_stack
 560       show_func = if simple_output then show_simple else mapM_ (show_normal pkg_map)
 561
 562   show_func (reverse db_stack_sorted)
 563
 564   where show_normal pkg_map (db_name,pkg_confs) =
 565           hPutStrLn stdout (render $
 566                 text db_name <> colon $$ nest 4 packages
 567                 )
 568            where packages = fsep (punctuate comma (map pp_pkg pkg_confs))
 569                  pp_pkg p
 570                    | isBrokenPackage p pkg_map = braces doc
 571                    | exposed p = doc
 572                    | otherwise = parens doc
 573                    where doc = text (showPackageId (package p))
 574
 575         show_simple db_stack = do
 576           let showPkg = if FlagNamesOnly `elem` flags then pkgName
 577                                                       else showPackageId
 578               pkgs = map showPkg $ sortBy compPkgIdVer $
 579                           map package (concatMap snd db_stack)
 580           when (not (null pkgs)) $
 581              hPutStrLn stdout $ concat $ intersperse " " pkgs
 582
 583 -- -----------------------------------------------------------------------------
 584 -- Prints the highest (hidden or exposed) version of a package
 585
 586 latestPackage ::  [Flag] -> PackageIdentifier -> IO ()
 587 latestPackage flags pkgid = do
 588   db_stack <- getPkgDatabases False flags
 589   ps <- findPackages db_stack (Id pkgid)
 590   show_pkg (sortBy compPkgIdVer (map package ps))
 591   where
 592     show_pkg [] = die "no matches"
 593     show_pkg pids = hPutStrLn stdout (showPackageId (last pids))
 594
 595 -- -----------------------------------------------------------------------------
 596 -- Describe
 597
 598 describePackage :: [Flag] -> PackageArg -> IO ()
 599 describePackage flags pkgarg = do
 600   db_stack <- getPkgDatabases False flags
 601   ps <- findPackages db_stack pkgarg
 602   mapM_ (putStrLn . showInstalledPackageInfo) ps
 603
 604 -- PackageId is can have globVersion for the version
 605 findPackages :: PackageDBStack -> PackageArg -> IO [InstalledPackageInfo]
 606 findPackages db_stack pkgarg
 607   = case [ p | p <- all_pkgs, pkgarg `matchesPkg` p ] of
 608         []  -> die ("cannot find package " ++ pkg_msg pkgarg)
 609         ps -> return ps
 610   where
 611         all_pkgs = concat (map snd db_stack)
 612         pkg_msg (Id pkgid)           = showPackageId pkgid
 613         pkg_msg (Substring pkgpat _) = "matching "++pkgpat
 614
 615 matches :: PackageIdentifier -> PackageIdentifier -> Bool
 616 pid `matches` pid'
 617   = (pkgName pid == pkgName pid')
 618     && (pkgVersion pid == pkgVersion pid' || not (realVersion pid))
 619
 620 matchesPkg :: PackageArg -> InstalledPackageInfo -> Bool
 621 (Id pid)        `matchesPkg` pkg = pid `matches` package pkg
 622 (Substring _ m) `matchesPkg` pkg = m (pkgName (package pkg))
 623
 624 compPkgIdVer :: PackageIdentifier -> PackageIdentifier -> Ordering
 625 compPkgIdVer p1 p2 = pkgVersion p1 `compare` pkgVersion p2
 626
 627 -- -----------------------------------------------------------------------------
 628 -- Field
 629
 630 describeField :: [Flag] -> PackageArg -> [String] -> IO ()
 631 describeField flags pkgarg fields = do
 632   db_stack <- getPkgDatabases False flags
 633   fns <- toFields fields
 634   ps <- findPackages db_stack pkgarg
 635   let top_dir = takeDirectory (fst (last db_stack))
 636   mapM_ (selectFields fns) (mungePackagePaths top_dir ps)
 637   where toFields [] = return []
 638         toFields (f:fs) = case toField f of
 639             Nothing -> die ("unknown field: " ++ f)
 640             Just fn -> do fns <- toFields fs
 641                           return (fn:fns)
 642         selectFields fns info = mapM_ (\fn->putStrLn (fn info)) fns
 643
 644 mungePackagePaths :: String -> [InstalledPackageInfo] -> [InstalledPackageInfo]
 645 -- Replace the strings "$topdir" and "$httptopdir" at the beginning of a path
 646 -- with the current topdir (obtained from the -B option).
 647 mungePackagePaths top_dir ps = map munge_pkg ps
 648   where
 649   munge_pkg p = p{ importDirs        = munge_paths (importDirs p),
 650                    includeDirs       = munge_paths (includeDirs p),
 651                    libraryDirs       = munge_paths (libraryDirs p),
 652                    frameworkDirs     = munge_paths (frameworkDirs p),
 653                    haddockInterfaces = munge_paths (haddockInterfaces p),
 654                    haddockHTMLs      = munge_paths (haddockHTMLs p)
 655                  }
 656
 657   munge_paths = map munge_path
 658
 659   munge_path p
 660    | Just p' <- maybePrefixMatch "$topdir"     p =            top_dir ++ p'
 661    | Just p' <- maybePrefixMatch "$httptopdir" p = toHttpPath top_dir ++ p'
 662    | otherwise                               = p
 663
 664   toHttpPath p = "file:///" ++ p
 665
 666 maybePrefixMatch :: String -> String -> Maybe String
 667 maybePrefixMatch []    rest = Just rest
 668 maybePrefixMatch (_:_) []   = Nothing
 669 maybePrefixMatch (p:pat) (r:rest)
 670   | p == r    = maybePrefixMatch pat rest
 671   | otherwise = Nothing
 672
 673 toField :: String -> Maybe (InstalledPackageInfo -> String)
 674 -- backwards compatibility:
 675 toField "import_dirs"     = Just $ strList . importDirs
 676 toField "source_dirs"     = Just $ strList . importDirs
 677 toField "library_dirs"    = Just $ strList . libraryDirs
 678 toField "hs_libraries"    = Just $ strList . hsLibraries
 679 toField "extra_libraries" = Just $ strList . extraLibraries
 680 toField "include_dirs"    = Just $ strList . includeDirs
 681 toField "c_includes"      = Just $ strList . includes
 682 toField "package_deps"    = Just $ strList . map showPackageId. depends
 683 toField "extra_cc_opts"   = Just $ strList . ccOptions
 684 toField "extra_ld_opts"   = Just $ strList . ldOptions
 685 toField "framework_dirs"  = Just $ strList . frameworkDirs
 686 toField "extra_frameworks"= Just $ strList . frameworks
 687 toField s                 = showInstalledPackageInfoField s
 688
 689 strList :: [String] -> String
 690 strList = show
 691
 692
 693 -- -----------------------------------------------------------------------------
 694 -- Check: Check consistency of installed packages
 695
 696 checkConsistency :: [Flag] -> IO ()
 697 checkConsistency flags = do
 698   db_stack <- getPkgDatabases True flags
 699          -- check behaves like modify for the purposes of deciding which
 700          -- databases to use, because ordering is important.
 701   let pkgs = map (\p -> (package p, p)) $ concatMap snd db_stack
 702       broken_pkgs = do
 703         (pid, p) <- pkgs
 704         let broken_deps = missingPackageDeps p pkgs
 705         guard (not . null $ broken_deps)
 706         return (pid, broken_deps)
 707   mapM_ (putStrLn . render . show_func) broken_pkgs
 708   where
 709   show_func | FlagSimpleOutput `elem` flags = show_simple
 710             | otherwise = show_normal
 711   show_simple (pid,deps) =
 712     text (showPackageId pid) <> colon
 713       <+> fsep (punctuate comma (map (text . showPackageId) deps))
 714   show_normal (pid,deps) =
 715     text "package" <+> text (showPackageId pid) <+> text "has missing dependencies:"
 716       $$ nest 4 (fsep (punctuate comma (map (text . showPackageId) deps)))
 717
 718 missingPackageDeps :: InstalledPackageInfo
 719                    -> [(PackageIdentifier, InstalledPackageInfo)]
 720                    -> [PackageIdentifier]
 721 missingPackageDeps pkg pkg_map =
 722   [ d | d <- depends pkg, isNothing (lookup d pkg_map)] ++
 723   [ d | d <- depends pkg, Just p <- return (lookup d pkg_map), isBrokenPackage p pkg_map]
 724
 725 isBrokenPackage :: InstalledPackageInfo -> [(PackageIdentifier, InstalledPackageInfo)] -> Bool
 726 isBrokenPackage pkg pkg_map = not . null $ missingPackageDeps pkg pkg_map
 727
 728
 729 -- -----------------------------------------------------------------------------
 730 -- Manipulating package.conf files
 731
 732 writeNewConfig :: FilePath -> [InstalledPackageInfo] -> IO ()
 733 writeNewConfig filename packages = do
 734   hPutStr stdout "Writing new package config file... "
 735   createDirectoryIfMissing True $ takeDirectory filename
 736   h <- openFile filename WriteMode `catch` \e ->
 737       if isPermissionError e
 738       then die (filename ++ ": you don't have permission to modify this file")
 739       else ioError e
 740   let shown = concat $ intersperse ",\n " $ map show packages
 741       fileContents = "[" ++ shown ++ "\n]"
 742   hPutStrLn h fileContents
 743   hClose h
 744   hPutStrLn stdout "done."
 745
 746 savingOldConfig :: FilePath -> IO () -> IO ()
 747 savingOldConfig filename io = Exception.block $ do
 748   hPutStr stdout "Saving old package config file... "
 749     -- mv rather than cp because we've already done an hGetContents
 750     -- on this file so we won't be able to open it for writing
 751     -- unless we move the old one out of the way...
 752   let oldFile = filename ++ ".old"
 753   restore_on_error <- catch (renameFile filename oldFile >> return True) $
 754       \err -> do
 755           unless (isDoesNotExistError err) $ do
 756               hPutStrLn stderr (unwords ["Unable to rename", show filename,
 757                                          "to", show oldFile])
 758               ioError err
 759           return False
 760   (do hPutStrLn stdout "done."; io)
 761     `Exception.catch` \e -> do
 762       hPutStr stdout ("WARNING: an error was encountered while writing "
 763                    ++ "the new configuration.\n")
 764         -- remove any partially complete new version:
 765       try (removeFile filename)
 766         -- and attempt to restore the old one, if we had one:
 767       when restore_on_error $ do
 768            hPutStr stdout "Attempting to restore the old configuration... "
 769            do renameFile oldFile filename
 770               hPutStrLn stdout "done."
 771             `catch` \err -> hPutStrLn stdout ("Failed: " ++ show err)
 772         -- Note the above renameFile sometimes fails on Windows with
 773         -- "permission denied", I have no idea why --SDM.
 774       Exception.throwIO e
 775
 776 -----------------------------------------------------------------------------
 777 -- Sanity-check a new package config, and automatically build GHCi libs
 778 -- if requested.
 779
 780 validatePackageConfig :: InstalledPackageInfo
 781                       -> PackageDBStack
 782                       -> Bool   -- auto-ghc-libs
 783                       -> Bool   -- update
 784                       -> Force
 785                       -> IO ()
 786 validatePackageConfig pkg db_stack auto_ghci_libs update force = do
 787   checkPackageId pkg
 788   checkDuplicates db_stack pkg update force
 789   mapM_ (checkDep db_stack force) (depends pkg)
 790   mapM_ (checkDir force) (importDirs pkg)
 791   mapM_ (checkDir force) (libraryDirs pkg)
 792   mapM_ (checkDir force) (includeDirs pkg)
 793   mapM_ (checkHSLib (libraryDirs pkg) auto_ghci_libs force) (hsLibraries pkg)
 794   -- ToDo: check these somehow?
 795   --    extra_libraries :: [String],
 796   --    c_includes      :: [String],
 797
 798 -- When the package name and version are put together, sometimes we can
 799 -- end up with a package id that cannot be parsed.  This will lead to
 800 -- difficulties when the user wants to refer to the package later, so
 801 -- we check that the package id can be parsed properly here.
 802 checkPackageId :: InstalledPackageInfo -> IO ()
 803 checkPackageId ipi =
 804   let str = showPackageId (package ipi) in
 805   case [ x | (x,ys) <- readP_to_S parsePackageId str, all isSpace ys ] of
 806     [_] -> return ()
 807     []  -> die ("invalid package identifier: " ++ str)
 808     _   -> die ("ambiguous package identifier: " ++ str)
 809
 810 checkDuplicates :: PackageDBStack -> InstalledPackageInfo -> Bool -> Force -> IO ()
 811 checkDuplicates db_stack pkg update force = do
 812   let
 813         pkgid = package pkg
 814         (_top_db_name, pkgs) : _  = db_stack
 815   --
 816   -- Check whether this package id already exists in this DB
 817   --
 818   when (not update && (pkgid `elem` map package pkgs)) $
 819        die ("package " ++ showPackageId pkgid ++ " is already installed")
 820
 821   let
 822         uncasep = map toLower . showPackageId
 823         dups = filter ((== uncasep pkgid) . uncasep) (map package pkgs)
 824
 825   when (not update && not (null dups)) $ dieOrForceAll force $
 826         "Package names may be treated case-insensitively in the future.\n"++
 827         "Package " ++ showPackageId pkgid ++
 828         " overlaps with: " ++ unwords (map showPackageId dups)
 829
 830
 831 checkDir :: Force -> String -> IO ()
 832 checkDir force d
 833  | "$topdir"     `isPrefixOf` d = return ()
 834  | "$httptopdir" `isPrefixOf` d = return ()
 835         -- can't check these, because we don't know what $(http)topdir is
 836  | otherwise = do
 837    there <- doesDirectoryExist d
 838    when (not there)
 839        (dieOrForceFile force (d ++ " doesn't exist or isn't a directory"))
 840
 841 checkDep :: PackageDBStack -> Force -> PackageIdentifier -> IO ()
 842 checkDep db_stack force pkgid
 843   | pkgid `elem` pkgids || (not real_version && name_exists) = return ()
 844   | otherwise = dieOrForceAll force ("dependency " ++ showPackageId pkgid
 845                                         ++ " doesn't exist")
 846   where
 847         -- for backwards compat, we treat 0.0 as a special version,
 848         -- and don't check that it actually exists.
 849         real_version = realVersion pkgid
 850
 851         name_exists = any (\p -> pkgName (package p) == name) all_pkgs
 852         name = pkgName pkgid
 853
 854         all_pkgs = concat (map snd db_stack)
 855         pkgids = map package all_pkgs
 856
 857 realVersion :: PackageIdentifier -> Bool
 858 realVersion pkgid = versionBranch (pkgVersion pkgid) /= []
 859
 860 checkHSLib :: [String] -> Bool -> Force -> String -> IO ()
 861 checkHSLib dirs auto_ghci_libs force lib = do
 862   let batch_lib_file = "lib" ++ lib ++ ".a"
 863   bs <- mapM (doesLibExistIn batch_lib_file) dirs
 864   case [ dir | (exists,dir) <- zip bs dirs, exists ] of
 865         [] -> dieOrForceFile force ("cannot find " ++ batch_lib_file ++
 866                                     " on library path")
 867         (dir:_) -> checkGHCiLib dirs dir batch_lib_file lib auto_ghci_libs
 868
 869 doesLibExistIn :: String -> String -> IO Bool
 870 doesLibExistIn lib d
 871  | "$topdir"     `isPrefixOf` d = return True
 872  | "$httptopdir" `isPrefixOf` d = return True
 873  | otherwise                = doesFileExist (d ++ '/':lib)
 874
 875 checkGHCiLib :: [String] -> String -> String -> String -> Bool -> IO ()
 876 checkGHCiLib dirs batch_lib_dir batch_lib_file lib auto_build
 877   | auto_build = autoBuildGHCiLib batch_lib_dir batch_lib_file ghci_lib_file
 878   | otherwise  = do
 879       bs <- mapM (doesLibExistIn ghci_lib_file) dirs
 880       case [dir | (exists,dir) <- zip bs dirs, exists] of
 881         []    -> hPutStrLn stderr ("warning: can't find GHCi lib " ++ ghci_lib_file)
 882         (_:_) -> return ()
 883   where
 884     ghci_lib_file = lib ++ ".o"
 885
 886 -- automatically build the GHCi version of a batch lib,
 887 -- using ld --whole-archive.
 888
 889 autoBuildGHCiLib :: String -> String -> String -> IO ()
 890 autoBuildGHCiLib dir batch_file ghci_file = do
 891   let ghci_lib_file  = dir ++ '/':ghci_file
 892       batch_lib_file = dir ++ '/':batch_file
 893   hPutStr stderr ("building GHCi library " ++ ghci_lib_file ++ "...")
 894 #if defined(darwin_HOST_OS)
 895   r <- rawSystem "ld" ["-r","-x","-o",ghci_lib_file,"-all_load",batch_lib_file]
 896 #elif defined(mingw32_HOST_OS)
 897   execDir <- getExecDir "/bin/ghc-pkg.exe"
 898   r <- rawSystem (maybe "" (++"/gcc-lib/") execDir++"ld") ["-r","-x","-o",ghci_lib_file,"--whole-archive",batch_lib_file]
 899 #else
 900   r <- rawSystem "ld" ["-r","-x","-o",ghci_lib_file,"--whole-archive",batch_lib_file]
 901 #endif
 902   when (r /= ExitSuccess) $ exitWith r
 903   hPutStrLn stderr (" done.")
 904
 905 -- -----------------------------------------------------------------------------
 906 -- Searching for modules
 907
 908 #if not_yet
 909
 910 findModules :: [FilePath] -> IO [String]
 911 findModules paths =
 912   mms <- mapM searchDir paths
 913   return (concat mms)
 914
 915 searchDir path prefix = do
 916   fs <- getDirectoryEntries path `catch` \_ -> return []
 917   searchEntries path prefix fs
 918
 919 searchEntries path prefix [] = return []
 920 searchEntries path prefix (f:fs)
 921   | looks_like_a_module  =  do
 922         ms <- searchEntries path prefix fs
 923         return (prefix `joinModule` f : ms)
 924   | looks_like_a_component  =  do
 925         ms <- searchDir (path </> f) (prefix `joinModule` f)
 926         ms' <- searchEntries path prefix fs
 927         return (ms ++ ms')
 928   | otherwise
 929         searchEntries path prefix fs
 930
 931   where
 932         (base,suffix) = splitFileExt f
 933         looks_like_a_module =
 934                 suffix `elem` haskell_suffixes &&
 935                 all okInModuleName base
 936         looks_like_a_component =
 937                 null suffix && all okInModuleName base
 938
 939 okInModuleName c
 940
 941 #endif
 942
 943 -- ---------------------------------------------------------------------------
 944 -- expanding environment variables in the package configuration
 945
 946 expandEnvVars :: String -> Force -> IO String
 947 expandEnvVars str force = go str ""
 948  where
 949    go "" acc = return $! reverse acc
 950    go ('$':'{':str) acc | (var, '}':rest) <- break close str
 951         = do value <- lookupEnvVar var
 952              go rest (reverse value ++ acc)
 953         where close c = c == '}' || c == '\n' -- don't span newlines
 954    go (c:str) acc
 955         = go str (c:acc)
 956
 957    lookupEnvVar :: String -> IO String
 958    lookupEnvVar nm =
 959         catch (System.Environment.getEnv nm)
 960            (\ _ -> do dieOrForceAll force ("Unable to expand variable " ++
 961                                         show nm)
 962                       return "")
 963
 964 -----------------------------------------------------------------------------
 965
 966 getProgramName :: IO String
 967 getProgramName = liftM (`withoutSuffix` ".bin") getProgName
 968    where str `withoutSuffix` suff
 969             | suff `isSuffixOf` str = take (length str - length suff) str
 970             | otherwise             = str
 971
 972 bye :: String -> IO a
 973 bye s = putStr s >> exitWith ExitSuccess
 974
 975 die :: String -> IO a
 976 die s = do
 977   hFlush stdout
 978   prog <- getProgramName
 979   hPutStrLn stderr (prog ++ ": " ++ s)
 980   exitWith (ExitFailure 1)
 981
 982 dieOrForceAll :: Force -> String -> IO ()
 983 dieOrForceAll ForceAll s = ignoreError s
 984 dieOrForceAll _other s   = dieForcible s
 985
 986 dieOrForceFile :: Force -> String -> IO ()
 987 dieOrForceFile ForceAll   s = ignoreError s
 988 dieOrForceFile ForceFiles s = ignoreError s
 989 dieOrForceFile _other     s = dieForcible s
 990
 991 ignoreError :: String -> IO ()
 992 ignoreError s = do hFlush stdout; hPutStrLn stderr (s ++ " (ignoring)")
 993
 994 dieForcible :: String -> IO ()
 995 dieForcible s = die (s ++ " (use --force to override)")
 996
 997 my_head :: String -> [a] -> a
 998 my_head s [] = error s
 999 my_head s (x:xs) = x
1000
1001 -----------------------------------------
1002 -- Cut and pasted from ghc/compiler/main/SysTools
1003
1004 #if defined(mingw32_HOST_OS)
1005 subst :: Char -> Char -> String -> String
1006 subst a b ls = map (\ x -> if x == a then b else x) ls
1007
1008 unDosifyPath :: FilePath -> FilePath
1009 unDosifyPath xs = subst '\\' '/' xs
1010
1011 getExecDir :: String -> IO (Maybe String)
1012 -- (getExecDir cmd) returns the directory in which the current
1013 --                  executable, which should be called 'cmd', is running
1014 -- So if the full path is /a/b/c/d/e, and you pass "d/e" as cmd,
1015 -- you'll get "/a/b/c" back as the result
1016 getExecDir cmd
1017   = allocaArray len $ \buf -> do
1018         ret <- getModuleFileName nullPtr buf len
1019         if ret == 0 then return Nothing
1020                     else do s <- peekCString buf
1021                             return (Just (reverse (drop (length cmd)
1022                                                         (reverse (unDosifyPath s)))))
1023   where
1024     len = 2048::Int -- Plenty, PATH_MAX is 512 under Win32.
1025
1026 foreign import stdcall unsafe  "GetModuleFileNameA"
1027   getModuleFileName :: Ptr () -> CString -> Int -> IO Int32
1028 #else
1029 getExecDir :: String -> IO (Maybe String)
1030 getExecDir _ = return Nothing
1031 #endif
1032
1033 -----------------------------------------
1034 -- Adapted from ghc/compiler/utils/Panic
1035
1036 installSignalHandlers :: IO ()
1037 installSignalHandlers = do
1038   threadid <- myThreadId
1039   let
1040       interrupt = throwTo threadid (Exception.ErrorCall "interrupted")
1041   --
1042 #if !defined(mingw32_HOST_OS)
1043   installHandler sigQUIT (Catch interrupt) Nothing
1044   installHandler sigINT  (Catch interrupt) Nothing
1045   return ()
1046 #elif __GLASGOW_HASKELL__ >= 603
1047   -- GHC 6.3+ has support for console events on Windows
1048   -- NOTE: running GHCi under a bash shell for some reason requires
1049   -- you to press Ctrl-Break rather than Ctrl-C to provoke
1050   -- an interrupt.  Ctrl-C is getting blocked somewhere, I don't know
1051   -- why --SDM 17/12/2004
1052   let sig_handler ControlC = interrupt
1053       sig_handler Break    = interrupt
1054       sig_handler _        = return ()
1055
1056   installHandler (Catch sig_handler)
1057   return ()
1058 #else
1059   return () -- nothing
1060 #endif