utils/ghc-pkg/Main.hs

   1 {-# OPTIONS -fglasgow-exts #-}
   2 -----------------------------------------------------------------------------
   3 --
   4 -- (c) The University of Glasgow 2004.
   5 --
   6 -- Package management tool
   7 --
   8 -----------------------------------------------------------------------------
   9
  10 -- TODO:
  11 --      - validate modules
  12 --      - expanding of variables in new-style package conf
  13 --      - version manipulation (checking whether old version exists,
  14 --        hiding old version?)
  15
  16 module Main (main) where
  17
  18 import Version  ( version, targetOS, targetARCH )
  19 import Distribution.InstalledPackageInfo
  20 import Distribution.Compat.ReadP
  21 import Distribution.ParseUtils  ( showError )
  22 import Distribution.Package
  23 import Distribution.Version
  24 import Compat.Directory         ( getAppUserDataDirectory, createDirectoryIfMissing )
  25 import Compat.RawSystem         ( rawSystem )
  26
  27 import Prelude
  28
  29 #include "../../includes/ghcconfig.h"
  30
  31 #if __GLASGOW_HASKELL__ >= 504
  32 import System.Console.GetOpt
  33 import Text.PrettyPrint
  34 import qualified Control.Exception as Exception
  35 import Data.Maybe
  36 #else
  37 import GetOpt
  38 import Pretty
  39 import qualified Exception
  40 import Maybe
  41 #endif
  42
  43 import Data.Char        ( isSpace )
  44 import Monad
  45 import Directory
  46 import System   ( getArgs, getProgName, getEnv,
  47                   exitWith, ExitCode(..)
  48                 )
  49 import System.IO
  50 #if __GLASGOW_HASKELL__ >= 600
  51 import System.IO.Error (try)
  52 #else
  53 import System.IO (try)
  54 #endif
  55 import Data.List ( isPrefixOf, isSuffixOf, intersperse, groupBy, sortBy )
  56
  57 #ifdef mingw32_HOST_OS
  58 import Foreign
  59
  60 #if __GLASGOW_HASKELL__ >= 504
  61 import Foreign.C.String
  62 #else
  63 import CString
  64 #endif
  65 #endif
  66
  67 -- -----------------------------------------------------------------------------
  68 -- Entry point
  69
  70 main :: IO ()
  71 main = do
  72   args <- getArgs
  73
  74   case getOpt Permute flags args of
  75         (cli,_,[]) | FlagHelp `elem` cli -> do
  76            prog <- getProgramName
  77            bye (usageInfo (usageHeader prog) flags)
  78         (cli,_,[]) | FlagVersion `elem` cli ->
  79            bye ourCopyright
  80         (cli,nonopts,[]) ->
  81            runit cli nonopts
  82         (_,_,errors) -> tryOldCmdLine errors args
  83
  84 -- If the new command-line syntax fails, then we try the old.  If that
  85 -- fails too, then we output the original errors and the new syntax
  86 -- (so the old syntax is still available, but hidden).
  87 tryOldCmdLine :: [String] -> [String] -> IO ()
  88 tryOldCmdLine errors args = do
  89   case getOpt Permute oldFlags args of
  90         (cli@(_:_),[],[]) ->
  91            oldRunit cli
  92         _failed -> do
  93            prog <- getProgramName
  94            die (concat errors ++ usageInfo (usageHeader prog) flags)
  95
  96 -- -----------------------------------------------------------------------------
  97 -- Command-line syntax
  98
  99 data Flag
 100   = FlagUser
 101   | FlagGlobal
 102   | FlagHelp
 103   | FlagVersion
 104   | FlagConfig  FilePath
 105   | FlagGlobalConfig FilePath
 106   | FlagForce
 107   | FlagAutoGHCiLibs
 108   | FlagDefinedName String String
 109   | FlagSimpleOutput
 110   deriving Eq
 111
 112 flags :: [OptDescr Flag]
 113 flags = [
 114   Option [] ["user"] (NoArg FlagUser)
 115         "use the current user's package database",
 116   Option [] ["global"] (NoArg FlagGlobal)
 117         "(default) use the global package database",
 118   Option ['f'] ["package-conf"] (ReqArg FlagConfig "FILE")
 119         "act upon specified package config file (only)",
 120   Option [] ["global-conf"] (ReqArg FlagGlobalConfig "FILE")
 121         "location of the global package config",
 122   Option [] ["force"] (NoArg FlagForce)
 123         "ignore missing dependencies, directories, and libraries",
 124   Option ['g'] ["auto-ghci-libs"] (NoArg FlagAutoGHCiLibs)
 125         "automatically build libs for GHCi (with register)",
 126   Option ['?'] ["help"] (NoArg FlagHelp)
 127         "display this help and exit",
 128   Option ['D'] ["define-name"] (ReqArg toDefined "NAME=VALUE")
 129         "define NAME as VALUE",
 130   Option ['V'] ["version"] (NoArg FlagVersion)
 131         "output version information and exit",
 132   Option [] ["simple-output"] (NoArg FlagSimpleOutput)
 133         "print output in easy-to-parse format when running command 'list'"
 134   ]
 135  where
 136   toDefined str =
 137     case break (=='=') str of
 138       (nm,[])    -> FlagDefinedName nm []
 139       (nm,_:val) -> FlagDefinedName nm val
 140
 141 ourCopyright :: String
 142 ourCopyright = "GHC package manager version " ++ version ++ "\n"
 143
 144 usageHeader :: String -> String
 145 usageHeader prog = substProg prog $
 146   "Usage:\n" ++
 147   "  $p register {filename | -}\n" ++
 148   "    Register the package using the specified installed package\n" ++
 149   "    description. The syntax for the latter is given in the $p\n" ++
 150   "    documentation.\n" ++
 151   "\n" ++
 152   "  $p update {filename | -}\n" ++
 153   "    Register the package, overwriting any other package with the\n" ++
 154   "    same name.\n" ++
 155   "\n" ++
 156   "  $p unregister {pkg-id}\n" ++
 157   "    Unregister the specified package.\n" ++
 158   "\n" ++
 159   "  $p expose {pkg-id}\n" ++
 160   "    Expose the specified package.\n" ++
 161   "\n" ++
 162   "  $p hide {pkg-id}\n" ++
 163   "    Hide the specified package.\n" ++
 164   "\n" ++
 165   "  $p list [pkg]\n" ++
 166   "    List registered packages in the global database, and also the\n" ++
 167   "    user database if --user is given. If a package name is given\n" ++
 168   "    all the registered versions will be listed in ascending order.\n" ++
 169   "\n" ++
 170   "  $p latest pkg\n" ++
 171   "    Prints the highest registered version of a package.\n" ++
 172   "\n" ++
 173   "  $p describe {pkg-id}\n" ++
 174   "    Give the registered description for the specified package. The\n" ++
 175   "    description is returned in precisely the syntax required by $p\n" ++
 176   "    register.\n" ++
 177   "\n" ++
 178   "  $p field {pkg-id} {field}\n" ++
 179   "    Extract the specified field of the package description for the\n" ++
 180   "    specified package.\n" ++
 181   "\n" ++
 182   " The following optional flags are also accepted:\n"
 183
 184 substProg :: String -> String -> String
 185 substProg _ [] = []
 186 substProg prog ('$':'p':xs) = prog ++ substProg prog xs
 187 substProg prog (c:xs) = c : substProg prog xs
 188
 189 -- -----------------------------------------------------------------------------
 190 -- Do the business
 191
 192 runit :: [Flag] -> [String] -> IO ()
 193 runit cli nonopts = do
 194   prog <- getProgramName
 195   let
 196         force = FlagForce `elem` cli
 197         auto_ghci_libs = FlagAutoGHCiLibs `elem` cli
 198         defines = [ (nm,val) | FlagDefinedName nm val <- cli ]
 199   --
 200   -- first, parse the command
 201   case nonopts of
 202     ["register", filename] ->
 203         registerPackage filename defines cli auto_ghci_libs False force
 204     ["update", filename] ->
 205         registerPackage filename defines cli auto_ghci_libs True force
 206     ["unregister", pkgid_str] -> do
 207         pkgid <- readGlobPkgId pkgid_str
 208         unregisterPackage pkgid cli
 209     ["expose", pkgid_str] -> do
 210         pkgid <- readGlobPkgId pkgid_str
 211         exposePackage pkgid cli
 212     ["hide",   pkgid_str] -> do
 213         pkgid <- readGlobPkgId pkgid_str
 214         hidePackage pkgid cli
 215     ["list"] -> do
 216         listPackages cli Nothing
 217     ["list", pkgid_str] -> do
 218         pkgid <- readGlobPkgId pkgid_str
 219         listPackages cli (Just pkgid)
 220     ["latest", pkgid_str] -> do
 221         pkgid <- readGlobPkgId pkgid_str
 222         latestPackage cli pkgid
 223     ["describe", pkgid_str] -> do
 224         pkgid <- readGlobPkgId pkgid_str
 225         describePackage cli pkgid
 226     ["field", pkgid_str, field] -> do
 227         pkgid <- readGlobPkgId pkgid_str
 228         describeField cli pkgid field
 229     [] -> do
 230         die ("missing command\n" ++
 231                 usageInfo (usageHeader prog) flags)
 232     (_cmd:_) -> do
 233         die ("command-line syntax error\n" ++
 234                 usageInfo (usageHeader prog) flags)
 235
 236 parseCheck :: ReadP a a -> String -> String -> IO a
 237 parseCheck parser str what =
 238   case [ x | (x,ys) <- readP_to_S parser str, all isSpace ys ] of
 239     [x] -> return x
 240     _ -> die ("cannot parse \'" ++ str ++ "\' as a " ++ what)
 241
 242 readPkgId :: String -> IO PackageIdentifier
 243 readPkgId str = parseCheck parsePackageId str "package identifier"
 244
 245 readGlobPkgId :: String -> IO PackageIdentifier
 246 readGlobPkgId str = parseCheck parseGlobPackageId str "package identifier"
 247
 248 parseGlobPackageId :: ReadP r PackageIdentifier
 249 parseGlobPackageId =
 250   parsePackageId
 251      +++
 252   (do n <- parsePackageName; string "-*"
 253       return (PackageIdentifier{ pkgName = n, pkgVersion = globVersion }))
 254
 255 -- globVersion means "all versions"
 256 globVersion :: Version
 257 globVersion = Version{ versionBranch=[], versionTags=["*"] }
 258
 259 -- -----------------------------------------------------------------------------
 260 -- Package databases
 261
 262 -- Some commands operate on a single database:
 263 --      register, unregister, expose, hide
 264 -- however these commands also check the union of the available databases
 265 -- in order to check consistency.  For example, register will check that
 266 -- dependencies exist before registering a package.
 267 --
 268 -- Some commands operate  on multiple databases, with overlapping semantics:
 269 --      list, describe, field
 270
 271 type PackageDBName  = FilePath
 272 type PackageDB      = [InstalledPackageInfo]
 273
 274 type PackageDBStack = [(PackageDBName,PackageDB)]
 275         -- A stack of package databases.  Convention: head is the topmost
 276         -- in the stack.  Earlier entries override later one.
 277
 278 getPkgDatabases :: Bool -> [Flag] -> IO PackageDBStack
 279 getPkgDatabases modify flags = do
 280   -- first we determine the location of the global package config.  On Windows,
 281   -- this is found relative to the ghc-pkg.exe binary, whereas on Unix the
 282   -- location is passed to the binary using the --global-config flag by the
 283   -- wrapper script.
 284   let err_msg = "missing --global-conf option, location of global package.conf unknown\n"
 285   global_conf <-
 286      case [ f | FlagGlobalConfig f <- flags ] of
 287         [] -> do mb_dir <- getExecDir "/bin/ghc-pkg.exe"
 288                  case mb_dir of
 289                         Nothing  -> die err_msg
 290                         Just dir -> return (dir `joinFileName` "package.conf")
 291         fs -> return (last fs)
 292
 293   let global_conf_dir = global_conf ++ ".d"
 294   global_conf_dir_exists <- doesDirectoryExist global_conf_dir
 295   global_confs <-
 296     if global_conf_dir_exists
 297       then do files <- getDirectoryContents global_conf_dir
 298               return [ global_conf_dir ++ '/' : file
 299                      | file <- files
 300                      , isSuffixOf ".conf" file]
 301       else return []
 302
 303   -- get the location of the user package database, and create it if necessary
 304   appdir <- getAppUserDataDirectory "ghc"
 305
 306   let
 307         subdir = targetARCH ++ '-':targetOS ++ '-':version
 308         archdir   = appdir `joinFileName` subdir
 309         user_conf = archdir `joinFileName` "package.conf"
 310   user_exists <- doesFileExist user_conf
 311
 312   -- If the user database doesn't exist, and this command isn't a
 313   -- "modify" command, then we won't attempt to create or use it.
 314   let sys_databases
 315         | modify || user_exists = user_conf : global_confs ++ [global_conf]
 316         | otherwise             = global_confs ++ [global_conf]
 317
 318   e_pkg_path <- try (getEnv "GHC_PACKAGE_PATH")
 319   let env_stack =
 320         case e_pkg_path of
 321                 Left  _ -> sys_databases
 322                 Right path
 323                   | last cs == ""  -> init cs ++ sys_databases
 324                   | otherwise      -> cs
 325                   where cs = parseSearchPath path
 326
 327         -- The "global" database is always the one at the bottom of the stack.
 328         -- This is the database we modify by default.
 329       virt_global_conf = last env_stack
 330
 331   -- -f flags on the command line add to the database stack, unless any
 332   -- of them are present in the stack already.
 333   let flag_stack = filter (`notElem` env_stack)
 334                         [ f | FlagConfig f <- reverse flags ] ++ env_stack
 335
 336   -- Now we have the full stack of databases.  Next, if the current
 337   -- command is a "modify" type command, then we truncate the stack
 338   -- so that the topmost element is the database being modified.
 339   final_stack <-
 340      if not modify
 341         then return flag_stack
 342         else let
 343                 go (FlagUser : fs)     = modifying user_conf
 344                 go (FlagGlobal : fs)   = modifying virt_global_conf
 345                 go (FlagConfig f : fs) = modifying f
 346                 go (_ : fs)            = go fs
 347                 go []                  = modifying virt_global_conf
 348
 349                 modifying f
 350                   | f `elem` flag_stack = return (dropWhile (/= f) flag_stack)
 351                   | otherwise           = die ("requesting modification of database:\n\t" ++ f ++ "\n\twhich is not in the database stack.")
 352              in
 353                 go flags
 354
 355   db_stack <- mapM readParseDatabase final_stack
 356   return db_stack
 357
 358 readParseDatabase :: PackageDBName -> IO (PackageDBName,PackageDB)
 359 readParseDatabase filename = do
 360   str <- readFile filename `Exception.catch` \_ -> return emptyPackageConfig
 361   let packages = read str
 362   Exception.evaluate packages
 363     `Exception.catch` \_ ->
 364         die (filename ++ ": parse error in package config file")
 365   return (filename,packages)
 366
 367 emptyPackageConfig :: String
 368 emptyPackageConfig = "[]"
 369
 370 -- -----------------------------------------------------------------------------
 371 -- Registering
 372
 373 registerPackage :: FilePath
 374                 -> [(String,String)] -- defines
 375                 -> [Flag]
 376                 -> Bool         -- auto_ghci_libs
 377                 -> Bool         -- update
 378                 -> Bool         -- force
 379                 -> IO ()
 380 registerPackage input defines flags auto_ghci_libs update force = do
 381   db_stack <- getPkgDatabases True flags
 382   let
 383         db_to_operate_on = my_head "db" db_stack
 384         db_filename      = fst db_to_operate_on
 385   --
 386   checkConfigAccess db_filename
 387
 388   s <-
 389     case input of
 390       "-" -> do
 391         putStr "Reading package info from stdin ... "
 392         getContents
 393       f   -> do
 394         putStr ("Reading package info from " ++ show f ++ " ... ")
 395         readFile f
 396
 397   expanded <- expandEnvVars s defines force
 398
 399   pkg0 <- parsePackageInfo expanded defines force
 400   putStrLn "done."
 401
 402   let pkg = resolveDeps db_stack pkg0
 403   overlaps <- validatePackageConfig pkg db_stack auto_ghci_libs update force
 404   new_details <- updatePackageDB db_stack overlaps (snd db_to_operate_on) pkg
 405   savePackageConfig db_filename
 406   maybeRestoreOldConfig db_filename $
 407     writeNewConfig db_filename new_details
 408
 409 parsePackageInfo
 410         :: String
 411         -> [(String,String)]
 412         -> Bool
 413         -> IO InstalledPackageInfo
 414 parsePackageInfo str defines force =
 415   case parseInstalledPackageInfo str of
 416     ParseOk _warns ok -> return ok
 417     ParseFailed err -> die (showError err)
 418
 419 -- -----------------------------------------------------------------------------
 420 -- Exposing, Hiding, Unregistering are all similar
 421
 422 exposePackage :: PackageIdentifier ->  [Flag] -> IO ()
 423 exposePackage = modifyPackage (\p -> [p{exposed=True}])
 424
 425 hidePackage :: PackageIdentifier ->  [Flag] -> IO ()
 426 hidePackage = modifyPackage (\p -> [p{exposed=False}])
 427
 428 unregisterPackage :: PackageIdentifier ->  [Flag] -> IO ()
 429 unregisterPackage = modifyPackage (\p -> [])
 430
 431 modifyPackage
 432   :: (InstalledPackageInfo -> [InstalledPackageInfo])
 433   -> PackageIdentifier
 434   -> [Flag]
 435   -> IO ()
 436 modifyPackage fn pkgid flags  = do
 437   db_stack <- getPkgDatabases True{-modify-} flags
 438   let ((db_name, pkgs) : _) = db_stack
 439   checkConfigAccess db_name
 440   ps <- findPackages [(db_name,pkgs)] pkgid
 441   let pids = map package ps
 442   savePackageConfig db_name
 443   let new_config = concat (map modify pkgs)
 444       modify pkg
 445           | package pkg `elem` pids = fn pkg
 446           | otherwise               = [pkg]
 447   maybeRestoreOldConfig db_name $
 448       writeNewConfig db_name new_config
 449
 450 -- -----------------------------------------------------------------------------
 451 -- Listing packages
 452
 453 listPackages ::  [Flag] -> Maybe PackageIdentifier -> IO ()
 454 listPackages flags mPackageName = do
 455   let simple_output = FlagSimpleOutput `elem` flags
 456   db_stack <- getPkgDatabases False flags
 457   let db_stack_filtered -- if a package is given, filter out all other packages
 458         | Just this <- mPackageName =
 459             map (\(conf,pkgs) -> (conf, filter (this `matchesPkg`) pkgs))
 460                 db_stack
 461         | otherwise = db_stack
 462
 463       db_stack_sorted
 464           = [ (db, sort_pkgs pkgs) | (db,pkgs) <- db_stack_filtered ]
 465           where sort_pkgs = sortBy cmpPkgIds
 466                 cmpPkgIds pkg1 pkg2 =
 467                    case pkgName p1 `compare` pkgName p2 of
 468                         LT -> LT
 469                         GT -> GT
 470                         EQ -> pkgVersion p1 `compare` pkgVersion p2
 471                    where (p1,p2) = (package pkg1, package pkg2)
 472
 473       show_func = if simple_output then show_easy else mapM_ show_regular
 474
 475   show_func (reverse db_stack_sorted)
 476
 477   where show_regular (db_name,pkg_confs) =
 478           hPutStrLn stdout (render $
 479                 text (db_name ++ ":") $$ nest 4 packages
 480                 )
 481            where packages = fsep (punctuate comma (map pp_pkg pkg_confs))
 482                  pp_pkg p
 483                    | exposed p = doc
 484                    | otherwise = parens doc
 485                    where doc = text (showPackageId (package p))
 486
 487         show_easy db_stack = do
 488           let pkgs = map showPackageId $ sortBy compPkgIdVer $
 489                           map package (concatMap snd db_stack)
 490           when (null pkgs) $ die "no matches"
 491           hPutStrLn stdout $ concat $ intersperse " " pkgs
 492
 493 -- -----------------------------------------------------------------------------
 494 -- Prints the highest (hidden or exposed) version of a package
 495
 496 latestPackage ::  [Flag] -> PackageIdentifier -> IO ()
 497 latestPackage flags pkgid = do
 498   db_stack <- getPkgDatabases False flags
 499   ps <- findPackages db_stack pkgid
 500   show_pkg (sortBy compPkgIdVer (map package ps))
 501   where
 502     show_pkg [] = die "no matches"
 503     show_pkg pids = hPutStrLn stdout (showPackageId (last pids))
 504
 505 -- -----------------------------------------------------------------------------
 506 -- Describe
 507
 508 describePackage :: [Flag] -> PackageIdentifier -> IO ()
 509 describePackage flags pkgid = do
 510   db_stack <- getPkgDatabases False flags
 511   ps <- findPackages db_stack pkgid
 512   mapM_ (putStrLn . showInstalledPackageInfo) ps
 513
 514 -- PackageId is can have globVersion for the version
 515 findPackages :: PackageDBStack -> PackageIdentifier -> IO [InstalledPackageInfo]
 516 findPackages db_stack pkgid
 517   = case [ p | p <- all_pkgs, pkgid `matchesPkg` p ] of
 518         []  -> die ("cannot find package " ++ showPackageId pkgid)
 519         ps -> return ps
 520   where
 521         all_pkgs = concat (map snd db_stack)
 522
 523 matches :: PackageIdentifier -> PackageIdentifier -> Bool
 524 pid `matches` pid'
 525   = (pkgName pid == pkgName pid')
 526     && (pkgVersion pid == pkgVersion pid' || not (realVersion pid))
 527
 528 matchesPkg :: PackageIdentifier -> InstalledPackageInfo -> Bool
 529 pid `matchesPkg` pkg = pid `matches` package pkg
 530
 531 compPkgIdVer :: PackageIdentifier -> PackageIdentifier -> Ordering
 532 compPkgIdVer p1 p2 = pkgVersion p1 `compare` pkgVersion p2
 533
 534 -- -----------------------------------------------------------------------------
 535 -- Field
 536
 537 describeField :: [Flag] -> PackageIdentifier -> String -> IO ()
 538 describeField flags pkgid field = do
 539   db_stack <- getPkgDatabases False flags
 540   case toField field of
 541     Nothing -> die ("unknown field: " ++ field)
 542     Just fn -> do
 543         ps <- findPackages db_stack pkgid
 544         mapM_ (putStrLn.fn) ps
 545
 546 toField :: String -> Maybe (InstalledPackageInfo -> String)
 547 -- backwards compatibility:
 548 toField "import_dirs"     = Just $ strList . importDirs
 549 toField "source_dirs"     = Just $ strList . importDirs
 550 toField "library_dirs"    = Just $ strList . libraryDirs
 551 toField "hs_libraries"    = Just $ strList . hsLibraries
 552 toField "extra_libraries" = Just $ strList . extraLibraries
 553 toField "include_dirs"    = Just $ strList . includeDirs
 554 toField "c_includes"      = Just $ strList . includes
 555 toField "package_deps"    = Just $ strList . map showPackageId. depends
 556 toField "extra_cc_opts"   = Just $ strList . ccOptions
 557 toField "extra_ld_opts"   = Just $ strList . ldOptions
 558 toField "framework_dirs"  = Just $ strList . frameworkDirs
 559 toField "extra_frameworks"= Just $ strList . frameworks
 560 toField s                 = showInstalledPackageInfoField s
 561
 562 strList :: [String] -> String
 563 strList = show
 564
 565 -- -----------------------------------------------------------------------------
 566 -- Manipulating package.conf files
 567
 568 checkConfigAccess :: FilePath -> IO ()
 569 checkConfigAccess filename = do
 570   access <- getPermissions filename
 571   when (not (writable access))
 572       (die (filename ++ ": you don't have permission to modify this file"))
 573
 574 maybeRestoreOldConfig :: FilePath -> IO () -> IO ()
 575 maybeRestoreOldConfig filename io
 576   = io `catch` \e -> do
 577         hPutStrLn stderr (show e)
 578         hPutStr stdout ("\nWARNING: an error was encountered while the new \n"++
 579                           "configuration was being written.  Attempting to \n"++
 580                           "restore the old configuration... ")
 581         renameFile (filename ++ ".old")  filename
 582         hPutStrLn stdout "done."
 583         ioError e
 584
 585 writeNewConfig :: FilePath -> [InstalledPackageInfo] -> IO ()
 586 writeNewConfig filename packages = do
 587   hPutStr stdout "Writing new package config file... "
 588   h <- openFile filename WriteMode
 589   hPutStrLn h (show packages)
 590   hClose h
 591   hPutStrLn stdout "done."
 592
 593 savePackageConfig :: FilePath -> IO ()
 594 savePackageConfig filename = do
 595   hPutStr stdout "Saving old package config file... "
 596     -- mv rather than cp because we've already done an hGetContents
 597     -- on this file so we won't be able to open it for writing
 598     -- unless we move the old one out of the way...
 599   let oldFile = filename ++ ".old"
 600   doesExist <- doesFileExist oldFile  `catch` (\ _ -> return False)
 601   when doesExist (removeFile oldFile `catch` (const $ return ()))
 602   catch (renameFile filename oldFile)
 603         (\ err -> do
 604                 hPutStrLn stderr (unwords [ "Unable to rename "
 605                                           , show filename
 606                                           , " to "
 607                                           , show oldFile
 608                                           ])
 609                 ioError err)
 610   hPutStrLn stdout "done."
 611
 612 -----------------------------------------------------------------------------
 613 -- Sanity-check a new package config, and automatically build GHCi libs
 614 -- if requested.
 615
 616 validatePackageConfig :: InstalledPackageInfo
 617                       -> PackageDBStack
 618                       -> Bool   -- auto-ghc-libs
 619                       -> Bool   -- update
 620                       -> Bool   -- force
 621                       -> IO [PackageIdentifier]
 622 validatePackageConfig pkg db_stack auto_ghci_libs update force = do
 623   checkPackageId pkg
 624   overlaps <- checkDuplicates db_stack pkg update force
 625   mapM_ (checkDep db_stack force) (depends pkg)
 626   mapM_ (checkDir force) (importDirs pkg)
 627   mapM_ (checkDir force) (libraryDirs pkg)
 628   mapM_ (checkDir force) (includeDirs pkg)
 629   mapM_ (checkHSLib (libraryDirs pkg) auto_ghci_libs force) (hsLibraries pkg)
 630   return overlaps
 631   -- ToDo: check these somehow?
 632   --    extra_libraries :: [String],
 633   --    c_includes      :: [String],
 634
 635 -- When the package name and version are put together, sometimes we can
 636 -- end up with a package id that cannot be parsed.  This will lead to
 637 -- difficulties when the user wants to refer to the package later, so
 638 -- we check that the package id can be parsed properly here.
 639 checkPackageId :: InstalledPackageInfo -> IO ()
 640 checkPackageId ipi =
 641   let str = showPackageId (package ipi) in
 642   case [ x | (x,ys) <- readP_to_S parsePackageId str, all isSpace ys ] of
 643     [_] -> return ()
 644     []  -> die ("invalid package identifier: " ++ str)
 645     _   -> die ("ambiguous package identifier: " ++ str)
 646
 647 resolveDeps :: PackageDBStack -> InstalledPackageInfo -> InstalledPackageInfo
 648 resolveDeps db_stack p = updateDeps p
 649   where
 650         -- The input package spec is allowed to give a package dependency
 651         -- without a version number; e.g.
 652         --      depends: base
 653         -- Here, we update these dependencies without version numbers to
 654         -- match the actual versions of the relevant packages installed.
 655         updateDeps p = p{depends = map resolveDep (depends p)}
 656
 657         resolveDep dep_pkgid
 658            | realVersion dep_pkgid  = dep_pkgid
 659            | otherwise              = lookupDep dep_pkgid
 660
 661         lookupDep dep_pkgid
 662            = let
 663                 name = pkgName dep_pkgid
 664              in
 665              case [ pid | p <- concat (map snd db_stack),
 666                           let pid = package p,
 667                           pkgName pid == name ] of
 668                 (pid:_) -> pid          -- Found installed package,
 669                                         -- replete with its version
 670                 []      -> dep_pkgid    -- No installed package; use
 671                                         -- the version-less one
 672
 673 checkDuplicates :: PackageDBStack -> InstalledPackageInfo -> Bool -> Bool
 674          -> IO [PackageIdentifier]
 675 checkDuplicates db_stack pkg update force = do
 676   let
 677         pkgid = package pkg
 678         (_top_db_name, pkgs) : _  = db_stack
 679   --
 680   -- Check whether this package id already exists in this DB
 681   --
 682   when (not update && (pkgid `elem` map package pkgs)) $
 683        die ("package " ++ showPackageId pkgid ++ " is already installed")
 684
 685   --
 686   -- Check whether any of the dependencies of the current package
 687   -- conflict with each other.
 688   --
 689   let
 690         all_pkgs = concat (map snd db_stack)
 691
 692         allModules p = exposedModules p ++ hiddenModules p
 693
 694         our_dependencies = closePackageDeps all_pkgs [pkg]
 695         all_dep_modules = concat (map (\p -> zip (allModules p) (repeat p))
 696                                          our_dependencies)
 697
 698         overlaps = [ (m, map snd group)
 699                    | group@((m,_):_) <- groupBy eqfst (sortBy cmpfst all_dep_modules),
 700                      length group > 1 ]
 701                 where eqfst  (a,_) (b,_) = a == b
 702                       cmpfst (a,_) (b,_) = a `compare` b
 703
 704   when (not (null overlaps)) $
 705     diePrettyOrForce force $ vcat [
 706         text "package" <+> text (showPackageId (package pkg)) <+>
 707           text "has conflicting dependencies:",
 708         let complain_about (mod,ps) =
 709                 text mod <+> text "is in the following packages:" <+>
 710                         sep (map (text.showPackageId.package) ps)
 711         in
 712         nest 3 (vcat (map complain_about overlaps))
 713         ]
 714
 715   --
 716   -- Now check whether exposing this package will result in conflicts, and
 717   -- Figure out which packages we need to hide to resolve the conflicts.
 718   --
 719   let
 720         closure_exposed_pkgs = closePackageDeps pkgs (filter exposed pkgs)
 721
 722         new_dep_modules = concat $ map allModules $
 723                           filter (\p -> package p `notElem`
 724                                         map package closure_exposed_pkgs) $
 725                           our_dependencies
 726
 727         pkgs_with_overlapping_modules =
 728                 [ (p, overlapping_mods)
 729                 | p <- closure_exposed_pkgs,
 730                   let overlapping_mods =
 731                         filter (`elem` new_dep_modules) (allModules p),
 732                   (_:_) <- [overlapping_mods] --trick to get the non-empty ones
 733                 ]
 734
 735         to_hide = map package
 736                  $ filter exposed
 737                  $ closePackageDepsUpward pkgs
 738                  $ map fst pkgs_with_overlapping_modules
 739
 740   when (not update && exposed pkg && not (null pkgs_with_overlapping_modules)) $ do
 741     diePretty $ vcat [
 742             text "package" <+> text (showPackageId (package pkg)) <+>
 743                 text "conflicts with the following packages, which are",
 744             text "either exposed or a dependency (direct or indirect) of an exposed package:",
 745             let complain_about (p, mods)
 746                   = text (showPackageId (package p)) <+> text "contains modules" <+>
 747                         sep (punctuate comma (map text mods)) in
 748             nest 3 (vcat (map complain_about pkgs_with_overlapping_modules)),
 749             text "Using 'update' instead of 'register' will cause the following packages",
 750             text "to be hidden, which will eliminate the conflict:",
 751             nest 3 (sep (map (text.showPackageId) to_hide))
 752           ]
 753
 754   when (not (null to_hide)) $ do
 755     hPutStrLn stderr $ render $
 756         sep [text "Warning: hiding the following packages to avoid conflict: ",
 757              nest 2 (sep (map (text.showPackageId) to_hide))]
 758
 759   return to_hide
 760
 761
 762 closure :: (a->[a]->Bool) -> (a -> [a]) -> [a] -> [a] -> [a]
 763 closure pred more []     res = res
 764 closure pred more (p:ps) res
 765   | p `pred` res = closure pred more ps res
 766   | otherwise    = closure pred more (more p ++ ps) (p:res)
 767
 768 closePackageDeps :: [InstalledPackageInfo] -> [InstalledPackageInfo]
 769          -> [InstalledPackageInfo]
 770 closePackageDeps db start
 771   = closure (\p ps -> package p `elem` map package ps) getDepends start []
 772   where
 773         getDepends p = [ pkg | dep <- depends p, pkg <- lookupPkg dep ]
 774         lookupPkg p = [ q | q <- db, p == package q ]
 775
 776 closePackageDepsUpward :: [InstalledPackageInfo] -> [InstalledPackageInfo]
 777          -> [InstalledPackageInfo]
 778 closePackageDepsUpward db start
 779   = closure (\p ps -> package p `elem` map package ps) getUpwardDepends start []
 780   where
 781         getUpwardDepends p = [ pkg | pkg <- db, package p `elem` depends pkg ]
 782
 783
 784 checkDir :: Bool -> String -> IO ()
 785 checkDir force d
 786  | "$topdir" `isPrefixOf` d = return ()
 787         -- can't check this, because we don't know what $topdir is
 788  | otherwise = do
 789    there <- doesDirectoryExist d
 790    when (not there)
 791        (dieOrForce force (d ++ " doesn't exist or isn't a directory"))
 792
 793 checkDep :: PackageDBStack -> Bool -> PackageIdentifier -> IO ()
 794 checkDep db_stack force pkgid
 795   | not real_version || pkgid `elem` pkgids = return ()
 796   | otherwise = dieOrForce force ("dependency " ++ showPackageId pkgid
 797                                         ++ " doesn't exist")
 798   where
 799         -- for backwards compat, we treat 0.0 as a special version,
 800         -- and don't check that it actually exists.
 801         real_version = realVersion pkgid
 802
 803         all_pkgs = concat (map snd db_stack)
 804         pkgids = map package all_pkgs
 805
 806 realVersion :: PackageIdentifier -> Bool
 807 realVersion pkgid = versionBranch (pkgVersion pkgid) /= []
 808
 809 checkHSLib :: [String] -> Bool -> Bool -> String -> IO ()
 810 checkHSLib dirs auto_ghci_libs force lib = do
 811   let batch_lib_file = "lib" ++ lib ++ ".a"
 812   bs <- mapM (doesLibExistIn batch_lib_file) dirs
 813   case [ dir | (exists,dir) <- zip bs dirs, exists ] of
 814         [] -> dieOrForce force ("cannot find " ++ batch_lib_file ++
 815                                  " on library path")
 816         (dir:_) -> checkGHCiLib dirs dir batch_lib_file lib auto_ghci_libs
 817
 818 doesLibExistIn :: String -> String -> IO Bool
 819 doesLibExistIn lib d
 820  | "$topdir" `isPrefixOf` d = return True
 821  | otherwise                = doesFileExist (d ++ '/':lib)
 822
 823 checkGHCiLib :: [String] -> String -> String -> String -> Bool -> IO ()
 824 checkGHCiLib dirs batch_lib_dir batch_lib_file lib auto_build
 825   | auto_build = autoBuildGHCiLib batch_lib_dir batch_lib_file ghci_lib_file
 826   | otherwise  = do
 827       bs <- mapM (doesLibExistIn ghci_lib_file) dirs
 828       case [dir | (exists,dir) <- zip bs dirs, exists] of
 829         []    -> hPutStrLn stderr ("warning: can't find GHCi lib " ++ ghci_lib_file)
 830         (_:_) -> return ()
 831   where
 832     ghci_lib_file = lib ++ ".o"
 833
 834 -- automatically build the GHCi version of a batch lib,
 835 -- using ld --whole-archive.
 836
 837 autoBuildGHCiLib :: String -> String -> String -> IO ()
 838 autoBuildGHCiLib dir batch_file ghci_file = do
 839   let ghci_lib_file  = dir ++ '/':ghci_file
 840       batch_lib_file = dir ++ '/':batch_file
 841   hPutStr stderr ("building GHCi library " ++ ghci_lib_file ++ "...")
 842 #if defined(darwin_HOST_OS)
 843   r <- rawSystem "ld" ["-r","-x","-o",ghci_lib_file,"-all_load",batch_lib_file]
 844 #elif defined(mingw32_HOST_OS)
 845   execDir <- getExecDir "/bin/ghc-pkg.exe"
 846   r <- rawSystem (maybe "" (++"/gcc-lib/") execDir++"ld") ["-r","-x","-o",ghci_lib_file,"--whole-archive",batch_lib_file]
 847 #else
 848   r <- rawSystem "ld" ["-r","-x","-o",ghci_lib_file,"--whole-archive",batch_lib_file]
 849 #endif
 850   when (r /= ExitSuccess) $ exitWith r
 851   hPutStrLn stderr (" done.")
 852
 853 -- -----------------------------------------------------------------------------
 854 -- Updating the DB with the new package.
 855
 856 updatePackageDB
 857         :: PackageDBStack               -- the full stack
 858         -> [PackageIdentifier]          -- packages to hide
 859         -> [InstalledPackageInfo]       -- packages in *this* DB
 860         -> InstalledPackageInfo         -- the new package
 861         -> IO [InstalledPackageInfo]
 862 updatePackageDB db_stack to_hide pkgs new_pkg = do
 863   let
 864         pkgid = package new_pkg
 865
 866         pkgs' = [ maybe_hide p | p <- pkgs, package p /= pkgid ]
 867
 868         -- When update is on, and we're exposing the new package,
 869         -- we hide any packages which conflict (see checkDuplicates)
 870         -- in the current DB.
 871         maybe_hide p
 872           | exposed new_pkg && package p `elem` to_hide = p{ exposed = False }
 873           | otherwise = p
 874   --
 875   return (pkgs'++ [new_pkg])
 876
 877 -- -----------------------------------------------------------------------------
 878 -- Searching for modules
 879
 880 #if not_yet
 881
 882 findModules :: [FilePath] -> IO [String]
 883 findModules paths =
 884   mms <- mapM searchDir paths
 885   return (concat mms)
 886
 887 searchDir path prefix = do
 888   fs <- getDirectoryEntries path `catch` \_ -> return []
 889   searchEntries path prefix fs
 890
 891 searchEntries path prefix [] = return []
 892 searchEntries path prefix (f:fs)
 893   | looks_like_a_module  =  do
 894         ms <- searchEntries path prefix fs
 895         return (prefix `joinModule` f : ms)
 896   | looks_like_a_component  =  do
 897         ms <- searchDir (path `joinFilename` f) (prefix `joinModule` f)
 898         ms' <- searchEntries path prefix fs
 899         return (ms ++ ms')
 900   | otherwise
 901         searchEntries path prefix fs
 902
 903   where
 904         (base,suffix) = splitFileExt f
 905         looks_like_a_module =
 906                 suffix `elem` haskell_suffixes &&
 907                 all okInModuleName base
 908         looks_like_a_component =
 909                 null suffix && all okInModuleName base
 910
 911 okInModuleName c
 912
 913 #endif
 914
 915 -- -----------------------------------------------------------------------------
 916 -- The old command-line syntax, supported for backwards compatibility
 917
 918 data OldFlag
 919   = OF_Config FilePath
 920   | OF_Input FilePath
 921   | OF_List
 922   | OF_ListLocal
 923   | OF_Add Bool {- True => replace existing info -}
 924   | OF_Remove String | OF_Show String
 925   | OF_Field String | OF_AutoGHCiLibs | OF_Force
 926   | OF_DefinedName String String
 927   | OF_GlobalConfig FilePath
 928   deriving (Eq)
 929
 930 isAction :: OldFlag -> Bool
 931 isAction OF_Config{}        = False
 932 isAction OF_Field{}         = False
 933 isAction OF_Input{}         = False
 934 isAction OF_AutoGHCiLibs{}  = False
 935 isAction OF_Force{}         = False
 936 isAction OF_DefinedName{}   = False
 937 isAction OF_GlobalConfig{}  = False
 938 isAction _                  = True
 939
 940 oldFlags :: [OptDescr OldFlag]
 941 oldFlags = [
 942   Option ['f'] ["config-file"] (ReqArg OF_Config "FILE")
 943         "use the specified package config file",
 944   Option ['l'] ["list-packages"] (NoArg OF_List)
 945         "list packages in all config files",
 946   Option ['L'] ["list-local-packages"] (NoArg OF_ListLocal)
 947         "list packages in the specified config file",
 948   Option ['a'] ["add-package"] (NoArg (OF_Add False))
 949         "add a new package",
 950   Option ['u'] ["update-package"] (NoArg (OF_Add True))
 951         "update package with new configuration",
 952   Option ['i'] ["input-file"] (ReqArg OF_Input "FILE")
 953         "read new package info from specified file",
 954   Option ['s'] ["show-package"] (ReqArg OF_Show "NAME")
 955         "show the configuration for package NAME",
 956   Option [] ["field"] (ReqArg OF_Field "FIELD")
 957         "(with --show-package) Show field FIELD only",
 958   Option [] ["force"] (NoArg OF_Force)
 959         "ignore missing directories/libraries",
 960   Option ['r'] ["remove-package"] (ReqArg OF_Remove "NAME")
 961         "remove an installed package",
 962   Option ['g'] ["auto-ghci-libs"] (NoArg OF_AutoGHCiLibs)
 963         "automatically build libs for GHCi (with -a)",
 964   Option ['D'] ["define-name"] (ReqArg toDefined "NAME=VALUE")
 965         "define NAME as VALUE",
 966   Option [] ["global-conf"] (ReqArg OF_GlobalConfig "FILE")
 967         "location of the global package config"
 968   ]
 969  where
 970   toDefined str =
 971     case break (=='=') str of
 972       (nm,[]) -> OF_DefinedName nm []
 973       (nm,_:val) -> OF_DefinedName nm val
 974
 975 oldRunit :: [OldFlag] -> IO ()
 976 oldRunit clis = do
 977   let new_flags = [ f | Just f <- map conv clis ]
 978
 979       conv (OF_GlobalConfig f) = Just (FlagGlobalConfig f)
 980       conv (OF_Config f)       = Just (FlagConfig f)
 981       conv _                   = Nothing
 982
 983
 984
 985   let fields = [ f | OF_Field f <- clis ]
 986
 987   let auto_ghci_libs = any isAuto clis
 988          where isAuto OF_AutoGHCiLibs = True; isAuto _ = False
 989       input_file = my_head "inp" ([ f | (OF_Input f) <- clis] ++ ["-"])
 990
 991       force = OF_Force `elem` clis
 992
 993       defines = [ (nm,val) | OF_DefinedName nm val <- clis ]
 994
 995   case [ c | c <- clis, isAction c ] of
 996     [ OF_List ]      -> listPackages new_flags Nothing
 997     [ OF_ListLocal ] -> listPackages new_flags Nothing
 998     [ OF_Add upd ]   ->
 999         registerPackage input_file defines new_flags auto_ghci_libs upd force
1000     [ OF_Remove pkgid_str ]  -> do
1001         pkgid <- readPkgId pkgid_str
1002         unregisterPackage pkgid new_flags
1003     [ OF_Show pkgid_str ]
1004         | null fields -> do
1005                 pkgid <- readPkgId pkgid_str
1006                 describePackage new_flags pkgid
1007         | otherwise   -> do
1008                 pkgid <- readPkgId pkgid_str
1009                 mapM_ (describeField new_flags pkgid) fields
1010     _ -> do
1011         prog <- getProgramName
1012         die (usageInfo (usageHeader prog) flags)
1013
1014 my_head :: String -> [a] -> a
1015 my_head s [] = error s
1016 my_head s (x:xs) = x
1017
1018 -- ---------------------------------------------------------------------------
1019 -- expanding environment variables in the package configuration
1020
1021 expandEnvVars :: String -> [(String, String)] -> Bool -> IO String
1022 expandEnvVars str defines force = go str ""
1023  where
1024    go "" acc = return $! reverse acc
1025    go ('$':'{':str) acc | (var, '}':rest) <- break close str
1026         = do value <- lookupEnvVar var
1027              go rest (reverse value ++ acc)
1028         where close c = c == '}' || c == '\n' -- don't span newlines
1029    go (c:str) acc
1030         = go str (c:acc)
1031
1032    lookupEnvVar :: String -> IO String
1033    lookupEnvVar nm =
1034      case lookup nm defines of
1035        Just x | not (null x) -> return x
1036        _      ->
1037         catch (System.getEnv nm)
1038            (\ _ -> do dieOrForce force ("Unable to expand variable " ++
1039                                         show nm)
1040                       return "")
1041
1042 -----------------------------------------------------------------------------
1043
1044 getProgramName :: IO String
1045 getProgramName = liftM (`withoutSuffix` ".bin") getProgName
1046    where str `withoutSuffix` suff
1047             | suff `isSuffixOf` str = take (length str - length suff) str
1048             | otherwise             = str
1049
1050 bye :: String -> IO a
1051 bye s = putStr s >> exitWith ExitSuccess
1052
1053 die :: String -> IO a
1054 die s = do
1055   hFlush stdout
1056   prog <- getProgramName
1057   hPutStrLn stderr (prog ++ ": " ++ s)
1058   exitWith (ExitFailure 1)
1059
1060 dieOrForce :: Bool -> String -> IO ()
1061 dieOrForce force s
1062   | force     = do hFlush stdout; hPutStrLn stderr (s ++ " (ignoring)")
1063   | otherwise = die (s ++ " (use --force to override)")
1064
1065 diePretty :: Doc -> IO ()
1066 diePretty doc = do
1067   hFlush stdout
1068   prog <- getProgramName
1069   hPutStrLn stderr $ render $ (text prog <> colon $$ nest 2 doc)
1070   exitWith (ExitFailure 1)
1071
1072 diePrettyOrForce :: Bool -> Doc -> IO ()
1073 diePrettyOrForce force doc
1074   | force     = do hFlush stdout; hPutStrLn stderr (render (doc $$  text "(ignoring)"))
1075   | otherwise = diePretty (doc $$ text "(use --force to override)")
1076
1077 -----------------------------------------
1078 --      Cut and pasted from ghc/compiler/SysTools
1079
1080 #if defined(mingw32_HOST_OS)
1081 subst a b ls = map (\ x -> if x == a then b else x) ls
1082 unDosifyPath xs = subst '\\' '/' xs
1083
1084 getExecDir :: String -> IO (Maybe String)
1085 -- (getExecDir cmd) returns the directory in which the current
1086 --                  executable, which should be called 'cmd', is running
1087 -- So if the full path is /a/b/c/d/e, and you pass "d/e" as cmd,
1088 -- you'll get "/a/b/c" back as the result
1089 getExecDir cmd
1090   = allocaArray len $ \buf -> do
1091         ret <- getModuleFileName nullPtr buf len
1092         if ret == 0 then return Nothing
1093                     else do s <- peekCString buf
1094                             return (Just (reverse (drop (length cmd)
1095                                                         (reverse (unDosifyPath s)))))
1096   where
1097     len = 2048::Int -- Plenty, PATH_MAX is 512 under Win32.
1098
1099 foreign import stdcall unsafe  "GetModuleFileNameA"
1100   getModuleFileName :: Ptr () -> CString -> Int -> IO Int32
1101 #else
1102 getExecDir :: String -> IO (Maybe String)
1103 getExecDir _ = return Nothing
1104 #endif
1105
1106 -- -----------------------------------------------------------------------------
1107 -- FilePath utils
1108
1109 -- | The 'joinFileName' function is the opposite of 'splitFileName'.
1110 -- It joins directory and file names to form a complete file path.
1111 --
1112 -- The general rule is:
1113 --
1114 -- > dir `joinFileName` basename == path
1115 -- >   where
1116 -- >     (dir,basename) = splitFileName path
1117 --
1118 -- There might be an exceptions to the rule but in any case the
1119 -- reconstructed path will refer to the same object (file or directory).
1120 -- An example exception is that on Windows some slashes might be converted
1121 -- to backslashes.
1122 joinFileName :: String -> String -> FilePath
1123 joinFileName ""  fname = fname
1124 joinFileName "." fname = fname
1125 joinFileName dir ""    = dir
1126 joinFileName dir fname
1127   | isPathSeparator (last dir) = dir++fname
1128   | otherwise                  = dir++pathSeparator:fname
1129
1130 -- | Checks whether the character is a valid path separator for the host
1131 -- platform. The valid character is a 'pathSeparator' but since the Windows
1132 -- operating system also accepts a slash (\"\/\") since DOS 2, the function
1133 -- checks for it on this platform, too.
1134 isPathSeparator :: Char -> Bool
1135 isPathSeparator ch = ch == pathSeparator || ch == '/'
1136
1137 -- | Provides a platform-specific character used to separate directory levels in
1138 -- a path string that reflects a hierarchical file system organization. The
1139 -- separator is a slash (@\"\/\"@) on Unix and Macintosh, and a backslash
1140 -- (@\"\\\"@) on the Windows operating system.
1141 pathSeparator :: Char
1142 #ifdef mingw32_HOST_OS
1143 pathSeparator = '\\'
1144 #else
1145 pathSeparator = '/'
1146 #endif
1147
1148 -- | The function splits the given string to substrings
1149 -- using the 'searchPathSeparator'.
1150 parseSearchPath :: String -> [FilePath]
1151 parseSearchPath path = split path
1152   where
1153     split :: String -> [String]
1154     split s =
1155       case rest' of
1156         []     -> [chunk]
1157         _:rest -> chunk : split rest
1158       where
1159         chunk =
1160           case chunk' of
1161 #ifdef mingw32_HOST_OS
1162             ('\"':xs@(_:_)) | last xs == '\"' -> init xs
1163 #endif
1164             _                                 -> chunk'
1165
1166         (chunk', rest') = break (==searchPathSeparator) s
1167
1168 -- | A platform-specific character used to separate search path strings in
1169 -- environment variables. The separator is a colon (\":\") on Unix and Macintosh,
1170 -- and a semicolon (\";\") on the Windows operating system.
1171 searchPathSeparator :: Char
1172 #if mingw32_HOST_OS || mingw32_TARGET_OS
1173 searchPathSeparator = ';'
1174 #else
1175 searchPathSeparator = ':'
1176 #endif
1177