src/org/ibex/nestedvm/linker.ld

   1 ENTRY(_start)
   2 INPUT(support.o support_aux.o)
   3 GROUP(-lc -lgcc)
   4 /*GROUP(-lgcc)*/
   5 __DYNAMIC  =  0;
   6
   7 SECTIONS {
   8   . = 0x10000;
   9   .text : {
  10     KEEP(*(.init))
  11     KEEP(*(.fini))
  12     KEEP(*(.text))
  13     *(.text.*)
  14     *(.gnu.linkonce.t*)
  15   }
  16
  17   _etext = .;
  18
  19   .ctors :
  20   {
  21     KEEP (*crtbegin.o(.ctors))
  22     KEEP (*(EXCLUDE_FILE (*crtend.o) .ctors))
  23     KEEP (*(SORT(.ctors.*)))
  24     KEEP (*(.ctors))
  25   }
  26
  27   .dtors :
  28   {
  29     KEEP (*crtbegin.o(.dtors))
  30     KEEP (*(EXCLUDE_FILE (*crtend.o) .dtors))
  31     KEEP (*(SORT(.dtors.*)))
  32     KEEP (*(.dtors))
  33   }
  34
  35   . = ALIGN(4k);
  36
  37   .rodata : {
  38     *(.rodata*) *(.gnu.linkonce.r*)
  39     *(.gcc_except_table)
  40     KEEP(*(.eh_frame)) KEEP(*(.jcr))
  41   }
  42
  43   .data : {
  44     *(.data*) *(.gnu.linkonce.d*)
  45   }
  46
  47   . = ALIGN(16);
  48    _gp = . + 0x8000;
  49   .sdata : {
  50     *(.rosdata*) *(.sdata*) *(.gnu.linkonce.s*)
  51   }
  52   .sbss : {
  53     *(.sbss*) *(.scommon*)
  54   }
  55   .bss : {
  56     *(.bss*) *(.gnu.linkonce.b*) *(COMMON)
  57   }
  58
  59   _end = .;
  60 }