tests/meta.g

   1 s         ::=  ws grammar ws                  => "gram"
   2 ws       !::=  w**
   3 grammar   ::=  r +/ ws                        => "grammar"
   4 r         ::=  word  ^"::=" alternatives /ws
   5             |  word ^"!::=" alternatives /ws
   6
   7 alternatives  ::=  equiAlt   +/ (ws ">" ws)
   8 equiAlt       ::=  conjuncts +/ (ws "|" ws)
   9
  10 conjuncts   ::=  sequence
  11               |  sequence ^"&"  e*/ws   /ws
  12               |  sequence ^"&~" e*/ws   /ws
  13
  14 sequence    ::= e*/ws
  15                 (ws "/" e)?
  16                 (ws "=>" ws (word|quoted))?              => "seq"
  17
  18 ec       ::= [~\-\]\\\~]
  19            | escaped
  20
  21 range    ::= ec          => "range"
  22            | ec ^"-" ec
  23
  24 e        ::= word                           => "nonTerminal"
  25            |  quoted                        => "literal"
  26            |    ^"()"
  27            |    ^"{" sequence "}"   /ws
  28            |    ^"["  (range*) "]"
  29            |    ^"[~" (range*) "]"
  30            |    ^"^" quoted             /ws
  31            |    ^"!" e                  /ws
  32
  33            |  (e ws ^"**" > e ws ^"*")
  34            |  e ^"*/" e                 /ws
  35            |  (e ws ^"++" > e ws ^"+")
  36            |  e ^"+/" e                 /ws
  37            |  e ^"?"                    /ws
  38
  39            |     "(" word         ^")"  /ws
  40            >    ^"(" alternatives  ")"  /ws
  41
  42 w       !::= " "
  43            | "//" ([~\n]*) "\n"
  44            | "\n"
  45            | "\r"
  46 word     ::= [a-zA-Z0-9_]++
  47 quoted   ::= "\"" (([~\"\\] | escaped)+) "\""
  48            | "\"\"" => ""
  49 escaped  ::= "\\n" => "\n"
  50            | "\\r" => "\r"
  51            | "\\" [~nr]
  52
  53