tests/meta.g

   1 s         ::=  ws grammar ws                  => "gram"
   2 ws       !::=  w** | w** "//" (~[\n]*) "\n" ws
   3 wp       !::=  w++
   4 grammar   ::=  r +/ ws                        => "grammar"
   5
   6 r         ::=  word  ^"::=" alternatives /ws
   7             |  word ^"!::=" alternatives /ws
   8
   9 alternatives  ::=  (conjuncts +/ (ws "|" ws)) +/ (ws ">" ws)
  10
  11 conjuncts     ::=  sequence
  12                 |  sequence ^"&"  e*/ws   /ws
  13                 |  sequence ^"&~" e*/ws   /ws
  14
  15 ps         ::= e*/ws                              => "ps"
  16              | (e+/ws ws)? "^" quoted (ws e+/ws)? => "ps2"
  17 psy        ::= ps
  18              | ps wp ^"/" ws e
  19 psx        ::= psy ^"?=>" e /ws
  20              | psy ^"!=>" e /ws
  21              > psy
  22 sequence   ::= quoted => "qprod"
  23              > psx
  24              | psx ^"=>" (word|quoted) /ws
  25
  26 ec       ::= [~\-\]\\\~]
  27            | escaped
  28
  29 range    ::= ec          => "range"
  30            | ec ^"-" ec
  31
  32 e        ::=  word                          => "nonTerminal"
  33            |  quoted                        => "literal"
  34            |    ^"()"
  35            |    ^"{" sequence "}"       /ws
  36            |    ^"["  range* "]"
  37            |    ^"[~" range* "]"
  38
  39            |  (e ^"++"    /ws > e ^"+"    /ws)
  40            |  (e ^"++/" e /ws > e ^"+/" e /ws)
  41            |  (e ^"**"    /ws > e ^"*"    /ws)
  42            |  (e ^"**/" e /ws > e ^"*/" e /ws)
  43            |  e ^"?"                    /ws
  44
  45            |     "(" word         ^")"  /ws
  46            >    ^"(" alternatives  ")"  /ws
  47 w       !::= " "
  48            | "\n"
  49            | "\r"
  50 word     ::= [a-zA-Z0-9_]++
  51 quoted   ::= "\"" (([~\"\\] | escaped)+) "\""
  52            | "\"\"" => ""
  53 escaped  ::= "\\n" => "\n"
  54            | "\\r" => "\r"
  55            | "\\" [~nr]
  56
  57