tests/meta.g

   1 s         ::=  ws grammar ws                  => "gram"
   2 ws       !::=  w**
   3 grammar   ::=  r$$ws => "grammar"
   4 r         ::=  word  ^"::=" alternatives /ws
   5             |  word ^"!::=" alternatives /ws
   6
   7 ec        ::=  [~\]\\\-\~] | escaped
   8
   9 alternatives  ::=  equiAlt   $$ (ws ">" ws)
  10 equiAlt       ::=  conjuncts $$ (ws "|" ws)          => "alternatives"
  11
  12 sequence    ::= Es
  13               > Es ^"/" e  /ws
  14 Es          ::= e+
  15 es          ::= e$$ws
  16
  17
  18 conjuncts   ::=  rewrite
  19               |  rewrite ^"&"  sequence   /ws
  20               |  rewrite ^"&~" sequence   /ws
  21
  22 rewrite  ::=  sequence                  /ws        => "rewrite"
  23            |  sequence ^"=>" word       /ws
  24            |  sequence ^"=>" quoted     /ws
  25            |  sequence  "=>" "()"       /ws        => "wrap"
  26
  27 range    ::= ec          => "range0"
  28            | ec ^"-" ec  => "range0"
  29
  30 e        ::= word                             => "nonTerminalY"
  31            |    [(][)] => "epsilon"
  32            |    ^"{" alternatives "}"   /ws
  33            |     "[" [\~]?  range* "]"        => "range"
  34            |  e ^"%%" e                 /ws
  35            |  e ^"$$" e                 /ws
  36            |  e ^"?"                    /ws
  37            |  e ^"~/~"                  /ws
  38
  39            |  e ^"-"  e                 /ws
  40
  41            |    ^"!" e                  /ws
  42            |     "^" quoted             /ws => "care"
  43            |    ^"`" e                  /ws
  44            |  e ^"#"                    /ws
  45            |  quoted                        => "literal"
  46
  47            |  (e ws ^"**" > e ws ^"*")
  48            |  (e ws ^"++" > e ws ^"+")
  49
  50            |     "(" word ^")"          /ws
  51            >    ^"(" alternatives ")"   /ws
  52
  53 w       !::= " "
  54            | "//" [~\n]* "\n"
  55            | "\n"
  56            | "\r"
  57 an       ::= [a-zA-Z0-9_]
  58 word     ::= an++                           => "sify"
  59 quoted   ::= "\"" ([~\"\\] | escaped)* "\"" => "sify"
  60 escaped  ::= "\\n" => "\n"
  61            | "\\r" => "\r"
  62            | "\\" [~nr]
  63
  64