tests/meta.g

   1 s         ::=  ws grammar ws                  => "gram"
   2 ws       !::=  w**
   3 grammar   ::=  r +/ ws                        => "grammar"
   4 r         ::=  word  ^"::=" alternatives /ws
   5             |  word ^"!::=" alternatives /ws
   6
   7 alternatives  ::=  equiAlt   +/ (ws ">" ws)
   8 equiAlt       ::=  conjuncts +/ (ws "|" ws)
   9
  10 sequence    ::= es
  11               > es ws ^"/" e
  12 es          ::= e */ (w**)
  13
  14 ss ::= es => "seq" | es ^"/" e /ws
  15
  16 conjuncts   ::=  rewrite
  17               |  rewrite ^"&"  e*/ws   /ws
  18               |  rewrite ^"&~" e*/ws   /ws
  19
  20 rewrite  ::=  sequence                     /ws        => "rewrite"
  21            |  sequence ^"=>" (word|quoted) /ws
  22
  23 ec       ::= [~\-\]\\\~]
  24            | escaped
  25
  26 range    ::= ec          => "range"
  27            | ec ^"-" ec
  28
  29 e        ::= word                             => "nonTerminal"
  30            |    [(][)]                        => "epsilon"
  31            |    ^"{" alternatives "}"   /ws
  32            |    ^"["  (range*) "]"
  33            |    ^"[~" (range*) "]"
  34            |    ^"^" quoted             /ws
  35            |    ^"!" e                  /ws
  36
  37            |  (e ws ^"**" > e ws ^"*")
  38            |  e ^"*/" e                 /ws
  39            |  (e ws ^"++" > e ws ^"+")
  40            |  e ^"+/" e                 /ws
  41            |  e ^"?"                    /ws
  42
  43            |  quoted                        => "literal"
  44
  45            |     "(" word ^")"          /ws
  46            >    ^"(" alternatives ")"   /ws
  47
  48 w       !::= " "
  49            | "//" ([~\n]*) "\n"
  50            | "\n"
  51            | "\r"
  52 an       ::= [a-zA-Z0-9_]
  53 word     ::= an++
  54 quoted   ::= "\"" (([~\"\\] | escaped)+) "\""
  55            | "\"\"" => ""
  56 escaped  ::= "\\n" => "\n"
  57            | "\\r" => "\r"
  58            | "\\" [~nr]
  59
  60