s         ::=  ws grammar ws                  => "gram"
ws       !::=  w**
grammar   ::=  r+/ws => "grammar"
r         ::=  word  ^"::=" alternatives /ws
            |  word ^"!::=" alternatives /ws

ec        ::=  [~\]\\\-\~] | escaped

alternatives  ::=  equiAlt   +/ (ws ">" ws)
equiAlt       ::=  conjuncts +/ (ws "|" ws)          => "alternatives"

sequence    ::= Es
              > Es ^"/" e  /ws
Es          ::= e+
//es          ::= e+/ws


conjuncts   ::=  rewrite
              |  rewrite ^"&"  sequence   /ws
              |  rewrite ^"&~" sequence   /ws

rewrite  ::=  sequence                  /ws        => "rewrite"
           |  sequence ^"=>" word       /ws
           |  sequence ^"=>" quoted     /ws
           |  sequence  "=>" "()"       /ws        => "wrap"

range    ::= ec          => "range0"
           | ec ^"-" ec  => "range0"

e        ::= word                             => "nonTerminalY"
           |    [(][)] => "epsilon"
           |    ^"{" alternatives "}"   /ws
           |     "[" [\~]?  range* "]"        => "range"
           |  e ^"*/" e                 /ws
           |  e ^"%%" e                 /ws
           |  e ^"+/" e                 /ws
           |  e ^"?"                    /ws
           |  e ^"~/~"                  /ws

           |  e ^"-"  e                 /ws

           |    ^"!" e                  /ws
           |     "^" quoted             /ws => "care"
           |    ^"`" e                  /ws
           |  e ^"#"                    /ws
           |  quoted                        => "literal"

           |  (e ws ^"**" > e ws ^"*")
           |  (e ws ^"++" > e ws ^"+")

           |     "(" word ^")"          /ws
           >    ^"(" alternatives ")"   /ws

w       !::= " "
           | "//" [~\n]* "\n"
           | "\n"
           | "\r"
an       ::= [a-zA-Z0-9_]
word     ::= an++                           => "sify"
quoted   ::= "\"" ([~\"\\] | escaped)* "\"" => "sify"
escaped  ::= "\\n" => "\n"
           | "\\r" => "\r"
           | "\\" [~nr]