s             =  ws gram:Grammar ws
Grammar       =  grammar:: NonTerminal +/ ws
NonTerminal   =            word  !wp ^"=" !wp RHS
        
RHS           =  (Sequence +/ (!ws "|" !ws)) +/ (!ws ">" !ws)

Elements      =  e*/ws

PreSequence   = ps::  Elements
              |       PreSequence !wp ^"/"  !ws e
              |       PreSequence     ^"->"     e /ws
              |       (Quoted|word)   ^"::" PreSequence /ws

Sequence      = psx:: PreSequence
              |       Sequence !ws ^"&"  !ws Elements
              |       Sequence !ws ^"&~" !ws Elements

ec            = ~[\-\]\\]
              | escaped

Range         = range:: ec
              |         ec ^"-" ec

e             =                (Quoted|word) ^":" e
              > nonTerminal::          word
              | literal::       Quoted
              |                  ^"()"
              |                  ^"{" Sequence "}"       /ws
              |                  ^"["  Range* "]"
              |                e ^"++"                   /ws -> ~[/]
              |                e ^"+"                    /ws -> ~[+]
              |                e ^"++/" e                /ws        
              |                e ^"+/"  e                /ws        
              |                e ^"**"                   /ws -> ~[/]
              |                e ^"*"                    /ws -> ~[*]
              |                e ^"**/" e                /ws        
              |                e ^"*/"  e                /ws        
              |                  ^"!"   e                /ws
              |                e ^"?"                    /ws
              |                  ^"^"   Quoted
              |     "(" word     ^")"                    /ws
              >                  ^"(" RHS  ")"           /ws
              |                  ^"~" e
              >  "^^"::           "^"   e

word       = [a-zA-Z0-9_]++
Quoted     = "\"" ((~[\"\\] | escaped)+) "\""
           | ""::   "\"\""
escaped    = "\n":: "\\n"
           | "\r":: "\\r"
           |        "\\" ~[nr]


w             = " " | "\n" | "\r"
ws            =  "()":: w**
              |  "()":: w** "//" ~[\n]* "\n" ws
wp            =  w++