s ::= ws grammar ws => "gram"
ws !::= w**
wp !::= w++
grammar ::= r +/ ws => "grammar"
r ::= word ^"::=" alternatives /ws
| word ^"!::=" alternatives /ws
alternatives ::= (conjuncts +/ (ws "|" ws)) +/ (ws ">" ws)
conjuncts ::= sequence
| sequence ^"&" e*/ws /ws
| sequence ^"&~" e*/ws /ws
ps ::= e*/ws => "ps"
| (e+/ws ws)? "^" quoted (ws e+/ws)? => "ps2"
psy ::= ps
| ps wp ^"/" ws e
psx ::= psy ^"?=>" e /ws
| psy ^"!=>" e /ws
> psy
sequence ::= quoted => "qprod"
> psx
| psx ^"=>" (word|quoted) /ws
ec ::= [~\-\]\\\~]
| escaped
range ::= ec => "range"
| ec ^"-" ec
e ::= word => "nonTerminal"
| quoted => "literal"
| ^"()"
| ^"{" sequence "}" /ws
| ^"[" range* "]"
| ^"[~" range* "]"
| (e ^"++" /ws > e ^"+" /ws)
| (e ^"++/" e /ws > e ^"+/" e /ws)
| (e ^"**" /ws > e ^"*" /ws)
| (e ^"**/" e /ws > e ^"*/" e /ws)
| e ^"?" /ws
| "(" word ^")" /ws
> ^"(" alternatives ")" /ws
w !::= " "
| "//" ([~\n]*) "\n"
| "\n"
| "\r"
word ::= [a-zA-Z0-9_]+ !=> [a-zA-Z0-9_]
quoted ::= "\"" (([~\"\\] | escaped)+) "\""
| "\"\"" => ""
escaped ::= "\\n" => "\n"
| "\\r" => "\r"
| "\\" [~nr]