s             =  gram::    !ws Grammar ws
Grammar       =  grammar:: NonTerminal +/ ws
NonTerminal   =            word  !wp ^"=" !wp RHS
        
RHS           =  (Conjuncts +/ (!ws "|" !ws)) +/ (!ws ">" !ws)

Conjuncts     =  Sequence
              |  Sequence ^"&"  Elements  /ws
              |  Sequence ^"&~" Elements  /ws
Elements      =  e*/ws

PreSequence   = ps::  Elements
              |       PreSequence !wp ^"/"  !ws e
              |       PreSequence     ^"->"     e /ws
              |       (Quoted|word)   ^"::" PreSequence /ws
              |       PreSequence     ^"=>" ("[]"|"()"|word|Quoted) /ws
Sequence      = psx:: PreSequence

ec            = ~[\-\]\\]
              | escaped

Range         = range:: ec
              |         ec ^"-" ec

e             =                (Quoted|word) ^":" e
              > nonTerminal::          word
              | literal::       Quoted
              |                  ^"()"
              |                  ^"{" Sequence "}"       /ws
              |                  ^"["  Range* "]"
              |                e ^"++"                   /ws -> ~[/]
              |                e ^"+"                    /ws -> ~[+]
              |                e ^"++/" e                /ws        
              |                e ^"+/"  e                /ws        
              |                e ^"**"                   /ws -> ~[/]
              |                e ^"*"                    /ws -> ~[*]
              |                e ^"**/" e                /ws        
              |                e ^"*/"  e                /ws        
              |                  ^"!"   e                /ws
              |                e ^"?"                    /ws
              |                  ^"^" Quoted             /ws

              |                   "(" word         ^")"  /ws
              >                  ^"(" RHS  ")"           /ws
              |                  ^"~" e

word       = [a-zA-Z0-9_]++
Quoted     = "\"" ((~[\"\\] | escaped)+) "\""
           | ""::   "\"\""
escaped    = "\n":: "\\n"
           | "\r":: "\\r"
           |        "\\" ~[nr]


w             = " " | "\n" | "\r"
ws            =  w** => ()
              |  w** "//" ~[\n]* "\n" ws => ()
wp            =  w++