Control/Concurrent.hs

   1 -----------------------------------------------------------------------------
   2 -- |
   3 -- Module      :  Control.Concurrent
   4 -- Copyright   :  (c) The University of Glasgow 2001
   5 -- License     :  BSD-style (see the file libraries/base/LICENSE)
   6 --
   7 -- Maintainer  :  libraries@haskell.org
   8 -- Stability   :  experimental
   9 -- Portability :  non-portable (concurrency)
  10 --
  11 -- A common interface to a collection of useful concurrency
  12 -- abstractions.
  13 --
  14 -----------------------------------------------------------------------------
  15
  16 module Control.Concurrent (
  17         -- * Concurrent Haskell
  18
  19         -- $conc_intro
  20
  21         -- * Basic concurrency operations
  22
  23         ThreadId,
  24 #ifdef __GLASGOW_HASKELL__
  25         myThreadId,
  26 #endif
  27
  28         forkIO,
  29 #ifdef __GLASGOW_HASKELL__
  30         killThread,
  31         throwTo,
  32 #endif
  33
  34         -- * Scheduling
  35
  36         -- $conc_scheduling
  37         yield,                  -- :: IO ()
  38
  39         -- ** Blocking
  40
  41         -- $blocking
  42
  43 #ifdef __GLASGOW_HASKELL__
  44         -- ** Waiting
  45         threadDelay,            -- :: Int -> IO ()
  46         threadWaitRead,         -- :: Int -> IO ()
  47         threadWaitWrite,        -- :: Int -> IO ()
  48 #endif
  49
  50         -- * Communication abstractions
  51
  52         module Control.Concurrent.MVar,
  53         module Control.Concurrent.Chan,
  54         module Control.Concurrent.QSem,
  55         module Control.Concurrent.QSemN,
  56         module Control.Concurrent.SampleVar,
  57
  58         -- * Merging of streams
  59 #ifndef __HUGS__
  60         mergeIO,                -- :: [a]   -> [a] -> IO [a]
  61         nmergeIO,               -- :: [[a]] -> IO [a]
  62 #endif
  63         -- $merge
  64
  65 #ifdef __GLASGOW_HASKELL__
  66         -- * Bound Threads
  67         -- $boundthreads
  68         rtsSupportsBoundThreads,
  69         forkOS,
  70         isCurrentThreadBound,
  71         runInBoundThread,
  72         runInUnboundThread
  73 #endif
  74
  75         -- * GHC's implementation of concurrency
  76
  77         -- |This section describes features specific to GHC's
  78         -- implementation of Concurrent Haskell.
  79
  80         -- ** Haskell threads and Operating System threads
  81
  82         -- $osthreads
  83
  84         -- ** Terminating the program
  85
  86         -- $termination
  87
  88         -- ** Pre-emption
  89
  90         -- $preemption
  91     ) where
  92
  93 import Prelude
  94
  95 import Control.Exception.Base as Exception
  96
  97 #ifdef __GLASGOW_HASKELL__
  98 import GHC.Exception
  99 import GHC.Conc         ( ThreadId(..), myThreadId, killThread, yield,
 100                           threadDelay, forkIO, childHandler )
 101 import qualified GHC.Conc
 102 import GHC.IOBase       ( IO(..) )
 103 import GHC.IOBase       ( unsafeInterleaveIO )
 104 import GHC.IOBase       ( newIORef, readIORef, writeIORef )
 105 import GHC.Base
 106
 107 import System.Posix.Types ( Fd )
 108 import Foreign.StablePtr
 109 import Foreign.C.Types  ( CInt )
 110 import Control.Monad    ( when )
 111
 112 #ifdef mingw32_HOST_OS
 113 import Foreign.C
 114 import System.IO
 115 import GHC.Handle
 116 #endif
 117 #endif
 118
 119 #ifdef __HUGS__
 120 import Hugs.ConcBase
 121 #endif
 122
 123 import Control.Concurrent.MVar
 124 import Control.Concurrent.Chan
 125 import Control.Concurrent.QSem
 126 import Control.Concurrent.QSemN
 127 import Control.Concurrent.SampleVar
 128
 129 #ifdef __HUGS__
 130 type ThreadId = ()
 131 #endif
 132
 133 {- $conc_intro
 134
 135 The concurrency extension for Haskell is described in the paper
 136 /Concurrent Haskell/
 137 <http://www.haskell.org/ghc/docs/papers/concurrent-haskell.ps.gz>.
 138
 139 Concurrency is \"lightweight\", which means that both thread creation
 140 and context switching overheads are extremely low.  Scheduling of
 141 Haskell threads is done internally in the Haskell runtime system, and
 142 doesn't make use of any operating system-supplied thread packages.
 143
 144 However, if you want to interact with a foreign library that expects your
 145 program to use the operating system-supplied thread package, you can do so
 146 by using 'forkOS' instead of 'forkIO'.
 147
 148 Haskell threads can communicate via 'MVar's, a kind of synchronised
 149 mutable variable (see "Control.Concurrent.MVar").  Several common
 150 concurrency abstractions can be built from 'MVar's, and these are
 151 provided by the "Control.Concurrent" library.
 152 In GHC, threads may also communicate via exceptions.
 153 -}
 154
 155 {- $conc_scheduling
 156
 157     Scheduling may be either pre-emptive or co-operative,
 158     depending on the implementation of Concurrent Haskell (see below
 159     for information related to specific compilers).  In a co-operative
 160     system, context switches only occur when you use one of the
 161     primitives defined in this module.  This means that programs such
 162     as:
 163
 164
 165 >   main = forkIO (write 'a') >> write 'b'
 166 >     where write c = putChar c >> write c
 167
 168     will print either @aaaaaaaaaaaaaa...@ or @bbbbbbbbbbbb...@,
 169     instead of some random interleaving of @a@s and @b@s.  In
 170     practice, cooperative multitasking is sufficient for writing
 171     simple graphical user interfaces.
 172 -}
 173
 174 {- $blocking
 175 Different Haskell implementations have different characteristics with
 176 regard to which operations block /all/ threads.
 177
 178 Using GHC without the @-threaded@ option, all foreign calls will block
 179 all other Haskell threads in the system, although I\/O operations will
 180 not.  With the @-threaded@ option, only foreign calls with the @unsafe@
 181 attribute will block all other threads.
 182
 183 Using Hugs, all I\/O operations and foreign calls will block all other
 184 Haskell threads.
 185 -}
 186
 187 #ifndef __HUGS__
 188 max_buff_size :: Int
 189 max_buff_size = 1
 190
 191 mergeIO :: [a] -> [a] -> IO [a]
 192 nmergeIO :: [[a]] -> IO [a]
 193
 194 -- $merge
 195 -- The 'mergeIO' and 'nmergeIO' functions fork one thread for each
 196 -- input list that concurrently evaluates that list; the results are
 197 -- merged into a single output list.
 198 --
 199 -- Note: Hugs does not provide these functions, since they require
 200 -- preemptive multitasking.
 201
 202 mergeIO ls rs
 203  = newEmptyMVar                >>= \ tail_node ->
 204    newMVar tail_node           >>= \ tail_list ->
 205    newQSem max_buff_size       >>= \ e ->
 206    newMVar 2                   >>= \ branches_running ->
 207    let
 208     buff = (tail_list,e)
 209    in
 210     forkIO (suckIO branches_running buff ls) >>
 211     forkIO (suckIO branches_running buff rs) >>
 212     takeMVar tail_node  >>= \ val ->
 213     signalQSem e        >>
 214     return val
 215
 216 type Buffer a
 217  = (MVar (MVar [a]), QSem)
 218
 219 suckIO :: MVar Int -> Buffer a -> [a] -> IO ()
 220
 221 suckIO branches_running buff@(tail_list,e) vs
 222  = case vs of
 223         [] -> takeMVar branches_running >>= \ val ->
 224               if val == 1 then
 225                  takeMVar tail_list     >>= \ node ->
 226                  putMVar node []        >>
 227                  putMVar tail_list node
 228               else
 229                  putMVar branches_running (val-1)
 230         (x:xs) ->
 231                 waitQSem e                       >>
 232                 takeMVar tail_list               >>= \ node ->
 233                 newEmptyMVar                     >>= \ next_node ->
 234                 unsafeInterleaveIO (
 235                         takeMVar next_node  >>= \ y ->
 236                         signalQSem e        >>
 237                         return y)                >>= \ next_node_val ->
 238                 putMVar node (x:next_node_val)   >>
 239                 putMVar tail_list next_node      >>
 240                 suckIO branches_running buff xs
 241
 242 nmergeIO lss
 243  = let
 244     len = length lss
 245    in
 246     newEmptyMVar          >>= \ tail_node ->
 247     newMVar tail_node     >>= \ tail_list ->
 248     newQSem max_buff_size >>= \ e ->
 249     newMVar len           >>= \ branches_running ->
 250     let
 251      buff = (tail_list,e)
 252     in
 253     mapIO (\ x -> forkIO (suckIO branches_running buff x)) lss >>
 254     takeMVar tail_node  >>= \ val ->
 255     signalQSem e        >>
 256     return val
 257   where
 258     mapIO f xs = sequence (map f xs)
 259 #endif /* __HUGS__ */
 260
 261 #ifdef __GLASGOW_HASKELL__
 262 -- ---------------------------------------------------------------------------
 263 -- Bound Threads
 264
 265 {- $boundthreads
 266    #boundthreads#
 267
 268 Support for multiple operating system threads and bound threads as described
 269 below is currently only available in the GHC runtime system if you use the
 270 /-threaded/ option when linking.
 271
 272 Other Haskell systems do not currently support multiple operating system threads.
 273
 274 A bound thread is a haskell thread that is /bound/ to an operating system
 275 thread. While the bound thread is still scheduled by the Haskell run-time
 276 system, the operating system thread takes care of all the foreign calls made
 277 by the bound thread.
 278
 279 To a foreign library, the bound thread will look exactly like an ordinary
 280 operating system thread created using OS functions like @pthread_create@
 281 or @CreateThread@.
 282
 283 Bound threads can be created using the 'forkOS' function below. All foreign
 284 exported functions are run in a bound thread (bound to the OS thread that
 285 called the function). Also, the @main@ action of every Haskell program is
 286 run in a bound thread.
 287
 288 Why do we need this? Because if a foreign library is called from a thread
 289 created using 'forkIO', it won't have access to any /thread-local state/ -
 290 state variables that have specific values for each OS thread
 291 (see POSIX's @pthread_key_create@ or Win32's @TlsAlloc@). Therefore, some
 292 libraries (OpenGL, for example) will not work from a thread created using
 293 'forkIO'. They work fine in threads created using 'forkOS' or when called
 294 from @main@ or from a @foreign export@.
 295
 296 In terms of performance, 'forkOS' (aka bound) threads are much more
 297 expensive than 'forkIO' (aka unbound) threads, because a 'forkOS'
 298 thread is tied to a particular OS thread, whereas a 'forkIO' thread
 299 can be run by any OS thread.  Context-switching between a 'forkOS'
 300 thread and a 'forkIO' thread is many times more expensive than between
 301 two 'forkIO' threads.
 302
 303 Note in particular that the main program thread (the thread running
 304 @Main.main@) is always a bound thread, so for good concurrency
 305 performance you should ensure that the main thread is not doing
 306 repeated communication with other threads in the system.  Typically
 307 this means forking subthreads to do the work using 'forkIO', and
 308 waiting for the results in the main thread.
 309
 310 -}
 311
 312 -- | 'True' if bound threads are supported.
 313 -- If @rtsSupportsBoundThreads@ is 'False', 'isCurrentThreadBound'
 314 -- will always return 'False' and both 'forkOS' and 'runInBoundThread' will
 315 -- fail.
 316 foreign import ccall rtsSupportsBoundThreads :: Bool
 317
 318
 319 {- |
 320 Like 'forkIO', this sparks off a new thread to run the 'IO'
 321 computation passed as the first argument, and returns the 'ThreadId'
 322 of the newly created thread.
 323
 324 However, 'forkOS' creates a /bound/ thread, which is necessary if you
 325 need to call foreign (non-Haskell) libraries that make use of
 326 thread-local state, such as OpenGL (see "Control.Concurrent#boundthreads").
 327
 328 Using 'forkOS' instead of 'forkIO' makes no difference at all to the
 329 scheduling behaviour of the Haskell runtime system.  It is a common
 330 misconception that you need to use 'forkOS' instead of 'forkIO' to
 331 avoid blocking all the Haskell threads when making a foreign call;
 332 this isn't the case.  To allow foreign calls to be made without
 333 blocking all the Haskell threads (with GHC), it is only necessary to
 334 use the @-threaded@ option when linking your program, and to make sure
 335 the foreign import is not marked @unsafe@.
 336 -}
 337
 338 forkOS :: IO () -> IO ThreadId
 339
 340 foreign export ccall forkOS_entry
 341     :: StablePtr (IO ()) -> IO ()
 342
 343 foreign import ccall "forkOS_entry" forkOS_entry_reimported
 344     :: StablePtr (IO ()) -> IO ()
 345
 346 forkOS_entry :: StablePtr (IO ()) -> IO ()
 347 forkOS_entry stableAction = do
 348         action <- deRefStablePtr stableAction
 349         action
 350
 351 foreign import ccall forkOS_createThread
 352     :: StablePtr (IO ()) -> IO CInt
 353
 354 failNonThreaded :: IO a
 355 failNonThreaded = fail $ "RTS doesn't support multiple OS threads "
 356                        ++"(use ghc -threaded when linking)"
 357
 358 forkOS action0
 359     | rtsSupportsBoundThreads = do
 360         mv <- newEmptyMVar
 361         b <- Exception.blocked
 362         let
 363             -- async exceptions are blocked in the child if they are blocked
 364             -- in the parent, as for forkIO (see #1048). forkOS_createThread
 365             -- creates a thread with exceptions blocked by default.
 366             action1 | b = action0
 367                     | otherwise = unblock action0
 368
 369             action_plus = Exception.catch action1 childHandler
 370
 371         entry <- newStablePtr (myThreadId >>= putMVar mv >> action_plus)
 372         err <- forkOS_createThread entry
 373         when (err /= 0) $ fail "Cannot create OS thread."
 374         tid <- takeMVar mv
 375         freeStablePtr entry
 376         return tid
 377     | otherwise = failNonThreaded
 378
 379 -- | Returns 'True' if the calling thread is /bound/, that is, if it is
 380 -- safe to use foreign libraries that rely on thread-local state from the
 381 -- calling thread.
 382 isCurrentThreadBound :: IO Bool
 383 isCurrentThreadBound = IO $ \ s# ->
 384     case isCurrentThreadBound# s# of
 385         (# s2#, flg #) -> (# s2#, not (flg ==# 0#) #)
 386
 387
 388 {- |
 389 Run the 'IO' computation passed as the first argument. If the calling thread
 390 is not /bound/, a bound thread is created temporarily. @runInBoundThread@
 391 doesn't finish until the 'IO' computation finishes.
 392
 393 You can wrap a series of foreign function calls that rely on thread-local state
 394 with @runInBoundThread@ so that you can use them without knowing whether the
 395 current thread is /bound/.
 396 -}
 397 runInBoundThread :: IO a -> IO a
 398
 399 runInBoundThread action
 400     | rtsSupportsBoundThreads = do
 401         bound <- isCurrentThreadBound
 402         if bound
 403             then action
 404             else do
 405                 ref <- newIORef undefined
 406                 let action_plus = Exception.try action >>= writeIORef ref
 407                 resultOrException <-
 408                     bracket (newStablePtr action_plus)
 409                             freeStablePtr
 410                             (\cEntry -> forkOS_entry_reimported cEntry >> readIORef ref)
 411                 case resultOrException of
 412                     Left exception -> Exception.throw (exception :: SomeException)
 413                     Right result -> return result
 414     | otherwise = failNonThreaded
 415
 416 {- |
 417 Run the 'IO' computation passed as the first argument. If the calling thread
 418 is /bound/, an unbound thread is created temporarily using 'forkIO'.
 419 @runInBoundThread@ doesn't finish until the 'IO' computation finishes.
 420
 421 Use this function /only/ in the rare case that you have actually observed a
 422 performance loss due to the use of bound threads. A program that
 423 doesn't need it's main thread to be bound and makes /heavy/ use of concurrency
 424 (e.g. a web server), might want to wrap it's @main@ action in
 425 @runInUnboundThread@.
 426 -}
 427 runInUnboundThread :: IO a -> IO a
 428
 429 runInUnboundThread action = do
 430     bound <- isCurrentThreadBound
 431     if bound
 432         then do
 433             mv <- newEmptyMVar
 434             forkIO (Exception.try action >>= putMVar mv)
 435             takeMVar mv >>= \ei -> case ei of
 436                 Left exception -> Exception.throw (exception :: SomeException)
 437                 Right result -> return result
 438         else action
 439
 440 #endif /* __GLASGOW_HASKELL__ */
 441
 442 #ifdef __GLASGOW_HASKELL__
 443 -- ---------------------------------------------------------------------------
 444 -- threadWaitRead/threadWaitWrite
 445
 446 -- | Block the current thread until data is available to read on the
 447 -- given file descriptor (GHC only).
 448 threadWaitRead :: Fd -> IO ()
 449 threadWaitRead fd
 450 #ifdef mingw32_HOST_OS
 451   -- we have no IO manager implementing threadWaitRead on Windows.
 452   -- fdReady does the right thing, but we have to call it in a
 453   -- separate thread, otherwise threadWaitRead won't be interruptible,
 454   -- and this only works with -threaded.
 455   | threaded  = withThread (waitFd fd 0)
 456   | otherwise = case fd of
 457                   0 -> do hWaitForInput stdin (-1); return ()
 458                         -- hWaitForInput does work properly, but we can only
 459                         -- do this for stdin since we know its FD.
 460                   _ -> error "threadWaitRead requires -threaded on Windows, or use System.IO.hWaitForInput"
 461 #else
 462   = GHC.Conc.threadWaitRead fd
 463 #endif
 464
 465 -- | Block the current thread until data can be written to the
 466 -- given file descriptor (GHC only).
 467 threadWaitWrite :: Fd -> IO ()
 468 threadWaitWrite fd
 469 #ifdef mingw32_HOST_OS
 470   | threaded  = withThread (waitFd fd 1)
 471   | otherwise = error "threadWaitWrite requires -threaded on Windows"
 472 #else
 473   = GHC.Conc.threadWaitWrite fd
 474 #endif
 475
 476 #ifdef mingw32_HOST_OS
 477 foreign import ccall unsafe "rtsSupportsBoundThreads" threaded :: Bool
 478
 479 withThread :: IO a -> IO a
 480 withThread io = do
 481   m <- newEmptyMVar
 482   forkIO $ try io >>= putMVar m
 483   x <- takeMVar m
 484   case x of
 485     Right a -> return a
 486     Left e  -> throwIO (e :: IOException)
 487
 488 waitFd :: Fd -> CInt -> IO ()
 489 waitFd fd write = do
 490    throwErrnoIfMinus1 "fdReady" $
 491         fdReady (fromIntegral fd) write (fromIntegral iNFINITE) 0
 492    return ()
 493
 494 iNFINITE = 0xFFFFFFFF :: CInt -- urgh
 495
 496 foreign import ccall safe "fdReady"
 497   fdReady :: CInt -> CInt -> CInt -> CInt -> IO CInt
 498 #endif
 499
 500 -- ---------------------------------------------------------------------------
 501 -- More docs
 502
 503 {- $osthreads
 504
 505       #osthreads# In GHC, threads created by 'forkIO' are lightweight threads, and
 506       are managed entirely by the GHC runtime.  Typically Haskell
 507       threads are an order of magnitude or two more efficient (in
 508       terms of both time and space) than operating system threads.
 509
 510       The downside of having lightweight threads is that only one can
 511       run at a time, so if one thread blocks in a foreign call, for
 512       example, the other threads cannot continue.  The GHC runtime
 513       works around this by making use of full OS threads where
 514       necessary.  When the program is built with the @-threaded@
 515       option (to link against the multithreaded version of the
 516       runtime), a thread making a @safe@ foreign call will not block
 517       the other threads in the system; another OS thread will take
 518       over running Haskell threads until the original call returns.
 519       The runtime maintains a pool of these /worker/ threads so that
 520       multiple Haskell threads can be involved in external calls
 521       simultaneously.
 522
 523       The "System.IO" library manages multiplexing in its own way.  On
 524       Windows systems it uses @safe@ foreign calls to ensure that
 525       threads doing I\/O operations don't block the whole runtime,
 526       whereas on Unix systems all the currently blocked I\/O reqwests
 527       are managed by a single thread (the /IO manager thread/) using
 528       @select@.
 529
 530       The runtime will run a Haskell thread using any of the available
 531       worker OS threads.  If you need control over which particular OS
 532       thread is used to run a given Haskell thread, perhaps because
 533       you need to call a foreign library that uses OS-thread-local
 534       state, then you need bound threads (see "Control.Concurrent#boundthreads").
 535
 536       If you don't use the @-threaded@ option, then the runtime does
 537       not make use of multiple OS threads.  Foreign calls will block
 538       all other running Haskell threads until the call returns.  The
 539       "System.IO" library still does multiplexing, so there can be multiple
 540       threads doing I\/O, and this is handled internally by the runtime using
 541       @select@.
 542 -}
 543
 544 {- $termination
 545
 546       In a standalone GHC program, only the main thread is
 547       required to terminate in order for the process to terminate.
 548       Thus all other forked threads will simply terminate at the same
 549       time as the main thread (the terminology for this kind of
 550       behaviour is \"daemonic threads\").
 551
 552       If you want the program to wait for child threads to
 553       finish before exiting, you need to program this yourself.  A
 554       simple mechanism is to have each child thread write to an
 555       'MVar' when it completes, and have the main
 556       thread wait on all the 'MVar's before
 557       exiting:
 558
 559 >   myForkIO :: IO () -> IO (MVar ())
 560 >   myForkIO io = do
 561 >     mvar <- newEmptyMVar
 562 >     forkIO (io `finally` putMVar mvar ())
 563 >     return mvar
 564
 565       Note that we use 'finally' from the
 566       "Control.Exception" module to make sure that the
 567       'MVar' is written to even if the thread dies or
 568       is killed for some reason.
 569
 570       A better method is to keep a global list of all child
 571       threads which we should wait for at the end of the program:
 572
 573 >    children :: MVar [MVar ()]
 574 >    children = unsafePerformIO (newMVar [])
 575 >
 576 >    waitForChildren :: IO ()
 577 >    waitForChildren = do
 578 >      cs <- takeMVar children
 579 >      case cs of
 580 >        []   -> return ()
 581 >        m:ms -> do
 582 >           putMVar children ms
 583 >           takeMVar m
 584 >           waitForChildren
 585 >
 586 >    forkChild :: IO () -> IO ThreadId
 587 >    forkChild io = do
 588 >        mvar <- newEmptyMVar
 589 >        childs <- takeMVar children
 590 >        putMVar children (mvar:childs)
 591 >        forkIO (io `finally` putMVar mvar ())
 592 >
 593 >     main =
 594 >       later waitForChildren $
 595 >       ...
 596
 597       The main thread principle also applies to calls to Haskell from
 598       outside, using @foreign export@.  When the @foreign export@ed
 599       function is invoked, it starts a new main thread, and it returns
 600       when this main thread terminates.  If the call causes new
 601       threads to be forked, they may remain in the system after the
 602       @foreign export@ed function has returned.
 603 -}
 604
 605 {- $preemption
 606
 607       GHC implements pre-emptive multitasking: the execution of
 608       threads are interleaved in a random fashion.  More specifically,
 609       a thread may be pre-empted whenever it allocates some memory,
 610       which unfortunately means that tight loops which do no
 611       allocation tend to lock out other threads (this only seems to
 612       happen with pathological benchmark-style code, however).
 613
 614       The rescheduling timer runs on a 20ms granularity by
 615       default, but this may be altered using the
 616       @-i\<n\>@ RTS option.  After a rescheduling
 617       \"tick\" the running thread is pre-empted as soon as
 618       possible.
 619
 620       One final note: the
 621       @aaaa@ @bbbb@ example may not
 622       work too well on GHC (see Scheduling, above), due
 623       to the locking on a 'System.IO.Handle'.  Only one thread
 624       may hold the lock on a 'System.IO.Handle' at any one
 625       time, so if a reschedule happens while a thread is holding the
 626       lock, the other thread won't be able to run.  The upshot is that
 627       the switch from @aaaa@ to
 628       @bbbbb@ happens infrequently.  It can be
 629       improved by lowering the reschedule tick period.  We also have a
 630       patch that causes a reschedule whenever a thread waiting on a
 631       lock is woken up, but haven't found it to be useful for anything
 632       other than this example :-)
 633 -}
 634 #endif /* __GLASGOW_HASKELL__ */