Control/Exception.hs

   1 -----------------------------------------------------------------------------
   2 -- |
   3 -- Module      :  Control.Exception
   4 -- Copyright   :  (c) The University of Glasgow 2001
   5 -- License     :  BSD-style (see the file libraries/base/LICENSE)
   6 --
   7 -- Maintainer  :  libraries@haskell.org
   8 -- Stability   :  experimental
   9 -- Portability :  non-portable (extended exceptions)
  10 --
  11 -- This module provides support for raising and catching both built-in
  12 -- and user-defined exceptions.
  13 --
  14 -- In addition to exceptions thrown by 'IO' operations, exceptions may
  15 -- be thrown by pure code (imprecise exceptions) or by external events
  16 -- (asynchronous exceptions), but may only be caught in the 'IO' monad.
  17 -- For more details, see:
  18 --
  19 --  * /A semantics for imprecise exceptions/, by Simon Peyton Jones,
  20 --    Alastair Reid, Tony Hoare, Simon Marlow, Fergus Henderson,
  21 --    in /PLDI'99/.
  22 --
  23 --  * /Asynchronous exceptions in Haskell/, by Simon Marlow, Simon Peyton
  24 --    Jones, Andy Moran and John Reppy, in /PLDI'01/.
  25 --
  26 -----------------------------------------------------------------------------
  27
  28 module Control.Exception (
  29
  30         -- * The Exception type
  31         Exception(..),          -- instance Eq, Ord, Show, Typeable
  32         IOException,            -- instance Eq, Ord, Show, Typeable
  33         ArithException(..),     -- instance Eq, Ord, Show, Typeable
  34         ArrayException(..),     -- instance Eq, Ord, Show, Typeable
  35         AsyncException(..),     -- instance Eq, Ord, Show, Typeable
  36
  37         -- * Throwing exceptions
  38         throwIO,        -- :: Exception -> IO a
  39         throw,          -- :: Exception -> a
  40         ioError,        -- :: IOError -> IO a
  41 #ifdef __GLASGOW_HASKELL__
  42         throwTo,        -- :: ThreadId -> Exception -> a
  43 #endif
  44
  45         -- * Catching Exceptions
  46
  47         -- |There are several functions for catching and examining
  48         -- exceptions; all of them may only be used from within the
  49         -- 'IO' monad.
  50
  51         -- ** The @catch@ functions
  52         catch,     -- :: IO a -> (Exception -> IO a) -> IO a
  53         catchJust, -- :: (Exception -> Maybe b) -> IO a -> (b -> IO a) -> IO a
  54
  55         -- ** The @handle@ functions
  56         handle,    -- :: (Exception -> IO a) -> IO a -> IO a
  57         handleJust,-- :: (Exception -> Maybe b) -> (b -> IO a) -> IO a -> IO a
  58
  59         -- ** The @try@ functions
  60         try,       -- :: IO a -> IO (Either Exception a)
  61         tryJust,   -- :: (Exception -> Maybe b) -> a    -> IO (Either b a)
  62
  63         -- ** The @evaluate@ function
  64         evaluate,  -- :: a -> IO a
  65
  66         -- ** The @mapException@ function
  67         mapException,           -- :: (Exception -> Exception) -> a -> a
  68
  69         -- ** Exception predicates
  70
  71         -- $preds
  72
  73         ioErrors,               -- :: Exception -> Maybe IOError
  74         arithExceptions,        -- :: Exception -> Maybe ArithException
  75         errorCalls,             -- :: Exception -> Maybe String
  76         dynExceptions,          -- :: Exception -> Maybe Dynamic
  77         assertions,             -- :: Exception -> Maybe String
  78         asyncExceptions,        -- :: Exception -> Maybe AsyncException
  79         userErrors,             -- :: Exception -> Maybe String
  80
  81         -- * Dynamic exceptions
  82
  83         -- $dynamic
  84         throwDyn,       -- :: Typeable ex => ex -> b
  85 #ifdef __GLASGOW_HASKELL__
  86         throwDynTo,     -- :: Typeable ex => ThreadId -> ex -> b
  87 #endif
  88         catchDyn,       -- :: Typeable ex => IO a -> (ex -> IO a) -> IO a
  89
  90         -- * Asynchronous Exceptions
  91
  92         -- $async
  93
  94         -- ** Asynchronous exception control
  95
  96         -- |The following two functions allow a thread to control delivery of
  97         -- asynchronous exceptions during a critical region.
  98
  99         block,          -- :: IO a -> IO a
 100         unblock,        -- :: IO a -> IO a
 101
 102         -- *** Applying @block@ to an exception handler
 103
 104         -- $block_handler
 105
 106         -- *** Interruptible operations
 107
 108         -- $interruptible
 109
 110         -- * Assertions
 111
 112         assert,         -- :: Bool -> a -> a
 113
 114         -- * Utilities
 115
 116         bracket,        -- :: IO a -> (a -> IO b) -> (a -> IO c) -> IO ()
 117         bracket_,       -- :: IO a -> IO b -> IO c -> IO ()
 118         bracketOnError,
 119
 120         finally,        -- :: IO a -> IO b -> IO a
 121
 122 #ifdef __GLASGOW_HASKELL__
 123         setUncaughtExceptionHandler,      -- :: (Exception -> IO ()) -> IO ()
 124         getUncaughtExceptionHandler       -- :: IO (Exception -> IO ())
 125 #endif
 126   ) where
 127
 128 #ifdef __GLASGOW_HASKELL__
 129 import GHC.Base         ( assert )
 130 import GHC.Exception    as ExceptionBase hiding (catch)
 131 import GHC.Conc         ( throwTo, ThreadId )
 132 import Data.IORef       ( IORef, newIORef, readIORef, writeIORef )
 133 import Foreign.C.String ( CString, withCString )
 134 import System.IO        ( stdout, hFlush )
 135 #endif
 136
 137 #ifdef __HUGS__
 138 import Hugs.Exception   as ExceptionBase
 139 #endif
 140
 141 import Prelude          hiding ( catch )
 142 import System.IO.Error  hiding ( catch, try )
 143 import System.IO.Unsafe (unsafePerformIO)
 144 import Data.Dynamic
 145
 146 -----------------------------------------------------------------------------
 147 -- Catching exceptions
 148
 149 -- |This is the simplest of the exception-catching functions.  It
 150 -- takes a single argument, runs it, and if an exception is raised
 151 -- the \"handler\" is executed, with the value of the exception passed as an
 152 -- argument.  Otherwise, the result is returned as normal.  For example:
 153 --
 154 -- >   catch (openFile f ReadMode)
 155 -- >       (\e -> hPutStr stderr (\"Couldn\'t open \"++f++\": \" ++ show e))
 156 --
 157 -- For catching exceptions in pure (non-'IO') expressions, see the
 158 -- function 'evaluate'.
 159 --
 160 -- Note that due to Haskell\'s unspecified evaluation order, an
 161 -- expression may return one of several possible exceptions: consider
 162 -- the expression @error \"urk\" + 1 \`div\` 0@.  Does
 163 -- 'catch' execute the handler passing
 164 -- @ErrorCall \"urk\"@, or @ArithError DivideByZero@?
 165 --
 166 -- The answer is \"either\": 'catch' makes a
 167 -- non-deterministic choice about which exception to catch.  If you
 168 -- call it again, you might get a different exception back.  This is
 169 -- ok, because 'catch' is an 'IO' computation.
 170 --
 171 -- Note that 'catch' catches all types of exceptions, and is generally
 172 -- used for \"cleaning up\" before passing on the exception using
 173 -- 'throwIO'.  It is not good practice to discard the exception and
 174 -- continue, without first checking the type of the exception (it
 175 -- might be a 'ThreadKilled', for example).  In this case it is usually better
 176 -- to use 'catchJust' and select the kinds of exceptions to catch.
 177 --
 178 -- Also note that the "Prelude" also exports a function called
 179 -- 'Prelude.catch' with a similar type to 'Control.Exception.catch',
 180 -- except that the "Prelude" version only catches the IO and user
 181 -- families of exceptions (as required by Haskell 98).  We recommend
 182 -- either hiding the "Prelude" version of
 183 -- 'Prelude.catch' when importing
 184 -- "Control.Exception", or importing
 185 -- "Control.Exception" qualified, to avoid name-clashes.
 186
 187 catch   :: IO a                 -- ^ The computation to run
 188         -> (Exception -> IO a)  -- ^ Handler to invoke if an exception is raised
 189         -> IO a
 190 catch =  ExceptionBase.catchException
 191
 192 -- | The function 'catchJust' is like 'catch', but it takes an extra
 193 -- argument which is an /exception predicate/, a function which
 194 -- selects which type of exceptions we\'re interested in.  There are
 195 -- some predefined exception predicates for useful subsets of
 196 -- exceptions: 'ioErrors', 'arithExceptions', and so on.  For example,
 197 -- to catch just calls to the 'error' function, we could use
 198 --
 199 -- >   result <- catchJust errorCalls thing_to_try handler
 200 --
 201 -- Any other exceptions which are not matched by the predicate
 202 -- are re-raised, and may be caught by an enclosing
 203 -- 'catch' or 'catchJust'.
 204 catchJust
 205         :: (Exception -> Maybe b) -- ^ Predicate to select exceptions
 206         -> IO a                   -- ^ Computation to run
 207         -> (b -> IO a)            -- ^ Handler
 208         -> IO a
 209 catchJust p a handler = catch a handler'
 210   where handler' e = case p e of
 211                         Nothing -> throw e
 212                         Just b  -> handler b
 213
 214 -- | A version of 'catch' with the arguments swapped around; useful in
 215 -- situations where the code for the handler is shorter.  For example:
 216 --
 217 -- >   do handle (\e -> exitWith (ExitFailure 1)) $
 218 -- >      ...
 219 handle     :: (Exception -> IO a) -> IO a -> IO a
 220 handle     =  flip catch
 221
 222 -- | A version of 'catchJust' with the arguments swapped around (see
 223 -- 'handle').
 224 handleJust :: (Exception -> Maybe b) -> (b -> IO a) -> IO a -> IO a
 225 handleJust p =  flip (catchJust p)
 226
 227 -----------------------------------------------------------------------------
 228 -- 'mapException'
 229
 230 -- | This function maps one exception into another as proposed in the
 231 -- paper \"A semantics for imprecise exceptions\".
 232
 233 -- Notice that the usage of 'unsafePerformIO' is safe here.
 234
 235 mapException :: (Exception -> Exception) -> a -> a
 236 mapException f v = unsafePerformIO (catch (evaluate v)
 237                                           (\x -> throw (f x)))
 238
 239 -----------------------------------------------------------------------------
 240 -- 'try' and variations.
 241
 242 -- | Similar to 'catch', but returns an 'Either' result which is
 243 -- @('Right' a)@ if no exception was raised, or @('Left' e)@ if an
 244 -- exception was raised and its value is @e@.
 245 --
 246 -- >  try a = catch (Right \`liftM\` a) (return . Left)
 247 --
 248 -- Note: as with 'catch', it is only polite to use this variant if you intend
 249 -- to re-throw the exception after performing whatever cleanup is needed.
 250 -- Otherwise, 'tryJust' is generally considered to be better.
 251 --
 252 -- Also note that "System.IO.Error" also exports a function called
 253 -- 'System.IO.Error.try' with a similar type to 'Control.Exception.try',
 254 -- except that it catches only the IO and user families of exceptions
 255 -- (as required by the Haskell 98 @IO@ module).
 256
 257 try :: IO a -> IO (Either Exception a)
 258 try a = catch (a >>= \ v -> return (Right v)) (\e -> return (Left e))
 259
 260 -- | A variant of 'try' that takes an exception predicate to select
 261 -- which exceptions are caught (c.f. 'catchJust').  If the exception
 262 -- does not match the predicate, it is re-thrown.
 263 tryJust :: (Exception -> Maybe b) -> IO a -> IO (Either b a)
 264 tryJust p a = do
 265   r <- try a
 266   case r of
 267         Right v -> return (Right v)
 268         Left  e -> case p e of
 269                         Nothing -> throw e
 270                         Just b  -> return (Left b)
 271
 272 -----------------------------------------------------------------------------
 273 -- Dynamic exceptions
 274
 275 -- $dynamic
 276 --  #DynamicExceptions# Because the 'Exception' datatype is not extensible, there is an
 277 -- interface for throwing and catching exceptions of type 'Dynamic'
 278 -- (see "Data.Dynamic") which allows exception values of any type in
 279 -- the 'Typeable' class to be thrown and caught.
 280
 281 -- | Raise any value as an exception, provided it is in the
 282 -- 'Typeable' class.
 283 throwDyn :: Typeable exception => exception -> b
 284 throwDyn exception = throw (DynException (toDyn exception))
 285
 286 #ifdef __GLASGOW_HASKELL__
 287 -- | A variant of 'throwDyn' that throws the dynamic exception to an
 288 -- arbitrary thread (GHC only: c.f. 'throwTo').
 289 throwDynTo :: Typeable exception => ThreadId -> exception -> IO ()
 290 throwDynTo t exception = throwTo t (DynException (toDyn exception))
 291 #endif /* __GLASGOW_HASKELL__ */
 292
 293 -- | Catch dynamic exceptions of the required type.  All other
 294 -- exceptions are re-thrown, including dynamic exceptions of the wrong
 295 -- type.
 296 --
 297 -- When using dynamic exceptions it is advisable to define a new
 298 -- datatype to use for your exception type, to avoid possible clashes
 299 -- with dynamic exceptions used in other libraries.
 300 --
 301 catchDyn :: Typeable exception => IO a -> (exception -> IO a) -> IO a
 302 catchDyn m k = catchException m handle
 303   where handle ex = case ex of
 304                            (DynException dyn) ->
 305                                 case fromDynamic dyn of
 306                                     Just exception  -> k exception
 307                                     Nothing -> throw ex
 308                            _ -> throw ex
 309
 310 -----------------------------------------------------------------------------
 311 -- Exception Predicates
 312
 313 -- $preds
 314 -- These pre-defined predicates may be used as the first argument to
 315 -- 'catchJust', 'tryJust', or 'handleJust' to select certain common
 316 -- classes of exceptions.
 317
 318 ioErrors                :: Exception -> Maybe IOError
 319 arithExceptions         :: Exception -> Maybe ArithException
 320 errorCalls              :: Exception -> Maybe String
 321 assertions              :: Exception -> Maybe String
 322 dynExceptions           :: Exception -> Maybe Dynamic
 323 asyncExceptions         :: Exception -> Maybe AsyncException
 324 userErrors              :: Exception -> Maybe String
 325
 326 ioErrors (IOException e) = Just e
 327 ioErrors _ = Nothing
 328
 329 arithExceptions (ArithException e) = Just e
 330 arithExceptions _ = Nothing
 331
 332 errorCalls (ErrorCall e) = Just e
 333 errorCalls _ = Nothing
 334
 335 assertions (AssertionFailed e) = Just e
 336 assertions _ = Nothing
 337
 338 dynExceptions (DynException e) = Just e
 339 dynExceptions _ = Nothing
 340
 341 asyncExceptions (AsyncException e) = Just e
 342 asyncExceptions _ = Nothing
 343
 344 userErrors (IOException e) | isUserError e = Just (ioeGetErrorString e)
 345 userErrors _ = Nothing
 346
 347 -----------------------------------------------------------------------------
 348 -- Some Useful Functions
 349
 350 -- | When you want to acquire a resource, do some work with it, and
 351 -- then release the resource, it is a good idea to use 'bracket',
 352 -- because 'bracket' will install the necessary exception handler to
 353 -- release the resource in the event that an exception is raised
 354 -- during the computation.  If an exception is raised, then 'bracket' will
 355 -- re-raise the exception (after performing the release).
 356 --
 357 -- A common example is opening a file:
 358 --
 359 -- > bracket
 360 -- >   (openFile "filename" ReadMode)
 361 -- >   (hClose)
 362 -- >   (\handle -> do { ... })
 363 --
 364 -- The arguments to 'bracket' are in this order so that we can partially apply
 365 -- it, e.g.:
 366 --
 367 -- > withFile name = bracket (openFile name) hClose
 368 --
 369 bracket
 370         :: IO a         -- ^ computation to run first (\"acquire resource\")
 371         -> (a -> IO b)  -- ^ computation to run last (\"release resource\")
 372         -> (a -> IO c)  -- ^ computation to run in-between
 373         -> IO c         -- returns the value from the in-between computation
 374 bracket before after thing =
 375   block (do
 376     a <- before
 377     r <- catch
 378            (unblock (thing a))
 379            (\e -> do { after a; throw e })
 380     after a
 381     return r
 382  )
 383
 384
 385 -- | A specialised variant of 'bracket' with just a computation to run
 386 -- afterward.
 387 --
 388 finally :: IO a         -- ^ computation to run first
 389         -> IO b         -- ^ computation to run afterward (even if an exception
 390                         -- was raised)
 391         -> IO a         -- returns the value from the first computation
 392 a `finally` sequel =
 393   block (do
 394     r <- catch
 395              (unblock a)
 396              (\e -> do { sequel; throw e })
 397     sequel
 398     return r
 399   )
 400
 401 -- | A variant of 'bracket' where the return value from the first computation
 402 -- is not required.
 403 bracket_ :: IO a -> IO b -> IO c -> IO c
 404 bracket_ before after thing = bracket before (const after) (const thing)
 405
 406 -- | Like bracket, but only performs the final action if there was an
 407 -- exception raised by the in-between computation.
 408 bracketOnError
 409         :: IO a         -- ^ computation to run first (\"acquire resource\")
 410         -> (a -> IO b)  -- ^ computation to run last (\"release resource\")
 411         -> (a -> IO c)  -- ^ computation to run in-between
 412         -> IO c         -- returns the value from the in-between computation
 413 bracketOnError before after thing =
 414   block (do
 415     a <- before
 416     catch
 417         (unblock (thing a))
 418         (\e -> do { after a; throw e })
 419  )
 420
 421 -- -----------------------------------------------------------------------------
 422 -- Asynchronous exceptions
 423
 424 {- $async
 425
 426  #AsynchronousExceptions# Asynchronous exceptions are so-called because they arise due to
 427 external influences, and can be raised at any point during execution.
 428 'StackOverflow' and 'HeapOverflow' are two examples of
 429 system-generated asynchronous exceptions.
 430
 431 The primary source of asynchronous exceptions, however, is
 432 'throwTo':
 433
 434 >  throwTo :: ThreadId -> Exception -> IO ()
 435
 436 'throwTo' (also 'throwDynTo' and 'Control.Concurrent.killThread') allows one
 437 running thread to raise an arbitrary exception in another thread.  The
 438 exception is therefore asynchronous with respect to the target thread,
 439 which could be doing anything at the time it receives the exception.
 440 Great care should be taken with asynchronous exceptions; it is all too
 441 easy to introduce race conditions by the over zealous use of
 442 'throwTo'.
 443 -}
 444
 445 {- $block_handler
 446 There\'s an implied 'block' around every exception handler in a call
 447 to one of the 'catch' family of functions.  This is because that is
 448 what you want most of the time - it eliminates a common race condition
 449 in starting an exception handler, because there may be no exception
 450 handler on the stack to handle another exception if one arrives
 451 immediately.  If asynchronous exceptions are blocked on entering the
 452 handler, though, we have time to install a new exception handler
 453 before being interrupted.  If this weren\'t the default, one would have
 454 to write something like
 455
 456 >      block (
 457 >           catch (unblock (...))
 458 >                      (\e -> handler)
 459 >      )
 460
 461 If you need to unblock asynchronous exceptions again in the exception
 462 handler, just use 'unblock' as normal.
 463
 464 Note that 'try' and friends /do not/ have a similar default, because
 465 there is no exception handler in this case.  If you want to use 'try'
 466 in an asynchronous-exception-safe way, you will need to use
 467 'block'.
 468 -}
 469
 470 {- $interruptible
 471
 472 Some operations are /interruptible/, which means that they can receive
 473 asynchronous exceptions even in the scope of a 'block'.  Any function
 474 which may itself block is defined as interruptible; this includes
 475 'Control.Concurrent.MVar.takeMVar'
 476 (but not 'Control.Concurrent.MVar.tryTakeMVar'),
 477 and most operations which perform
 478 some I\/O with the outside world.  The reason for having
 479 interruptible operations is so that we can write things like
 480
 481 >      block (
 482 >         a <- takeMVar m
 483 >         catch (unblock (...))
 484 >               (\e -> ...)
 485 >      )
 486
 487 if the 'Control.Concurrent.MVar.takeMVar' was not interruptible,
 488 then this particular
 489 combination could lead to deadlock, because the thread itself would be
 490 blocked in a state where it can\'t receive any asynchronous exceptions.
 491 With 'Control.Concurrent.MVar.takeMVar' interruptible, however, we can be
 492 safe in the knowledge that the thread can receive exceptions right up
 493 until the point when the 'Control.Concurrent.MVar.takeMVar' succeeds.
 494 Similar arguments apply for other interruptible operations like
 495 'System.IO.openFile'.
 496 -}
 497
 498 #ifndef __GLASGOW_HASKELL__
 499 assert :: Bool -> a -> a
 500 assert True x = x
 501 assert False _ = throw (AssertionFailed "")
 502 #endif
 503
 504
 505 #ifdef __GLASGOW_HASKELL__
 506 {-# NOINLINE uncaughtExceptionHandler #-}
 507 uncaughtExceptionHandler :: IORef (Exception -> IO ())
 508 uncaughtExceptionHandler = unsafePerformIO (newIORef defaultHandler)
 509    where
 510       defaultHandler :: Exception -> IO ()
 511       defaultHandler ex = do
 512          (hFlush stdout) `catchException` (\ _ -> return ())
 513          let msg = case ex of
 514                Deadlock    -> "no threads to run:  infinite loop or deadlock?"
 515                ErrorCall s -> s
 516                other       -> showsPrec 0 other "\n"
 517          withCString "%s" $ \cfmt ->
 518           withCString msg $ \cmsg ->
 519             errorBelch cfmt cmsg
 520
 521 foreign import ccall unsafe errorBelch :: CString -> CString -> IO ()
 522
 523 setUncaughtExceptionHandler :: (Exception -> IO ()) -> IO ()
 524 setUncaughtExceptionHandler = writeIORef uncaughtExceptionHandler
 525
 526 getUncaughtExceptionHandler :: IO (Exception -> IO ())
 527 getUncaughtExceptionHandler = readIORef uncaughtExceptionHandler
 528 #endif