Control/OldException.hs

   1 {-# OPTIONS_GHC -XNoImplicitPrelude #-}
   2
   3 #include "Typeable.h"
   4
   5 -----------------------------------------------------------------------------
   6 -- |
   7 -- Module      :  Control.OldException
   8 -- Copyright   :  (c) The University of Glasgow 2001
   9 -- License     :  BSD-style (see the file libraries/base/LICENSE)
  10 --
  11 -- Maintainer  :  libraries@haskell.org
  12 -- Stability   :  experimental
  13 -- Portability :  non-portable (extended exceptions)
  14 --
  15 -- This module provides support for raising and catching both built-in
  16 -- and user-defined exceptions.
  17 --
  18 -- In addition to exceptions thrown by 'IO' operations, exceptions may
  19 -- be thrown by pure code (imprecise exceptions) or by external events
  20 -- (asynchronous exceptions), but may only be caught in the 'IO' monad.
  21 -- For more details, see:
  22 --
  23 --  * /A semantics for imprecise exceptions/, by Simon Peyton Jones,
  24 --    Alastair Reid, Tony Hoare, Simon Marlow, Fergus Henderson,
  25 --    in /PLDI'99/.
  26 --
  27 --  * /Asynchronous exceptions in Haskell/, by Simon Marlow, Simon Peyton
  28 --    Jones, Andy Moran and John Reppy, in /PLDI'01/.
  29 --
  30 -----------------------------------------------------------------------------
  31
  32 module Control.OldException {-# DEPRECATED "Future versions of base will not support the old exceptions style. Please switch to extensible exceptions." #-} (
  33
  34         -- * The Exception type
  35         Exception(..),          -- instance Eq, Ord, Show, Typeable
  36         New.IOException,        -- instance Eq, Ord, Show, Typeable
  37         New.ArithException(..), -- instance Eq, Ord, Show, Typeable
  38         New.ArrayException(..), -- instance Eq, Ord, Show, Typeable
  39         New.AsyncException(..), -- instance Eq, Ord, Show, Typeable
  40
  41         -- * Throwing exceptions
  42         throwIO,        -- :: Exception -> IO a
  43         throw,          -- :: Exception -> a
  44         ioError,        -- :: IOError -> IO a
  45 #ifdef __GLASGOW_HASKELL__
  46         -- XXX Need to restrict the type of this:
  47         New.throwTo,        -- :: ThreadId -> Exception -> a
  48 #endif
  49
  50         -- * Catching Exceptions
  51
  52         -- |There are several functions for catching and examining
  53         -- exceptions; all of them may only be used from within the
  54         -- 'IO' monad.
  55
  56         -- ** The @catch@ functions
  57         catch,     -- :: IO a -> (Exception -> IO a) -> IO a
  58         catchJust, -- :: (Exception -> Maybe b) -> IO a -> (b -> IO a) -> IO a
  59
  60         -- ** The @handle@ functions
  61         handle,    -- :: (Exception -> IO a) -> IO a -> IO a
  62         handleJust,-- :: (Exception -> Maybe b) -> (b -> IO a) -> IO a -> IO a
  63
  64         -- ** The @try@ functions
  65         try,       -- :: IO a -> IO (Either Exception a)
  66         tryJust,   -- :: (Exception -> Maybe b) -> a    -> IO (Either b a)
  67
  68         -- ** The @evaluate@ function
  69         evaluate,  -- :: a -> IO a
  70
  71         -- ** The @mapException@ function
  72         mapException,           -- :: (Exception -> Exception) -> a -> a
  73
  74         -- ** Exception predicates
  75
  76         -- $preds
  77
  78         ioErrors,               -- :: Exception -> Maybe IOError
  79         arithExceptions,        -- :: Exception -> Maybe ArithException
  80         errorCalls,             -- :: Exception -> Maybe String
  81         dynExceptions,          -- :: Exception -> Maybe Dynamic
  82         assertions,             -- :: Exception -> Maybe String
  83         asyncExceptions,        -- :: Exception -> Maybe AsyncException
  84         userErrors,             -- :: Exception -> Maybe String
  85
  86         -- * Dynamic exceptions
  87
  88         -- $dynamic
  89         throwDyn,       -- :: Typeable ex => ex -> b
  90 #ifdef __GLASGOW_HASKELL__
  91         throwDynTo,     -- :: Typeable ex => ThreadId -> ex -> b
  92 #endif
  93         catchDyn,       -- :: Typeable ex => IO a -> (ex -> IO a) -> IO a
  94
  95         -- * Asynchronous Exceptions
  96
  97         -- $async
  98
  99         -- ** Asynchronous exception control
 100
 101         -- |The following two functions allow a thread to control delivery of
 102         -- asynchronous exceptions during a critical region.
 103
 104         block,          -- :: IO a -> IO a
 105         unblock,        -- :: IO a -> IO a
 106
 107         -- *** Applying @block@ to an exception handler
 108
 109         -- $block_handler
 110
 111         -- *** Interruptible operations
 112
 113         -- $interruptible
 114
 115         -- * Assertions
 116
 117         assert,         -- :: Bool -> a -> a
 118
 119         -- * Utilities
 120
 121         bracket,        -- :: IO a -> (a -> IO b) -> (a -> IO c) -> IO ()
 122         bracket_,       -- :: IO a -> IO b -> IO c -> IO ()
 123         bracketOnError,
 124
 125         finally,        -- :: IO a -> IO b -> IO a
 126
 127 #ifdef __GLASGOW_HASKELL__
 128         setUncaughtExceptionHandler,      -- :: (Exception -> IO ()) -> IO ()
 129         getUncaughtExceptionHandler       -- :: IO (Exception -> IO ())
 130 #endif
 131   ) where
 132
 133 #ifdef __GLASGOW_HASKELL__
 134 import GHC.Base
 135 import GHC.Show
 136 -- import GHC.IO ( IO )
 137 import GHC.IO.Handle.FD ( stdout )
 138 import qualified GHC.IO as New
 139 import qualified GHC.IO.Exception as New
 140 import GHC.Conc hiding (setUncaughtExceptionHandler,
 141                         getUncaughtExceptionHandler)
 142 import Data.IORef       ( IORef, newIORef, readIORef, writeIORef )
 143 import Foreign.C.String ( CString, withCString )
 144 import GHC.IO.Handle ( hFlush )
 145 #endif
 146
 147 #ifdef __HUGS__
 148 import Prelude          hiding (catch)
 149 import Hugs.Prelude     as New (ExitCode(..))
 150 #endif
 151
 152 import qualified Control.Exception as New
 153 import           Control.Exception ( toException, fromException, throw, block, unblock, mask, evaluate, throwIO )
 154 import System.IO.Error  hiding ( catch, try )
 155 import System.IO.Unsafe (unsafePerformIO)
 156 import Data.Dynamic
 157 import Data.Either
 158 import Data.Maybe
 159
 160 #ifdef __NHC__
 161 import System.IO.Error (catch, ioError)
 162 import IO              (bracket)
 163 import DIOError         -- defn of IOError type
 164
 165 -- minimum needed for nhc98 to pretend it has Exceptions
 166 type Exception   = IOError
 167 type IOException = IOError
 168 data ArithException
 169 data ArrayException
 170 data AsyncException
 171
 172 throwIO  :: Exception -> IO a
 173 throwIO   = ioError
 174 throw    :: Exception -> a
 175 throw     = unsafePerformIO . throwIO
 176
 177 evaluate :: a -> IO a
 178 evaluate x = x `seq` return x
 179
 180 ioErrors        :: Exception -> Maybe IOError
 181 ioErrors e       = Just e
 182 arithExceptions :: Exception -> Maybe ArithException
 183 arithExceptions  = const Nothing
 184 errorCalls      :: Exception -> Maybe String
 185 errorCalls       = const Nothing
 186 dynExceptions   :: Exception -> Maybe Dynamic
 187 dynExceptions    = const Nothing
 188 assertions      :: Exception -> Maybe String
 189 assertions       = const Nothing
 190 asyncExceptions :: Exception -> Maybe AsyncException
 191 asyncExceptions  = const Nothing
 192 userErrors      :: Exception -> Maybe String
 193 userErrors (UserError _ s) = Just s
 194 userErrors  _              = Nothing
 195
 196 block   :: IO a -> IO a
 197 block    = id
 198 unblock :: IO a -> IO a
 199 unblock  = id
 200
 201 assert :: Bool -> a -> a
 202 assert True  x = x
 203 assert False _ = throw (UserError "" "Assertion failed")
 204 #endif
 205
 206 -----------------------------------------------------------------------------
 207 -- Catching exceptions
 208
 209 -- |This is the simplest of the exception-catching functions.  It
 210 -- takes a single argument, runs it, and if an exception is raised
 211 -- the \"handler\" is executed, with the value of the exception passed as an
 212 -- argument.  Otherwise, the result is returned as normal.  For example:
 213 --
 214 -- >   catch (openFile f ReadMode)
 215 -- >       (\e -> hPutStr stderr ("Couldn't open "++f++": " ++ show e))
 216 --
 217 -- For catching exceptions in pure (non-'IO') expressions, see the
 218 -- function 'evaluate'.
 219 --
 220 -- Note that due to Haskell\'s unspecified evaluation order, an
 221 -- expression may return one of several possible exceptions: consider
 222 -- the expression @error \"urk\" + 1 \`div\` 0@.  Does
 223 -- 'catch' execute the handler passing
 224 -- @ErrorCall \"urk\"@, or @ArithError DivideByZero@?
 225 --
 226 -- The answer is \"either\": 'catch' makes a
 227 -- non-deterministic choice about which exception to catch.  If you
 228 -- call it again, you might get a different exception back.  This is
 229 -- ok, because 'catch' is an 'IO' computation.
 230 --
 231 -- Note that 'catch' catches all types of exceptions, and is generally
 232 -- used for \"cleaning up\" before passing on the exception using
 233 -- 'throwIO'.  It is not good practice to discard the exception and
 234 -- continue, without first checking the type of the exception (it
 235 -- might be a 'ThreadKilled', for example).  In this case it is usually better
 236 -- to use 'catchJust' and select the kinds of exceptions to catch.
 237 --
 238 -- Also note that the "Prelude" also exports a function called
 239 -- 'Prelude.catch' with a similar type to 'Control.OldException.catch',
 240 -- except that the "Prelude" version only catches the IO and user
 241 -- families of exceptions (as required by Haskell 98).
 242 --
 243 -- We recommend either hiding the "Prelude" version of 'Prelude.catch'
 244 -- when importing "Control.OldException":
 245 --
 246 -- > import Prelude hiding (catch)
 247 --
 248 -- or importing "Control.OldException" qualified, to avoid name-clashes:
 249 --
 250 -- > import qualified Control.OldException as C
 251 --
 252 -- and then using @C.catch@
 253 --
 254
 255 catch   :: IO a                 -- ^ The computation to run
 256         -> (Exception -> IO a)  -- ^ Handler to invoke if an exception is raised
 257         -> IO a
 258 -- note: bundling the exceptions is done in the New.Exception
 259 -- instance of Exception; see below.
 260 catch = New.catch
 261
 262 -- | The function 'catchJust' is like 'catch', but it takes an extra
 263 -- argument which is an /exception predicate/, a function which
 264 -- selects which type of exceptions we\'re interested in.  There are
 265 -- some predefined exception predicates for useful subsets of
 266 -- exceptions: 'ioErrors', 'arithExceptions', and so on.  For example,
 267 -- to catch just calls to the 'error' function, we could use
 268 --
 269 -- >   result <- catchJust errorCalls thing_to_try handler
 270 --
 271 -- Any other exceptions which are not matched by the predicate
 272 -- are re-raised, and may be caught by an enclosing
 273 -- 'catch' or 'catchJust'.
 274 catchJust
 275         :: (Exception -> Maybe b) -- ^ Predicate to select exceptions
 276         -> IO a                   -- ^ Computation to run
 277         -> (b -> IO a)            -- ^ Handler
 278         -> IO a
 279 catchJust p a handler = catch a handler'
 280   where handler' e = case p e of
 281                         Nothing -> throw e
 282                         Just b  -> handler b
 283
 284 -- | A version of 'catch' with the arguments swapped around; useful in
 285 -- situations where the code for the handler is shorter.  For example:
 286 --
 287 -- >   do handle (\e -> exitWith (ExitFailure 1)) $
 288 -- >      ...
 289 handle     :: (Exception -> IO a) -> IO a -> IO a
 290 handle     =  flip catch
 291
 292 -- | A version of 'catchJust' with the arguments swapped around (see
 293 -- 'handle').
 294 handleJust :: (Exception -> Maybe b) -> (b -> IO a) -> IO a -> IO a
 295 handleJust p =  flip (catchJust p)
 296
 297 -----------------------------------------------------------------------------
 298 -- 'mapException'
 299
 300 -- | This function maps one exception into another as proposed in the
 301 -- paper \"A semantics for imprecise exceptions\".
 302
 303 -- Notice that the usage of 'unsafePerformIO' is safe here.
 304
 305 mapException :: (Exception -> Exception) -> a -> a
 306 mapException f v = unsafePerformIO (catch (evaluate v)
 307                                           (\x -> throw (f x)))
 308
 309 -----------------------------------------------------------------------------
 310 -- 'try' and variations.
 311
 312 -- | Similar to 'catch', but returns an 'Either' result which is
 313 -- @('Right' a)@ if no exception was raised, or @('Left' e)@ if an
 314 -- exception was raised and its value is @e@.
 315 --
 316 -- >  try a = catch (Right `liftM` a) (return . Left)
 317 --
 318 -- Note: as with 'catch', it is only polite to use this variant if you intend
 319 -- to re-throw the exception after performing whatever cleanup is needed.
 320 -- Otherwise, 'tryJust' is generally considered to be better.
 321 --
 322 -- Also note that "System.IO.Error" also exports a function called
 323 -- 'System.IO.Error.try' with a similar type to 'Control.OldException.try',
 324 -- except that it catches only the IO and user families of exceptions
 325 -- (as required by the Haskell 98 @IO@ module).
 326
 327 try :: IO a -> IO (Either Exception a)
 328 try a = catch (a >>= \ v -> return (Right v)) (\e -> return (Left e))
 329
 330 -- | A variant of 'try' that takes an exception predicate to select
 331 -- which exceptions are caught (c.f. 'catchJust').  If the exception
 332 -- does not match the predicate, it is re-thrown.
 333 tryJust :: (Exception -> Maybe b) -> IO a -> IO (Either b a)
 334 tryJust p a = do
 335   r <- try a
 336   case r of
 337         Right v -> return (Right v)
 338         Left  e -> case p e of
 339                         Nothing -> throw e
 340                         Just b  -> return (Left b)
 341
 342 -----------------------------------------------------------------------------
 343 -- Dynamic exceptions
 344
 345 -- $dynamic
 346 --  #DynamicExceptions# Because the 'Exception' datatype is not extensible, there is an
 347 -- interface for throwing and catching exceptions of type 'Dynamic'
 348 -- (see "Data.Dynamic") which allows exception values of any type in
 349 -- the 'Typeable' class to be thrown and caught.
 350
 351 -- | Raise any value as an exception, provided it is in the
 352 -- 'Typeable' class.
 353 throwDyn :: Typeable exception => exception -> b
 354 #ifdef __NHC__
 355 throwDyn exception = throw (UserError "" "dynamic exception")
 356 #else
 357 throwDyn exception = throw (DynException (toDyn exception))
 358 #endif
 359
 360 #ifdef __GLASGOW_HASKELL__
 361 -- | A variant of 'throwDyn' that throws the dynamic exception to an
 362 -- arbitrary thread (GHC only: c.f. 'throwTo').
 363 throwDynTo :: Typeable exception => ThreadId -> exception -> IO ()
 364 throwDynTo t exception = New.throwTo t (DynException (toDyn exception))
 365 #endif /* __GLASGOW_HASKELL__ */
 366
 367 -- | Catch dynamic exceptions of the required type.  All other
 368 -- exceptions are re-thrown, including dynamic exceptions of the wrong
 369 -- type.
 370 --
 371 -- When using dynamic exceptions it is advisable to define a new
 372 -- datatype to use for your exception type, to avoid possible clashes
 373 -- with dynamic exceptions used in other libraries.
 374 --
 375 catchDyn :: Typeable exception => IO a -> (exception -> IO a) -> IO a
 376 #ifdef __NHC__
 377 catchDyn m k = m        -- can't catch dyn exceptions in nhc98
 378 #else
 379 catchDyn m k = New.catch m handler
 380   where handler ex = case ex of
 381                            (DynException dyn) ->
 382                                 case fromDynamic dyn of
 383                                     Just exception  -> k exception
 384                                     Nothing -> throw ex
 385                            _ -> throw ex
 386 #endif
 387
 388 -----------------------------------------------------------------------------
 389 -- Exception Predicates
 390
 391 -- $preds
 392 -- These pre-defined predicates may be used as the first argument to
 393 -- 'catchJust', 'tryJust', or 'handleJust' to select certain common
 394 -- classes of exceptions.
 395 #ifndef __NHC__
 396 ioErrors                :: Exception -> Maybe IOError
 397 arithExceptions         :: Exception -> Maybe New.ArithException
 398 errorCalls              :: Exception -> Maybe String
 399 assertions              :: Exception -> Maybe String
 400 dynExceptions           :: Exception -> Maybe Dynamic
 401 asyncExceptions         :: Exception -> Maybe New.AsyncException
 402 userErrors              :: Exception -> Maybe String
 403
 404 ioErrors (IOException e) = Just e
 405 ioErrors _ = Nothing
 406
 407 arithExceptions (ArithException e) = Just e
 408 arithExceptions _ = Nothing
 409
 410 errorCalls (ErrorCall e) = Just e
 411 errorCalls _ = Nothing
 412
 413 assertions (AssertionFailed e) = Just e
 414 assertions _ = Nothing
 415
 416 dynExceptions (DynException e) = Just e
 417 dynExceptions _ = Nothing
 418
 419 asyncExceptions (AsyncException e) = Just e
 420 asyncExceptions _ = Nothing
 421
 422 userErrors (IOException e) | isUserError e = Just (ioeGetErrorString e)
 423 userErrors _ = Nothing
 424 #endif
 425 -----------------------------------------------------------------------------
 426 -- Some Useful Functions
 427
 428 -- | When you want to acquire a resource, do some work with it, and
 429 -- then release the resource, it is a good idea to use 'bracket',
 430 -- because 'bracket' will install the necessary exception handler to
 431 -- release the resource in the event that an exception is raised
 432 -- during the computation.  If an exception is raised, then 'bracket' will
 433 -- re-raise the exception (after performing the release).
 434 --
 435 -- A common example is opening a file:
 436 --
 437 -- > bracket
 438 -- >   (openFile "filename" ReadMode)
 439 -- >   (hClose)
 440 -- >   (\handle -> do { ... })
 441 --
 442 -- The arguments to 'bracket' are in this order so that we can partially apply
 443 -- it, e.g.:
 444 --
 445 -- > withFile name mode = bracket (openFile name mode) hClose
 446 --
 447 #ifndef __NHC__
 448 bracket
 449         :: IO a         -- ^ computation to run first (\"acquire resource\")
 450         -> (a -> IO b)  -- ^ computation to run last (\"release resource\")
 451         -> (a -> IO c)  -- ^ computation to run in-between
 452         -> IO c         -- returns the value from the in-between computation
 453 bracket before after thing =
 454   mask $ \restore -> do
 455     a <- before
 456     r <- catch
 457            (restore (thing a))
 458            (\e -> do { _ <- after a; throw e })
 459     _ <- after a
 460     return r
 461 #endif
 462
 463 -- | A specialised variant of 'bracket' with just a computation to run
 464 -- afterward.
 465 --
 466 finally :: IO a         -- ^ computation to run first
 467         -> IO b         -- ^ computation to run afterward (even if an exception
 468                         -- was raised)
 469         -> IO a         -- returns the value from the first computation
 470 a `finally` sequel =
 471   mask $ \restore -> do
 472     r <- catch
 473              (restore a)
 474              (\e -> do { _ <- sequel; throw e })
 475     _ <- sequel
 476     return r
 477
 478 -- | A variant of 'bracket' where the return value from the first computation
 479 -- is not required.
 480 bracket_ :: IO a -> IO b -> IO c -> IO c
 481 bracket_ before after thing = bracket before (const after) (const thing)
 482
 483 -- | Like bracket, but only performs the final action if there was an
 484 -- exception raised by the in-between computation.
 485 bracketOnError
 486         :: IO a         -- ^ computation to run first (\"acquire resource\")
 487         -> (a -> IO b)  -- ^ computation to run last (\"release resource\")
 488         -> (a -> IO c)  -- ^ computation to run in-between
 489         -> IO c         -- returns the value from the in-between computation
 490 bracketOnError before after thing =
 491   mask $ \restore -> do
 492     a <- before
 493     catch
 494         (restore (thing a))
 495         (\e -> do { _ <- after a; throw e })
 496
 497 -- -----------------------------------------------------------------------------
 498 -- Asynchronous exceptions
 499
 500 {- $async
 501
 502  #AsynchronousExceptions# Asynchronous exceptions are so-called because they arise due to
 503 external influences, and can be raised at any point during execution.
 504 'StackOverflow' and 'HeapOverflow' are two examples of
 505 system-generated asynchronous exceptions.
 506
 507 The primary source of asynchronous exceptions, however, is
 508 'throwTo':
 509
 510 >  throwTo :: ThreadId -> Exception -> IO ()
 511
 512 'throwTo' (also 'throwDynTo' and 'Control.Concurrent.killThread') allows one
 513 running thread to raise an arbitrary exception in another thread.  The
 514 exception is therefore asynchronous with respect to the target thread,
 515 which could be doing anything at the time it receives the exception.
 516 Great care should be taken with asynchronous exceptions; it is all too
 517 easy to introduce race conditions by the over zealous use of
 518 'throwTo'.
 519 -}
 520
 521 {- $block_handler
 522 There\'s an implied 'mask_' around every exception handler in a call
 523 to one of the 'catch' family of functions.  This is because that is
 524 what you want most of the time - it eliminates a common race condition
 525 in starting an exception handler, because there may be no exception
 526 handler on the stack to handle another exception if one arrives
 527 immediately.  If asynchronous exceptions are blocked on entering the
 528 handler, though, we have time to install a new exception handler
 529 before being interrupted.  If this weren\'t the default, one would have
 530 to write something like
 531
 532 >      mask $ \restore ->
 533 >           catch (restore (...))
 534 >                      (\e -> handler)
 535
 536 If you need to unblock asynchronous exceptions again in the exception
 537 handler, just use 'unblock' as normal.
 538
 539 Note that 'try' and friends /do not/ have a similar default, because
 540 there is no exception handler in this case.  If you want to use 'try'
 541 in an asynchronous-exception-safe way, you will need to use
 542 'mask'.
 543 -}
 544
 545 {- $interruptible
 546
 547 Some operations are /interruptible/, which means that they can receive
 548 asynchronous exceptions even in the scope of a 'mask'.  Any function
 549 which may itself block is defined as interruptible; this includes
 550 'Control.Concurrent.MVar.takeMVar'
 551 (but not 'Control.Concurrent.MVar.tryTakeMVar'),
 552 and most operations which perform
 553 some I\/O with the outside world.  The reason for having
 554 interruptible operations is so that we can write things like
 555
 556 >      mask $ \restore -> do
 557 >         a <- takeMVar m
 558 >         catch (restore (...))
 559 >               (\e -> ...)
 560
 561 if the 'Control.Concurrent.MVar.takeMVar' was not interruptible,
 562 then this particular
 563 combination could lead to deadlock, because the thread itself would be
 564 blocked in a state where it can\'t receive any asynchronous exceptions.
 565 With 'Control.Concurrent.MVar.takeMVar' interruptible, however, we can be
 566 safe in the knowledge that the thread can receive exceptions right up
 567 until the point when the 'Control.Concurrent.MVar.takeMVar' succeeds.
 568 Similar arguments apply for other interruptible operations like
 569 'System.IO.openFile'.
 570 -}
 571
 572 #if !(__GLASGOW_HASKELL__ || __NHC__)
 573 assert :: Bool -> a -> a
 574 assert True x = x
 575 assert False _ = throw (AssertionFailed "")
 576 #endif
 577
 578
 579 #ifdef __GLASGOW_HASKELL__
 580 {-# NOINLINE uncaughtExceptionHandler #-}
 581 uncaughtExceptionHandler :: IORef (Exception -> IO ())
 582 uncaughtExceptionHandler = unsafePerformIO (newIORef defaultHandler)
 583    where
 584       defaultHandler :: Exception -> IO ()
 585       defaultHandler ex = do
 586          (hFlush stdout) `New.catchAny` (\ _ -> return ())
 587          let msg = case ex of
 588                Deadlock    -> "no threads to run:  infinite loop or deadlock?"
 589                ErrorCall s -> s
 590                other       -> showsPrec 0 other ""
 591          withCString "%s" $ \cfmt ->
 592           withCString msg $ \cmsg ->
 593             errorBelch cfmt cmsg
 594
 595 -- don't use errorBelch() directly, because we cannot call varargs functions
 596 -- using the FFI.
 597 foreign import ccall unsafe "HsBase.h errorBelch2"
 598    errorBelch :: CString -> CString -> IO ()
 599
 600 setUncaughtExceptionHandler :: (Exception -> IO ()) -> IO ()
 601 setUncaughtExceptionHandler = writeIORef uncaughtExceptionHandler
 602
 603 getUncaughtExceptionHandler :: IO (Exception -> IO ())
 604 getUncaughtExceptionHandler = readIORef uncaughtExceptionHandler
 605 #endif
 606
 607 -- ------------------------------------------------------------------------
 608 -- Exception datatype and operations
 609
 610 -- |The type of exceptions.  Every kind of system-generated exception
 611 -- has a constructor in the 'Exception' type, and values of other
 612 -- types may be injected into 'Exception' by coercing them to
 613 -- 'Data.Dynamic.Dynamic' (see the section on Dynamic Exceptions:
 614 -- "Control.OldException\#DynamicExceptions").
 615 data Exception
 616   = ArithException      New.ArithException
 617         -- ^Exceptions raised by arithmetic
 618         -- operations.  (NOTE: GHC currently does not throw
 619         -- 'ArithException's except for 'DivideByZero').
 620   | ArrayException      New.ArrayException
 621         -- ^Exceptions raised by array-related
 622         -- operations.  (NOTE: GHC currently does not throw
 623         -- 'ArrayException's).
 624   | AssertionFailed     String
 625         -- ^This exception is thrown by the
 626         -- 'assert' operation when the condition
 627         -- fails.  The 'String' argument contains the
 628         -- location of the assertion in the source program.
 629   | AsyncException      New.AsyncException
 630         -- ^Asynchronous exceptions (see section on Asynchronous Exceptions: "Control.OldException\#AsynchronousExceptions").
 631   | BlockedOnDeadMVar
 632         -- ^The current thread was executing a call to
 633         -- 'Control.Concurrent.MVar.takeMVar' that could never return,
 634         -- because there are no other references to this 'MVar'.
 635   | BlockedIndefinitely
 636         -- ^The current thread was waiting to retry an atomic memory transaction
 637         -- that could never become possible to complete because there are no other
 638         -- threads referring to any of the TVars involved.
 639   | NestedAtomically
 640         -- ^The runtime detected an attempt to nest one STM transaction
 641         -- inside another one, presumably due to the use of
 642         -- 'unsafePeformIO' with 'atomically'.
 643   | Deadlock
 644         -- ^There are no runnable threads, so the program is
 645         -- deadlocked.  The 'Deadlock' exception is
 646         -- raised in the main thread only (see also: "Control.Concurrent").
 647   | DynException        Dynamic
 648         -- ^Dynamically typed exceptions (see section on Dynamic Exceptions: "Control.OldException\#DynamicExceptions").
 649   | ErrorCall           String
 650         -- ^The 'ErrorCall' exception is thrown by 'error'.  The 'String'
 651         -- argument of 'ErrorCall' is the string passed to 'error' when it was
 652         -- called.
 653   | ExitException       New.ExitCode
 654         -- ^The 'ExitException' exception is thrown by 'System.Exit.exitWith' (and
 655         -- 'System.Exit.exitFailure').  The 'ExitCode' argument is the value passed
 656         -- to 'System.Exit.exitWith'.  An unhandled 'ExitException' exception in the
 657         -- main thread will cause the program to be terminated with the given
 658         -- exit code.
 659   | IOException         New.IOException
 660         -- ^These are the standard IO exceptions generated by
 661         -- Haskell\'s @IO@ operations.  See also "System.IO.Error".
 662   | NoMethodError       String
 663         -- ^An attempt was made to invoke a class method which has
 664         -- no definition in this instance, and there was no default
 665         -- definition given in the class declaration.  GHC issues a
 666         -- warning when you compile an instance which has missing
 667         -- methods.
 668   | NonTermination
 669         -- ^The current thread is stuck in an infinite loop.  This
 670         -- exception may or may not be thrown when the program is
 671         -- non-terminating.
 672   | PatternMatchFail    String
 673         -- ^A pattern matching failure.  The 'String' argument should contain a
 674         -- descriptive message including the function name, source file
 675         -- and line number.
 676   | RecConError         String
 677         -- ^An attempt was made to evaluate a field of a record
 678         -- for which no value was given at construction time.  The
 679         -- 'String' argument gives the location of the
 680         -- record construction in the source program.
 681   | RecSelError         String
 682         -- ^A field selection was attempted on a constructor that
 683         -- doesn\'t have the requested field.  This can happen with
 684         -- multi-constructor records when one or more fields are
 685         -- missing from some of the constructors.  The
 686         -- 'String' argument gives the location of the
 687         -- record selection in the source program.
 688   | RecUpdError         String
 689         -- ^An attempt was made to update a field in a record,
 690         -- where the record doesn\'t have the requested field.  This can
 691         -- only occur with multi-constructor records, when one or more
 692         -- fields are missing from some of the constructors.  The
 693         -- 'String' argument gives the location of the
 694         -- record update in the source program.
 695 INSTANCE_TYPEABLE0(Exception,exceptionTc,"Exception")
 696
 697 -- helper type for simplifying the type casting logic below
 698 data Caster = forall e . New.Exception e => Caster (e -> Exception)
 699
 700 instance New.Exception Exception where
 701   -- We need to collect all the sorts of exceptions that used to be
 702   -- bundled up into the Exception type, and rebundle them for
 703   -- legacy handlers.
 704   fromException exc0 = foldr tryCast Nothing casters where
 705     tryCast (Caster f) e = case fromException exc0 of
 706       Just exc -> Just (f exc)
 707       _        -> e
 708     casters =
 709       [Caster (\exc -> ArithException exc),
 710        Caster (\exc -> ArrayException exc),
 711        Caster (\(New.AssertionFailed err) -> AssertionFailed err),
 712        Caster (\exc -> AsyncException exc),
 713        Caster (\New.BlockedIndefinitelyOnMVar -> BlockedOnDeadMVar),
 714        Caster (\New.BlockedIndefinitelyOnSTM -> BlockedIndefinitely),
 715        Caster (\New.NestedAtomically -> NestedAtomically),
 716        Caster (\New.Deadlock -> Deadlock),
 717        Caster (\exc -> DynException exc),
 718        Caster (\(New.ErrorCall err) -> ErrorCall err),
 719        Caster (\exc -> ExitException exc),
 720        Caster (\exc -> IOException exc),
 721        Caster (\(New.NoMethodError err) -> NoMethodError err),
 722        Caster (\New.NonTermination -> NonTermination),
 723        Caster (\(New.PatternMatchFail err) -> PatternMatchFail err),
 724        Caster (\(New.RecConError err) -> RecConError err),
 725        Caster (\(New.RecSelError err) -> RecSelError err),
 726        Caster (\(New.RecUpdError err) -> RecUpdError err),
 727        -- Anything else gets taken as a Dynamic exception. It's
 728        -- important that we put all exceptions into the old Exception
 729        -- type somehow, or throwing a new exception wouldn't cause
 730        -- the cleanup code for bracket, finally etc to happen.
 731        Caster (\exc -> DynException (toDyn (exc :: New.SomeException)))]
 732
 733   -- Unbundle exceptions.
 734   toException (ArithException exc)   = toException exc
 735   toException (ArrayException exc)   = toException exc
 736   toException (AssertionFailed err)  = toException (New.AssertionFailed err)
 737   toException (AsyncException exc)   = toException exc
 738   toException BlockedOnDeadMVar      = toException New.BlockedIndefinitelyOnMVar
 739   toException BlockedIndefinitely    = toException New.BlockedIndefinitelyOnSTM
 740   toException NestedAtomically       = toException New.NestedAtomically
 741   toException Deadlock               = toException New.Deadlock
 742   -- If a dynamic exception is a SomeException then resurrect it, so
 743   -- that bracket, catch+throw etc rethrow the same exception even
 744   -- when the exception is in the new style.
 745   -- If it's not a SomeException, then just throw the Dynamic.
 746   toException (DynException exc)     = case fromDynamic exc of
 747                                        Just exc' -> exc'
 748                                        Nothing -> toException exc
 749   toException (ErrorCall err)        = toException (New.ErrorCall err)
 750   toException (ExitException exc)    = toException exc
 751   toException (IOException exc)      = toException exc
 752   toException (NoMethodError err)    = toException (New.NoMethodError err)
 753   toException NonTermination         = toException New.NonTermination
 754   toException (PatternMatchFail err) = toException (New.PatternMatchFail err)
 755   toException (RecConError err)      = toException (New.RecConError err)
 756   toException (RecSelError err)      = toException (New.RecSelError err)
 757   toException (RecUpdError err)      = toException (New.RecUpdError err)
 758
 759 instance Show Exception where
 760   showsPrec _ (IOException err)          = shows err
 761   showsPrec _ (ArithException err)       = shows err
 762   showsPrec _ (ArrayException err)       = shows err
 763   showsPrec _ (ErrorCall err)            = showString err
 764   showsPrec _ (ExitException err)        = showString "exit: " . shows err
 765   showsPrec _ (NoMethodError err)        = showString err
 766   showsPrec _ (PatternMatchFail err)     = showString err
 767   showsPrec _ (RecSelError err)          = showString err
 768   showsPrec _ (RecConError err)          = showString err
 769   showsPrec _ (RecUpdError err)          = showString err
 770   showsPrec _ (AssertionFailed err)      = showString err
 771   showsPrec _ (DynException err)         = showString "exception :: " . showsTypeRep (dynTypeRep err)
 772   showsPrec _ (AsyncException e)         = shows e
 773   showsPrec p BlockedOnDeadMVar          = showsPrec p New.BlockedIndefinitelyOnMVar
 774   showsPrec p BlockedIndefinitely        = showsPrec p New.BlockedIndefinitelyOnSTM
 775   showsPrec p NestedAtomically           = showsPrec p New.NestedAtomically
 776   showsPrec p NonTermination             = showsPrec p New.NonTermination
 777   showsPrec p Deadlock                   = showsPrec p New.Deadlock
 778
 779 instance Eq Exception where
 780   IOException e1      == IOException e2      = e1 == e2
 781   ArithException e1   == ArithException e2   = e1 == e2
 782   ArrayException e1   == ArrayException e2   = e1 == e2
 783   ErrorCall e1        == ErrorCall e2        = e1 == e2
 784   ExitException e1    == ExitException e2    = e1 == e2
 785   NoMethodError e1    == NoMethodError e2    = e1 == e2
 786   PatternMatchFail e1 == PatternMatchFail e2 = e1 == e2
 787   RecSelError e1      == RecSelError e2      = e1 == e2
 788   RecConError e1      == RecConError e2      = e1 == e2
 789   RecUpdError e1      == RecUpdError e2      = e1 == e2
 790   AssertionFailed e1  == AssertionFailed e2  = e1 == e2
 791   DynException _      == DynException _      = False -- incomparable
 792   AsyncException e1   == AsyncException e2   = e1 == e2
 793   BlockedOnDeadMVar   == BlockedOnDeadMVar   = True
 794   NonTermination      == NonTermination      = True
 795   NestedAtomically    == NestedAtomically    = True
 796   Deadlock            == Deadlock            = True
 797   _                   == _                   = False
 798