Data/Dynamic.hs

   1 {-# OPTIONS -fno-implicit-prelude #-}
   2 -----------------------------------------------------------------------------
   3 -- |
   4 -- Module      :  Data.Dynamic
   5 -- Copyright   :  (c) The University of Glasgow 2001
   6 -- License     :  BSD-style (see the file libraries/base/LICENSE)
   7 --
   8 -- Maintainer  :  libraries@haskell.org
   9 -- Stability   :  experimental
  10 -- Portability :  portable
  11 --
  12 -- The Dynamic interface provides basic support for dynamic types.
  13 --
  14 -- Operations for injecting values of arbitrary type into
  15 -- a dynamically typed value, Dynamic, are provided, together
  16 -- with operations for converting dynamic values into a concrete
  17 -- (monomorphic) type.
  18 --
  19 -----------------------------------------------------------------------------
  20
  21 module Data.Dynamic
  22   (
  23         -- * The @Dynamic@ type
  24         Dynamic,        -- abstract, instance of: Show, Typeable
  25
  26         -- * Converting to and from @Dynamic@
  27         toDyn,          -- :: Typeable a => a -> Dynamic
  28         fromDyn,        -- :: Typeable a => Dynamic -> a -> a
  29         fromDynamic,    -- :: Typeable a => Dynamic -> Maybe a
  30
  31         -- * Applying functions of dynamic type
  32         dynApply,
  33         dynApp,
  34
  35         -- * Concrete Type Representations
  36
  37         -- | This section is useful if you need to define your own
  38         -- instances of 'Typeable'.
  39
  40         Typeable(
  41              typeOf),   -- :: a -> TypeRep
  42
  43         -- ** Building concrete type representations
  44         TypeRep,        -- abstract, instance of: Eq, Show, Typeable
  45         TyCon,          -- abstract, instance of: Eq, Show, Typeable
  46
  47         mkTyCon,        -- :: String  -> TyCon
  48         mkAppTy,        -- :: TyCon   -> [TypeRep] -> TypeRep
  49         mkFunTy,        -- :: TypeRep -> TypeRep   -> TypeRep
  50         applyTy,        -- :: TypeRep -> TypeRep   -> Maybe TypeRep
  51
  52         --
  53         -- let fTy = mkTyCon "Foo" in show (mkAppTy (mkTyCon ",,")
  54         --                                 [fTy,fTy,fTy])
  55         --
  56         -- returns "(Foo,Foo,Foo)"
  57         --
  58         -- The TypeRep Show instance promises to print tuple types
  59         -- correctly. Tuple type constructors are specified by a
  60         -- sequence of commas, e.g., (mkTyCon ",,,,") returns
  61         -- the 5-tuple tycon.
  62         ) where
  63
  64
  65 import Data.Maybe
  66 import Data.Either
  67 import Data.Int
  68 import Data.Word
  69 import Foreign.Ptr
  70 import Foreign.StablePtr
  71
  72 #ifdef __GLASGOW_HASKELL__
  73 import GHC.Base
  74 import GHC.Show
  75 import GHC.Err
  76 import GHC.Num
  77 import GHC.Float
  78 import GHC.IOBase
  79 #endif
  80
  81 #ifdef __HUGS__
  82 import Hugs.IO
  83 import Hugs.IORef
  84 import Hugs.IOExts
  85 #endif
  86
  87 #ifdef __GLASGOW_HASKELL__
  88 unsafeCoerce :: a -> b
  89 unsafeCoerce = unsafeCoerce#
  90 #endif
  91
  92 #include "Dynamic.h"
  93
  94 {-|
  95   A value of type 'Dynamic' is an object encapsulated together with its type.
  96
  97   A 'Dynamic' may only represent a monomorphic value; an attempt to
  98   create a value of type 'Dynamic' from a polymorphically-typed
  99   expression will result in an ambiguity error (see 'toDyn').
 100
 101   'Show'ing a value of type 'Dynamic' returns a pretty-printed representation
 102   of the object\'s type; useful for debugging.
 103 -}
 104 data Dynamic = Dynamic TypeRep Obj
 105
 106 instance Show Dynamic where
 107    -- the instance just prints the type representation.
 108    showsPrec _ (Dynamic t _) =
 109           showString "<<" .
 110           showsPrec 0 t   .
 111           showString ">>"
 112
 113 data Obj = Obj
 114  -- dummy type to hold the dynamically typed value.
 115
 116 -- | A concrete representation of a (monomorphic) type.  'TypeRep'
 117 -- supports reasonably efficient equality.
 118 data TypeRep
 119  = App TyCon   [TypeRep]
 120  | Fun TypeRep TypeRep
 121    deriving ( Eq )
 122
 123 instance Show TypeRep where
 124   showsPrec p (App tycon tys) =
 125     case tys of
 126       [] -> showsPrec p tycon
 127       [x] | tycon == listTc    -> showChar '[' . shows x . showChar ']'
 128       xs
 129         | isTupleTyCon tycon -> showTuple tycon xs
 130         | otherwise          ->
 131             showParen (p > 9) $
 132             showsPrec p tycon .
 133             showChar ' '      .
 134             showArgs tys
 135
 136   showsPrec p (Fun f a) =
 137      showParen (p > 8) $
 138      showsPrec 9 f . showString " -> " . showsPrec 8 a
 139
 140 -- | An abstract representation of a type constructor.  'TyCon' objects can
 141 -- be built using 'mkTyCon'.
 142 data TyCon = TyCon Int String
 143
 144 instance Eq TyCon where
 145   (TyCon t1 _) == (TyCon t2 _) = t1 == t2
 146
 147 instance Show TyCon where
 148   showsPrec _ (TyCon _ s) = showString s
 149
 150
 151 -- | Converts an arbitrary value into an object of type 'Dynamic'.
 152 --
 153 -- The type of the object must be an instance of 'Typeable', which
 154 -- ensures that only monomorphically-typed objects may be converted to
 155 -- 'Dynamic'.  To convert a polymorphic object into 'Dynamic', give it
 156 -- a monomorphic type signature.  For example:
 157 --
 158 -- >    toDyn (id :: Int -> Int)
 159 --
 160 toDyn :: Typeable a => a -> Dynamic
 161 toDyn v = Dynamic (typeOf v) (unsafeCoerce v)
 162
 163 -- | Converts a 'Dynamic' object back into an ordinary Haskell value of
 164 -- the correct type.  See also 'fromDynamic'.
 165 fromDyn :: Typeable a
 166         => Dynamic      -- ^ the dynamically-typed object
 167         -> a            -- ^ a default value
 168         -> a            -- ^ returns: the value of the first argument, if
 169                         -- it has the correct type, otherwise the value of
 170                         -- the second argument.
 171 fromDyn (Dynamic t v) def
 172   | typeOf def == t = unsafeCoerce v
 173   | otherwise       = def
 174
 175 -- | Converts a 'Dynamic' object back into an ordinary Haskell value of
 176 -- the correct type.  See also 'fromDyn'.
 177 fromDynamic
 178         :: Typeable a
 179         => Dynamic      -- ^ the dynamically-typed object
 180         -> Maybe a      -- ^ returns: @'Just' a@, if the dyanmically-typed
 181                         -- object has the correct type (and @a@ is its value),
 182                         -- or 'Nothing' otherwise.
 183 fromDynamic (Dynamic t v) =
 184   case unsafeCoerce v of
 185     r | t == typeOf r -> Just r
 186       | otherwise     -> Nothing
 187
 188 -- | The class 'Typeable' allows a concrete representation of a type to
 189 -- be calculated.
 190 class Typeable a where
 191   typeOf :: a -> TypeRep
 192   -- ^ Takes a value of type @a@ and returns a concrete representation
 193   -- of that type.  The /value/ of the argument should be ignored by
 194   -- any instance of 'Typeable', so that it is safe to pass 'undefined' as
 195   -- the argument.
 196
 197 isTupleTyCon :: TyCon -> Bool
 198 isTupleTyCon (TyCon _ (',':_)) = True
 199 isTupleTyCon _                 = False
 200
 201 -- If we enforce the restriction that there is only one
 202 -- @TyCon@ for a type & it is shared among all its uses,
 203 -- we can map them onto Ints very simply. The benefit is,
 204 -- of course, that @TyCon@s can then be compared efficiently.
 205
 206 -- Provided the implementor of other @Typeable@ instances
 207 -- takes care of making all the @TyCon@s CAFs (toplevel constants),
 208 -- this will work.
 209
 210 -- If this constraint does turn out to be a sore thumb, changing
 211 -- the Eq instance for TyCons is trivial.
 212
 213 -- | Builds a 'TyCon' object representing a type constructor.  An
 214 -- implementation of "Data.Dynamic" should ensure that the following holds:
 215 --
 216 -- >  mkTyCon "a" == mkTyCon "a"
 217 --
 218 -- NOTE: GHC\'s implementation is quite hacky, and the above equation
 219 -- does not necessarily hold.  For defining your own instances of
 220 -- 'Typeable', try to ensure that only one call to 'mkTyCon' exists
 221 -- for each type constructor (put it at the top level, and annotate the
 222 -- corresponding definition with a @NOINLINE@ pragma).
 223 mkTyCon
 224         :: String       -- ^ the name of the type constructor (should be unique
 225                         -- in the program, so it might be wise to use the
 226                         -- fully qualified name).
 227         -> TyCon        -- ^ A unique 'TyCon' object
 228 mkTyCon str = unsafePerformIO $ do
 229    v <- readIORef uni
 230    writeIORef uni (v+1)
 231    return (TyCon v str)
 232
 233 {-# NOINLINE uni #-}
 234 uni :: IORef Int
 235 uni = unsafePerformIO ( newIORef 0 )
 236
 237 -- Some (Show.TypeRep) helpers:
 238
 239 showArgs :: Show a => [a] -> ShowS
 240 showArgs [] = id
 241 showArgs [a] = showsPrec 10 a
 242 showArgs (a:as) = showsPrec 10 a . showString " " . showArgs as
 243
 244 showTuple :: TyCon -> [TypeRep] -> ShowS
 245 showTuple (TyCon _ str) args = showChar '(' . go str args
 246  where
 247   go [] [a] = showsPrec 10 a . showChar ')'
 248   go _  []  = showChar ')' -- a failure condition, really.
 249   go (',':xs) (a:as) = showsPrec 10 a . showChar ',' . go xs as
 250   go _ _   = showChar ')'
 251
 252
 253 -- | Applies a type constructor to a sequence of types
 254 mkAppTy  :: TyCon   -> [TypeRep] -> TypeRep
 255 mkAppTy tyc args = App tyc args
 256
 257 -- | A special case of 'mkAppTy', which applies the function type constructor to
 258 -- a pair of types.
 259 mkFunTy  :: TypeRep -> TypeRep   -> TypeRep
 260 mkFunTy f a = Fun f a
 261
 262 -- Auxillary functions
 263
 264 -- (f::(a->b)) `dynApply` (x::a) = (f a)::b
 265 dynApply :: Dynamic -> Dynamic -> Maybe Dynamic
 266 dynApply (Dynamic t1 f) (Dynamic t2 x) =
 267   case applyTy t1 t2 of
 268     Just t3 -> Just (Dynamic t3 ((unsafeCoerce f) x))
 269     Nothing -> Nothing
 270
 271 dynApp :: Dynamic -> Dynamic -> Dynamic
 272 dynApp f x = case dynApply f x of
 273              Just r -> r
 274              Nothing -> error ("Type error in dynamic application.\n" ++
 275                                "Can't apply function " ++ show f ++
 276                                " to argument " ++ show x)
 277
 278 -- | Applies a type to a function type.  Returns: @'Just' u@ if the
 279 -- first argument represents a function of type @t -> u@ and the
 280 -- second argument represents a function of type @t@.  Otherwise,
 281 -- returns 'Nothing'.
 282 applyTy :: TypeRep -> TypeRep -> Maybe TypeRep
 283 applyTy (Fun t1 t2) t3
 284   | t1 == t3    = Just t2
 285 applyTy _ _     = Nothing
 286
 287 -- Prelude types
 288
 289 listTc :: TyCon
 290 listTc = mkTyCon "[]"
 291
 292 instance Typeable a => Typeable [a] where
 293   typeOf ls = mkAppTy listTc [typeOf ((undefined:: [a] -> a) ls)]
 294
 295 unitTc :: TyCon
 296 unitTc = mkTyCon "()"
 297
 298 instance Typeable () where
 299   typeOf _ = mkAppTy unitTc []
 300
 301 tup2Tc :: TyCon
 302 tup2Tc = mkTyCon ","
 303
 304 instance (Typeable a, Typeable b) => Typeable (a,b) where
 305   typeOf tu = mkAppTy tup2Tc [typeOf ((undefined :: (a,b) -> a) tu),
 306                               typeOf ((undefined :: (a,b) -> b) tu)]
 307
 308 tup3Tc :: TyCon
 309 tup3Tc = mkTyCon ",,"
 310
 311 instance ( Typeable a , Typeable b , Typeable c) => Typeable (a,b,c) where
 312   typeOf tu = mkAppTy tup3Tc [typeOf ((undefined :: (a,b,c) -> a) tu),
 313                               typeOf ((undefined :: (a,b,c) -> b) tu),
 314                               typeOf ((undefined :: (a,b,c) -> c) tu)]
 315
 316 tup4Tc :: TyCon
 317 tup4Tc = mkTyCon ",,,"
 318
 319 instance ( Typeable a
 320          , Typeable b
 321          , Typeable c
 322          , Typeable d) => Typeable (a,b,c,d) where
 323   typeOf tu = mkAppTy tup4Tc [typeOf ((undefined :: (a,b,c,d) -> a) tu),
 324                               typeOf ((undefined :: (a,b,c,d) -> b) tu),
 325                               typeOf ((undefined :: (a,b,c,d) -> c) tu),
 326                               typeOf ((undefined :: (a,b,c,d) -> d) tu)]
 327
 328 tup5Tc :: TyCon
 329 tup5Tc = mkTyCon ",,,,"
 330
 331 instance ( Typeable a
 332          , Typeable b
 333          , Typeable c
 334          , Typeable d
 335          , Typeable e) => Typeable (a,b,c,d,e) where
 336   typeOf tu = mkAppTy tup5Tc [typeOf ((undefined :: (a,b,c,d,e) -> a) tu),
 337                               typeOf ((undefined :: (a,b,c,d,e) -> b) tu),
 338                               typeOf ((undefined :: (a,b,c,d,e) -> c) tu),
 339                               typeOf ((undefined :: (a,b,c,d,e) -> d) tu),
 340                               typeOf ((undefined :: (a,b,c,d,e) -> e) tu)]
 341
 342 instance (Typeable a, Typeable b) => Typeable (a -> b) where
 343   typeOf f = mkFunTy (typeOf ((undefined :: (a -> b) -> a) f))
 344                      (typeOf ((undefined :: (a -> b) -> b) f))
 345
 346 INSTANCE_TYPEABLE0(Bool,boolTc,"Bool")
 347 INSTANCE_TYPEABLE0(Char,charTc,"Char")
 348 INSTANCE_TYPEABLE0(Float,floatTc,"Float")
 349 INSTANCE_TYPEABLE0(Double,doubleTc,"Double")
 350 INSTANCE_TYPEABLE0(Int,intTc,"Int")
 351 INSTANCE_TYPEABLE0(Integer,integerTc,"Integer")
 352 INSTANCE_TYPEABLE2(Either,eitherTc,"Either")
 353 INSTANCE_TYPEABLE1(IO,ioTc,"IO")
 354 INSTANCE_TYPEABLE1(Maybe,maybeTc,"Maybe")
 355 INSTANCE_TYPEABLE0(Ordering,orderingTc,"Ordering")
 356 INSTANCE_TYPEABLE0(Handle,handleTc,"Handle")
 357 INSTANCE_TYPEABLE1(Ptr,ptrTc,"Ptr")
 358 INSTANCE_TYPEABLE1(StablePtr,stablePtrTc,"StablePtr")
 359
 360 INSTANCE_TYPEABLE0(Int8,int8Tc, "Int8")
 361 INSTANCE_TYPEABLE0(Int16,int16Tc,"Int16")
 362 INSTANCE_TYPEABLE0(Int32,int32Tc,"Int32")
 363 INSTANCE_TYPEABLE0(Int64,int64Tc,"Int64")
 364
 365 INSTANCE_TYPEABLE0(Word8,word8Tc, "Word8" )
 366 INSTANCE_TYPEABLE0(Word16,word16Tc,"Word16")
 367 INSTANCE_TYPEABLE0(Word32,word32Tc,"Word32")
 368 INSTANCE_TYPEABLE0(Word64,word64Tc,"Word64")
 369
 370 INSTANCE_TYPEABLE0(TyCon,tyconTc,"TyCon")
 371 INSTANCE_TYPEABLE0(TypeRep,typeRepTc,"TypeRep")
 372 INSTANCE_TYPEABLE0(Dynamic,dynamicTc,"Dynamic")
 373
 374 #ifndef __NHC__
 375 #include "Dynamic.h"
 376 INSTANCE_TYPEABLE1(IORef,ioRefTc,"IORef")
 377 #endif