Data/Either.hs

   1 {-# OPTIONS_GHC -XNoImplicitPrelude #-}
   2 -----------------------------------------------------------------------------
   3 -- |
   4 -- Module      :  Data.Either
   5 -- Copyright   :  (c) The University of Glasgow 2001
   6 -- License     :  BSD-style (see the file libraries/base/LICENSE)
   7 --
   8 -- Maintainer  :  libraries@haskell.org
   9 -- Stability   :  experimental
  10 -- Portability :  portable
  11 --
  12 -- The Either type, and associated operations.
  13 --
  14 -----------------------------------------------------------------------------
  15
  16 module Data.Either (
  17    Either(..),
  18    either,           -- :: (a -> c) -> (b -> c) -> Either a b -> c
  19    lefts,            -- :: [Either a b] -> [a]
  20    rights,           -- :: [Either a b] -> [b]
  21    partitionEithers, -- :: [Either a b] -> ([a],[b])
  22  ) where
  23
  24 import Data.Tuple ()
  25
  26 #ifdef __GLASGOW_HASKELL__
  27 import GHC.Base
  28
  29 {-
  30 -- just for testing
  31 import Test.QuickCheck
  32 -}
  33
  34 {-|
  35
  36 The 'Either' type represents values with two possibilities: a value of
  37 type @'Either' a b@ is either @'Left' a@ or @'Right' b@.
  38
  39 The 'Either' type is sometimes used to represent a value which is
  40 either correct or an error; by convention, the 'Left' constructor is
  41 used to hold an error value and the 'Right' constructor is used to
  42 hold a correct value (mnemonic: \"right\" also means \"correct\").
  43 -}
  44 data  Either a b  =  Left a | Right b   deriving (Eq, Ord )
  45
  46 -- | Case analysis for the 'Either' type.
  47 -- If the value is @'Left' a@, apply the first function to @a@;
  48 -- if it is @'Right' b@, apply the second function to @b@.
  49 either                  :: (a -> c) -> (b -> c) -> Either a b -> c
  50 either f _ (Left x)     =  f x
  51 either _ g (Right y)    =  g y
  52 #endif  /* __GLASGOW_HASKELL__ */
  53
  54 -- | Extracts from a list of 'Either' all the 'Left' elements
  55 -- All the 'Left' elements are extracted in order.
  56
  57 lefts   :: [Either a b] -> [a]
  58 lefts x = [a | Left a <- x]
  59
  60 -- | Extracts from a list of 'Either' all the 'Right' elements
  61 -- All the 'Right' elements are extracted in order.
  62
  63 rights   :: [Either a b] -> [b]
  64 rights x = [a | Right a <- x]
  65
  66 -- | Partitions a list of 'Either' into two lists
  67 -- All the 'Left' elements are extracted, in order, to the first
  68 -- component of the output.  Similarly the 'Right' elements are extracted
  69 -- to the second component of the output.
  70
  71 partitionEithers :: [Either a b] -> ([a],[b])
  72 partitionEithers = foldr (either left right) ([],[])
  73  where
  74   left  a (l, r) = (a:l, r)
  75   right a (l, r) = (l, a:r)
  76
  77 {-
  78 {--------------------------------------------------------------------
  79   Testing
  80 --------------------------------------------------------------------}
  81 prop_partitionEithers :: [Either Int Int] -> Bool
  82 prop_partitionEithers x =
  83   partitionEithers x == (lefts x, rights x)
  84 -}
  85