Data/Foldable.hs

   1 -----------------------------------------------------------------------------
   2 -- |
   3 -- Module      :  Data.Foldable
   4 -- Copyright   :  Ross Paterson 2005
   5 -- License     :  BSD-style (see the LICENSE file in the distribution)
   6 --
   7 -- Maintainer  :  libraries@haskell.org
   8 -- Stability   :  experimental
   9 -- Portability :  portable
  10 --
  11 -- Class of data structures that can be folded to a summary value.
  12 --
  13 -- Many of these functions generalize "Prelude", "Control.Monad" and
  14 -- "Data.List" functions of the same names from lists to any 'Foldable'
  15 -- functor.  To avoid ambiguity, either import those modules hiding
  16 -- these names or qualify uses of these function names with an alias
  17 -- for this module.
  18
  19 module Data.Foldable (
  20         -- * Folds
  21         Foldable(..),
  22         -- ** Special biased folds
  23         foldr',
  24         foldl',
  25         foldrM,
  26         foldlM,
  27         -- ** Folding actions
  28         -- *** Applicative actions
  29         traverse_,
  30         for_,
  31         sequenceA_,
  32         asum,
  33         -- *** Monadic actions
  34         mapM_,
  35         forM_,
  36         sequence_,
  37         msum,
  38         -- ** Specialized folds
  39         toList,
  40         concat,
  41         concatMap,
  42         and,
  43         or,
  44         any,
  45         all,
  46         sum,
  47         product,
  48         maximum,
  49         maximumBy,
  50         minimum,
  51         minimumBy,
  52         -- ** Searches
  53         elem,
  54         notElem,
  55         find
  56         ) where
  57
  58 import Prelude hiding (foldl, foldr, foldl1, foldr1, mapM_, sequence_,
  59                 elem, notElem, concat, concatMap, and, or, any, all,
  60                 sum, product, maximum, minimum)
  61 import qualified Prelude (foldl, foldr, foldl1, foldr1)
  62 import Control.Applicative
  63 import Control.Monad (MonadPlus(..))
  64 import Data.Maybe (fromMaybe, listToMaybe)
  65 import Data.Monoid
  66
  67 #ifdef __NHC__
  68 import Control.Arrow (ArrowZero(..)) -- work around nhc98 typechecker problem
  69 #endif
  70
  71 #ifdef __GLASGOW_HASKELL__
  72 import GHC.Exts (build)
  73 #endif
  74
  75 -- | Data structures that can be folded.
  76 --
  77 -- Minimal complete definition: 'foldMap' or 'foldr'.
  78 --
  79 -- For example, given a data type
  80 --
  81 -- > data Tree a = Empty | Leaf a | Node (Tree a) a (Tree a)
  82 --
  83 -- a suitable instance would be
  84 --
  85 -- > instance Foldable Tree
  86 -- >    foldMap f Empty = mempty
  87 -- >    foldMap f (Leaf x) = f x
  88 -- >    foldMap f (Node l k r) = foldMap f l `mappend` f k `mappend` foldMap f r
  89 --
  90 -- This is suitable even for abstract types, as the monoid is assumed
  91 -- to satisfy the monoid laws.
  92 --
  93 class Foldable t where
  94         -- | Combine the elements of a structure using a monoid.
  95         fold :: Monoid m => t m -> m
  96         fold = foldMap id
  97
  98         -- | Map each element of the structure to a monoid,
  99         -- and combine the results.
 100         foldMap :: Monoid m => (a -> m) -> t a -> m
 101         foldMap f = foldr (mappend . f) mempty
 102
 103         -- | Right-associative fold of a structure.
 104         --
 105         -- @'foldr' f z = 'Prelude.foldr' f z . 'toList'@
 106         foldr :: (a -> b -> b) -> b -> t a -> b
 107         foldr f z t = appEndo (foldMap (Endo . f) t) z
 108
 109         -- | Left-associative fold of a structure.
 110         --
 111         -- @'foldl' f z = 'Prelude.foldl' f z . 'toList'@
 112         foldl :: (a -> b -> a) -> a -> t b -> a
 113         foldl f z t = appEndo (getDual (foldMap (Dual . Endo . flip f) t)) z
 114
 115         -- | A variant of 'foldr' that has no base case,
 116         -- and thus may only be applied to non-empty structures.
 117         --
 118         -- @'foldr1' f = 'Prelude.foldr1' f . 'toList'@
 119         foldr1 :: (a -> a -> a) -> t a -> a
 120         foldr1 f xs = fromMaybe (error "foldr1: empty structure")
 121                         (foldr mf Nothing xs)
 122           where mf x Nothing = Just x
 123                 mf x (Just y) = Just (f x y)
 124
 125         -- | A variant of 'foldl' that has no base case,
 126         -- and thus may only be applied to non-empty structures.
 127         --
 128         -- @'foldl1' f = 'Prelude.foldl1' f . 'toList'@
 129         foldl1 :: (a -> a -> a) -> t a -> a
 130         foldl1 f xs = fromMaybe (error "foldl1: empty structure")
 131                         (foldl mf Nothing xs)
 132           where mf Nothing y = Just y
 133                 mf (Just x) y = Just (f x y)
 134
 135 -- instances for Prelude types
 136
 137 instance Foldable Maybe where
 138         foldr f z Nothing = z
 139         foldr f z (Just x) = f x z
 140
 141         foldl f z Nothing = z
 142         foldl f z (Just x) = f z x
 143
 144 instance Foldable [] where
 145         foldr = Prelude.foldr
 146         foldl = Prelude.foldl
 147         foldr1 = Prelude.foldr1
 148         foldl1 = Prelude.foldl1
 149
 150 -- | Fold over the elements of a structure,
 151 -- associating to the right, but strictly.
 152 foldr' :: Foldable t => (a -> b -> b) -> b -> t a -> b
 153 foldr' f z xs = foldl f' id xs z
 154   where f' k x z = k $! f x z
 155
 156 -- | Monadic fold over the elements of a structure,
 157 -- associating to the right, i.e. from right to left.
 158 foldrM :: (Foldable t, Monad m) => (a -> b -> m b) -> b -> t a -> m b
 159 foldrM f z xs = foldl f' return xs z
 160   where f' k x z = f x z >>= k
 161
 162 -- | Fold over the elements of a structure,
 163 -- associating to the left, but strictly.
 164 foldl' :: Foldable t => (a -> b -> a) -> a -> t b -> a
 165 foldl' f z xs = foldr f' id xs z
 166   where f' x k z = k $! f z x
 167
 168 -- | Monadic fold over the elements of a structure,
 169 -- associating to the left, i.e. from left to right.
 170 foldlM :: (Foldable t, Monad m) => (a -> b -> m a) -> a -> t b -> m a
 171 foldlM f z xs = foldr f' return xs z
 172   where f' x k z = f z x >>= k
 173
 174 -- | Map each element of a structure to an action, evaluate
 175 -- these actions from left to right, and ignore the results.
 176 traverse_ :: (Foldable t, Applicative f) => (a -> f b) -> t a -> f ()
 177 traverse_ f = foldr ((*>) . f) (pure ())
 178
 179 -- | 'for_' is 'traverse_' with its arguments flipped.
 180 for_ :: (Foldable t, Applicative f) => t a -> (a -> f b) -> f ()
 181 {-# INLINE for_ #-}
 182 for_ = flip traverse_
 183
 184 -- | Map each element of a structure to a monadic action, evaluate
 185 -- these actions from left to right, and ignore the results.
 186 mapM_ :: (Foldable t, Monad m) => (a -> m b) -> t a -> m ()
 187 mapM_ f = foldr ((>>) . f) (return ())
 188
 189 -- | 'forM_' is 'mapM_' with its arguments flipped.
 190 forM_ :: (Foldable t, Monad m) => t a -> (a -> m b) -> m ()
 191 {-# INLINE forM_ #-}
 192 forM_ = flip mapM_
 193
 194 -- | Evaluate each action in the structure from left to right,
 195 -- and ignore the results.
 196 sequenceA_ :: (Foldable t, Applicative f) => t (f a) -> f ()
 197 sequenceA_ = foldr (*>) (pure ())
 198
 199 -- | Evaluate each monadic action in the structure from left to right,
 200 -- and ignore the results.
 201 sequence_ :: (Foldable t, Monad m) => t (m a) -> m ()
 202 sequence_ = foldr (>>) (return ())
 203
 204 -- | The sum of a collection of actions, generalizing 'concat'.
 205 asum :: (Foldable t, Alternative f) => t (f a) -> f a
 206 {-# INLINE asum #-}
 207 asum = foldr (<|>) empty
 208
 209 -- | The sum of a collection of actions, generalizing 'concat'.
 210 msum :: (Foldable t, MonadPlus m) => t (m a) -> m a
 211 {-# INLINE msum #-}
 212 msum = foldr mplus mzero
 213
 214 -- These use foldr rather than foldMap to avoid repeated concatenation.
 215
 216 -- | List of elements of a structure.
 217 toList :: Foldable t => t a -> [a]
 218 #ifdef __GLASGOW_HASKELL__
 219 toList t = build (\ c n -> foldr c n t)
 220 #else
 221 toList = foldr (:) []
 222 #endif
 223
 224 -- | The concatenation of all the elements of a container of lists.
 225 concat :: Foldable t => t [a] -> [a]
 226 concat = fold
 227
 228 -- | Map a function over all the elements of a container and concatenate
 229 -- the resulting lists.
 230 concatMap :: Foldable t => (a -> [b]) -> t a -> [b]
 231 concatMap = foldMap
 232
 233 -- | 'and' returns the conjunction of a container of Bools.  For the
 234 -- result to be 'True', the container must be finite; 'False', however,
 235 -- results from a 'False' value finitely far from the left end.
 236 and :: Foldable t => t Bool -> Bool
 237 and = getAll . foldMap All
 238
 239 -- | 'or' returns the disjunction of a container of Bools.  For the
 240 -- result to be 'False', the container must be finite; 'True', however,
 241 -- results from a 'True' value finitely far from the left end.
 242 or :: Foldable t => t Bool -> Bool
 243 or = getAny . foldMap Any
 244
 245 -- | Determines whether any element of the structure satisfies the predicate.
 246 any :: Foldable t => (a -> Bool) -> t a -> Bool
 247 any p = getAny . foldMap (Any . p)
 248
 249 -- | Determines whether all elements of the structure satisfy the predicate.
 250 all :: Foldable t => (a -> Bool) -> t a -> Bool
 251 all p = getAll . foldMap (All . p)
 252
 253 -- | The 'sum' function computes the sum of the numbers of a structure.
 254 sum :: (Foldable t, Num a) => t a -> a
 255 sum = getSum . foldMap Sum
 256
 257 -- | The 'product' function computes the product of the numbers of a structure.
 258 product :: (Foldable t, Num a) => t a -> a
 259 product = getProduct . foldMap Product
 260
 261 -- | The largest element of a non-empty structure.
 262 maximum :: (Foldable t, Ord a) => t a -> a
 263 maximum = foldr1 max
 264
 265 -- | The largest element of a non-empty structure with respect to the
 266 -- given comparison function.
 267 maximumBy :: Foldable t => (a -> a -> Ordering) -> t a -> a
 268 maximumBy cmp = foldr1 max'
 269   where max' x y = case cmp x y of
 270                         GT -> x
 271                         _  -> y
 272
 273 -- | The least element of a non-empty structure.
 274 minimum :: (Foldable t, Ord a) => t a -> a
 275 minimum = foldr1 min
 276
 277 -- | The least element of a non-empty structure with respect to the
 278 -- given comparison function.
 279 minimumBy :: Foldable t => (a -> a -> Ordering) -> t a -> a
 280 minimumBy cmp = foldr1 min'
 281   where min' x y = case cmp x y of
 282                         GT -> y
 283                         _  -> x
 284
 285 -- | Does the element occur in the structure?
 286 elem :: (Foldable t, Eq a) => a -> t a -> Bool
 287 elem = any . (==)
 288
 289 -- | 'notElem' is the negation of 'elem'.
 290 notElem :: (Foldable t, Eq a) => a -> t a -> Bool
 291 notElem x = not . elem x
 292
 293 -- | The 'find' function takes a predicate and a structure and returns
 294 -- the leftmost element of the structure matching the predicate, or
 295 -- 'Nothing' if there is no such element.
 296 find :: Foldable t => (a -> Bool) -> t a -> Maybe a
 297 find p = listToMaybe . concatMap (\ x -> if p x then [x] else [])