Data/Queue.hs

   1 -----------------------------------------------------------------------------
   2 -- |
   3 -- Module      :  Data.Queue
   4 -- Copyright   :  (c) The University of Glasgow 2002
   5 -- License     :  BSD-style (see the file libraries/base/LICENSE)
   6 --
   7 -- Maintainer  :  libraries@haskell.org
   8 -- Stability   :  experimental
   9 -- Portability :  portable
  10 --
  11 -- Queues with constant time operations, from
  12 -- /Simple and efficient purely functional queues and deques/,
  13 -- by Chris Okasaki, /JFP/ 5(4):583-592, October 1995.
  14 --
  15 -----------------------------------------------------------------------------
  16
  17 module Data.Queue(
  18         Queue,
  19         -- * Primitive operations
  20         -- | Each of these requires /O(1)/ time in the worst case.
  21         emptyQueue, addToQueue, deQueue,
  22         -- * Queues and lists
  23         listToQueue, queueToList
  24     ) where
  25
  26 import Prelude -- necessary to get dependencies right
  27
  28 -- | The type of FIFO queues.
  29 data Queue a = Q [a] [a] [a]
  30
  31 -- Invariants for Q xs ys xs':
  32 --      length xs = length ys + length xs'
  33 --      xs' = drop (length ys) xs       -- in fact, shared (except after fmap)
  34 -- The queue then represents the list xs ++ reverse ys
  35
  36 instance Functor Queue where
  37         fmap f (Q xs ys xs') = Q (map f xs) (map f ys) (map f xs')
  38         -- The new xs' does not share the tail of the new xs, but it does
  39         -- share the tail of the old xs, so it still forces the rotations.
  40         -- Note that elements of xs' are ignored.
  41
  42 -- | The empty queue.
  43 emptyQueue :: Queue a
  44 emptyQueue = Q [] [] []
  45
  46 -- | Add an element to the back of a queue.
  47 addToQueue :: Queue a -> a -> Queue a
  48 addToQueue (Q xs ys xs') y = makeQ xs (y:ys) xs'
  49
  50 -- | Attempt to extract the front element from a queue.
  51 -- If the queue is empty, 'Nothing',
  52 -- otherwise the first element paired with the remainder of the queue.
  53 deQueue :: Queue a -> Maybe (a, Queue a)
  54 deQueue (Q [] _ _) = Nothing
  55 deQueue (Q (x:xs) ys xs') = Just (x, makeQ xs ys xs')
  56
  57 -- Assuming
  58 --      length ys <= length xs + 1
  59 --      xs' = drop (length ys - 1) xs
  60 -- construct a queue respecting the invariant.
  61 makeQ :: [a] -> [a] -> [a] -> Queue a
  62 makeQ xs ys [] = listToQueue (rotate xs ys [])
  63 makeQ xs ys (_:xs') = Q xs ys xs'
  64
  65 -- Assuming length ys = length xs + 1,
  66 --      rotate xs ys zs = xs ++ reverse ys ++ zs
  67 rotate :: [a] -> [a] -> [a] -> [a]
  68 rotate [] (y:_) zs = y : zs             -- the _ here must be []
  69 rotate (x:xs) (y:ys) zs = x : rotate xs ys (y:zs)
  70
  71 -- | A queue with the same elements as the list.
  72 listToQueue :: [a] -> Queue a
  73 listToQueue xs = Q xs [] xs
  74
  75 -- | The elements of a queue, front first.
  76 queueToList :: Queue a -> [a]
  77 queueToList (Q xs ys _) = xs ++ reverse ys