Data/Typeable.hs

   1 {-# OPTIONS_GHC -XNoImplicitPrelude -XOverlappingInstances -funbox-strict-fields #-}
   2
   3 -- The -XOverlappingInstances flag allows the user to over-ride
   4 -- the instances for Typeable given here.  In particular, we provide an instance
   5 --      instance ... => Typeable (s a)
   6 -- But a user might want to say
   7 --      instance ... => Typeable (MyType a b)
   8
   9 -----------------------------------------------------------------------------
  10 -- |
  11 -- Module      :  Data.Typeable
  12 -- Copyright   :  (c) The University of Glasgow, CWI 2001--2004
  13 -- License     :  BSD-style (see the file libraries/base/LICENSE)
  14 --
  15 -- Maintainer  :  libraries@haskell.org
  16 -- Stability   :  experimental
  17 -- Portability :  portable
  18 --
  19 -- The 'Typeable' class reifies types to some extent by associating type
  20 -- representations to types. These type representations can be compared,
  21 -- and one can in turn define a type-safe cast operation. To this end,
  22 -- an unsafe cast is guarded by a test for type (representation)
  23 -- equivalence. The module "Data.Dynamic" uses Typeable for an
  24 -- implementation of dynamics. The module "Data.Data" uses Typeable
  25 -- and type-safe cast (but not dynamics) to support the \"Scrap your
  26 -- boilerplate\" style of generic programming.
  27 --
  28 -----------------------------------------------------------------------------
  29
  30 module Data.Typeable
  31   (
  32
  33         -- * The Typeable class
  34         Typeable( typeOf ),     -- :: a -> TypeRep
  35
  36         -- * Type-safe cast
  37         cast,                   -- :: (Typeable a, Typeable b) => a -> Maybe b
  38         gcast,                  -- a generalisation of cast
  39
  40         -- * Type representations
  41         TypeRep,        -- abstract, instance of: Eq, Show, Typeable
  42         TyCon,          -- abstract, instance of: Eq, Show, Typeable
  43         showsTypeRep,
  44
  45         -- * Construction of type representations
  46         mkTyCon,        -- :: String  -> TyCon
  47         mkTyConApp,     -- :: TyCon   -> [TypeRep] -> TypeRep
  48         mkAppTy,        -- :: TypeRep -> TypeRep   -> TypeRep
  49         mkFunTy,        -- :: TypeRep -> TypeRep   -> TypeRep
  50
  51         -- * Observation of type representations
  52         splitTyConApp,  -- :: TypeRep -> (TyCon, [TypeRep])
  53         funResultTy,    -- :: TypeRep -> TypeRep   -> Maybe TypeRep
  54         typeRepTyCon,   -- :: TypeRep -> TyCon
  55         typeRepArgs,    -- :: TypeRep -> [TypeRep]
  56         tyConString,    -- :: TyCon   -> String
  57         typeRepKey,     -- :: TypeRep -> IO Int
  58
  59         -- * The other Typeable classes
  60         -- | /Note:/ The general instances are provided for GHC only.
  61         Typeable1( typeOf1 ),   -- :: t a -> TypeRep
  62         Typeable2( typeOf2 ),   -- :: t a b -> TypeRep
  63         Typeable3( typeOf3 ),   -- :: t a b c -> TypeRep
  64         Typeable4( typeOf4 ),   -- :: t a b c d -> TypeRep
  65         Typeable5( typeOf5 ),   -- :: t a b c d e -> TypeRep
  66         Typeable6( typeOf6 ),   -- :: t a b c d e f -> TypeRep
  67         Typeable7( typeOf7 ),   -- :: t a b c d e f g -> TypeRep
  68         gcast1,                 -- :: ... => c (t a) -> Maybe (c (t' a))
  69         gcast2,                 -- :: ... => c (t a b) -> Maybe (c (t' a b))
  70
  71         -- * Default instances
  72         -- | /Note:/ These are not needed by GHC, for which these instances
  73         -- are generated by general instance declarations.
  74         typeOfDefault,  -- :: (Typeable1 t, Typeable a) => t a -> TypeRep
  75         typeOf1Default, -- :: (Typeable2 t, Typeable a) => t a b -> TypeRep
  76         typeOf2Default, -- :: (Typeable3 t, Typeable a) => t a b c -> TypeRep
  77         typeOf3Default, -- :: (Typeable4 t, Typeable a) => t a b c d -> TypeRep
  78         typeOf4Default, -- :: (Typeable5 t, Typeable a) => t a b c d e -> TypeRep
  79         typeOf5Default, -- :: (Typeable6 t, Typeable a) => t a b c d e f -> TypeRep
  80         typeOf6Default  -- :: (Typeable7 t, Typeable a) => t a b c d e f g -> TypeRep
  81
  82   ) where
  83
  84 import qualified Data.HashTable as HT
  85 import Data.Maybe
  86 import Data.Int
  87 import Data.Word
  88 import Data.List( foldl, intersperse )
  89 import Unsafe.Coerce
  90
  91 #ifdef __GLASGOW_HASKELL__
  92 import GHC.Base
  93 import GHC.Show         (Show(..), ShowS,
  94                          shows, showString, showChar, showParen)
  95 import GHC.Err          (undefined)
  96 import GHC.Num          (Integer, fromInteger, (+))
  97 import GHC.Real         ( rem, Ratio )
  98 import GHC.IORef        (IORef,newIORef)
  99 import GHC.IO           (IO, unsafePerformIO,block)
 100
 101 -- These imports are so we can define Typeable instances
 102 -- It'd be better to give Typeable instances in the modules themselves
 103 -- but they all have to be compiled before Typeable
 104 import GHC.IOArray
 105 import GHC.MVar
 106 import GHC.ST           ( ST )
 107 import GHC.STRef        ( STRef )
 108 import GHC.Ptr          ( Ptr, FunPtr )
 109 import GHC.Stable       ( StablePtr, newStablePtr, freeStablePtr,
 110                           deRefStablePtr, castStablePtrToPtr,
 111                           castPtrToStablePtr )
 112 import GHC.Arr          ( Array, STArray )
 113
 114 #endif
 115
 116 #ifdef __HUGS__
 117 import Hugs.Prelude     ( Key(..), TypeRep(..), TyCon(..), Ratio,
 118                           Handle, Ptr, FunPtr, ForeignPtr, StablePtr )
 119 import Hugs.IORef       ( IORef, newIORef, readIORef, writeIORef )
 120 import Hugs.IOExts      ( unsafePerformIO )
 121         -- For the Typeable instance
 122 import Hugs.Array       ( Array )
 123 import Hugs.IOArray
 124 import Hugs.ConcBase    ( MVar )
 125 #endif
 126
 127 #ifdef __NHC__
 128 import NHC.IOExtras (IOArray,IORef,newIORef,readIORef,writeIORef,unsafePerformIO)
 129 import IO (Handle)
 130 import Ratio (Ratio)
 131         -- For the Typeable instance
 132 import NHC.FFI  ( Ptr,FunPtr,StablePtr,ForeignPtr )
 133 import Array    ( Array )
 134 #endif
 135
 136 #include "Typeable.h"
 137
 138 #ifndef __HUGS__
 139
 140 -------------------------------------------------------------
 141 --
 142 --              Type representations
 143 --
 144 -------------------------------------------------------------
 145
 146 -- | A concrete representation of a (monomorphic) type.  'TypeRep'
 147 -- supports reasonably efficient equality.
 148 data TypeRep = TypeRep !Key TyCon [TypeRep]
 149
 150 -- Compare keys for equality
 151 instance Eq TypeRep where
 152   (TypeRep k1 _ _) == (TypeRep k2 _ _) = k1 == k2
 153
 154 -- | An abstract representation of a type constructor.  'TyCon' objects can
 155 -- be built using 'mkTyCon'.
 156 data TyCon = TyCon !Key String
 157
 158 instance Eq TyCon where
 159   (TyCon t1 _) == (TyCon t2 _) = t1 == t2
 160 #endif
 161
 162 -- | Returns a unique integer associated with a 'TypeRep'.  This can
 163 -- be used for making a mapping with TypeReps
 164 -- as the keys, for example.  It is guaranteed that @t1 == t2@ if and only if
 165 -- @typeRepKey t1 == typeRepKey t2@.
 166 --
 167 -- It is in the 'IO' monad because the actual value of the key may
 168 -- vary from run to run of the program.  You should only rely on
 169 -- the equality property, not any actual key value.  The relative ordering
 170 -- of keys has no meaning either.
 171 --
 172 typeRepKey :: TypeRep -> IO Int
 173 typeRepKey (TypeRep (Key i) _ _) = return i
 174
 175         --
 176         -- let fTy = mkTyCon "Foo" in show (mkTyConApp (mkTyCon ",,")
 177         --                                 [fTy,fTy,fTy])
 178         --
 179         -- returns "(Foo,Foo,Foo)"
 180         --
 181         -- The TypeRep Show instance promises to print tuple types
 182         -- correctly. Tuple type constructors are specified by a
 183         -- sequence of commas, e.g., (mkTyCon ",,,,") returns
 184         -- the 5-tuple tycon.
 185
 186 ----------------- Construction --------------------
 187
 188 -- | Applies a type constructor to a sequence of types
 189 mkTyConApp  :: TyCon -> [TypeRep] -> TypeRep
 190 mkTyConApp tc@(TyCon tc_k _) args
 191   = TypeRep (appKeys tc_k arg_ks) tc args
 192   where
 193     arg_ks = [k | TypeRep k _ _ <- args]
 194
 195 -- | A special case of 'mkTyConApp', which applies the function
 196 -- type constructor to a pair of types.
 197 mkFunTy  :: TypeRep -> TypeRep -> TypeRep
 198 mkFunTy f a = mkTyConApp funTc [f,a]
 199
 200 -- | Splits a type constructor application
 201 splitTyConApp :: TypeRep -> (TyCon,[TypeRep])
 202 splitTyConApp (TypeRep _ tc trs) = (tc,trs)
 203
 204 -- | Applies a type to a function type.  Returns: @'Just' u@ if the
 205 -- first argument represents a function of type @t -> u@ and the
 206 -- second argument represents a function of type @t@.  Otherwise,
 207 -- returns 'Nothing'.
 208 funResultTy :: TypeRep -> TypeRep -> Maybe TypeRep
 209 funResultTy trFun trArg
 210   = case splitTyConApp trFun of
 211       (tc, [t1,t2]) | tc == funTc && t1 == trArg -> Just t2
 212       _ -> Nothing
 213
 214 -- | Adds a TypeRep argument to a TypeRep.
 215 mkAppTy :: TypeRep -> TypeRep -> TypeRep
 216 mkAppTy (TypeRep tr_k tc trs) arg_tr
 217   = let (TypeRep arg_k _ _) = arg_tr
 218      in  TypeRep (appKey tr_k arg_k) tc (trs++[arg_tr])
 219
 220 -- If we enforce the restriction that there is only one
 221 -- @TyCon@ for a type & it is shared among all its uses,
 222 -- we can map them onto Ints very simply. The benefit is,
 223 -- of course, that @TyCon@s can then be compared efficiently.
 224
 225 -- Provided the implementor of other @Typeable@ instances
 226 -- takes care of making all the @TyCon@s CAFs (toplevel constants),
 227 -- this will work.
 228
 229 -- If this constraint does turn out to be a sore thumb, changing
 230 -- the Eq instance for TyCons is trivial.
 231
 232 -- | Builds a 'TyCon' object representing a type constructor.  An
 233 -- implementation of "Data.Typeable" should ensure that the following holds:
 234 --
 235 -- >  mkTyCon "a" == mkTyCon "a"
 236 --
 237
 238 mkTyCon :: String       -- ^ the name of the type constructor (should be unique
 239                         -- in the program, so it might be wise to use the
 240                         -- fully qualified name).
 241         -> TyCon        -- ^ A unique 'TyCon' object
 242 mkTyCon str = TyCon (mkTyConKey str) str
 243
 244 ----------------- Observation ---------------------
 245
 246 -- | Observe the type constructor of a type representation
 247 typeRepTyCon :: TypeRep -> TyCon
 248 typeRepTyCon (TypeRep _ tc _) = tc
 249
 250 -- | Observe the argument types of a type representation
 251 typeRepArgs :: TypeRep -> [TypeRep]
 252 typeRepArgs (TypeRep _ _ args) = args
 253
 254 -- | Observe string encoding of a type representation
 255 tyConString :: TyCon   -> String
 256 tyConString  (TyCon _ str) = str
 257
 258 ----------------- Showing TypeReps --------------------
 259
 260 instance Show TypeRep where
 261   showsPrec p (TypeRep _ tycon tys) =
 262     case tys of
 263       [] -> showsPrec p tycon
 264       [x]   | tycon == listTc -> showChar '[' . shows x . showChar ']'
 265       [a,r] | tycon == funTc  -> showParen (p > 8) $
 266                                  showsPrec 9 a .
 267                                  showString " -> " .
 268                                  showsPrec 8 r
 269       xs | isTupleTyCon tycon -> showTuple xs
 270          | otherwise         ->
 271             showParen (p > 9) $
 272             showsPrec p tycon .
 273             showChar ' '      .
 274             showArgs tys
 275
 276 showsTypeRep :: TypeRep -> ShowS
 277 showsTypeRep = shows
 278
 279 instance Show TyCon where
 280   showsPrec _ (TyCon _ s) = showString s
 281
 282 isTupleTyCon :: TyCon -> Bool
 283 isTupleTyCon (TyCon _ ('(':',':_)) = True
 284 isTupleTyCon _                     = False
 285
 286 -- Some (Show.TypeRep) helpers:
 287
 288 showArgs :: Show a => [a] -> ShowS
 289 showArgs [] = id
 290 showArgs [a] = showsPrec 10 a
 291 showArgs (a:as) = showsPrec 10 a . showString " " . showArgs as
 292
 293 showTuple :: [TypeRep] -> ShowS
 294 showTuple args = showChar '('
 295                . (foldr (.) id $ intersperse (showChar ',')
 296                                $ map (showsPrec 10) args)
 297                . showChar ')'
 298
 299 -------------------------------------------------------------
 300 --
 301 --      The Typeable class and friends
 302 --
 303 -------------------------------------------------------------
 304
 305 -- | The class 'Typeable' allows a concrete representation of a type to
 306 -- be calculated.
 307 class Typeable a where
 308   typeOf :: a -> TypeRep
 309   -- ^ Takes a value of type @a@ and returns a concrete representation
 310   -- of that type.  The /value/ of the argument should be ignored by
 311   -- any instance of 'Typeable', so that it is safe to pass 'undefined' as
 312   -- the argument.
 313
 314 -- | Variant for unary type constructors
 315 class Typeable1 t where
 316   typeOf1 :: t a -> TypeRep
 317
 318 -- | For defining a 'Typeable' instance from any 'Typeable1' instance.
 319 typeOfDefault :: (Typeable1 t, Typeable a) => t a -> TypeRep
 320 typeOfDefault x = typeOf1 x `mkAppTy` typeOf (argType x)
 321  where
 322    argType :: t a -> a
 323    argType =  undefined
 324
 325 -- | Variant for binary type constructors
 326 class Typeable2 t where
 327   typeOf2 :: t a b -> TypeRep
 328
 329 -- | For defining a 'Typeable1' instance from any 'Typeable2' instance.
 330 typeOf1Default :: (Typeable2 t, Typeable a) => t a b -> TypeRep
 331 typeOf1Default x = typeOf2 x `mkAppTy` typeOf (argType x)
 332  where
 333    argType :: t a b -> a
 334    argType =  undefined
 335
 336 -- | Variant for 3-ary type constructors
 337 class Typeable3 t where
 338   typeOf3 :: t a b c -> TypeRep
 339
 340 -- | For defining a 'Typeable2' instance from any 'Typeable3' instance.
 341 typeOf2Default :: (Typeable3 t, Typeable a) => t a b c -> TypeRep
 342 typeOf2Default x = typeOf3 x `mkAppTy` typeOf (argType x)
 343  where
 344    argType :: t a b c -> a
 345    argType =  undefined
 346
 347 -- | Variant for 4-ary type constructors
 348 class Typeable4 t where
 349   typeOf4 :: t a b c d -> TypeRep
 350
 351 -- | For defining a 'Typeable3' instance from any 'Typeable4' instance.
 352 typeOf3Default :: (Typeable4 t, Typeable a) => t a b c d -> TypeRep
 353 typeOf3Default x = typeOf4 x `mkAppTy` typeOf (argType x)
 354  where
 355    argType :: t a b c d -> a
 356    argType =  undefined
 357
 358 -- | Variant for 5-ary type constructors
 359 class Typeable5 t where
 360   typeOf5 :: t a b c d e -> TypeRep
 361
 362 -- | For defining a 'Typeable4' instance from any 'Typeable5' instance.
 363 typeOf4Default :: (Typeable5 t, Typeable a) => t a b c d e -> TypeRep
 364 typeOf4Default x = typeOf5 x `mkAppTy` typeOf (argType x)
 365  where
 366    argType :: t a b c d e -> a
 367    argType =  undefined
 368
 369 -- | Variant for 6-ary type constructors
 370 class Typeable6 t where
 371   typeOf6 :: t a b c d e f -> TypeRep
 372
 373 -- | For defining a 'Typeable5' instance from any 'Typeable6' instance.
 374 typeOf5Default :: (Typeable6 t, Typeable a) => t a b c d e f -> TypeRep
 375 typeOf5Default x = typeOf6 x `mkAppTy` typeOf (argType x)
 376  where
 377    argType :: t a b c d e f -> a
 378    argType =  undefined
 379
 380 -- | Variant for 7-ary type constructors
 381 class Typeable7 t where
 382   typeOf7 :: t a b c d e f g -> TypeRep
 383
 384 -- | For defining a 'Typeable6' instance from any 'Typeable7' instance.
 385 typeOf6Default :: (Typeable7 t, Typeable a) => t a b c d e f g -> TypeRep
 386 typeOf6Default x = typeOf7 x `mkAppTy` typeOf (argType x)
 387  where
 388    argType :: t a b c d e f g -> a
 389    argType =  undefined
 390
 391 #ifdef __GLASGOW_HASKELL__
 392 -- Given a @Typeable@/n/ instance for an /n/-ary type constructor,
 393 -- define the instances for partial applications.
 394 -- Programmers using non-GHC implementations must do this manually
 395 -- for each type constructor.
 396 -- (The INSTANCE_TYPEABLE/n/ macros in Typeable.h include this.)
 397
 398 -- | One Typeable instance for all Typeable1 instances
 399 instance (Typeable1 s, Typeable a)
 400        => Typeable (s a) where
 401   typeOf = typeOfDefault
 402
 403 -- | One Typeable1 instance for all Typeable2 instances
 404 instance (Typeable2 s, Typeable a)
 405        => Typeable1 (s a) where
 406   typeOf1 = typeOf1Default
 407
 408 -- | One Typeable2 instance for all Typeable3 instances
 409 instance (Typeable3 s, Typeable a)
 410        => Typeable2 (s a) where
 411   typeOf2 = typeOf2Default
 412
 413 -- | One Typeable3 instance for all Typeable4 instances
 414 instance (Typeable4 s, Typeable a)
 415        => Typeable3 (s a) where
 416   typeOf3 = typeOf3Default
 417
 418 -- | One Typeable4 instance for all Typeable5 instances
 419 instance (Typeable5 s, Typeable a)
 420        => Typeable4 (s a) where
 421   typeOf4 = typeOf4Default
 422
 423 -- | One Typeable5 instance for all Typeable6 instances
 424 instance (Typeable6 s, Typeable a)
 425        => Typeable5 (s a) where
 426   typeOf5 = typeOf5Default
 427
 428 -- | One Typeable6 instance for all Typeable7 instances
 429 instance (Typeable7 s, Typeable a)
 430        => Typeable6 (s a) where
 431   typeOf6 = typeOf6Default
 432
 433 #endif /* __GLASGOW_HASKELL__ */
 434
 435 -------------------------------------------------------------
 436 --
 437 --              Type-safe cast
 438 --
 439 -------------------------------------------------------------
 440
 441 -- | The type-safe cast operation
 442 cast :: (Typeable a, Typeable b) => a -> Maybe b
 443 cast x = r
 444        where
 445          r = if typeOf x == typeOf (fromJust r)
 446                then Just $ unsafeCoerce x
 447                else Nothing
 448
 449 -- | A flexible variation parameterised in a type constructor
 450 gcast :: (Typeable a, Typeable b) => c a -> Maybe (c b)
 451 gcast x = r
 452  where
 453   r = if typeOf (getArg x) == typeOf (getArg (fromJust r))
 454         then Just $ unsafeCoerce x
 455         else Nothing
 456   getArg :: c x -> x
 457   getArg = undefined
 458
 459 -- | Cast for * -> *
 460 gcast1 :: (Typeable1 t, Typeable1 t') => c (t a) -> Maybe (c (t' a))
 461 gcast1 x = r
 462  where
 463   r = if typeOf1 (getArg x) == typeOf1 (getArg (fromJust r))
 464        then Just $ unsafeCoerce x
 465        else Nothing
 466   getArg :: c x -> x
 467   getArg = undefined
 468
 469 -- | Cast for * -> * -> *
 470 gcast2 :: (Typeable2 t, Typeable2 t') => c (t a b) -> Maybe (c (t' a b))
 471 gcast2 x = r
 472  where
 473   r = if typeOf2 (getArg x) == typeOf2 (getArg (fromJust r))
 474        then Just $ unsafeCoerce x
 475        else Nothing
 476   getArg :: c x -> x
 477   getArg = undefined
 478
 479 -------------------------------------------------------------
 480 --
 481 --      Instances of the Typeable classes for Prelude types
 482 --
 483 -------------------------------------------------------------
 484
 485 INSTANCE_TYPEABLE0((),unitTc,"()")
 486 INSTANCE_TYPEABLE1([],listTc,"[]")
 487 INSTANCE_TYPEABLE1(Maybe,maybeTc,"Maybe")
 488 INSTANCE_TYPEABLE1(Ratio,ratioTc,"Ratio")
 489 INSTANCE_TYPEABLE2((->),funTc,"->")
 490 INSTANCE_TYPEABLE1(IO,ioTc,"IO")
 491
 492 #if defined(__GLASGOW_HASKELL__) || defined(__HUGS__)
 493 -- Types defined in GHC.MVar
 494 INSTANCE_TYPEABLE1(MVar,mvarTc,"MVar" )
 495 #endif
 496
 497 INSTANCE_TYPEABLE2(Array,arrayTc,"Array")
 498 INSTANCE_TYPEABLE2(IOArray,iOArrayTc,"IOArray")
 499
 500 #ifdef __GLASGOW_HASKELL__
 501 -- Hugs has these too, but their Typeable<n> instances are defined
 502 -- elsewhere to keep this module within Haskell 98.
 503 -- This is important because every invocation of runhugs or ffihugs
 504 -- uses this module via Data.Dynamic.
 505 INSTANCE_TYPEABLE2(ST,stTc,"ST")
 506 INSTANCE_TYPEABLE2(STRef,stRefTc,"STRef")
 507 INSTANCE_TYPEABLE3(STArray,sTArrayTc,"STArray")
 508 #endif
 509
 510 #ifndef __NHC__
 511 INSTANCE_TYPEABLE2((,),pairTc,"(,)")
 512 INSTANCE_TYPEABLE3((,,),tup3Tc,"(,,)")
 513 INSTANCE_TYPEABLE4((,,,),tup4Tc,"(,,,)")
 514 INSTANCE_TYPEABLE5((,,,,),tup5Tc,"(,,,,)")
 515 INSTANCE_TYPEABLE6((,,,,,),tup6Tc,"(,,,,,)")
 516 INSTANCE_TYPEABLE7((,,,,,,),tup7Tc,"(,,,,,,)")
 517 #endif /* __NHC__ */
 518
 519 INSTANCE_TYPEABLE1(Ptr,ptrTc,"Ptr")
 520 INSTANCE_TYPEABLE1(FunPtr,funPtrTc,"FunPtr")
 521 #ifndef __GLASGOW_HASKELL__
 522 INSTANCE_TYPEABLE1(ForeignPtr,foreignPtrTc,"ForeignPtr")
 523 #endif
 524 INSTANCE_TYPEABLE1(StablePtr,stablePtrTc,"StablePtr")
 525 INSTANCE_TYPEABLE1(IORef,iORefTc,"IORef")
 526
 527 -------------------------------------------------------
 528 --
 529 -- Generate Typeable instances for standard datatypes
 530 --
 531 -------------------------------------------------------
 532
 533 INSTANCE_TYPEABLE0(Bool,boolTc,"Bool")
 534 INSTANCE_TYPEABLE0(Char,charTc,"Char")
 535 INSTANCE_TYPEABLE0(Float,floatTc,"Float")
 536 INSTANCE_TYPEABLE0(Double,doubleTc,"Double")
 537 INSTANCE_TYPEABLE0(Int,intTc,"Int")
 538 #ifndef __NHC__
 539 INSTANCE_TYPEABLE0(Word,wordTc,"Word" )
 540 #endif
 541 INSTANCE_TYPEABLE0(Integer,integerTc,"Integer")
 542 INSTANCE_TYPEABLE0(Ordering,orderingTc,"Ordering")
 543 #ifndef __GLASGOW_HASKELL__
 544 INSTANCE_TYPEABLE0(Handle,handleTc,"Handle")
 545 #endif
 546
 547 INSTANCE_TYPEABLE0(Int8,int8Tc,"Int8")
 548 INSTANCE_TYPEABLE0(Int16,int16Tc,"Int16")
 549 INSTANCE_TYPEABLE0(Int32,int32Tc,"Int32")
 550 INSTANCE_TYPEABLE0(Int64,int64Tc,"Int64")
 551
 552 INSTANCE_TYPEABLE0(Word8,word8Tc,"Word8" )
 553 INSTANCE_TYPEABLE0(Word16,word16Tc,"Word16")
 554 INSTANCE_TYPEABLE0(Word32,word32Tc,"Word32")
 555 INSTANCE_TYPEABLE0(Word64,word64Tc,"Word64")
 556
 557 INSTANCE_TYPEABLE0(TyCon,tyconTc,"TyCon")
 558 INSTANCE_TYPEABLE0(TypeRep,typeRepTc,"TypeRep")
 559
 560 #ifdef __GLASGOW_HASKELL__
 561 INSTANCE_TYPEABLE0(RealWorld,realWorldTc,"RealWorld")
 562 #endif
 563
 564 ---------------------------------------------
 565 --
 566 --              Internals
 567 --
 568 ---------------------------------------------
 569
 570 #ifndef __HUGS__
 571 newtype Key = Key Int deriving( Eq )
 572 #endif
 573
 574 data KeyPr = KeyPr !Key !Key deriving( Eq )
 575
 576 hashKP :: KeyPr -> Int32
 577 hashKP (KeyPr (Key k1) (Key k2)) = (HT.hashInt k1 + HT.hashInt k2) `rem` HT.prime
 578
 579 data Cache = Cache { next_key :: !(IORef Key),  -- Not used by GHC (calls genSym instead)
 580                      tc_tbl   :: !(HT.HashTable String Key),
 581                      ap_tbl   :: !(HT.HashTable KeyPr Key) }
 582
 583 {-# NOINLINE cache #-}
 584 #ifdef __GLASGOW_HASKELL__
 585 foreign import ccall unsafe "RtsTypeable.h getOrSetTypeableStore"
 586     getOrSetTypeableStore :: Ptr a -> IO (Ptr a)
 587 #endif
 588
 589 cache :: Cache
 590 cache = unsafePerformIO $ do
 591                 empty_tc_tbl <- HT.new (==) HT.hashString
 592                 empty_ap_tbl <- HT.new (==) hashKP
 593                 key_loc      <- newIORef (Key 1)
 594                 let ret = Cache {       next_key = key_loc,
 595                                         tc_tbl = empty_tc_tbl,
 596                                         ap_tbl = empty_ap_tbl }
 597 #ifdef __GLASGOW_HASKELL__
 598                 block $ do
 599                         stable_ref <- newStablePtr ret
 600                         let ref = castStablePtrToPtr stable_ref
 601                         ref2 <- getOrSetTypeableStore ref
 602                         if ref==ref2
 603                                 then deRefStablePtr stable_ref
 604                                 else do
 605                                         freeStablePtr stable_ref
 606                                         deRefStablePtr
 607                                                 (castPtrToStablePtr ref2)
 608 #else
 609                 return ret
 610 #endif
 611
 612 newKey :: IORef Key -> IO Key
 613 #ifdef __GLASGOW_HASKELL__
 614 newKey _ = do i <- genSym; return (Key i)
 615 #else
 616 newKey kloc = do { k@(Key i) <- readIORef kloc ;
 617                    writeIORef kloc (Key (i+1)) ;
 618                    return k }
 619 #endif
 620
 621 #ifdef __GLASGOW_HASKELL__
 622 foreign import ccall unsafe "genSymZh"
 623   genSym :: IO Int
 624 #endif
 625
 626 mkTyConKey :: String -> Key
 627 mkTyConKey str
 628   = unsafePerformIO $ do
 629         let Cache {next_key = kloc, tc_tbl = tbl} = cache
 630         mb_k <- HT.lookup tbl str
 631         case mb_k of
 632           Just k  -> return k
 633           Nothing -> do { k <- newKey kloc ;
 634                           HT.insert tbl str k ;
 635                           return k }
 636
 637 appKey :: Key -> Key -> Key
 638 appKey k1 k2
 639   = unsafePerformIO $ do
 640         let Cache {next_key = kloc, ap_tbl = tbl} = cache
 641         mb_k <- HT.lookup tbl kpr
 642         case mb_k of
 643           Just k  -> return k
 644           Nothing -> do { k <- newKey kloc ;
 645                           HT.insert tbl kpr k ;
 646                           return k }
 647   where
 648     kpr = KeyPr k1 k2
 649
 650 appKeys :: Key -> [Key] -> Key
 651 appKeys k ks = foldl appKey k ks