Data/Typeable.hs

   1 {-# OPTIONS_GHC -XNoImplicitPrelude -XOverlappingInstances -funbox-strict-fields #-}
   2
   3 -- The -XOverlappingInstances flag allows the user to over-ride
   4 -- the instances for Typeable given here.  In particular, we provide an instance
   5 --      instance ... => Typeable (s a)
   6 -- But a user might want to say
   7 --      instance ... => Typeable (MyType a b)
   8
   9 -----------------------------------------------------------------------------
  10 -- |
  11 -- Module      :  Data.Typeable
  12 -- Copyright   :  (c) The University of Glasgow, CWI 2001--2004
  13 -- License     :  BSD-style (see the file libraries/base/LICENSE)
  14 --
  15 -- Maintainer  :  libraries@haskell.org
  16 -- Stability   :  experimental
  17 -- Portability :  portable
  18 --
  19 -- The 'Typeable' class reifies types to some extent by associating type
  20 -- representations to types. These type representations can be compared,
  21 -- and one can in turn define a type-safe cast operation. To this end,
  22 -- an unsafe cast is guarded by a test for type (representation)
  23 -- equivalence. The module "Data.Dynamic" uses Typeable for an
  24 -- implementation of dynamics. The module "Data.Generics" uses Typeable
  25 -- and type-safe cast (but not dynamics) to support the \"Scrap your
  26 -- boilerplate\" style of generic programming.
  27 --
  28 -----------------------------------------------------------------------------
  29
  30 module Data.Typeable
  31   (
  32
  33         -- * The Typeable class
  34         Typeable( typeOf ),     -- :: a -> TypeRep
  35
  36         -- * Type-safe cast
  37         cast,                   -- :: (Typeable a, Typeable b) => a -> Maybe b
  38         gcast,                  -- a generalisation of cast
  39
  40         -- * Type representations
  41         TypeRep,        -- abstract, instance of: Eq, Show, Typeable
  42         TyCon,          -- abstract, instance of: Eq, Show, Typeable
  43         showsTypeRep,
  44
  45         -- * Construction of type representations
  46         mkTyCon,        -- :: String  -> TyCon
  47         mkTyConApp,     -- :: TyCon   -> [TypeRep] -> TypeRep
  48         mkAppTy,        -- :: TypeRep -> TypeRep   -> TypeRep
  49         mkFunTy,        -- :: TypeRep -> TypeRep   -> TypeRep
  50
  51         -- * Observation of type representations
  52         splitTyConApp,  -- :: TypeRep -> (TyCon, [TypeRep])
  53         funResultTy,    -- :: TypeRep -> TypeRep   -> Maybe TypeRep
  54         typeRepTyCon,   -- :: TypeRep -> TyCon
  55         typeRepArgs,    -- :: TypeRep -> [TypeRep]
  56         tyConString,    -- :: TyCon   -> String
  57         typeRepKey,     -- :: TypeRep -> IO Int
  58
  59         -- * The other Typeable classes
  60         -- | /Note:/ The general instances are provided for GHC only.
  61         Typeable1( typeOf1 ),   -- :: t a -> TypeRep
  62         Typeable2( typeOf2 ),   -- :: t a b -> TypeRep
  63         Typeable3( typeOf3 ),   -- :: t a b c -> TypeRep
  64         Typeable4( typeOf4 ),   -- :: t a b c d -> TypeRep
  65         Typeable5( typeOf5 ),   -- :: t a b c d e -> TypeRep
  66         Typeable6( typeOf6 ),   -- :: t a b c d e f -> TypeRep
  67         Typeable7( typeOf7 ),   -- :: t a b c d e f g -> TypeRep
  68         gcast1,                 -- :: ... => c (t a) -> Maybe (c (t' a))
  69         gcast2,                 -- :: ... => c (t a b) -> Maybe (c (t' a b))
  70
  71         -- * Default instances
  72         -- | /Note:/ These are not needed by GHC, for which these instances
  73         -- are generated by general instance declarations.
  74         typeOfDefault,  -- :: (Typeable1 t, Typeable a) => t a -> TypeRep
  75         typeOf1Default, -- :: (Typeable2 t, Typeable a) => t a b -> TypeRep
  76         typeOf2Default, -- :: (Typeable3 t, Typeable a) => t a b c -> TypeRep
  77         typeOf3Default, -- :: (Typeable4 t, Typeable a) => t a b c d -> TypeRep
  78         typeOf4Default, -- :: (Typeable5 t, Typeable a) => t a b c d e -> TypeRep
  79         typeOf5Default, -- :: (Typeable6 t, Typeable a) => t a b c d e f -> TypeRep
  80         typeOf6Default  -- :: (Typeable7 t, Typeable a) => t a b c d e f g -> TypeRep
  81
  82   ) where
  83
  84 import qualified Data.HashTable as HT
  85 import Data.Maybe
  86 import Data.Either
  87 import Data.Int
  88 import Data.Word
  89 import Data.List( foldl, intersperse )
  90 import Unsafe.Coerce
  91
  92 #ifdef __GLASGOW_HASKELL__
  93 import GHC.Base
  94 import GHC.Show
  95 import GHC.Err
  96 import GHC.Num
  97 import GHC.Float
  98 import GHC.Real         ( rem, Ratio )
  99 import GHC.IOBase       (IORef,newIORef,unsafePerformIO)
 100
 101 -- These imports are so we can define Typeable instances
 102 -- It'd be better to give Typeable instances in the modules themselves
 103 -- but they all have to be compiled before Typeable
 104 import GHC.IOBase       ( IO, MVar, Exception, ArithException, IOException,
 105                           ArrayException, AsyncException, Handle, block )
 106 import GHC.ST           ( ST )
 107 import GHC.STRef        ( STRef )
 108 import GHC.Ptr          ( Ptr, FunPtr )
 109 import GHC.ForeignPtr   ( ForeignPtr )
 110 import GHC.Stable       ( StablePtr, newStablePtr, freeStablePtr,
 111                           deRefStablePtr, castStablePtrToPtr,
 112                           castPtrToStablePtr )
 113 import GHC.Arr          ( Array, STArray )
 114
 115 #endif
 116
 117 #ifdef __HUGS__
 118 import Hugs.Prelude     ( Key(..), TypeRep(..), TyCon(..), Ratio,
 119                           Exception, ArithException, IOException,
 120                           ArrayException, AsyncException, Handle,
 121                           Ptr, FunPtr, ForeignPtr, StablePtr )
 122 import Hugs.IORef       ( IORef, newIORef, readIORef, writeIORef )
 123 import Hugs.IOExts      ( unsafePerformIO )
 124         -- For the Typeable instance
 125 import Hugs.Array       ( Array )
 126 import Hugs.ConcBase    ( MVar )
 127 #endif
 128
 129 #ifdef __NHC__
 130 import NHC.IOExtras (IORef,newIORef,readIORef,writeIORef,unsafePerformIO)
 131 import IO (Handle)
 132 import Ratio (Ratio)
 133         -- For the Typeable instance
 134 import NHC.FFI  ( Ptr,FunPtr,StablePtr,ForeignPtr )
 135 import Array    ( Array )
 136 #endif
 137
 138 #include "Typeable.h"
 139
 140 #ifndef __HUGS__
 141
 142 -------------------------------------------------------------
 143 --
 144 --              Type representations
 145 --
 146 -------------------------------------------------------------
 147
 148 -- | A concrete representation of a (monomorphic) type.  'TypeRep'
 149 -- supports reasonably efficient equality.
 150 data TypeRep = TypeRep !Key TyCon [TypeRep]
 151
 152 -- Compare keys for equality
 153 instance Eq TypeRep where
 154   (TypeRep k1 _ _) == (TypeRep k2 _ _) = k1 == k2
 155
 156 -- | An abstract representation of a type constructor.  'TyCon' objects can
 157 -- be built using 'mkTyCon'.
 158 data TyCon = TyCon !Key String
 159
 160 instance Eq TyCon where
 161   (TyCon t1 _) == (TyCon t2 _) = t1 == t2
 162 #endif
 163
 164 -- | Returns a unique integer associated with a 'TypeRep'.  This can
 165 -- be used for making a mapping with TypeReps
 166 -- as the keys, for example.  It is guaranteed that @t1 == t2@ if and only if
 167 -- @typeRepKey t1 == typeRepKey t2@.
 168 --
 169 -- It is in the 'IO' monad because the actual value of the key may
 170 -- vary from run to run of the program.  You should only rely on
 171 -- the equality property, not any actual key value.  The relative ordering
 172 -- of keys has no meaning either.
 173 --
 174 typeRepKey :: TypeRep -> IO Int
 175 typeRepKey (TypeRep (Key i) _ _) = return i
 176
 177         --
 178         -- let fTy = mkTyCon "Foo" in show (mkTyConApp (mkTyCon ",,")
 179         --                                 [fTy,fTy,fTy])
 180         --
 181         -- returns "(Foo,Foo,Foo)"
 182         --
 183         -- The TypeRep Show instance promises to print tuple types
 184         -- correctly. Tuple type constructors are specified by a
 185         -- sequence of commas, e.g., (mkTyCon ",,,,") returns
 186         -- the 5-tuple tycon.
 187
 188 ----------------- Construction --------------------
 189
 190 -- | Applies a type constructor to a sequence of types
 191 mkTyConApp  :: TyCon -> [TypeRep] -> TypeRep
 192 mkTyConApp tc@(TyCon tc_k _) args
 193   = TypeRep (appKeys tc_k arg_ks) tc args
 194   where
 195     arg_ks = [k | TypeRep k _ _ <- args]
 196
 197 -- | A special case of 'mkTyConApp', which applies the function
 198 -- type constructor to a pair of types.
 199 mkFunTy  :: TypeRep -> TypeRep -> TypeRep
 200 mkFunTy f a = mkTyConApp funTc [f,a]
 201
 202 -- | Splits a type constructor application
 203 splitTyConApp :: TypeRep -> (TyCon,[TypeRep])
 204 splitTyConApp (TypeRep _ tc trs) = (tc,trs)
 205
 206 -- | Applies a type to a function type.  Returns: @'Just' u@ if the
 207 -- first argument represents a function of type @t -> u@ and the
 208 -- second argument represents a function of type @t@.  Otherwise,
 209 -- returns 'Nothing'.
 210 funResultTy :: TypeRep -> TypeRep -> Maybe TypeRep
 211 funResultTy trFun trArg
 212   = case splitTyConApp trFun of
 213       (tc, [t1,t2]) | tc == funTc && t1 == trArg -> Just t2
 214       _ -> Nothing
 215
 216 -- | Adds a TypeRep argument to a TypeRep.
 217 mkAppTy :: TypeRep -> TypeRep -> TypeRep
 218 mkAppTy (TypeRep tr_k tc trs) arg_tr
 219   = let (TypeRep arg_k _ _) = arg_tr
 220      in  TypeRep (appKey tr_k arg_k) tc (trs++[arg_tr])
 221
 222 -- If we enforce the restriction that there is only one
 223 -- @TyCon@ for a type & it is shared among all its uses,
 224 -- we can map them onto Ints very simply. The benefit is,
 225 -- of course, that @TyCon@s can then be compared efficiently.
 226
 227 -- Provided the implementor of other @Typeable@ instances
 228 -- takes care of making all the @TyCon@s CAFs (toplevel constants),
 229 -- this will work.
 230
 231 -- If this constraint does turn out to be a sore thumb, changing
 232 -- the Eq instance for TyCons is trivial.
 233
 234 -- | Builds a 'TyCon' object representing a type constructor.  An
 235 -- implementation of "Data.Typeable" should ensure that the following holds:
 236 --
 237 -- >  mkTyCon "a" == mkTyCon "a"
 238 --
 239
 240 mkTyCon :: String       -- ^ the name of the type constructor (should be unique
 241                         -- in the program, so it might be wise to use the
 242                         -- fully qualified name).
 243         -> TyCon        -- ^ A unique 'TyCon' object
 244 mkTyCon str = TyCon (mkTyConKey str) str
 245
 246 ----------------- Observation ---------------------
 247
 248 -- | Observe the type constructor of a type representation
 249 typeRepTyCon :: TypeRep -> TyCon
 250 typeRepTyCon (TypeRep _ tc _) = tc
 251
 252 -- | Observe the argument types of a type representation
 253 typeRepArgs :: TypeRep -> [TypeRep]
 254 typeRepArgs (TypeRep _ _ args) = args
 255
 256 -- | Observe string encoding of a type representation
 257 tyConString :: TyCon   -> String
 258 tyConString  (TyCon _ str) = str
 259
 260 ----------------- Showing TypeReps --------------------
 261
 262 instance Show TypeRep where
 263   showsPrec p (TypeRep _ tycon tys) =
 264     case tys of
 265       [] -> showsPrec p tycon
 266       [x]   | tycon == listTc -> showChar '[' . shows x . showChar ']'
 267       [a,r] | tycon == funTc  -> showParen (p > 8) $
 268                                  showsPrec 9 a .
 269                                  showString " -> " .
 270                                  showsPrec 8 r
 271       xs | isTupleTyCon tycon -> showTuple xs
 272          | otherwise         ->
 273             showParen (p > 9) $
 274             showsPrec p tycon .
 275             showChar ' '      .
 276             showArgs tys
 277
 278 showsTypeRep :: TypeRep -> ShowS
 279 showsTypeRep = shows
 280
 281 instance Show TyCon where
 282   showsPrec _ (TyCon _ s) = showString s
 283
 284 isTupleTyCon :: TyCon -> Bool
 285 isTupleTyCon (TyCon _ ('(':',':_)) = True
 286 isTupleTyCon _                     = False
 287
 288 -- Some (Show.TypeRep) helpers:
 289
 290 showArgs :: Show a => [a] -> ShowS
 291 showArgs [] = id
 292 showArgs [a] = showsPrec 10 a
 293 showArgs (a:as) = showsPrec 10 a . showString " " . showArgs as
 294
 295 showTuple :: [TypeRep] -> ShowS
 296 showTuple args = showChar '('
 297                . (foldr (.) id $ intersperse (showChar ',')
 298                                $ map (showsPrec 10) args)
 299                . showChar ')'
 300
 301 -------------------------------------------------------------
 302 --
 303 --      The Typeable class and friends
 304 --
 305 -------------------------------------------------------------
 306
 307 -- | The class 'Typeable' allows a concrete representation of a type to
 308 -- be calculated.
 309 class Typeable a where
 310   typeOf :: a -> TypeRep
 311   -- ^ Takes a value of type @a@ and returns a concrete representation
 312   -- of that type.  The /value/ of the argument should be ignored by
 313   -- any instance of 'Typeable', so that it is safe to pass 'undefined' as
 314   -- the argument.
 315
 316 -- | Variant for unary type constructors
 317 class Typeable1 t where
 318   typeOf1 :: t a -> TypeRep
 319
 320 -- | For defining a 'Typeable' instance from any 'Typeable1' instance.
 321 typeOfDefault :: (Typeable1 t, Typeable a) => t a -> TypeRep
 322 typeOfDefault x = typeOf1 x `mkAppTy` typeOf (argType x)
 323  where
 324    argType :: t a -> a
 325    argType =  undefined
 326
 327 -- | Variant for binary type constructors
 328 class Typeable2 t where
 329   typeOf2 :: t a b -> TypeRep
 330
 331 -- | For defining a 'Typeable1' instance from any 'Typeable2' instance.
 332 typeOf1Default :: (Typeable2 t, Typeable a) => t a b -> TypeRep
 333 typeOf1Default x = typeOf2 x `mkAppTy` typeOf (argType x)
 334  where
 335    argType :: t a b -> a
 336    argType =  undefined
 337
 338 -- | Variant for 3-ary type constructors
 339 class Typeable3 t where
 340   typeOf3 :: t a b c -> TypeRep
 341
 342 -- | For defining a 'Typeable2' instance from any 'Typeable3' instance.
 343 typeOf2Default :: (Typeable3 t, Typeable a) => t a b c -> TypeRep
 344 typeOf2Default x = typeOf3 x `mkAppTy` typeOf (argType x)
 345  where
 346    argType :: t a b c -> a
 347    argType =  undefined
 348
 349 -- | Variant for 4-ary type constructors
 350 class Typeable4 t where
 351   typeOf4 :: t a b c d -> TypeRep
 352
 353 -- | For defining a 'Typeable3' instance from any 'Typeable4' instance.
 354 typeOf3Default :: (Typeable4 t, Typeable a) => t a b c d -> TypeRep
 355 typeOf3Default x = typeOf4 x `mkAppTy` typeOf (argType x)
 356  where
 357    argType :: t a b c d -> a
 358    argType =  undefined
 359
 360 -- | Variant for 5-ary type constructors
 361 class Typeable5 t where
 362   typeOf5 :: t a b c d e -> TypeRep
 363
 364 -- | For defining a 'Typeable4' instance from any 'Typeable5' instance.
 365 typeOf4Default :: (Typeable5 t, Typeable a) => t a b c d e -> TypeRep
 366 typeOf4Default x = typeOf5 x `mkAppTy` typeOf (argType x)
 367  where
 368    argType :: t a b c d e -> a
 369    argType =  undefined
 370
 371 -- | Variant for 6-ary type constructors
 372 class Typeable6 t where
 373   typeOf6 :: t a b c d e f -> TypeRep
 374
 375 -- | For defining a 'Typeable5' instance from any 'Typeable6' instance.
 376 typeOf5Default :: (Typeable6 t, Typeable a) => t a b c d e f -> TypeRep
 377 typeOf5Default x = typeOf6 x `mkAppTy` typeOf (argType x)
 378  where
 379    argType :: t a b c d e f -> a
 380    argType =  undefined
 381
 382 -- | Variant for 7-ary type constructors
 383 class Typeable7 t where
 384   typeOf7 :: t a b c d e f g -> TypeRep
 385
 386 -- | For defining a 'Typeable6' instance from any 'Typeable7' instance.
 387 typeOf6Default :: (Typeable7 t, Typeable a) => t a b c d e f g -> TypeRep
 388 typeOf6Default x = typeOf7 x `mkAppTy` typeOf (argType x)
 389  where
 390    argType :: t a b c d e f g -> a
 391    argType =  undefined
 392
 393 #ifdef __GLASGOW_HASKELL__
 394 -- Given a @Typeable@/n/ instance for an /n/-ary type constructor,
 395 -- define the instances for partial applications.
 396 -- Programmers using non-GHC implementations must do this manually
 397 -- for each type constructor.
 398 -- (The INSTANCE_TYPEABLE/n/ macros in Typeable.h include this.)
 399
 400 -- | One Typeable instance for all Typeable1 instances
 401 instance (Typeable1 s, Typeable a)
 402        => Typeable (s a) where
 403   typeOf = typeOfDefault
 404
 405 -- | One Typeable1 instance for all Typeable2 instances
 406 instance (Typeable2 s, Typeable a)
 407        => Typeable1 (s a) where
 408   typeOf1 = typeOf1Default
 409
 410 -- | One Typeable2 instance for all Typeable3 instances
 411 instance (Typeable3 s, Typeable a)
 412        => Typeable2 (s a) where
 413   typeOf2 = typeOf2Default
 414
 415 -- | One Typeable3 instance for all Typeable4 instances
 416 instance (Typeable4 s, Typeable a)
 417        => Typeable3 (s a) where
 418   typeOf3 = typeOf3Default
 419
 420 -- | One Typeable4 instance for all Typeable5 instances
 421 instance (Typeable5 s, Typeable a)
 422        => Typeable4 (s a) where
 423   typeOf4 = typeOf4Default
 424
 425 -- | One Typeable5 instance for all Typeable6 instances
 426 instance (Typeable6 s, Typeable a)
 427        => Typeable5 (s a) where
 428   typeOf5 = typeOf5Default
 429
 430 -- | One Typeable6 instance for all Typeable7 instances
 431 instance (Typeable7 s, Typeable a)
 432        => Typeable6 (s a) where
 433   typeOf6 = typeOf6Default
 434
 435 #endif /* __GLASGOW_HASKELL__ */
 436
 437 -------------------------------------------------------------
 438 --
 439 --              Type-safe cast
 440 --
 441 -------------------------------------------------------------
 442
 443 -- | The type-safe cast operation
 444 cast :: (Typeable a, Typeable b) => a -> Maybe b
 445 cast x = r
 446        where
 447          r = if typeOf x == typeOf (fromJust r)
 448                then Just $ unsafeCoerce x
 449                else Nothing
 450
 451 -- | A flexible variation parameterised in a type constructor
 452 gcast :: (Typeable a, Typeable b) => c a -> Maybe (c b)
 453 gcast x = r
 454  where
 455   r = if typeOf (getArg x) == typeOf (getArg (fromJust r))
 456         then Just $ unsafeCoerce x
 457         else Nothing
 458   getArg :: c x -> x
 459   getArg = undefined
 460
 461 -- | Cast for * -> *
 462 gcast1 :: (Typeable1 t, Typeable1 t') => c (t a) -> Maybe (c (t' a))
 463 gcast1 x = r
 464  where
 465   r = if typeOf1 (getArg x) == typeOf1 (getArg (fromJust r))
 466        then Just $ unsafeCoerce x
 467        else Nothing
 468   getArg :: c x -> x
 469   getArg = undefined
 470
 471 -- | Cast for * -> * -> *
 472 gcast2 :: (Typeable2 t, Typeable2 t') => c (t a b) -> Maybe (c (t' a b))
 473 gcast2 x = r
 474  where
 475   r = if typeOf2 (getArg x) == typeOf2 (getArg (fromJust r))
 476        then Just $ unsafeCoerce x
 477        else Nothing
 478   getArg :: c x -> x
 479   getArg = undefined
 480
 481 -------------------------------------------------------------
 482 --
 483 --      Instances of the Typeable classes for Prelude types
 484 --
 485 -------------------------------------------------------------
 486
 487 INSTANCE_TYPEABLE0((),unitTc,"()")
 488 INSTANCE_TYPEABLE1([],listTc,"[]")
 489 INSTANCE_TYPEABLE1(Maybe,maybeTc,"Maybe")
 490 INSTANCE_TYPEABLE1(Ratio,ratioTc,"Ratio")
 491 INSTANCE_TYPEABLE2(Either,eitherTc,"Either")
 492 INSTANCE_TYPEABLE2((->),funTc,"->")
 493 INSTANCE_TYPEABLE1(IO,ioTc,"IO")
 494
 495 #if defined(__GLASGOW_HASKELL__) || defined(__HUGS__)
 496 -- Types defined in GHC.IOBase
 497 INSTANCE_TYPEABLE1(MVar,mvarTc,"MVar" )
 498 INSTANCE_TYPEABLE0(Exception,exceptionTc,"Exception")
 499 INSTANCE_TYPEABLE0(IOException,ioExceptionTc,"IOException")
 500 INSTANCE_TYPEABLE0(ArithException,arithExceptionTc,"ArithException")
 501 INSTANCE_TYPEABLE0(ArrayException,arrayExceptionTc,"ArrayException")
 502 INSTANCE_TYPEABLE0(AsyncException,asyncExceptionTc,"AsyncException")
 503 #endif
 504
 505 -- Types defined in GHC.Arr
 506 INSTANCE_TYPEABLE2(Array,arrayTc,"Array")
 507
 508 #ifdef __GLASGOW_HASKELL__
 509 -- Hugs has these too, but their Typeable<n> instances are defined
 510 -- elsewhere to keep this module within Haskell 98.
 511 -- This is important because every invocation of runhugs or ffihugs
 512 -- uses this module via Data.Dynamic.
 513 INSTANCE_TYPEABLE2(ST,stTc,"ST")
 514 INSTANCE_TYPEABLE2(STRef,stRefTc,"STRef")
 515 INSTANCE_TYPEABLE3(STArray,sTArrayTc,"STArray")
 516 #endif
 517
 518 #ifndef __NHC__
 519 INSTANCE_TYPEABLE2((,),pairTc,"(,)")
 520 INSTANCE_TYPEABLE3((,,),tup3Tc,"(,,)")
 521
 522 tup4Tc :: TyCon
 523 tup4Tc = mkTyCon "(,,,)"
 524
 525 instance Typeable4 (,,,) where
 526   typeOf4 tu = mkTyConApp tup4Tc []
 527
 528 tup5Tc :: TyCon
 529 tup5Tc = mkTyCon "(,,,,)"
 530
 531 instance Typeable5 (,,,,) where
 532   typeOf5 tu = mkTyConApp tup5Tc []
 533
 534 tup6Tc :: TyCon
 535 tup6Tc = mkTyCon "(,,,,,)"
 536
 537 instance Typeable6 (,,,,,) where
 538   typeOf6 tu = mkTyConApp tup6Tc []
 539
 540 tup7Tc :: TyCon
 541 tup7Tc = mkTyCon "(,,,,,,)"
 542
 543 instance Typeable7 (,,,,,,) where
 544   typeOf7 tu = mkTyConApp tup7Tc []
 545 #endif /* __NHC__ */
 546
 547 INSTANCE_TYPEABLE1(Ptr,ptrTc,"Ptr")
 548 INSTANCE_TYPEABLE1(FunPtr,funPtrTc,"FunPtr")
 549 INSTANCE_TYPEABLE1(ForeignPtr,foreignPtrTc,"ForeignPtr")
 550 INSTANCE_TYPEABLE1(StablePtr,stablePtrTc,"StablePtr")
 551 INSTANCE_TYPEABLE1(IORef,iORefTc,"IORef")
 552
 553 -------------------------------------------------------
 554 --
 555 -- Generate Typeable instances for standard datatypes
 556 --
 557 -------------------------------------------------------
 558
 559 INSTANCE_TYPEABLE0(Bool,boolTc,"Bool")
 560 INSTANCE_TYPEABLE0(Char,charTc,"Char")
 561 INSTANCE_TYPEABLE0(Float,floatTc,"Float")
 562 INSTANCE_TYPEABLE0(Double,doubleTc,"Double")
 563 INSTANCE_TYPEABLE0(Int,intTc,"Int")
 564 #ifndef __NHC__
 565 INSTANCE_TYPEABLE0(Word,wordTc,"Word" )
 566 #endif
 567 INSTANCE_TYPEABLE0(Integer,integerTc,"Integer")
 568 INSTANCE_TYPEABLE0(Ordering,orderingTc,"Ordering")
 569 INSTANCE_TYPEABLE0(Handle,handleTc,"Handle")
 570
 571 INSTANCE_TYPEABLE0(Int8,int8Tc,"Int8")
 572 INSTANCE_TYPEABLE0(Int16,int16Tc,"Int16")
 573 INSTANCE_TYPEABLE0(Int32,int32Tc,"Int32")
 574 INSTANCE_TYPEABLE0(Int64,int64Tc,"Int64")
 575
 576 INSTANCE_TYPEABLE0(Word8,word8Tc,"Word8" )
 577 INSTANCE_TYPEABLE0(Word16,word16Tc,"Word16")
 578 INSTANCE_TYPEABLE0(Word32,word32Tc,"Word32")
 579 INSTANCE_TYPEABLE0(Word64,word64Tc,"Word64")
 580
 581 INSTANCE_TYPEABLE0(TyCon,tyconTc,"TyCon")
 582 INSTANCE_TYPEABLE0(TypeRep,typeRepTc,"TypeRep")
 583
 584 #ifdef __GLASGOW_HASKELL__
 585 INSTANCE_TYPEABLE0(RealWorld,realWorldTc,"RealWorld")
 586 #endif
 587
 588 ---------------------------------------------
 589 --
 590 --              Internals
 591 --
 592 ---------------------------------------------
 593
 594 #ifndef __HUGS__
 595 newtype Key = Key Int deriving( Eq )
 596 #endif
 597
 598 data KeyPr = KeyPr !Key !Key deriving( Eq )
 599
 600 hashKP :: KeyPr -> Int32
 601 hashKP (KeyPr (Key k1) (Key k2)) = (HT.hashInt k1 + HT.hashInt k2) `rem` HT.prime
 602
 603 data Cache = Cache { next_key :: !(IORef Key),  -- Not used by GHC (calls genSym instead)
 604                      tc_tbl   :: !(HT.HashTable String Key),
 605                      ap_tbl   :: !(HT.HashTable KeyPr Key) }
 606
 607 {-# NOINLINE cache #-}
 608 #ifdef __GLASGOW_HASKELL__
 609 foreign import ccall unsafe "RtsTypeable.h getOrSetTypeableStore"
 610     getOrSetTypeableStore :: Ptr a -> IO (Ptr a)
 611 #endif
 612
 613 cache :: Cache
 614 cache = unsafePerformIO $ do
 615                 empty_tc_tbl <- HT.new (==) HT.hashString
 616                 empty_ap_tbl <- HT.new (==) hashKP
 617                 key_loc      <- newIORef (Key 1)
 618                 let ret = Cache {       next_key = key_loc,
 619                                         tc_tbl = empty_tc_tbl,
 620                                         ap_tbl = empty_ap_tbl }
 621 #ifdef __GLASGOW_HASKELL__
 622                 block $ do
 623                         stable_ref <- newStablePtr ret
 624                         let ref = castStablePtrToPtr stable_ref
 625                         ref2 <- getOrSetTypeableStore ref
 626                         if ref==ref2
 627                                 then deRefStablePtr stable_ref
 628                                 else do
 629                                         freeStablePtr stable_ref
 630                                         deRefStablePtr
 631                                                 (castPtrToStablePtr ref2)
 632 #else
 633                 return ret
 634 #endif
 635
 636 newKey :: IORef Key -> IO Key
 637 #ifdef __GLASGOW_HASKELL__
 638 newKey kloc = do i <- genSym; return (Key i)
 639 #else
 640 newKey kloc = do { k@(Key i) <- readIORef kloc ;
 641                    writeIORef kloc (Key (i+1)) ;
 642                    return k }
 643 #endif
 644
 645 #ifdef __GLASGOW_HASKELL__
 646 foreign import ccall unsafe "genSymZh"
 647   genSym :: IO Int
 648 #endif
 649
 650 mkTyConKey :: String -> Key
 651 mkTyConKey str
 652   = unsafePerformIO $ do
 653         let Cache {next_key = kloc, tc_tbl = tbl} = cache
 654         mb_k <- HT.lookup tbl str
 655         case mb_k of
 656           Just k  -> return k
 657           Nothing -> do { k <- newKey kloc ;
 658                           HT.insert tbl str k ;
 659                           return k }
 660
 661 appKey :: Key -> Key -> Key
 662 appKey k1 k2
 663   = unsafePerformIO $ do
 664         let Cache {next_key = kloc, ap_tbl = tbl} = cache
 665         mb_k <- HT.lookup tbl kpr
 666         case mb_k of
 667           Just k  -> return k
 668           Nothing -> do { k <- newKey kloc ;
 669                           HT.insert tbl kpr k ;
 670                           return k }
 671   where
 672     kpr = KeyPr k1 k2
 673
 674 appKeys :: Key -> [Key] -> Key
 675 appKeys k ks = foldl appKey k ks