Data/Version.hs

   1 -----------------------------------------------------------------------------
   2 -- |
   3 -- Module      :  Data.Version
   4 -- Copyright   :  (c) The University of Glasgow 2004
   5 -- License     :  BSD-style (see the file libraries/base/LICENSE)
   6 --
   7 -- Maintainer  :  libraries@haskell.org
   8 -- Stability   :  experimental
   9 -- Portability :  portable
  10 --
  11 -- A general library for representation and manipulation of versions.
  12 --
  13 -- Versioning schemes are many and varied, so the version
  14 -- representation provided by this library is intended to be a
  15 -- compromise between complete generality, where almost no common
  16 -- functionality could reasonably be provided, and fixing a particular
  17 -- versioning scheme, which would probably be too restrictive.
  18 --
  19 -- So the approach taken here is to provide a representation which
  20 -- subsumes many of the versioning schemes commonly in use, and we
  21 -- provide implementations of 'Eq', 'Ord' and conversion to\/from 'String'
  22 -- which will be appropriate for some applications, but not all.
  23 --
  24 -----------------------------------------------------------------------------
  25
  26 module Data.Version (
  27         -- * The @Version@ type
  28         Version(..),
  29         -- * A concrete representation of @Version@
  30         showVersion, parseVersion,
  31   ) where
  32
  33 import Text.ParserCombinators.ReadP
  34 import Data.Typeable    ( Typeable )
  35 import Data.List        ( intersperse )
  36 import Control.Monad    ( liftM )
  37 import Data.Char        ( isDigit, isAlphaNum )
  38
  39 {- |
  40 A 'Version' represents the version of a software entity.
  41
  42 An instance of 'Eq' is provided, which implements exact equality
  43 modulo reordering of the tags in the 'versionTags' field.
  44
  45 An instance of 'Ord' is also provided, which gives lexicographic
  46 ordering on the 'versionBranch' fields (i.e. 2.1 > 2.0, 1.2.3 > 1.2.2,
  47 etc.).  This is expected to be sufficient for many uses, but note that
  48 you may need to use a more specific ordering for your versioning
  49 scheme.  For example, some versioning schemes may include pre-releases
  50 which have tags @"pre1"@, @"pre2"@, and so on, and these would need to
  51 be taken into account when determining ordering.  In some cases, date
  52 ordering may be more appropriate, so the application would have to
  53 look for @date@ tags in the 'versionTags' field and compare those.
  54 The bottom line is, don't always assume that 'compare' and other 'Ord'
  55 operations are the right thing for every 'Version'.
  56
  57 Similarly, concrete representations of versions may differ.  One
  58 possible concrete representation is provided (see 'showVersion' and
  59 'parseVersion'), but depending on the application a different concrete
  60 representation may be more appropriate.
  61 -}
  62 data Version =
  63   Version { versionBranch :: [Int],
  64                 -- ^ The numeric branch for this version.  This reflects the
  65                 -- fact that most software versions are tree-structured; there
  66                 -- is a main trunk which is tagged with versions at various
  67                 -- points (1,2,3...), and the first branch off the trunk after
  68                 -- version 3 is 3.1, the second branch off the trunk after
  69                 -- version 3 is 3.2, and so on.  The tree can be branched
  70                 -- arbitrarily, just by adding more digits.
  71                 --
  72                 -- We represent the branch as a list of 'Int', so
  73                 -- version 3.2.1 becomes [3,2,1].  Lexicographic ordering
  74                 -- (i.e. the default instance of 'Ord' for @[Int]@) gives
  75                 -- the natural ordering of branches.
  76
  77            versionTags :: [String]  -- really a bag
  78                 -- ^ A version can be tagged with an arbitrary list of strings.
  79                 -- The interpretation of the list of tags is entirely dependent
  80                 -- on the entity that this version applies to.
  81         }
  82   deriving (Read,Show,Typeable)
  83
  84 instance Eq Version where
  85   v1 == v2  =  versionBranch v1 == versionBranch v2
  86                 && all (`elem` (versionTags v2)) (versionTags v1)
  87                 -- tags may be in any order
  88
  89 instance Ord Version where
  90   v1 `compare` v2 = versionBranch v1 `compare` versionBranch v2
  91
  92 -- -----------------------------------------------------------------------------
  93 -- A concrete representation of 'Version'
  94
  95 -- | Provides one possible concrete representation for 'Version'.  For
  96 -- a version with 'versionBranch' @= [1,2,3]@ and 'versionTags'
  97 -- @= ["tag1","tag2"]@, the output will be @1.2.3-tag1-tag2@.
  98 --
  99 showVersion :: Version -> String
 100 showVersion (Version branch tags)
 101   = concat (intersperse "." (map show branch)) ++
 102      concatMap ('-':) tags
 103
 104 -- | A parser for versions in the format produced by 'showVersion'.
 105 --
 106 parseVersion :: ReadP Version
 107 parseVersion = do branch <- sepBy1 (liftM read $ munch1 isDigit) (char '.')
 108                   tags   <- many (char '-' >> munch1 isAlphaNum)
 109                   return Version{versionBranch=branch, versionTags=tags}