Debug/Trace.hs

   1 -----------------------------------------------------------------------------
   2 -- |
   3 -- Module      :  Debug.Trace
   4 -- Copyright   :  (c) The University of Glasgow 2001
   5 -- License     :  BSD-style (see the file libraries/base/LICENSE)
   6 --
   7 -- Maintainer  :  libraries@haskell.org
   8 -- Stability   :  provisional
   9 -- Portability :  portable
  10 --
  11 -- The 'trace' function.
  12 --
  13 -----------------------------------------------------------------------------
  14
  15 module Debug.Trace (
  16         -- * Tracing
  17         putTraceMsg,      -- :: String -> IO ()
  18         trace,            -- :: String -> a -> a
  19         traceShow
  20   ) where
  21
  22 import Prelude
  23 import System.IO.Unsafe
  24
  25 #ifdef __GLASGOW_HASKELL__
  26 import Foreign.C.String
  27 #else
  28 import System.IO (hPutStrLn,stderr)
  29 #endif
  30
  31 -- | 'putTraceMsg' function outputs the trace message from IO monad.
  32 -- Usually the output stream is 'System.IO.stderr' but if the function is called
  33 -- from Windows GUI application then the output will be directed to the Windows
  34 -- debug console.
  35 putTraceMsg :: String -> IO ()
  36 putTraceMsg msg = do
  37 #ifndef __GLASGOW_HASKELL__
  38     hPutStrLn stderr msg
  39 #else
  40     withCString "%s\n" $ \cfmt ->
  41      withCString msg  $ \cmsg ->
  42       debugBelch cfmt cmsg
  43
  44 foreign import ccall unsafe "RtsMessages.h debugBelch"
  45    debugBelch :: CString -> CString -> IO ()
  46 #endif
  47
  48 {-# NOINLINE trace #-}
  49 {-|
  50 When called, 'trace' outputs the string in its first argument, before
  51 returning the second argument as its result. The 'trace' function is not
  52 referentially transparent, and should only be used for debugging, or for
  53 monitoring execution. Some implementations of 'trace' may decorate the string
  54 that\'s output to indicate that you\'re tracing. The function is implemented on
  55 top of 'putTraceMsg'.
  56 -}
  57 trace :: String -> a -> a
  58 trace string expr = unsafePerformIO $ do
  59     putTraceMsg string
  60     return expr
  61
  62 {-|
  63 Like 'trace', but uses 'show' on the argument to convert it to a 'String'.
  64
  65 > traceShow = trace . show
  66 -}
  67 traceShow :: (Show a) => a -> b -> b
  68 traceShow = trace . show