GHC/Base.lhs

   1 \section[GHC.Base]{Module @GHC.Base@}
   2
   3 The overall structure of the GHC Prelude is a bit tricky.
   4
   5   a) We want to avoid "orphan modules", i.e. ones with instance
   6         decls that don't belong either to a tycon or a class
   7         defined in the same module
   8
   9   b) We want to avoid giant modules
  10
  11 So the rough structure is as follows, in (linearised) dependency order
  12
  13
  14 GHC.Prim                Has no implementation.  It defines built-in things, and
  15                 by importing it you bring them into scope.
  16                 The source file is GHC.Prim.hi-boot, which is just
  17                 copied to make GHC.Prim.hi
  18
  19 GHC.Base        Classes: Eq, Ord, Functor, Monad
  20                 Types:   list, (), Int, Bool, Ordering, Char, String
  21
  22 Data.Tuple      Types: tuples, plus instances for GHC.Base classes
  23
  24 GHC.Show        Class: Show, plus instances for GHC.Base/GHC.Tup types
  25
  26 GHC.Enum        Class: Enum,  plus instances for GHC.Base/GHC.Tup types
  27
  28 Data.Maybe      Type: Maybe, plus instances for GHC.Base classes
  29
  30 GHC.List        List functions
  31
  32 GHC.Num         Class: Num, plus instances for Int
  33                 Type:  Integer, plus instances for all classes so far (Eq, Ord, Num, Show)
  34
  35                 Integer is needed here because it is mentioned in the signature
  36                 of 'fromInteger' in class Num
  37
  38 GHC.Real        Classes: Real, Integral, Fractional, RealFrac
  39                          plus instances for Int, Integer
  40                 Types:  Ratio, Rational
  41                         plus intances for classes so far
  42
  43                 Rational is needed here because it is mentioned in the signature
  44                 of 'toRational' in class Real
  45
  46 GHC.ST  The ST monad, instances and a few helper functions
  47
  48 Ix              Classes: Ix, plus instances for Int, Bool, Char, Integer, Ordering, tuples
  49
  50 GHC.Arr         Types: Array, MutableArray, MutableVar
  51
  52                 Arrays are used by a function in GHC.Float
  53
  54 GHC.Float       Classes: Floating, RealFloat
  55                 Types:   Float, Double, plus instances of all classes so far
  56
  57                 This module contains everything to do with floating point.
  58                 It is a big module (900 lines)
  59                 With a bit of luck, many modules can be compiled without ever reading GHC.Float.hi
  60
  61
  62 Other Prelude modules are much easier with fewer complex dependencies.
  63
  64 \begin{code}
  65 {-# OPTIONS_GHC -XNoImplicitPrelude #-}
  66 -- -fno-warn-orphans is needed for things like:
  67 -- Orphan rule: "x# -# x#" ALWAYS forall x# :: Int# -# x# x# = 0
  68 {-# OPTIONS_GHC -fno-warn-orphans #-}
  69 {-# OPTIONS_HADDOCK hide #-}
  70 -----------------------------------------------------------------------------
  71 -- |
  72 -- Module      :  GHC.Base
  73 -- Copyright   :  (c) The University of Glasgow, 1992-2002
  74 -- License     :  see libraries/base/LICENSE
  75 --
  76 -- Maintainer  :  cvs-ghc@haskell.org
  77 -- Stability   :  internal
  78 -- Portability :  non-portable (GHC extensions)
  79 --
  80 -- Basic data types and classes.
  81 --
  82 -----------------------------------------------------------------------------
  83
  84 #include "MachDeps.h"
  85
  86 -- #hide
  87 module GHC.Base
  88         (
  89         module GHC.Base,
  90         module GHC.Classes,
  91         module GHC.Generics,
  92         module GHC.Ordering,
  93         module GHC.Types,
  94         module GHC.Prim,        -- Re-export GHC.Prim and GHC.Err, to avoid lots
  95         module GHC.Err          -- of people having to import it explicitly
  96   )
  97         where
  98
  99 import GHC.Types
 100 import GHC.Classes
 101 import GHC.Generics
 102 import GHC.Ordering
 103 import GHC.Prim
 104 import {-# SOURCE #-} GHC.Show
 105 import {-# SOURCE #-} GHC.Err
 106 import {-# SOURCE #-} GHC.IO (failIO)
 107
 108 -- These two are not strictly speaking required by this module, but they are
 109 -- implicit dependencies whenever () or tuples are mentioned, so adding them
 110 -- as imports here helps to get the dependencies right in the new build system.
 111 import GHC.Tuple ()
 112 import GHC.Unit ()
 113
 114 infixr 9  .
 115 infixr 5  ++
 116 infixl 4  <$
 117 infixl 1  >>, >>=
 118 infixr 0  $
 119
 120 default ()              -- Double isn't available yet
 121 \end{code}
 122
 123
 124 %*********************************************************
 125 %*                                                      *
 126 \subsection{DEBUGGING STUFF}
 127 %*  (for use when compiling GHC.Base itself doesn't work)
 128 %*                                                      *
 129 %*********************************************************
 130
 131 \begin{code}
 132 {-
 133 data  Bool  =  False | True
 134 data Ordering = LT | EQ | GT
 135 data Char = C# Char#
 136 type  String = [Char]
 137 data Int = I# Int#
 138 data  ()  =  ()
 139 data [] a = MkNil
 140
 141 not True = False
 142 (&&) True True = True
 143 otherwise = True
 144
 145 build = error "urk"
 146 foldr = error "urk"
 147
 148 unpackCString# :: Addr# -> [Char]
 149 unpackFoldrCString# :: Addr# -> (Char  -> a -> a) -> a -> a
 150 unpackAppendCString# :: Addr# -> [Char] -> [Char]
 151 unpackCStringUtf8# :: Addr# -> [Char]
 152 unpackCString# a = error "urk"
 153 unpackFoldrCString# a = error "urk"
 154 unpackAppendCString# a = error "urk"
 155 unpackCStringUtf8# a = error "urk"
 156 -}
 157 \end{code}
 158
 159
 160 %*********************************************************
 161 %*                                                      *
 162 \subsection{Monadic classes @Functor@, @Monad@ }
 163 %*                                                      *
 164 %*********************************************************
 165
 166 \begin{code}
 167 {- | The 'Functor' class is used for types that can be mapped over.
 168 Instances of 'Functor' should satisfy the following laws:
 169
 170 > fmap id  ==  id
 171 > fmap (f . g)  ==  fmap f . fmap g
 172
 173 The instances of 'Functor' for lists, 'Data.Maybe.Maybe' and 'System.IO.IO'
 174 satisfy these laws.
 175 -}
 176
 177 class  Functor f  where
 178     fmap        :: (a -> b) -> f a -> f b
 179
 180     -- | Replace all locations in the input with the same value.
 181     -- The default definition is @'fmap' . 'const'@, but this may be
 182     -- overridden with a more efficient version.
 183     (<$)        :: a -> f b -> f a
 184     (<$)        =  fmap . const
 185
 186 {- | The 'Monad' class defines the basic operations over a /monad/,
 187 a concept from a branch of mathematics known as /category theory/.
 188 From the perspective of a Haskell programmer, however, it is best to
 189 think of a monad as an /abstract datatype/ of actions.
 190 Haskell's @do@ expressions provide a convenient syntax for writing
 191 monadic expressions.
 192
 193 Minimal complete definition: '>>=' and 'return'.
 194
 195 Instances of 'Monad' should satisfy the following laws:
 196
 197 > return a >>= k  ==  k a
 198 > m >>= return  ==  m
 199 > m >>= (\x -> k x >>= h)  ==  (m >>= k) >>= h
 200
 201 Instances of both 'Monad' and 'Functor' should additionally satisfy the law:
 202
 203 > fmap f xs  ==  xs >>= return . f
 204
 205 The instances of 'Monad' for lists, 'Data.Maybe.Maybe' and 'System.IO.IO'
 206 defined in the "Prelude" satisfy these laws.
 207 -}
 208
 209 class  Monad m  where
 210     -- | Sequentially compose two actions, passing any value produced
 211     -- by the first as an argument to the second.
 212     (>>=)       :: forall a b. m a -> (a -> m b) -> m b
 213     -- | Sequentially compose two actions, discarding any value produced
 214     -- by the first, like sequencing operators (such as the semicolon)
 215     -- in imperative languages.
 216     (>>)        :: forall a b. m a -> m b -> m b
 217         -- Explicit for-alls so that we know what order to
 218         -- give type arguments when desugaring
 219
 220     -- | Inject a value into the monadic type.
 221     return      :: a -> m a
 222     -- | Fail with a message.  This operation is not part of the
 223     -- mathematical definition of a monad, but is invoked on pattern-match
 224     -- failure in a @do@ expression.
 225     fail        :: String -> m a
 226
 227     {-# INLINE (>>) #-}
 228     m >> k      = m >>= \_ -> k
 229     fail s      = error s
 230 \end{code}
 231
 232
 233 %*********************************************************
 234 %*                                                      *
 235 \subsection{The list type}
 236 %*                                                      *
 237 %*********************************************************
 238
 239 \begin{code}
 240 instance Functor [] where
 241     fmap = map
 242
 243 instance  Monad []  where
 244     m >>= k             = foldr ((++) . k) [] m
 245     m >> k              = foldr ((++) . (\ _ -> k)) [] m
 246     return x            = [x]
 247     fail _              = []
 248 \end{code}
 249
 250 A few list functions that appear here because they are used here.
 251 The rest of the prelude list functions are in GHC.List.
 252
 253 ----------------------------------------------
 254 --      foldr/build/augment
 255 ----------------------------------------------
 256
 257 \begin{code}
 258 -- | 'foldr', applied to a binary operator, a starting value (typically
 259 -- the right-identity of the operator), and a list, reduces the list
 260 -- using the binary operator, from right to left:
 261 --
 262 -- > foldr f z [x1, x2, ..., xn] == x1 `f` (x2 `f` ... (xn `f` z)...)
 263
 264 foldr            :: (a -> b -> b) -> b -> [a] -> b
 265 -- foldr _ z []     =  z
 266 -- foldr f z (x:xs) =  f x (foldr f z xs)
 267 {-# INLINE [0] foldr #-}
 268 -- Inline only in the final stage, after the foldr/cons rule has had a chance
 269 -- Also note that we inline it when it has *two* parameters, which are the
 270 -- ones we are keen about specialising!
 271 foldr k z = go
 272           where
 273             go []     = z
 274             go (y:ys) = y `k` go ys
 275
 276 -- | A list producer that can be fused with 'foldr'.
 277 -- This function is merely
 278 --
 279 -- >    build g = g (:) []
 280 --
 281 -- but GHC's simplifier will transform an expression of the form
 282 -- @'foldr' k z ('build' g)@, which may arise after inlining, to @g k z@,
 283 -- which avoids producing an intermediate list.
 284
 285 build   :: forall a. (forall b. (a -> b -> b) -> b -> b) -> [a]
 286 {-# INLINE [1] build #-}
 287         -- The INLINE is important, even though build is tiny,
 288         -- because it prevents [] getting inlined in the version that
 289         -- appears in the interface file.  If [] *is* inlined, it
 290         -- won't match with [] appearing in rules in an importing module.
 291         --
 292         -- The "1" says to inline in phase 1
 293
 294 build g = g (:) []
 295
 296 -- | A list producer that can be fused with 'foldr'.
 297 -- This function is merely
 298 --
 299 -- >    augment g xs = g (:) xs
 300 --
 301 -- but GHC's simplifier will transform an expression of the form
 302 -- @'foldr' k z ('augment' g xs)@, which may arise after inlining, to
 303 -- @g k ('foldr' k z xs)@, which avoids producing an intermediate list.
 304
 305 augment :: forall a. (forall b. (a->b->b) -> b -> b) -> [a] -> [a]
 306 {-# INLINE [1] augment #-}
 307 augment g xs = g (:) xs
 308
 309 {-# RULES
 310 "fold/build"    forall k z (g::forall b. (a->b->b) -> b -> b) .
 311                 foldr k z (build g) = g k z
 312
 313 "foldr/augment" forall k z xs (g::forall b. (a->b->b) -> b -> b) .
 314                 foldr k z (augment g xs) = g k (foldr k z xs)
 315
 316 "foldr/id"                        foldr (:) [] = \x  -> x
 317 "foldr/app"     [1] forall ys. foldr (:) ys = \xs -> xs ++ ys
 318         -- Only activate this from phase 1, because that's
 319         -- when we disable the rule that expands (++) into foldr
 320
 321 -- The foldr/cons rule looks nice, but it can give disastrously
 322 -- bloated code when commpiling
 323 --      array (a,b) [(1,2), (2,2), (3,2), ...very long list... ]
 324 -- i.e. when there are very very long literal lists
 325 -- So I've disabled it for now. We could have special cases
 326 -- for short lists, I suppose.
 327 -- "foldr/cons" forall k z x xs. foldr k z (x:xs) = k x (foldr k z xs)
 328
 329 "foldr/single"  forall k z x. foldr k z [x] = k x z
 330 "foldr/nil"     forall k z.   foldr k z []  = z
 331
 332 "augment/build" forall (g::forall b. (a->b->b) -> b -> b)
 333                        (h::forall b. (a->b->b) -> b -> b) .
 334                        augment g (build h) = build (\c n -> g c (h c n))
 335 "augment/nil"   forall (g::forall b. (a->b->b) -> b -> b) .
 336                         augment g [] = build g
 337  #-}
 338
 339 -- This rule is true, but not (I think) useful:
 340 --      augment g (augment h t) = augment (\cn -> g c (h c n)) t
 341 \end{code}
 342
 343
 344 ----------------------------------------------
 345 --              map
 346 ----------------------------------------------
 347
 348 \begin{code}
 349 -- | 'map' @f xs@ is the list obtained by applying @f@ to each element
 350 -- of @xs@, i.e.,
 351 --
 352 -- > map f [x1, x2, ..., xn] == [f x1, f x2, ..., f xn]
 353 -- > map f [x1, x2, ...] == [f x1, f x2, ...]
 354
 355 map :: (a -> b) -> [a] -> [b]
 356 map _ []     = []
 357 map f (x:xs) = f x : map f xs
 358
 359 -- Note eta expanded
 360 mapFB ::  (elt -> lst -> lst) -> (a -> elt) -> a -> lst -> lst
 361 {-# INLINE [0] mapFB #-}
 362 mapFB c f = \x ys -> c (f x) ys
 363
 364 -- The rules for map work like this.
 365 --
 366 -- Up to (but not including) phase 1, we use the "map" rule to
 367 -- rewrite all saturated applications of map with its build/fold
 368 -- form, hoping for fusion to happen.
 369 -- In phase 1 and 0, we switch off that rule, inline build, and
 370 -- switch on the "mapList" rule, which rewrites the foldr/mapFB
 371 -- thing back into plain map.
 372 --
 373 -- It's important that these two rules aren't both active at once
 374 -- (along with build's unfolding) else we'd get an infinite loop
 375 -- in the rules.  Hence the activation control below.
 376 --
 377 -- The "mapFB" rule optimises compositions of map.
 378 --
 379 -- This same pattern is followed by many other functions:
 380 -- e.g. append, filter, iterate, repeat, etc.
 381
 382 {-# RULES
 383 "map"       [~1] forall f xs.   map f xs                = build (\c n -> foldr (mapFB c f) n xs)
 384 "mapList"   [1]  forall f.      foldr (mapFB (:) f) []  = map f
 385 "mapFB"     forall c f g.       mapFB (mapFB c f) g     = mapFB c (f.g)
 386   #-}
 387 \end{code}
 388
 389
 390 ----------------------------------------------
 391 --              append
 392 ----------------------------------------------
 393 \begin{code}
 394 -- | Append two lists, i.e.,
 395 --
 396 -- > [x1, ..., xm] ++ [y1, ..., yn] == [x1, ..., xm, y1, ..., yn]
 397 -- > [x1, ..., xm] ++ [y1, ...] == [x1, ..., xm, y1, ...]
 398 --
 399 -- If the first list is not finite, the result is the first list.
 400
 401 (++) :: [a] -> [a] -> [a]
 402 (++) []     ys = ys
 403 (++) (x:xs) ys = x : xs ++ ys
 404
 405 {-# RULES
 406 "++"    [~1] forall xs ys. xs ++ ys = augment (\c n -> foldr c n xs) ys
 407   #-}
 408
 409 \end{code}
 410
 411
 412 %*********************************************************
 413 %*                                                      *
 414 \subsection{Type @Bool@}
 415 %*                                                      *
 416 %*********************************************************
 417
 418 \begin{code}
 419 -- |'otherwise' is defined as the value 'True'.  It helps to make
 420 -- guards more readable.  eg.
 421 --
 422 -- >  f x | x < 0     = ...
 423 -- >      | otherwise = ...
 424 otherwise               :: Bool
 425 otherwise               =  True
 426 \end{code}
 427
 428 %*********************************************************
 429 %*                                                      *
 430 \subsection{Type @Char@ and @String@}
 431 %*                                                      *
 432 %*********************************************************
 433
 434 \begin{code}
 435 -- | A 'String' is a list of characters.  String constants in Haskell are values
 436 -- of type 'String'.
 437 --
 438 type String = [Char]
 439
 440 {-# RULES
 441 "x# `eqChar#` x#" forall x#. x# `eqChar#` x# = True
 442 "x# `neChar#` x#" forall x#. x# `neChar#` x# = False
 443 "x# `gtChar#` x#" forall x#. x# `gtChar#` x# = False
 444 "x# `geChar#` x#" forall x#. x# `geChar#` x# = True
 445 "x# `leChar#` x#" forall x#. x# `leChar#` x# = True
 446 "x# `ltChar#` x#" forall x#. x# `ltChar#` x# = False
 447   #-}
 448
 449 -- | The 'Prelude.toEnum' method restricted to the type 'Data.Char.Char'.
 450 chr :: Int -> Char
 451 chr i@(I# i#)
 452  | int2Word# i# `leWord#` int2Word# 0x10FFFF# = C# (chr# i#)
 453  | otherwise
 454     = error ("Prelude.chr: bad argument: " ++ showSignedInt (I# 9#) i "")
 455
 456 unsafeChr :: Int -> Char
 457 unsafeChr (I# i#) = C# (chr# i#)
 458
 459 -- | The 'Prelude.fromEnum' method restricted to the type 'Data.Char.Char'.
 460 ord :: Char -> Int
 461 ord (C# c#) = I# (ord# c#)
 462 \end{code}
 463
 464 String equality is used when desugaring pattern-matches against strings.
 465
 466 \begin{code}
 467 eqString :: String -> String -> Bool
 468 eqString []       []       = True
 469 eqString (c1:cs1) (c2:cs2) = c1 == c2 && cs1 `eqString` cs2
 470 eqString _        _        = False
 471
 472 {-# RULES "eqString" (==) = eqString #-}
 473 -- eqString also has a BuiltInRule in PrelRules.lhs:
 474 --      eqString (unpackCString# (Lit s1)) (unpackCString# (Lit s2) = s1==s2
 475 \end{code}
 476
 477
 478 %*********************************************************
 479 %*                                                      *
 480 \subsection{Type @Int@}
 481 %*                                                      *
 482 %*********************************************************
 483
 484 \begin{code}
 485 zeroInt, oneInt, twoInt, maxInt, minInt :: Int
 486 zeroInt = I# 0#
 487 oneInt  = I# 1#
 488 twoInt  = I# 2#
 489
 490 {- Seems clumsy. Should perhaps put minInt and MaxInt directly into MachDeps.h -}
 491 #if WORD_SIZE_IN_BITS == 31
 492 minInt  = I# (-0x40000000#)
 493 maxInt  = I# 0x3FFFFFFF#
 494 #elif WORD_SIZE_IN_BITS == 32
 495 minInt  = I# (-0x80000000#)
 496 maxInt  = I# 0x7FFFFFFF#
 497 #else
 498 minInt  = I# (-0x8000000000000000#)
 499 maxInt  = I# 0x7FFFFFFFFFFFFFFF#
 500 #endif
 501
 502 instance Eq Int where
 503     (==) = eqInt
 504     (/=) = neInt
 505
 506 instance Ord Int where
 507     compare = compareInt
 508     (<)     = ltInt
 509     (<=)    = leInt
 510     (>=)    = geInt
 511     (>)     = gtInt
 512
 513 compareInt :: Int -> Int -> Ordering
 514 (I# x#) `compareInt` (I# y#) = compareInt# x# y#
 515
 516 compareInt# :: Int# -> Int# -> Ordering
 517 compareInt# x# y#
 518     | x# <#  y# = LT
 519     | x# ==# y# = EQ
 520     | otherwise = GT
 521 \end{code}
 522
 523
 524 %*********************************************************
 525 %*                                                      *
 526 \subsection{The function type}
 527 %*                                                      *
 528 %*********************************************************
 529
 530 \begin{code}
 531 -- | Identity function.
 532 id                      :: a -> a
 533 id x                    =  x
 534
 535 -- | The call '(lazy e)' means the same as 'e', but 'lazy' has a
 536 -- magical strictness property: it is lazy in its first argument,
 537 -- even though its semantics is strict.
 538 lazy :: a -> a
 539 lazy x = x
 540 -- Implementation note: its strictness and unfolding are over-ridden
 541 -- by the definition in MkId.lhs; in both cases to nothing at all.
 542 -- That way, 'lazy' does not get inlined, and the strictness analyser
 543 -- sees it as lazy.  Then the worker/wrapper phase inlines it.
 544 -- Result: happiness
 545
 546 -- Assertion function.  This simply ignores its boolean argument.
 547 -- The compiler may rewrite it to @('assertError' line)@.
 548
 549 -- | If the first argument evaluates to 'True', then the result is the
 550 -- second argument.  Otherwise an 'AssertionFailed' exception is raised,
 551 -- containing a 'String' with the source file and line number of the
 552 -- call to 'assert'.
 553 --
 554 -- Assertions can normally be turned on or off with a compiler flag
 555 -- (for GHC, assertions are normally on unless optimisation is turned on
 556 -- with @-O@ or the @-fignore-asserts@
 557 -- option is given).  When assertions are turned off, the first
 558 -- argument to 'assert' is ignored, and the second argument is
 559 -- returned as the result.
 560
 561 --      SLPJ: in 5.04 etc 'assert' is in GHC.Prim,
 562 --      but from Template Haskell onwards it's simply
 563 --      defined here in Base.lhs
 564 assert :: Bool -> a -> a
 565 assert _pred r = r
 566
 567 breakpoint :: a -> a
 568 breakpoint r = r
 569
 570 breakpointCond :: Bool -> a -> a
 571 breakpointCond _ r = r
 572
 573 data Opaque = forall a. O a
 574
 575 -- | Constant function.
 576 const                   :: a -> b -> a
 577 const x _               =  x
 578
 579 -- | Function composition.
 580 {-# INLINE (.) #-}
 581 -- Make sure it has TWO args only on the left, so that it inlines
 582 -- when applied to two functions, even if there is no final argument
 583 (.)    :: (b -> c) -> (a -> b) -> a -> c
 584 (.) f g = \x -> f (g x)
 585
 586 -- | @'flip' f@ takes its (first) two arguments in the reverse order of @f@.
 587 flip                    :: (a -> b -> c) -> b -> a -> c
 588 flip f x y              =  f y x
 589
 590 -- | Application operator.  This operator is redundant, since ordinary
 591 -- application @(f x)@ means the same as @(f '$' x)@. However, '$' has
 592 -- low, right-associative binding precedence, so it sometimes allows
 593 -- parentheses to be omitted; for example:
 594 --
 595 -- >     f $ g $ h x  =  f (g (h x))
 596 --
 597 -- It is also useful in higher-order situations, such as @'map' ('$' 0) xs@,
 598 -- or @'Data.List.zipWith' ('$') fs xs@.
 599 {-# INLINE ($) #-}
 600 ($)                     :: (a -> b) -> a -> b
 601 f $ x                   =  f x
 602
 603 -- | @'until' p f@ yields the result of applying @f@ until @p@ holds.
 604 until                   :: (a -> Bool) -> (a -> a) -> a -> a
 605 until p f x | p x       =  x
 606             | otherwise =  until p f (f x)
 607
 608 -- | 'asTypeOf' is a type-restricted version of 'const'.  It is usually
 609 -- used as an infix operator, and its typing forces its first argument
 610 -- (which is usually overloaded) to have the same type as the second.
 611 asTypeOf                :: a -> a -> a
 612 asTypeOf                =  const
 613 \end{code}
 614
 615 %*********************************************************
 616 %*                                                      *
 617 \subsection{@Functor@ and @Monad@ instances for @IO@}
 618 %*                                                      *
 619 %*********************************************************
 620
 621 \begin{code}
 622 instance  Functor IO where
 623    fmap f x = x >>= (return . f)
 624
 625 instance  Monad IO  where
 626     {-# INLINE return #-}
 627     {-# INLINE (>>)   #-}
 628     {-# INLINE (>>=)  #-}
 629     m >> k    = m >>= \ _ -> k
 630     return    = returnIO
 631     (>>=)     = bindIO
 632     fail s    = GHC.IO.failIO s
 633
 634 returnIO :: a -> IO a
 635 returnIO x = IO $ \ s -> (# s, x #)
 636
 637 bindIO :: IO a -> (a -> IO b) -> IO b
 638 bindIO (IO m) k = IO $ \ s -> case m s of (# new_s, a #) -> unIO (k a) new_s
 639
 640 thenIO :: IO a -> IO b -> IO b
 641 thenIO (IO m) k = IO $ \ s -> case m s of (# new_s, _ #) -> unIO k new_s
 642
 643 unIO :: IO a -> (State# RealWorld -> (# State# RealWorld, a #))
 644 unIO (IO a) = a
 645 \end{code}
 646
 647 %*********************************************************
 648 %*                                                      *
 649 \subsection{@getTag@}
 650 %*                                                      *
 651 %*********************************************************
 652
 653 Returns the 'tag' of a constructor application; this function is used
 654 by the deriving code for Eq, Ord and Enum.
 655
 656 The primitive dataToTag# requires an evaluated constructor application
 657 as its argument, so we provide getTag as a wrapper that performs the
 658 evaluation before calling dataToTag#.  We could have dataToTag#
 659 evaluate its argument, but we prefer to do it this way because (a)
 660 dataToTag# can be an inline primop if it doesn't need to do any
 661 evaluation, and (b) we want to expose the evaluation to the
 662 simplifier, because it might be possible to eliminate the evaluation
 663 in the case when the argument is already known to be evaluated.
 664
 665 \begin{code}
 666 {-# INLINE getTag #-}
 667 getTag :: a -> Int#
 668 getTag x = x `seq` dataToTag# x
 669 \end{code}
 670
 671 %*********************************************************
 672 %*                                                      *
 673 \subsection{Numeric primops}
 674 %*                                                      *
 675 %*********************************************************
 676
 677 \begin{code}
 678 divInt# :: Int# -> Int# -> Int#
 679 x# `divInt#` y#
 680         -- Be careful NOT to overflow if we do any additional arithmetic
 681         -- on the arguments...  the following  previous version of this
 682         -- code has problems with overflow:
 683 --    | (x# ># 0#) && (y# <# 0#) = ((x# -# y#) -# 1#) `quotInt#` y#
 684 --    | (x# <# 0#) && (y# ># 0#) = ((x# -# y#) +# 1#) `quotInt#` y#
 685     | (x# ># 0#) && (y# <# 0#) = ((x# -# 1#) `quotInt#` y#) -# 1#
 686     | (x# <# 0#) && (y# ># 0#) = ((x# +# 1#) `quotInt#` y#) -# 1#
 687     | otherwise                = x# `quotInt#` y#
 688
 689 modInt# :: Int# -> Int# -> Int#
 690 x# `modInt#` y#
 691     | (x# ># 0#) && (y# <# 0#) ||
 692       (x# <# 0#) && (y# ># 0#)    = if r# /=# 0# then r# +# y# else 0#
 693     | otherwise                   = r#
 694     where
 695     !r# = x# `remInt#` y#
 696 \end{code}
 697
 698 Definitions of the boxed PrimOps; these will be
 699 used in the case of partial applications, etc.
 700
 701 \begin{code}
 702 {-# INLINE eqInt #-}
 703 {-# INLINE neInt #-}
 704 {-# INLINE gtInt #-}
 705 {-# INLINE geInt #-}
 706 {-# INLINE ltInt #-}
 707 {-# INLINE leInt #-}
 708 {-# INLINE plusInt #-}
 709 {-# INLINE minusInt #-}
 710 {-# INLINE timesInt #-}
 711 {-# INLINE quotInt #-}
 712 {-# INLINE remInt #-}
 713 {-# INLINE negateInt #-}
 714
 715 plusInt, minusInt, timesInt, quotInt, remInt, divInt, modInt :: Int -> Int -> Int
 716 (I# x) `plusInt`  (I# y) = I# (x +# y)
 717 (I# x) `minusInt` (I# y) = I# (x -# y)
 718 (I# x) `timesInt` (I# y) = I# (x *# y)
 719 (I# x) `quotInt`  (I# y) = I# (x `quotInt#` y)
 720 (I# x) `remInt`   (I# y) = I# (x `remInt#`  y)
 721 (I# x) `divInt`   (I# y) = I# (x `divInt#`  y)
 722 (I# x) `modInt`   (I# y) = I# (x `modInt#`  y)
 723
 724 {-# RULES
 725 "x# +# 0#" forall x#. x# +# 0# = x#
 726 "0# +# x#" forall x#. 0# +# x# = x#
 727 "x# -# 0#" forall x#. x# -# 0# = x#
 728 "x# -# x#" forall x#. x# -# x# = 0#
 729 "x# *# 0#" forall x#. x# *# 0# = 0#
 730 "0# *# x#" forall x#. 0# *# x# = 0#
 731 "x# *# 1#" forall x#. x# *# 1# = x#
 732 "1# *# x#" forall x#. 1# *# x# = x#
 733   #-}
 734
 735 negateInt :: Int -> Int
 736 negateInt (I# x) = I# (negateInt# x)
 737
 738 gtInt, geInt, eqInt, neInt, ltInt, leInt :: Int -> Int -> Bool
 739 (I# x) `gtInt` (I# y) = x >#  y
 740 (I# x) `geInt` (I# y) = x >=# y
 741 (I# x) `eqInt` (I# y) = x ==# y
 742 (I# x) `neInt` (I# y) = x /=# y
 743 (I# x) `ltInt` (I# y) = x <#  y
 744 (I# x) `leInt` (I# y) = x <=# y
 745
 746 {-# RULES
 747 "x# ># x#"  forall x#. x# >#  x# = False
 748 "x# >=# x#" forall x#. x# >=# x# = True
 749 "x# ==# x#" forall x#. x# ==# x# = True
 750 "x# /=# x#" forall x#. x# /=# x# = False
 751 "x# <# x#"  forall x#. x# <#  x# = False
 752 "x# <=# x#" forall x#. x# <=# x# = True
 753   #-}
 754
 755 {-# RULES
 756 "plusFloat x 0.0"   forall x#. plusFloat#  x#   0.0# = x#
 757 "plusFloat 0.0 x"   forall x#. plusFloat#  0.0# x#   = x#
 758 "minusFloat x 0.0"  forall x#. minusFloat# x#   0.0# = x#
 759 "minusFloat x x"    forall x#. minusFloat# x#   x#   = 0.0#
 760 "timesFloat x 0.0"  forall x#. timesFloat# x#   0.0# = 0.0#
 761 "timesFloat0.0 x"   forall x#. timesFloat# 0.0# x#   = 0.0#
 762 "timesFloat x 1.0"  forall x#. timesFloat# x#   1.0# = x#
 763 "timesFloat 1.0 x"  forall x#. timesFloat# 1.0# x#   = x#
 764 "divideFloat x 1.0" forall x#. divideFloat# x#  1.0# = x#
 765   #-}
 766
 767 {-# RULES
 768 "plusDouble x 0.0"   forall x#. (+##) x#    0.0## = x#
 769 "plusDouble 0.0 x"   forall x#. (+##) 0.0## x#    = x#
 770 "minusDouble x 0.0"  forall x#. (-##) x#    0.0## = x#
 771 "timesDouble x 1.0"  forall x#. (*##) x#    1.0## = x#
 772 "timesDouble 1.0 x"  forall x#. (*##) 1.0## x#    = x#
 773 "divideDouble x 1.0" forall x#. (/##) x#    1.0## = x#
 774   #-}
 775
 776 {-
 777 We'd like to have more rules, but for example:
 778
 779 This gives wrong answer (0) for NaN - NaN (should be NaN):
 780     "minusDouble x x"    forall x#. (-##) x#    x#    = 0.0##
 781
 782 This gives wrong answer (0) for 0 * NaN (should be NaN):
 783     "timesDouble 0.0 x"  forall x#. (*##) 0.0## x#    = 0.0##
 784
 785 This gives wrong answer (0) for NaN * 0 (should be NaN):
 786     "timesDouble x 0.0"  forall x#. (*##) x#    0.0## = 0.0##
 787
 788 These are tested by num014.
 789 -}
 790
 791 -- Wrappers for the shift operations.  The uncheckedShift# family are
 792 -- undefined when the amount being shifted by is greater than the size
 793 -- in bits of Int#, so these wrappers perform a check and return
 794 -- either zero or -1 appropriately.
 795 --
 796 -- Note that these wrappers still produce undefined results when the
 797 -- second argument (the shift amount) is negative.
 798
 799 -- | Shift the argument left by the specified number of bits
 800 -- (which must be non-negative).
 801 shiftL# :: Word# -> Int# -> Word#
 802 a `shiftL#` b   | b >=# WORD_SIZE_IN_BITS# = int2Word# 0#
 803                 | otherwise                = a `uncheckedShiftL#` b
 804
 805 -- | Shift the argument right by the specified number of bits
 806 -- (which must be non-negative).
 807 shiftRL# :: Word# -> Int# -> Word#
 808 a `shiftRL#` b  | b >=# WORD_SIZE_IN_BITS# = int2Word# 0#
 809                 | otherwise                = a `uncheckedShiftRL#` b
 810
 811 -- | Shift the argument left by the specified number of bits
 812 -- (which must be non-negative).
 813 iShiftL# :: Int# -> Int# -> Int#
 814 a `iShiftL#` b  | b >=# WORD_SIZE_IN_BITS# = 0#
 815                 | otherwise                = a `uncheckedIShiftL#` b
 816
 817 -- | Shift the argument right (signed) by the specified number of bits
 818 -- (which must be non-negative).
 819 iShiftRA# :: Int# -> Int# -> Int#
 820 a `iShiftRA#` b | b >=# WORD_SIZE_IN_BITS# = if a <# 0# then (-1#) else 0#
 821                 | otherwise                = a `uncheckedIShiftRA#` b
 822
 823 -- | Shift the argument right (unsigned) by the specified number of bits
 824 -- (which must be non-negative).
 825 iShiftRL# :: Int# -> Int# -> Int#
 826 a `iShiftRL#` b | b >=# WORD_SIZE_IN_BITS# = 0#
 827                 | otherwise                = a `uncheckedIShiftRL#` b
 828
 829 #if WORD_SIZE_IN_BITS == 32
 830 {-# RULES
 831 "narrow32Int#"  forall x#. narrow32Int#   x# = x#
 832 "narrow32Word#" forall x#. narrow32Word#   x# = x#
 833    #-}
 834 #endif
 835
 836 {-# RULES
 837 "int2Word2Int"  forall x#. int2Word# (word2Int# x#) = x#
 838 "word2Int2Word" forall x#. word2Int# (int2Word# x#) = x#
 839   #-}
 840 \end{code}
 841
 842
 843 %********************************************************
 844 %*                                                      *
 845 \subsection{Unpacking C strings}
 846 %*                                                      *
 847 %********************************************************
 848
 849 This code is needed for virtually all programs, since it's used for
 850 unpacking the strings of error messages.
 851
 852 \begin{code}
 853 unpackCString# :: Addr# -> [Char]
 854 {-# NOINLINE unpackCString# #-}
 855     -- There's really no point in inlining this, ever, cos
 856     -- the loop doesn't specialise in an interesting
 857     -- But it's pretty small, so there's a danger that
 858     -- it'll be inlined at every literal, which is a waste
 859 unpackCString# addr
 860   = unpack 0#
 861   where
 862     unpack nh
 863       | ch `eqChar#` '\0'# = []
 864       | otherwise          = C# ch : unpack (nh +# 1#)
 865       where
 866         !ch = indexCharOffAddr# addr nh
 867
 868 unpackAppendCString# :: Addr# -> [Char] -> [Char]
 869 {-# NOINLINE unpackAppendCString# #-}
 870      -- See the NOINLINE note on unpackCString#
 871 unpackAppendCString# addr rest
 872   = unpack 0#
 873   where
 874     unpack nh
 875       | ch `eqChar#` '\0'# = rest
 876       | otherwise          = C# ch : unpack (nh +# 1#)
 877       where
 878         !ch = indexCharOffAddr# addr nh
 879
 880 unpackFoldrCString# :: Addr# -> (Char  -> a -> a) -> a -> a
 881
 882 -- Usually the unpack-list rule turns unpackFoldrCString# into unpackCString#
 883
 884 -- It also has a BuiltInRule in PrelRules.lhs:
 885 --      unpackFoldrCString# "foo" c (unpackFoldrCString# "baz" c n)
 886 --        =  unpackFoldrCString# "foobaz" c n
 887
 888 {-# NOINLINE unpackFoldrCString# #-}
 889 -- At one stage I had NOINLINE [0] on the grounds that, unlike
 890 -- unpackCString#, there *is* some point in inlining
 891 -- unpackFoldrCString#, because we get better code for the
 892 -- higher-order function call.  BUT there may be a lot of
 893 -- literal strings, and making a separate 'unpack' loop for
 894 -- each is highly gratuitous.  See nofib/real/anna/PrettyPrint.
 895
 896 unpackFoldrCString# addr f z
 897   = unpack 0#
 898   where
 899     unpack nh
 900       | ch `eqChar#` '\0'# = z
 901       | otherwise          = C# ch `f` unpack (nh +# 1#)
 902       where
 903         !ch = indexCharOffAddr# addr nh
 904
 905 unpackCStringUtf8# :: Addr# -> [Char]
 906 unpackCStringUtf8# addr
 907   = unpack 0#
 908   where
 909     unpack nh
 910       | ch `eqChar#` '\0'#   = []
 911       | ch `leChar#` '\x7F'# = C# ch : unpack (nh +# 1#)
 912       | ch `leChar#` '\xDF'# =
 913           C# (chr# (((ord# ch                                  -# 0xC0#) `uncheckedIShiftL#`  6#) +#
 914                      (ord# (indexCharOffAddr# addr (nh +# 1#)) -# 0x80#))) :
 915           unpack (nh +# 2#)
 916       | ch `leChar#` '\xEF'# =
 917           C# (chr# (((ord# ch                                  -# 0xE0#) `uncheckedIShiftL#` 12#) +#
 918                     ((ord# (indexCharOffAddr# addr (nh +# 1#)) -# 0x80#) `uncheckedIShiftL#`  6#) +#
 919                      (ord# (indexCharOffAddr# addr (nh +# 2#)) -# 0x80#))) :
 920           unpack (nh +# 3#)
 921       | otherwise            =
 922           C# (chr# (((ord# ch                                  -# 0xF0#) `uncheckedIShiftL#` 18#) +#
 923                     ((ord# (indexCharOffAddr# addr (nh +# 1#)) -# 0x80#) `uncheckedIShiftL#` 12#) +#
 924                     ((ord# (indexCharOffAddr# addr (nh +# 2#)) -# 0x80#) `uncheckedIShiftL#`  6#) +#
 925                      (ord# (indexCharOffAddr# addr (nh +# 3#)) -# 0x80#))) :
 926           unpack (nh +# 4#)
 927       where
 928         !ch = indexCharOffAddr# addr nh
 929
 930 unpackNBytes# :: Addr# -> Int# -> [Char]
 931 unpackNBytes# _addr 0#   = []
 932 unpackNBytes#  addr len# = unpack [] (len# -# 1#)
 933     where
 934      unpack acc i#
 935       | i# <# 0#  = acc
 936       | otherwise =
 937          case indexCharOffAddr# addr i# of
 938             ch -> unpack (C# ch : acc) (i# -# 1#)
 939
 940 {-# RULES
 941 "unpack"       [~1] forall a   . unpackCString# a             = build (unpackFoldrCString# a)
 942 "unpack-list"  [1]  forall a   . unpackFoldrCString# a (:) [] = unpackCString# a
 943 "unpack-append"     forall a n . unpackFoldrCString# a (:) n  = unpackAppendCString# a n
 944
 945 -- There's a built-in rule (in PrelRules.lhs) for
 946 --      unpackFoldr "foo" c (unpackFoldr "baz" c n)  =  unpackFoldr "foobaz" c n
 947
 948   #-}
 949 \end{code}
 950
 951 #ifdef __HADDOCK__
 952 \begin{code}
 953 -- | A special argument for the 'Control.Monad.ST.ST' type constructor,
 954 -- indexing a state embedded in the 'Prelude.IO' monad by
 955 -- 'Control.Monad.ST.stToIO'.
 956 data RealWorld
 957 \end{code}
 958 #endif