GHC/Base.lhs

   1 \section[GHC.Base]{Module @GHC.Base@}
   2
   3 The overall structure of the GHC Prelude is a bit tricky.
   4
   5   a) We want to avoid "orphan modules", i.e. ones with instance
   6         decls that don't belong either to a tycon or a class
   7         defined in the same module
   8
   9   b) We want to avoid giant modules
  10
  11 So the rough structure is as follows, in (linearised) dependency order
  12
  13
  14 GHC.Prim                Has no implementation.  It defines built-in things, and
  15                 by importing it you bring them into scope.
  16                 The source file is GHC.Prim.hi-boot, which is just
  17                 copied to make GHC.Prim.hi
  18
  19 GHC.Base        Classes: Eq, Ord, Functor, Monad
  20                 Types:   list, (), Int, Bool, Ordering, Char, String
  21
  22 Data.Tuple      Types: tuples, plus instances for GHC.Base classes
  23
  24 GHC.Show        Class: Show, plus instances for GHC.Base/GHC.Tup types
  25
  26 GHC.Enum        Class: Enum,  plus instances for GHC.Base/GHC.Tup types
  27
  28 Data.Maybe      Type: Maybe, plus instances for GHC.Base classes
  29
  30 GHC.List        List functions
  31
  32 GHC.Num         Class: Num, plus instances for Int
  33                 Type:  Integer, plus instances for all classes so far (Eq, Ord, Num, Show)
  34
  35                 Integer is needed here because it is mentioned in the signature
  36                 of 'fromInteger' in class Num
  37
  38 GHC.Real        Classes: Real, Integral, Fractional, RealFrac
  39                          plus instances for Int, Integer
  40                 Types:  Ratio, Rational
  41                         plus intances for classes so far
  42
  43                 Rational is needed here because it is mentioned in the signature
  44                 of 'toRational' in class Real
  45
  46 GHC.ST  The ST monad, instances and a few helper functions
  47
  48 Ix              Classes: Ix, plus instances for Int, Bool, Char, Integer, Ordering, tuples
  49
  50 GHC.Arr         Types: Array, MutableArray, MutableVar
  51
  52                 Arrays are used by a function in GHC.Float
  53
  54 GHC.Float       Classes: Floating, RealFloat
  55                 Types:   Float, Double, plus instances of all classes so far
  56
  57                 This module contains everything to do with floating point.
  58                 It is a big module (900 lines)
  59                 With a bit of luck, many modules can be compiled without ever reading GHC.Float.hi
  60
  61
  62 Other Prelude modules are much easier with fewer complex dependencies.
  63
  64 \begin{code}
  65 {-# LANGUAGE CPP
  66            , NoImplicitPrelude
  67            , BangPatterns
  68            , ExplicitForAll
  69            , MagicHash
  70            , UnboxedTuples
  71            , ExistentialQuantification
  72            , Rank2Types
  73   #-}
  74 -- -fno-warn-orphans is needed for things like:
  75 -- Orphan rule: "x# -# x#" ALWAYS forall x# :: Int# -# x# x# = 0
  76 {-# OPTIONS_GHC -fno-warn-orphans #-}
  77 {-# OPTIONS_HADDOCK hide #-}
  78
  79 -----------------------------------------------------------------------------
  80 -- |
  81 -- Module      :  GHC.Base
  82 -- Copyright   :  (c) The University of Glasgow, 1992-2002
  83 -- License     :  see libraries/base/LICENSE
  84 --
  85 -- Maintainer  :  cvs-ghc@haskell.org
  86 -- Stability   :  internal
  87 -- Portability :  non-portable (GHC extensions)
  88 --
  89 -- Basic data types and classes.
  90 --
  91 -----------------------------------------------------------------------------
  92
  93 #include "MachDeps.h"
  94
  95 -- #hide
  96 module GHC.Base
  97         (
  98         module GHC.Base,
  99         module GHC.Classes,
 100         module GHC.Generics,
 101         module GHC.Ordering,
 102         module GHC.Types,
 103         module GHC.Prim,        -- Re-export GHC.Prim and GHC.Err, to avoid lots
 104         module GHC.Err          -- of people having to import it explicitly
 105   )
 106         where
 107
 108 import GHC.Types
 109 import GHC.Classes
 110 import GHC.Generics
 111 import GHC.Ordering
 112 import GHC.Prim
 113 import {-# SOURCE #-} GHC.Show
 114 import {-# SOURCE #-} GHC.Err
 115 import {-# SOURCE #-} GHC.IO (failIO)
 116
 117 -- These two are not strictly speaking required by this module, but they are
 118 -- implicit dependencies whenever () or tuples are mentioned, so adding them
 119 -- as imports here helps to get the dependencies right in the new build system.
 120 import GHC.Tuple ()
 121 import GHC.Unit ()
 122
 123 infixr 9  .
 124 infixr 5  ++
 125 infixl 4  <$
 126 infixl 1  >>, >>=
 127 infixr 0  $
 128
 129 default ()              -- Double isn't available yet
 130 \end{code}
 131
 132
 133 %*********************************************************
 134 %*                                                      *
 135 \subsection{DEBUGGING STUFF}
 136 %*  (for use when compiling GHC.Base itself doesn't work)
 137 %*                                                      *
 138 %*********************************************************
 139
 140 \begin{code}
 141 {-
 142 data  Bool  =  False | True
 143 data Ordering = LT | EQ | GT
 144 data Char = C# Char#
 145 type  String = [Char]
 146 data Int = I# Int#
 147 data  ()  =  ()
 148 data [] a = MkNil
 149
 150 not True = False
 151 (&&) True True = True
 152 otherwise = True
 153
 154 build = error "urk"
 155 foldr = error "urk"
 156
 157 unpackCString# :: Addr# -> [Char]
 158 unpackFoldrCString# :: Addr# -> (Char  -> a -> a) -> a -> a
 159 unpackAppendCString# :: Addr# -> [Char] -> [Char]
 160 unpackCStringUtf8# :: Addr# -> [Char]
 161 unpackCString# a = error "urk"
 162 unpackFoldrCString# a = error "urk"
 163 unpackAppendCString# a = error "urk"
 164 unpackCStringUtf8# a = error "urk"
 165 -}
 166 \end{code}
 167
 168
 169 %*********************************************************
 170 %*                                                      *
 171 \subsection{Monadic classes @Functor@, @Monad@ }
 172 %*                                                      *
 173 %*********************************************************
 174
 175 \begin{code}
 176 {- | The 'Functor' class is used for types that can be mapped over.
 177 Instances of 'Functor' should satisfy the following laws:
 178
 179 > fmap id  ==  id
 180 > fmap (f . g)  ==  fmap f . fmap g
 181
 182 The instances of 'Functor' for lists, 'Data.Maybe.Maybe' and 'System.IO.IO'
 183 satisfy these laws.
 184 -}
 185
 186 class  Functor f  where
 187     fmap        :: (a -> b) -> f a -> f b
 188
 189     -- | Replace all locations in the input with the same value.
 190     -- The default definition is @'fmap' . 'const'@, but this may be
 191     -- overridden with a more efficient version.
 192     (<$)        :: a -> f b -> f a
 193     (<$)        =  fmap . const
 194
 195 {- | The 'Monad' class defines the basic operations over a /monad/,
 196 a concept from a branch of mathematics known as /category theory/.
 197 From the perspective of a Haskell programmer, however, it is best to
 198 think of a monad as an /abstract datatype/ of actions.
 199 Haskell's @do@ expressions provide a convenient syntax for writing
 200 monadic expressions.
 201
 202 Minimal complete definition: '>>=' and 'return'.
 203
 204 Instances of 'Monad' should satisfy the following laws:
 205
 206 > return a >>= k  ==  k a
 207 > m >>= return  ==  m
 208 > m >>= (\x -> k x >>= h)  ==  (m >>= k) >>= h
 209
 210 Instances of both 'Monad' and 'Functor' should additionally satisfy the law:
 211
 212 > fmap f xs  ==  xs >>= return . f
 213
 214 The instances of 'Monad' for lists, 'Data.Maybe.Maybe' and 'System.IO.IO'
 215 defined in the "Prelude" satisfy these laws.
 216 -}
 217
 218 class  Monad m  where
 219     -- | Sequentially compose two actions, passing any value produced
 220     -- by the first as an argument to the second.
 221     (>>=)       :: forall a b. m a -> (a -> m b) -> m b
 222     -- | Sequentially compose two actions, discarding any value produced
 223     -- by the first, like sequencing operators (such as the semicolon)
 224     -- in imperative languages.
 225     (>>)        :: forall a b. m a -> m b -> m b
 226         -- Explicit for-alls so that we know what order to
 227         -- give type arguments when desugaring
 228
 229     -- | Inject a value into the monadic type.
 230     return      :: a -> m a
 231     -- | Fail with a message.  This operation is not part of the
 232     -- mathematical definition of a monad, but is invoked on pattern-match
 233     -- failure in a @do@ expression.
 234     fail        :: String -> m a
 235
 236     {-# INLINE (>>) #-}
 237     m >> k      = m >>= \_ -> k
 238     fail s      = error s
 239 \end{code}
 240
 241
 242 %*********************************************************
 243 %*                                                      *
 244 \subsection{The list type}
 245 %*                                                      *
 246 %*********************************************************
 247
 248 \begin{code}
 249 instance Functor [] where
 250     fmap = map
 251
 252 instance  Monad []  where
 253     m >>= k             = foldr ((++) . k) [] m
 254     m >> k              = foldr ((++) . (\ _ -> k)) [] m
 255     return x            = [x]
 256     fail _              = []
 257 \end{code}
 258
 259 A few list functions that appear here because they are used here.
 260 The rest of the prelude list functions are in GHC.List.
 261
 262 ----------------------------------------------
 263 --      foldr/build/augment
 264 ----------------------------------------------
 265
 266 \begin{code}
 267 -- | 'foldr', applied to a binary operator, a starting value (typically
 268 -- the right-identity of the operator), and a list, reduces the list
 269 -- using the binary operator, from right to left:
 270 --
 271 -- > foldr f z [x1, x2, ..., xn] == x1 `f` (x2 `f` ... (xn `f` z)...)
 272
 273 foldr            :: (a -> b -> b) -> b -> [a] -> b
 274 -- foldr _ z []     =  z
 275 -- foldr f z (x:xs) =  f x (foldr f z xs)
 276 {-# INLINE [0] foldr #-}
 277 -- Inline only in the final stage, after the foldr/cons rule has had a chance
 278 -- Also note that we inline it when it has *two* parameters, which are the
 279 -- ones we are keen about specialising!
 280 foldr k z = go
 281           where
 282             go []     = z
 283             go (y:ys) = y `k` go ys
 284
 285 -- | A list producer that can be fused with 'foldr'.
 286 -- This function is merely
 287 --
 288 -- >    build g = g (:) []
 289 --
 290 -- but GHC's simplifier will transform an expression of the form
 291 -- @'foldr' k z ('build' g)@, which may arise after inlining, to @g k z@,
 292 -- which avoids producing an intermediate list.
 293
 294 build   :: forall a. (forall b. (a -> b -> b) -> b -> b) -> [a]
 295 {-# INLINE [1] build #-}
 296         -- The INLINE is important, even though build is tiny,
 297         -- because it prevents [] getting inlined in the version that
 298         -- appears in the interface file.  If [] *is* inlined, it
 299         -- won't match with [] appearing in rules in an importing module.
 300         --
 301         -- The "1" says to inline in phase 1
 302
 303 build g = g (:) []
 304
 305 -- | A list producer that can be fused with 'foldr'.
 306 -- This function is merely
 307 --
 308 -- >    augment g xs = g (:) xs
 309 --
 310 -- but GHC's simplifier will transform an expression of the form
 311 -- @'foldr' k z ('augment' g xs)@, which may arise after inlining, to
 312 -- @g k ('foldr' k z xs)@, which avoids producing an intermediate list.
 313
 314 augment :: forall a. (forall b. (a->b->b) -> b -> b) -> [a] -> [a]
 315 {-# INLINE [1] augment #-}
 316 augment g xs = g (:) xs
 317
 318 {-# RULES
 319 "fold/build"    forall k z (g::forall b. (a->b->b) -> b -> b) .
 320                 foldr k z (build g) = g k z
 321
 322 "foldr/augment" forall k z xs (g::forall b. (a->b->b) -> b -> b) .
 323                 foldr k z (augment g xs) = g k (foldr k z xs)
 324
 325 "foldr/id"                        foldr (:) [] = \x  -> x
 326 "foldr/app"     [1] forall ys. foldr (:) ys = \xs -> xs ++ ys
 327         -- Only activate this from phase 1, because that's
 328         -- when we disable the rule that expands (++) into foldr
 329
 330 -- The foldr/cons rule looks nice, but it can give disastrously
 331 -- bloated code when commpiling
 332 --      array (a,b) [(1,2), (2,2), (3,2), ...very long list... ]
 333 -- i.e. when there are very very long literal lists
 334 -- So I've disabled it for now. We could have special cases
 335 -- for short lists, I suppose.
 336 -- "foldr/cons" forall k z x xs. foldr k z (x:xs) = k x (foldr k z xs)
 337
 338 "foldr/single"  forall k z x. foldr k z [x] = k x z
 339 "foldr/nil"     forall k z.   foldr k z []  = z
 340
 341 "augment/build" forall (g::forall b. (a->b->b) -> b -> b)
 342                        (h::forall b. (a->b->b) -> b -> b) .
 343                        augment g (build h) = build (\c n -> g c (h c n))
 344 "augment/nil"   forall (g::forall b. (a->b->b) -> b -> b) .
 345                         augment g [] = build g
 346  #-}
 347
 348 -- This rule is true, but not (I think) useful:
 349 --      augment g (augment h t) = augment (\cn -> g c (h c n)) t
 350 \end{code}
 351
 352
 353 ----------------------------------------------
 354 --              map
 355 ----------------------------------------------
 356
 357 \begin{code}
 358 -- | 'map' @f xs@ is the list obtained by applying @f@ to each element
 359 -- of @xs@, i.e.,
 360 --
 361 -- > map f [x1, x2, ..., xn] == [f x1, f x2, ..., f xn]
 362 -- > map f [x1, x2, ...] == [f x1, f x2, ...]
 363
 364 map :: (a -> b) -> [a] -> [b]
 365 map _ []     = []
 366 map f (x:xs) = f x : map f xs
 367
 368 -- Note eta expanded
 369 mapFB ::  (elt -> lst -> lst) -> (a -> elt) -> a -> lst -> lst
 370 {-# INLINE [0] mapFB #-}
 371 mapFB c f = \x ys -> c (f x) ys
 372
 373 -- The rules for map work like this.
 374 --
 375 -- Up to (but not including) phase 1, we use the "map" rule to
 376 -- rewrite all saturated applications of map with its build/fold
 377 -- form, hoping for fusion to happen.
 378 -- In phase 1 and 0, we switch off that rule, inline build, and
 379 -- switch on the "mapList" rule, which rewrites the foldr/mapFB
 380 -- thing back into plain map.
 381 --
 382 -- It's important that these two rules aren't both active at once
 383 -- (along with build's unfolding) else we'd get an infinite loop
 384 -- in the rules.  Hence the activation control below.
 385 --
 386 -- The "mapFB" rule optimises compositions of map.
 387 --
 388 -- This same pattern is followed by many other functions:
 389 -- e.g. append, filter, iterate, repeat, etc.
 390
 391 {-# RULES
 392 "map"       [~1] forall f xs.   map f xs                = build (\c n -> foldr (mapFB c f) n xs)
 393 "mapList"   [1]  forall f.      foldr (mapFB (:) f) []  = map f
 394 "mapFB"     forall c f g.       mapFB (mapFB c f) g     = mapFB c (f.g)
 395   #-}
 396 \end{code}
 397
 398
 399 ----------------------------------------------
 400 --              append
 401 ----------------------------------------------
 402 \begin{code}
 403 -- | Append two lists, i.e.,
 404 --
 405 -- > [x1, ..., xm] ++ [y1, ..., yn] == [x1, ..., xm, y1, ..., yn]
 406 -- > [x1, ..., xm] ++ [y1, ...] == [x1, ..., xm, y1, ...]
 407 --
 408 -- If the first list is not finite, the result is the first list.
 409
 410 (++) :: [a] -> [a] -> [a]
 411 (++) []     ys = ys
 412 (++) (x:xs) ys = x : xs ++ ys
 413
 414 {-# RULES
 415 "++"    [~1] forall xs ys. xs ++ ys = augment (\c n -> foldr c n xs) ys
 416   #-}
 417
 418 \end{code}
 419
 420
 421 %*********************************************************
 422 %*                                                      *
 423 \subsection{Type @Bool@}
 424 %*                                                      *
 425 %*********************************************************
 426
 427 \begin{code}
 428 -- |'otherwise' is defined as the value 'True'.  It helps to make
 429 -- guards more readable.  eg.
 430 --
 431 -- >  f x | x < 0     = ...
 432 -- >      | otherwise = ...
 433 otherwise               :: Bool
 434 otherwise               =  True
 435 \end{code}
 436
 437 %*********************************************************
 438 %*                                                      *
 439 \subsection{Type @Char@ and @String@}
 440 %*                                                      *
 441 %*********************************************************
 442
 443 \begin{code}
 444 -- | A 'String' is a list of characters.  String constants in Haskell are values
 445 -- of type 'String'.
 446 --
 447 type String = [Char]
 448
 449 {-# RULES
 450 "x# `eqChar#` x#" forall x#. x# `eqChar#` x# = True
 451 "x# `neChar#` x#" forall x#. x# `neChar#` x# = False
 452 "x# `gtChar#` x#" forall x#. x# `gtChar#` x# = False
 453 "x# `geChar#` x#" forall x#. x# `geChar#` x# = True
 454 "x# `leChar#` x#" forall x#. x# `leChar#` x# = True
 455 "x# `ltChar#` x#" forall x#. x# `ltChar#` x# = False
 456   #-}
 457
 458 -- | The 'Prelude.toEnum' method restricted to the type 'Data.Char.Char'.
 459 chr :: Int -> Char
 460 chr i@(I# i#)
 461  | int2Word# i# `leWord#` int2Word# 0x10FFFF# = C# (chr# i#)
 462  | otherwise
 463     = error ("Prelude.chr: bad argument: " ++ showSignedInt (I# 9#) i "")
 464
 465 unsafeChr :: Int -> Char
 466 unsafeChr (I# i#) = C# (chr# i#)
 467
 468 -- | The 'Prelude.fromEnum' method restricted to the type 'Data.Char.Char'.
 469 ord :: Char -> Int
 470 ord (C# c#) = I# (ord# c#)
 471 \end{code}
 472
 473 String equality is used when desugaring pattern-matches against strings.
 474
 475 \begin{code}
 476 eqString :: String -> String -> Bool
 477 eqString []       []       = True
 478 eqString (c1:cs1) (c2:cs2) = c1 == c2 && cs1 `eqString` cs2
 479 eqString _        _        = False
 480
 481 {-# RULES "eqString" (==) = eqString #-}
 482 -- eqString also has a BuiltInRule in PrelRules.lhs:
 483 --      eqString (unpackCString# (Lit s1)) (unpackCString# (Lit s2) = s1==s2
 484 \end{code}
 485
 486
 487 %*********************************************************
 488 %*                                                      *
 489 \subsection{Type @Int@}
 490 %*                                                      *
 491 %*********************************************************
 492
 493 \begin{code}
 494 zeroInt, oneInt, twoInt, maxInt, minInt :: Int
 495 zeroInt = I# 0#
 496 oneInt  = I# 1#
 497 twoInt  = I# 2#
 498
 499 {- Seems clumsy. Should perhaps put minInt and MaxInt directly into MachDeps.h -}
 500 #if WORD_SIZE_IN_BITS == 31
 501 minInt  = I# (-0x40000000#)
 502 maxInt  = I# 0x3FFFFFFF#
 503 #elif WORD_SIZE_IN_BITS == 32
 504 minInt  = I# (-0x80000000#)
 505 maxInt  = I# 0x7FFFFFFF#
 506 #else
 507 minInt  = I# (-0x8000000000000000#)
 508 maxInt  = I# 0x7FFFFFFFFFFFFFFF#
 509 #endif
 510
 511 instance Eq Int where
 512     (==) = eqInt
 513     (/=) = neInt
 514
 515 instance Ord Int where
 516     compare = compareInt
 517     (<)     = ltInt
 518     (<=)    = leInt
 519     (>=)    = geInt
 520     (>)     = gtInt
 521
 522 compareInt :: Int -> Int -> Ordering
 523 (I# x#) `compareInt` (I# y#) = compareInt# x# y#
 524
 525 compareInt# :: Int# -> Int# -> Ordering
 526 compareInt# x# y#
 527     | x# <#  y# = LT
 528     | x# ==# y# = EQ
 529     | otherwise = GT
 530 \end{code}
 531
 532
 533 %*********************************************************
 534 %*                                                      *
 535 \subsection{The function type}
 536 %*                                                      *
 537 %*********************************************************
 538
 539 \begin{code}
 540 -- | Identity function.
 541 id                      :: a -> a
 542 id x                    =  x
 543
 544 -- | The call '(lazy e)' means the same as 'e', but 'lazy' has a
 545 -- magical strictness property: it is lazy in its first argument,
 546 -- even though its semantics is strict.
 547 lazy :: a -> a
 548 lazy x = x
 549 -- Implementation note: its strictness and unfolding are over-ridden
 550 -- by the definition in MkId.lhs; in both cases to nothing at all.
 551 -- That way, 'lazy' does not get inlined, and the strictness analyser
 552 -- sees it as lazy.  Then the worker/wrapper phase inlines it.
 553 -- Result: happiness
 554
 555 -- Assertion function.  This simply ignores its boolean argument.
 556 -- The compiler may rewrite it to @('assertError' line)@.
 557
 558 -- | If the first argument evaluates to 'True', then the result is the
 559 -- second argument.  Otherwise an 'AssertionFailed' exception is raised,
 560 -- containing a 'String' with the source file and line number of the
 561 -- call to 'assert'.
 562 --
 563 -- Assertions can normally be turned on or off with a compiler flag
 564 -- (for GHC, assertions are normally on unless optimisation is turned on
 565 -- with @-O@ or the @-fignore-asserts@
 566 -- option is given).  When assertions are turned off, the first
 567 -- argument to 'assert' is ignored, and the second argument is
 568 -- returned as the result.
 569
 570 --      SLPJ: in 5.04 etc 'assert' is in GHC.Prim,
 571 --      but from Template Haskell onwards it's simply
 572 --      defined here in Base.lhs
 573 assert :: Bool -> a -> a
 574 assert _pred r = r
 575
 576 breakpoint :: a -> a
 577 breakpoint r = r
 578
 579 breakpointCond :: Bool -> a -> a
 580 breakpointCond _ r = r
 581
 582 data Opaque = forall a. O a
 583
 584 -- | Constant function.
 585 const                   :: a -> b -> a
 586 const x _               =  x
 587
 588 -- | Function composition.
 589 {-# INLINE (.) #-}
 590 -- Make sure it has TWO args only on the left, so that it inlines
 591 -- when applied to two functions, even if there is no final argument
 592 (.)    :: (b -> c) -> (a -> b) -> a -> c
 593 (.) f g = \x -> f (g x)
 594
 595 -- | @'flip' f@ takes its (first) two arguments in the reverse order of @f@.
 596 flip                    :: (a -> b -> c) -> b -> a -> c
 597 flip f x y              =  f y x
 598
 599 -- | Application operator.  This operator is redundant, since ordinary
 600 -- application @(f x)@ means the same as @(f '$' x)@. However, '$' has
 601 -- low, right-associative binding precedence, so it sometimes allows
 602 -- parentheses to be omitted; for example:
 603 --
 604 -- >     f $ g $ h x  =  f (g (h x))
 605 --
 606 -- It is also useful in higher-order situations, such as @'map' ('$' 0) xs@,
 607 -- or @'Data.List.zipWith' ('$') fs xs@.
 608 {-# INLINE ($) #-}
 609 ($)                     :: (a -> b) -> a -> b
 610 f $ x                   =  f x
 611
 612 -- | @'until' p f@ yields the result of applying @f@ until @p@ holds.
 613 until                   :: (a -> Bool) -> (a -> a) -> a -> a
 614 until p f x | p x       =  x
 615             | otherwise =  until p f (f x)
 616
 617 -- | 'asTypeOf' is a type-restricted version of 'const'.  It is usually
 618 -- used as an infix operator, and its typing forces its first argument
 619 -- (which is usually overloaded) to have the same type as the second.
 620 asTypeOf                :: a -> a -> a
 621 asTypeOf                =  const
 622 \end{code}
 623
 624 %*********************************************************
 625 %*                                                      *
 626 \subsection{@Functor@ and @Monad@ instances for @IO@}
 627 %*                                                      *
 628 %*********************************************************
 629
 630 \begin{code}
 631 instance  Functor IO where
 632    fmap f x = x >>= (return . f)
 633
 634 instance  Monad IO  where
 635     {-# INLINE return #-}
 636     {-# INLINE (>>)   #-}
 637     {-# INLINE (>>=)  #-}
 638     m >> k    = m >>= \ _ -> k
 639     return    = returnIO
 640     (>>=)     = bindIO
 641     fail s    = GHC.IO.failIO s
 642
 643 returnIO :: a -> IO a
 644 returnIO x = IO $ \ s -> (# s, x #)
 645
 646 bindIO :: IO a -> (a -> IO b) -> IO b
 647 bindIO (IO m) k = IO $ \ s -> case m s of (# new_s, a #) -> unIO (k a) new_s
 648
 649 thenIO :: IO a -> IO b -> IO b
 650 thenIO (IO m) k = IO $ \ s -> case m s of (# new_s, _ #) -> unIO k new_s
 651
 652 unIO :: IO a -> (State# RealWorld -> (# State# RealWorld, a #))
 653 unIO (IO a) = a
 654 \end{code}
 655
 656 %*********************************************************
 657 %*                                                      *
 658 \subsection{@getTag@}
 659 %*                                                      *
 660 %*********************************************************
 661
 662 Returns the 'tag' of a constructor application; this function is used
 663 by the deriving code for Eq, Ord and Enum.
 664
 665 The primitive dataToTag# requires an evaluated constructor application
 666 as its argument, so we provide getTag as a wrapper that performs the
 667 evaluation before calling dataToTag#.  We could have dataToTag#
 668 evaluate its argument, but we prefer to do it this way because (a)
 669 dataToTag# can be an inline primop if it doesn't need to do any
 670 evaluation, and (b) we want to expose the evaluation to the
 671 simplifier, because it might be possible to eliminate the evaluation
 672 in the case when the argument is already known to be evaluated.
 673
 674 \begin{code}
 675 {-# INLINE getTag #-}
 676 getTag :: a -> Int#
 677 getTag x = x `seq` dataToTag# x
 678 \end{code}
 679
 680 %*********************************************************
 681 %*                                                      *
 682 \subsection{Numeric primops}
 683 %*                                                      *
 684 %*********************************************************
 685
 686 \begin{code}
 687 divInt# :: Int# -> Int# -> Int#
 688 x# `divInt#` y#
 689         -- Be careful NOT to overflow if we do any additional arithmetic
 690         -- on the arguments...  the following  previous version of this
 691         -- code has problems with overflow:
 692 --    | (x# ># 0#) && (y# <# 0#) = ((x# -# y#) -# 1#) `quotInt#` y#
 693 --    | (x# <# 0#) && (y# ># 0#) = ((x# -# y#) +# 1#) `quotInt#` y#
 694     | (x# ># 0#) && (y# <# 0#) = ((x# -# 1#) `quotInt#` y#) -# 1#
 695     | (x# <# 0#) && (y# ># 0#) = ((x# +# 1#) `quotInt#` y#) -# 1#
 696     | otherwise                = x# `quotInt#` y#
 697
 698 modInt# :: Int# -> Int# -> Int#
 699 x# `modInt#` y#
 700     | (x# ># 0#) && (y# <# 0#) ||
 701       (x# <# 0#) && (y# ># 0#)    = if r# /=# 0# then r# +# y# else 0#
 702     | otherwise                   = r#
 703     where
 704     !r# = x# `remInt#` y#
 705 \end{code}
 706
 707 Definitions of the boxed PrimOps; these will be
 708 used in the case of partial applications, etc.
 709
 710 \begin{code}
 711 {-# INLINE eqInt #-}
 712 {-# INLINE neInt #-}
 713 {-# INLINE gtInt #-}
 714 {-# INLINE geInt #-}
 715 {-# INLINE ltInt #-}
 716 {-# INLINE leInt #-}
 717 {-# INLINE plusInt #-}
 718 {-# INLINE minusInt #-}
 719 {-# INLINE timesInt #-}
 720 {-# INLINE quotInt #-}
 721 {-# INLINE remInt #-}
 722 {-# INLINE negateInt #-}
 723
 724 plusInt, minusInt, timesInt, quotInt, remInt, divInt, modInt :: Int -> Int -> Int
 725 (I# x) `plusInt`  (I# y) = I# (x +# y)
 726 (I# x) `minusInt` (I# y) = I# (x -# y)
 727 (I# x) `timesInt` (I# y) = I# (x *# y)
 728 (I# x) `quotInt`  (I# y) = I# (x `quotInt#` y)
 729 (I# x) `remInt`   (I# y) = I# (x `remInt#`  y)
 730 (I# x) `divInt`   (I# y) = I# (x `divInt#`  y)
 731 (I# x) `modInt`   (I# y) = I# (x `modInt#`  y)
 732
 733 {-# RULES
 734 "x# +# 0#" forall x#. x# +# 0# = x#
 735 "0# +# x#" forall x#. 0# +# x# = x#
 736 "x# -# 0#" forall x#. x# -# 0# = x#
 737 "x# -# x#" forall x#. x# -# x# = 0#
 738 "x# *# 0#" forall x#. x# *# 0# = 0#
 739 "0# *# x#" forall x#. 0# *# x# = 0#
 740 "x# *# 1#" forall x#. x# *# 1# = x#
 741 "1# *# x#" forall x#. 1# *# x# = x#
 742   #-}
 743
 744 negateInt :: Int -> Int
 745 negateInt (I# x) = I# (negateInt# x)
 746
 747 gtInt, geInt, eqInt, neInt, ltInt, leInt :: Int -> Int -> Bool
 748 (I# x) `gtInt` (I# y) = x >#  y
 749 (I# x) `geInt` (I# y) = x >=# y
 750 (I# x) `eqInt` (I# y) = x ==# y
 751 (I# x) `neInt` (I# y) = x /=# y
 752 (I# x) `ltInt` (I# y) = x <#  y
 753 (I# x) `leInt` (I# y) = x <=# y
 754
 755 {-# RULES
 756 "x# ># x#"  forall x#. x# >#  x# = False
 757 "x# >=# x#" forall x#. x# >=# x# = True
 758 "x# ==# x#" forall x#. x# ==# x# = True
 759 "x# /=# x#" forall x#. x# /=# x# = False
 760 "x# <# x#"  forall x#. x# <#  x# = False
 761 "x# <=# x#" forall x#. x# <=# x# = True
 762   #-}
 763
 764 {-# RULES
 765 "plusFloat x 0.0"   forall x#. plusFloat#  x#   0.0# = x#
 766 "plusFloat 0.0 x"   forall x#. plusFloat#  0.0# x#   = x#
 767 "minusFloat x 0.0"  forall x#. minusFloat# x#   0.0# = x#
 768 "minusFloat x x"    forall x#. minusFloat# x#   x#   = 0.0#
 769 "timesFloat x 0.0"  forall x#. timesFloat# x#   0.0# = 0.0#
 770 "timesFloat0.0 x"   forall x#. timesFloat# 0.0# x#   = 0.0#
 771 "timesFloat x 1.0"  forall x#. timesFloat# x#   1.0# = x#
 772 "timesFloat 1.0 x"  forall x#. timesFloat# 1.0# x#   = x#
 773 "divideFloat x 1.0" forall x#. divideFloat# x#  1.0# = x#
 774   #-}
 775
 776 {-# RULES
 777 "plusDouble x 0.0"   forall x#. (+##) x#    0.0## = x#
 778 "plusDouble 0.0 x"   forall x#. (+##) 0.0## x#    = x#
 779 "minusDouble x 0.0"  forall x#. (-##) x#    0.0## = x#
 780 "timesDouble x 1.0"  forall x#. (*##) x#    1.0## = x#
 781 "timesDouble 1.0 x"  forall x#. (*##) 1.0## x#    = x#
 782 "divideDouble x 1.0" forall x#. (/##) x#    1.0## = x#
 783   #-}
 784
 785 {-
 786 We'd like to have more rules, but for example:
 787
 788 This gives wrong answer (0) for NaN - NaN (should be NaN):
 789     "minusDouble x x"    forall x#. (-##) x#    x#    = 0.0##
 790
 791 This gives wrong answer (0) for 0 * NaN (should be NaN):
 792     "timesDouble 0.0 x"  forall x#. (*##) 0.0## x#    = 0.0##
 793
 794 This gives wrong answer (0) for NaN * 0 (should be NaN):
 795     "timesDouble x 0.0"  forall x#. (*##) x#    0.0## = 0.0##
 796
 797 These are tested by num014.
 798 -}
 799
 800 -- Wrappers for the shift operations.  The uncheckedShift# family are
 801 -- undefined when the amount being shifted by is greater than the size
 802 -- in bits of Int#, so these wrappers perform a check and return
 803 -- either zero or -1 appropriately.
 804 --
 805 -- Note that these wrappers still produce undefined results when the
 806 -- second argument (the shift amount) is negative.
 807
 808 -- | Shift the argument left by the specified number of bits
 809 -- (which must be non-negative).
 810 shiftL# :: Word# -> Int# -> Word#
 811 a `shiftL#` b   | b >=# WORD_SIZE_IN_BITS# = int2Word# 0#
 812                 | otherwise                = a `uncheckedShiftL#` b
 813
 814 -- | Shift the argument right by the specified number of bits
 815 -- (which must be non-negative).
 816 shiftRL# :: Word# -> Int# -> Word#
 817 a `shiftRL#` b  | b >=# WORD_SIZE_IN_BITS# = int2Word# 0#
 818                 | otherwise                = a `uncheckedShiftRL#` b
 819
 820 -- | Shift the argument left by the specified number of bits
 821 -- (which must be non-negative).
 822 iShiftL# :: Int# -> Int# -> Int#
 823 a `iShiftL#` b  | b >=# WORD_SIZE_IN_BITS# = 0#
 824                 | otherwise                = a `uncheckedIShiftL#` b
 825
 826 -- | Shift the argument right (signed) by the specified number of bits
 827 -- (which must be non-negative).
 828 iShiftRA# :: Int# -> Int# -> Int#
 829 a `iShiftRA#` b | b >=# WORD_SIZE_IN_BITS# = if a <# 0# then (-1#) else 0#
 830                 | otherwise                = a `uncheckedIShiftRA#` b
 831
 832 -- | Shift the argument right (unsigned) by the specified number of bits
 833 -- (which must be non-negative).
 834 iShiftRL# :: Int# -> Int# -> Int#
 835 a `iShiftRL#` b | b >=# WORD_SIZE_IN_BITS# = 0#
 836                 | otherwise                = a `uncheckedIShiftRL#` b
 837
 838 #if WORD_SIZE_IN_BITS == 32
 839 {-# RULES
 840 "narrow32Int#"  forall x#. narrow32Int#   x# = x#
 841 "narrow32Word#" forall x#. narrow32Word#   x# = x#
 842    #-}
 843 #endif
 844
 845 {-# RULES
 846 "int2Word2Int"  forall x#. int2Word# (word2Int# x#) = x#
 847 "word2Int2Word" forall x#. word2Int# (int2Word# x#) = x#
 848   #-}
 849 \end{code}
 850
 851
 852 %********************************************************
 853 %*                                                      *
 854 \subsection{Unpacking C strings}
 855 %*                                                      *
 856 %********************************************************
 857
 858 This code is needed for virtually all programs, since it's used for
 859 unpacking the strings of error messages.
 860
 861 \begin{code}
 862 unpackCString# :: Addr# -> [Char]
 863 {-# NOINLINE unpackCString# #-}
 864     -- There's really no point in inlining this, ever, cos
 865     -- the loop doesn't specialise in an interesting
 866     -- But it's pretty small, so there's a danger that
 867     -- it'll be inlined at every literal, which is a waste
 868 unpackCString# addr
 869   = unpack 0#
 870   where
 871     unpack nh
 872       | ch `eqChar#` '\0'# = []
 873       | otherwise          = C# ch : unpack (nh +# 1#)
 874       where
 875         !ch = indexCharOffAddr# addr nh
 876
 877 unpackAppendCString# :: Addr# -> [Char] -> [Char]
 878 {-# NOINLINE unpackAppendCString# #-}
 879      -- See the NOINLINE note on unpackCString#
 880 unpackAppendCString# addr rest
 881   = unpack 0#
 882   where
 883     unpack nh
 884       | ch `eqChar#` '\0'# = rest
 885       | otherwise          = C# ch : unpack (nh +# 1#)
 886       where
 887         !ch = indexCharOffAddr# addr nh
 888
 889 unpackFoldrCString# :: Addr# -> (Char  -> a -> a) -> a -> a
 890
 891 -- Usually the unpack-list rule turns unpackFoldrCString# into unpackCString#
 892
 893 -- It also has a BuiltInRule in PrelRules.lhs:
 894 --      unpackFoldrCString# "foo" c (unpackFoldrCString# "baz" c n)
 895 --        =  unpackFoldrCString# "foobaz" c n
 896
 897 {-# NOINLINE unpackFoldrCString# #-}
 898 -- At one stage I had NOINLINE [0] on the grounds that, unlike
 899 -- unpackCString#, there *is* some point in inlining
 900 -- unpackFoldrCString#, because we get better code for the
 901 -- higher-order function call.  BUT there may be a lot of
 902 -- literal strings, and making a separate 'unpack' loop for
 903 -- each is highly gratuitous.  See nofib/real/anna/PrettyPrint.
 904
 905 unpackFoldrCString# addr f z
 906   = unpack 0#
 907   where
 908     unpack nh
 909       | ch `eqChar#` '\0'# = z
 910       | otherwise          = C# ch `f` unpack (nh +# 1#)
 911       where
 912         !ch = indexCharOffAddr# addr nh
 913
 914 unpackCStringUtf8# :: Addr# -> [Char]
 915 unpackCStringUtf8# addr
 916   = unpack 0#
 917   where
 918     unpack nh
 919       | ch `eqChar#` '\0'#   = []
 920       | ch `leChar#` '\x7F'# = C# ch : unpack (nh +# 1#)
 921       | ch `leChar#` '\xDF'# =
 922           C# (chr# (((ord# ch                                  -# 0xC0#) `uncheckedIShiftL#`  6#) +#
 923                      (ord# (indexCharOffAddr# addr (nh +# 1#)) -# 0x80#))) :
 924           unpack (nh +# 2#)
 925       | ch `leChar#` '\xEF'# =
 926           C# (chr# (((ord# ch                                  -# 0xE0#) `uncheckedIShiftL#` 12#) +#
 927                     ((ord# (indexCharOffAddr# addr (nh +# 1#)) -# 0x80#) `uncheckedIShiftL#`  6#) +#
 928                      (ord# (indexCharOffAddr# addr (nh +# 2#)) -# 0x80#))) :
 929           unpack (nh +# 3#)
 930       | otherwise            =
 931           C# (chr# (((ord# ch                                  -# 0xF0#) `uncheckedIShiftL#` 18#) +#
 932                     ((ord# (indexCharOffAddr# addr (nh +# 1#)) -# 0x80#) `uncheckedIShiftL#` 12#) +#
 933                     ((ord# (indexCharOffAddr# addr (nh +# 2#)) -# 0x80#) `uncheckedIShiftL#`  6#) +#
 934                      (ord# (indexCharOffAddr# addr (nh +# 3#)) -# 0x80#))) :
 935           unpack (nh +# 4#)
 936       where
 937         !ch = indexCharOffAddr# addr nh
 938
 939 unpackNBytes# :: Addr# -> Int# -> [Char]
 940 unpackNBytes# _addr 0#   = []
 941 unpackNBytes#  addr len# = unpack [] (len# -# 1#)
 942     where
 943      unpack acc i#
 944       | i# <# 0#  = acc
 945       | otherwise =
 946          case indexCharOffAddr# addr i# of
 947             ch -> unpack (C# ch : acc) (i# -# 1#)
 948
 949 {-# RULES
 950 "unpack"       [~1] forall a   . unpackCString# a             = build (unpackFoldrCString# a)
 951 "unpack-list"  [1]  forall a   . unpackFoldrCString# a (:) [] = unpackCString# a
 952 "unpack-append"     forall a n . unpackFoldrCString# a (:) n  = unpackAppendCString# a n
 953
 954 -- There's a built-in rule (in PrelRules.lhs) for
 955 --      unpackFoldr "foo" c (unpackFoldr "baz" c n)  =  unpackFoldr "foobaz" c n
 956
 957   #-}
 958 \end{code}
 959
 960 #ifdef __HADDOCK__
 961 \begin{code}
 962 -- | A special argument for the 'Control.Monad.ST.ST' type constructor,
 963 -- indexing a state embedded in the 'Prelude.IO' monad by
 964 -- 'Control.Monad.ST.stToIO'.
 965 data RealWorld
 966 \end{code}
 967 #endif