GHC/Base.lhs

   1 \section[GHC.Base]{Module @GHC.Base@}
   2
   3 The overall structure of the GHC Prelude is a bit tricky.
   4
   5   a) We want to avoid "orphan modules", i.e. ones with instance
   6         decls that don't belong either to a tycon or a class
   7         defined in the same module
   8
   9   b) We want to avoid giant modules
  10
  11 So the rough structure is as follows, in (linearised) dependency order
  12
  13
  14 GHC.Prim                Has no implementation.  It defines built-in things, and
  15                 by importing it you bring them into scope.
  16                 The source file is GHC.Prim.hi-boot, which is just
  17                 copied to make GHC.Prim.hi
  18
  19 GHC.Base        Classes: Eq, Ord, Functor, Monad
  20                 Types:   list, (), Int, Bool, Ordering, Char, String
  21
  22 Data.Tuple      Types: tuples, plus instances for GHC.Base classes
  23
  24 GHC.Show        Class: Show, plus instances for GHC.Base/GHC.Tup types
  25
  26 GHC.Enum        Class: Enum,  plus instances for GHC.Base/GHC.Tup types
  27
  28 Data.Maybe      Type: Maybe, plus instances for GHC.Base classes
  29
  30 GHC.List        List functions
  31
  32 GHC.Num         Class: Num, plus instances for Int
  33                 Type:  Integer, plus instances for all classes so far (Eq, Ord, Num, Show)
  34
  35                 Integer is needed here because it is mentioned in the signature
  36                 of 'fromInteger' in class Num
  37
  38 GHC.Real        Classes: Real, Integral, Fractional, RealFrac
  39                          plus instances for Int, Integer
  40                 Types:  Ratio, Rational
  41                         plus intances for classes so far
  42
  43                 Rational is needed here because it is mentioned in the signature
  44                 of 'toRational' in class Real
  45
  46 GHC.ST  The ST monad, instances and a few helper functions
  47
  48 Ix              Classes: Ix, plus instances for Int, Bool, Char, Integer, Ordering, tuples
  49
  50 GHC.Arr         Types: Array, MutableArray, MutableVar
  51
  52                 Arrays are used by a function in GHC.Float
  53
  54 GHC.Float       Classes: Floating, RealFloat
  55                 Types:   Float, Double, plus instances of all classes so far
  56
  57                 This module contains everything to do with floating point.
  58                 It is a big module (900 lines)
  59                 With a bit of luck, many modules can be compiled without ever reading GHC.Float.hi
  60
  61
  62 Other Prelude modules are much easier with fewer complex dependencies.
  63
  64 \begin{code}
  65 {-# OPTIONS_GHC -XNoImplicitPrelude #-}
  66 -- -fno-warn-orphans is needed for things like:
  67 -- Orphan rule: "x# -# x#" ALWAYS forall x# :: Int# -# x# x# = 0
  68 {-# OPTIONS_GHC -fno-warn-orphans #-}
  69 {-# OPTIONS_HADDOCK hide #-}
  70 -----------------------------------------------------------------------------
  71 -- |
  72 -- Module      :  GHC.Base
  73 -- Copyright   :  (c) The University of Glasgow, 1992-2002
  74 -- License     :  see libraries/base/LICENSE
  75 --
  76 -- Maintainer  :  cvs-ghc@haskell.org
  77 -- Stability   :  internal
  78 -- Portability :  non-portable (GHC extensions)
  79 --
  80 -- Basic data types and classes.
  81 --
  82 -----------------------------------------------------------------------------
  83
  84 #include "MachDeps.h"
  85
  86 -- #hide
  87 module GHC.Base
  88         (
  89         module GHC.Base,
  90         module GHC.Bool,
  91         module GHC.Classes,
  92         module GHC.Generics,
  93         module GHC.Ordering,
  94         module GHC.Types,
  95         module GHC.Prim,        -- Re-export GHC.Prim and GHC.Err, to avoid lots
  96         module GHC.Err          -- of people having to import it explicitly
  97   )
  98         where
  99
 100 import GHC.Types
 101 import GHC.Bool
 102 import GHC.Classes
 103 import GHC.Generics
 104 import GHC.Ordering
 105 import GHC.Prim
 106 import {-# SOURCE #-} GHC.Show
 107 import {-# SOURCE #-} GHC.Err
 108 import {-# SOURCE #-} GHC.IO (failIO)
 109
 110 -- These two are not strictly speaking required by this module, but they are
 111 -- implicit dependencies whenever () or tuples are mentioned, so adding them
 112 -- as imports here helps to get the dependencies right in the new build system.
 113 import GHC.Tuple ()
 114 import GHC.Unit ()
 115
 116 infixr 9  .
 117 infixr 5  ++
 118 infixl 4  <$
 119 infixl 1  >>, >>=
 120 infixr 0  $
 121
 122 default ()              -- Double isn't available yet
 123 \end{code}
 124
 125
 126 %*********************************************************
 127 %*                                                      *
 128 \subsection{DEBUGGING STUFF}
 129 %*  (for use when compiling GHC.Base itself doesn't work)
 130 %*                                                      *
 131 %*********************************************************
 132
 133 \begin{code}
 134 {-
 135 data  Bool  =  False | True
 136 data Ordering = LT | EQ | GT
 137 data Char = C# Char#
 138 type  String = [Char]
 139 data Int = I# Int#
 140 data  ()  =  ()
 141 data [] a = MkNil
 142
 143 not True = False
 144 (&&) True True = True
 145 otherwise = True
 146
 147 build = error "urk"
 148 foldr = error "urk"
 149
 150 unpackCString# :: Addr# -> [Char]
 151 unpackFoldrCString# :: Addr# -> (Char  -> a -> a) -> a -> a
 152 unpackAppendCString# :: Addr# -> [Char] -> [Char]
 153 unpackCStringUtf8# :: Addr# -> [Char]
 154 unpackCString# a = error "urk"
 155 unpackFoldrCString# a = error "urk"
 156 unpackAppendCString# a = error "urk"
 157 unpackCStringUtf8# a = error "urk"
 158 -}
 159 \end{code}
 160
 161
 162 %*********************************************************
 163 %*                                                      *
 164 \subsection{Monadic classes @Functor@, @Monad@ }
 165 %*                                                      *
 166 %*********************************************************
 167
 168 \begin{code}
 169 {- | The 'Functor' class is used for types that can be mapped over.
 170 Instances of 'Functor' should satisfy the following laws:
 171
 172 > fmap id  ==  id
 173 > fmap (f . g)  ==  fmap f . fmap g
 174
 175 The instances of 'Functor' for lists, 'Data.Maybe.Maybe' and 'System.IO.IO'
 176 defined in the "Prelude" satisfy these laws.
 177 -}
 178
 179 class  Functor f  where
 180     fmap        :: (a -> b) -> f a -> f b
 181
 182     -- | Replace all locations in the input with the same value.
 183     -- The default definition is @'fmap' . 'const'@, but this may be
 184     -- overridden with a more efficient version.
 185     (<$)        :: a -> f b -> f a
 186     (<$)        =  fmap . const
 187
 188 {- | The 'Monad' class defines the basic operations over a /monad/,
 189 a concept from a branch of mathematics known as /category theory/.
 190 From the perspective of a Haskell programmer, however, it is best to
 191 think of a monad as an /abstract datatype/ of actions.
 192 Haskell's @do@ expressions provide a convenient syntax for writing
 193 monadic expressions.
 194
 195 Minimal complete definition: '>>=' and 'return'.
 196
 197 Instances of 'Monad' should satisfy the following laws:
 198
 199 > return a >>= k  ==  k a
 200 > m >>= return  ==  m
 201 > m >>= (\x -> k x >>= h)  ==  (m >>= k) >>= h
 202
 203 Instances of both 'Monad' and 'Functor' should additionally satisfy the law:
 204
 205 > fmap f xs  ==  xs >>= return . f
 206
 207 The instances of 'Monad' for lists, 'Data.Maybe.Maybe' and 'System.IO.IO'
 208 defined in the "Prelude" satisfy these laws.
 209 -}
 210
 211 class  Monad m  where
 212     -- | Sequentially compose two actions, passing any value produced
 213     -- by the first as an argument to the second.
 214     (>>=)       :: forall a b. m a -> (a -> m b) -> m b
 215     -- | Sequentially compose two actions, discarding any value produced
 216     -- by the first, like sequencing operators (such as the semicolon)
 217     -- in imperative languages.
 218     (>>)        :: forall a b. m a -> m b -> m b
 219         -- Explicit for-alls so that we know what order to
 220         -- give type arguments when desugaring
 221
 222     -- | Inject a value into the monadic type.
 223     return      :: a -> m a
 224     -- | Fail with a message.  This operation is not part of the
 225     -- mathematical definition of a monad, but is invoked on pattern-match
 226     -- failure in a @do@ expression.
 227     fail        :: String -> m a
 228
 229     {-# INLINE (>>) #-}
 230     m >> k      = m >>= \_ -> k
 231     fail s      = error s
 232 \end{code}
 233
 234
 235 %*********************************************************
 236 %*                                                      *
 237 \subsection{The list type}
 238 %*                                                      *
 239 %*********************************************************
 240
 241 \begin{code}
 242 instance Functor [] where
 243     fmap = map
 244
 245 instance  Monad []  where
 246     m >>= k             = foldr ((++) . k) [] m
 247     m >> k              = foldr ((++) . (\ _ -> k)) [] m
 248     return x            = [x]
 249     fail _              = []
 250 \end{code}
 251
 252 A few list functions that appear here because they are used here.
 253 The rest of the prelude list functions are in GHC.List.
 254
 255 ----------------------------------------------
 256 --      foldr/build/augment
 257 ----------------------------------------------
 258
 259 \begin{code}
 260 -- | 'foldr', applied to a binary operator, a starting value (typically
 261 -- the right-identity of the operator), and a list, reduces the list
 262 -- using the binary operator, from right to left:
 263 --
 264 -- > foldr f z [x1, x2, ..., xn] == x1 `f` (x2 `f` ... (xn `f` z)...)
 265
 266 foldr            :: (a -> b -> b) -> b -> [a] -> b
 267 -- foldr _ z []     =  z
 268 -- foldr f z (x:xs) =  f x (foldr f z xs)
 269 {-# INLINE [0] foldr #-}
 270 -- Inline only in the final stage, after the foldr/cons rule has had a chance
 271 -- Also note that we inline it when it has *two* parameters, which are the
 272 -- ones we are keen about specialising!
 273 foldr k z = go
 274           where
 275             go []     = z
 276             go (y:ys) = y `k` go ys
 277
 278 -- | A list producer that can be fused with 'foldr'.
 279 -- This function is merely
 280 --
 281 -- >    build g = g (:) []
 282 --
 283 -- but GHC's simplifier will transform an expression of the form
 284 -- @'foldr' k z ('build' g)@, which may arise after inlining, to @g k z@,
 285 -- which avoids producing an intermediate list.
 286
 287 build   :: forall a. (forall b. (a -> b -> b) -> b -> b) -> [a]
 288 {-# INLINE [1] build #-}
 289         -- The INLINE is important, even though build is tiny,
 290         -- because it prevents [] getting inlined in the version that
 291         -- appears in the interface file.  If [] *is* inlined, it
 292         -- won't match with [] appearing in rules in an importing module.
 293         --
 294         -- The "1" says to inline in phase 1
 295
 296 build g = g (:) []
 297
 298 -- | A list producer that can be fused with 'foldr'.
 299 -- This function is merely
 300 --
 301 -- >    augment g xs = g (:) xs
 302 --
 303 -- but GHC's simplifier will transform an expression of the form
 304 -- @'foldr' k z ('augment' g xs)@, which may arise after inlining, to
 305 -- @g k ('foldr' k z xs)@, which avoids producing an intermediate list.
 306
 307 augment :: forall a. (forall b. (a->b->b) -> b -> b) -> [a] -> [a]
 308 {-# INLINE [1] augment #-}
 309 augment g xs = g (:) xs
 310
 311 {-# RULES
 312 "fold/build"    forall k z (g::forall b. (a->b->b) -> b -> b) .
 313                 foldr k z (build g) = g k z
 314
 315 "foldr/augment" forall k z xs (g::forall b. (a->b->b) -> b -> b) .
 316                 foldr k z (augment g xs) = g k (foldr k z xs)
 317
 318 "foldr/id"                        foldr (:) [] = \x  -> x
 319 "foldr/app"     [1] forall ys. foldr (:) ys = \xs -> xs ++ ys
 320         -- Only activate this from phase 1, because that's
 321         -- when we disable the rule that expands (++) into foldr
 322
 323 -- The foldr/cons rule looks nice, but it can give disastrously
 324 -- bloated code when commpiling
 325 --      array (a,b) [(1,2), (2,2), (3,2), ...very long list... ]
 326 -- i.e. when there are very very long literal lists
 327 -- So I've disabled it for now. We could have special cases
 328 -- for short lists, I suppose.
 329 -- "foldr/cons" forall k z x xs. foldr k z (x:xs) = k x (foldr k z xs)
 330
 331 "foldr/single"  forall k z x. foldr k z [x] = k x z
 332 "foldr/nil"     forall k z.   foldr k z []  = z
 333
 334 "augment/build" forall (g::forall b. (a->b->b) -> b -> b)
 335                        (h::forall b. (a->b->b) -> b -> b) .
 336                        augment g (build h) = build (\c n -> g c (h c n))
 337 "augment/nil"   forall (g::forall b. (a->b->b) -> b -> b) .
 338                         augment g [] = build g
 339  #-}
 340
 341 -- This rule is true, but not (I think) useful:
 342 --      augment g (augment h t) = augment (\cn -> g c (h c n)) t
 343 \end{code}
 344
 345
 346 ----------------------------------------------
 347 --              map
 348 ----------------------------------------------
 349
 350 \begin{code}
 351 -- | 'map' @f xs@ is the list obtained by applying @f@ to each element
 352 -- of @xs@, i.e.,
 353 --
 354 -- > map f [x1, x2, ..., xn] == [f x1, f x2, ..., f xn]
 355 -- > map f [x1, x2, ...] == [f x1, f x2, ...]
 356
 357 map :: (a -> b) -> [a] -> [b]
 358 map _ []     = []
 359 map f (x:xs) = f x : map f xs
 360
 361 -- Note eta expanded
 362 mapFB ::  (elt -> lst -> lst) -> (a -> elt) -> a -> lst -> lst
 363 {-# INLINE [0] mapFB #-}
 364 mapFB c f = \x ys -> c (f x) ys
 365
 366 -- The rules for map work like this.
 367 --
 368 -- Up to (but not including) phase 1, we use the "map" rule to
 369 -- rewrite all saturated applications of map with its build/fold
 370 -- form, hoping for fusion to happen.
 371 -- In phase 1 and 0, we switch off that rule, inline build, and
 372 -- switch on the "mapList" rule, which rewrites the foldr/mapFB
 373 -- thing back into plain map.
 374 --
 375 -- It's important that these two rules aren't both active at once
 376 -- (along with build's unfolding) else we'd get an infinite loop
 377 -- in the rules.  Hence the activation control below.
 378 --
 379 -- The "mapFB" rule optimises compositions of map.
 380 --
 381 -- This same pattern is followed by many other functions:
 382 -- e.g. append, filter, iterate, repeat, etc.
 383
 384 {-# RULES
 385 "map"       [~1] forall f xs.   map f xs                = build (\c n -> foldr (mapFB c f) n xs)
 386 "mapList"   [1]  forall f.      foldr (mapFB (:) f) []  = map f
 387 "mapFB"     forall c f g.       mapFB (mapFB c f) g     = mapFB c (f.g)
 388   #-}
 389 \end{code}
 390
 391
 392 ----------------------------------------------
 393 --              append
 394 ----------------------------------------------
 395 \begin{code}
 396 -- | Append two lists, i.e.,
 397 --
 398 -- > [x1, ..., xm] ++ [y1, ..., yn] == [x1, ..., xm, y1, ..., yn]
 399 -- > [x1, ..., xm] ++ [y1, ...] == [x1, ..., xm, y1, ...]
 400 --
 401 -- If the first list is not finite, the result is the first list.
 402
 403 (++) :: [a] -> [a] -> [a]
 404 (++) []     ys = ys
 405 (++) (x:xs) ys = x : xs ++ ys
 406
 407 {-# RULES
 408 "++"    [~1] forall xs ys. xs ++ ys = augment (\c n -> foldr c n xs) ys
 409   #-}
 410
 411 \end{code}
 412
 413
 414 %*********************************************************
 415 %*                                                      *
 416 \subsection{Type @Bool@}
 417 %*                                                      *
 418 %*********************************************************
 419
 420 \begin{code}
 421 -- |'otherwise' is defined as the value 'True'.  It helps to make
 422 -- guards more readable.  eg.
 423 --
 424 -- >  f x | x < 0     = ...
 425 -- >      | otherwise = ...
 426 otherwise               :: Bool
 427 otherwise               =  True
 428 \end{code}
 429
 430 %*********************************************************
 431 %*                                                      *
 432 \subsection{Type @Char@ and @String@}
 433 %*                                                      *
 434 %*********************************************************
 435
 436 \begin{code}
 437 -- | A 'String' is a list of characters.  String constants in Haskell are values
 438 -- of type 'String'.
 439 --
 440 type String = [Char]
 441
 442 {-| The character type 'Char' is an enumeration whose values represent
 443 Unicode (or equivalently ISO\/IEC 10646) characters
 444 (see <http://www.unicode.org/> for details).
 445 This set extends the ISO 8859-1 (Latin-1) character set
 446 (the first 256 charachers), which is itself an extension of the ASCII
 447 character set (the first 128 characters).
 448 A character literal in Haskell has type 'Char'.
 449
 450 To convert a 'Char' to or from the corresponding 'Int' value defined
 451 by Unicode, use 'Prelude.toEnum' and 'Prelude.fromEnum' from the
 452 'Prelude.Enum' class respectively (or equivalently 'ord' and 'chr').
 453 -}
 454
 455 {-# RULES
 456 "x# `eqChar#` x#" forall x#. x# `eqChar#` x# = True
 457 "x# `neChar#` x#" forall x#. x# `neChar#` x# = False
 458 "x# `gtChar#` x#" forall x#. x# `gtChar#` x# = False
 459 "x# `geChar#` x#" forall x#. x# `geChar#` x# = True
 460 "x# `leChar#` x#" forall x#. x# `leChar#` x# = True
 461 "x# `ltChar#` x#" forall x#. x# `ltChar#` x# = False
 462   #-}
 463
 464 -- | The 'Prelude.toEnum' method restricted to the type 'Data.Char.Char'.
 465 chr :: Int -> Char
 466 chr i@(I# i#)
 467  | int2Word# i# `leWord#` int2Word# 0x10FFFF# = C# (chr# i#)
 468  | otherwise
 469     = error ("Prelude.chr: bad argument: " ++ showSignedInt (I# 9#) i "")
 470
 471 unsafeChr :: Int -> Char
 472 unsafeChr (I# i#) = C# (chr# i#)
 473
 474 -- | The 'Prelude.fromEnum' method restricted to the type 'Data.Char.Char'.
 475 ord :: Char -> Int
 476 ord (C# c#) = I# (ord# c#)
 477 \end{code}
 478
 479 String equality is used when desugaring pattern-matches against strings.
 480
 481 \begin{code}
 482 eqString :: String -> String -> Bool
 483 eqString []       []       = True
 484 eqString (c1:cs1) (c2:cs2) = c1 == c2 && cs1 `eqString` cs2
 485 eqString _        _        = False
 486
 487 {-# RULES "eqString" (==) = eqString #-}
 488 -- eqString also has a BuiltInRule in PrelRules.lhs:
 489 --      eqString (unpackCString# (Lit s1)) (unpackCString# (Lit s2) = s1==s2
 490 \end{code}
 491
 492
 493 %*********************************************************
 494 %*                                                      *
 495 \subsection{Type @Int@}
 496 %*                                                      *
 497 %*********************************************************
 498
 499 \begin{code}
 500 zeroInt, oneInt, twoInt, maxInt, minInt :: Int
 501 zeroInt = I# 0#
 502 oneInt  = I# 1#
 503 twoInt  = I# 2#
 504
 505 {- Seems clumsy. Should perhaps put minInt and MaxInt directly into MachDeps.h -}
 506 #if WORD_SIZE_IN_BITS == 31
 507 minInt  = I# (-0x40000000#)
 508 maxInt  = I# 0x3FFFFFFF#
 509 #elif WORD_SIZE_IN_BITS == 32
 510 minInt  = I# (-0x80000000#)
 511 maxInt  = I# 0x7FFFFFFF#
 512 #else
 513 minInt  = I# (-0x8000000000000000#)
 514 maxInt  = I# 0x7FFFFFFFFFFFFFFF#
 515 #endif
 516
 517 instance Eq Int where
 518     (==) = eqInt
 519     (/=) = neInt
 520
 521 instance Ord Int where
 522     compare = compareInt
 523     (<)     = ltInt
 524     (<=)    = leInt
 525     (>=)    = geInt
 526     (>)     = gtInt
 527
 528 compareInt :: Int -> Int -> Ordering
 529 (I# x#) `compareInt` (I# y#) = compareInt# x# y#
 530
 531 compareInt# :: Int# -> Int# -> Ordering
 532 compareInt# x# y#
 533     | x# <#  y# = LT
 534     | x# ==# y# = EQ
 535     | otherwise = GT
 536 \end{code}
 537
 538
 539 %*********************************************************
 540 %*                                                      *
 541 \subsection{The function type}
 542 %*                                                      *
 543 %*********************************************************
 544
 545 \begin{code}
 546 -- | Identity function.
 547 id                      :: a -> a
 548 id x                    =  x
 549
 550 -- | The call '(lazy e)' means the same as 'e', but 'lazy' has a
 551 -- magical strictness property: it is lazy in its first argument,
 552 -- even though its semantics is strict.
 553 lazy :: a -> a
 554 lazy x = x
 555 -- Implementation note: its strictness and unfolding are over-ridden
 556 -- by the definition in MkId.lhs; in both cases to nothing at all.
 557 -- That way, 'lazy' does not get inlined, and the strictness analyser
 558 -- sees it as lazy.  Then the worker/wrapper phase inlines it.
 559 -- Result: happiness
 560
 561 -- Assertion function.  This simply ignores its boolean argument.
 562 -- The compiler may rewrite it to @('assertError' line)@.
 563
 564 -- | If the first argument evaluates to 'True', then the result is the
 565 -- second argument.  Otherwise an 'AssertionFailed' exception is raised,
 566 -- containing a 'String' with the source file and line number of the
 567 -- call to 'assert'.
 568 --
 569 -- Assertions can normally be turned on or off with a compiler flag
 570 -- (for GHC, assertions are normally on unless optimisation is turned on
 571 -- with @-O@ or the @-fignore-asserts@
 572 -- option is given).  When assertions are turned off, the first
 573 -- argument to 'assert' is ignored, and the second argument is
 574 -- returned as the result.
 575
 576 --      SLPJ: in 5.04 etc 'assert' is in GHC.Prim,
 577 --      but from Template Haskell onwards it's simply
 578 --      defined here in Base.lhs
 579 assert :: Bool -> a -> a
 580 assert _pred r = r
 581
 582 breakpoint :: a -> a
 583 breakpoint r = r
 584
 585 breakpointCond :: Bool -> a -> a
 586 breakpointCond _ r = r
 587
 588 data Opaque = forall a. O a
 589
 590 -- | Constant function.
 591 const                   :: a -> b -> a
 592 const x _               =  x
 593
 594 -- | Function composition.
 595 {-# INLINE (.) #-}
 596 -- Make sure it has TWO args only on the left, so that it inlines
 597 -- when applied to two functions, even if there is no final argument
 598 (.)    :: (b -> c) -> (a -> b) -> a -> c
 599 (.) f g = \x -> f (g x)
 600
 601 -- | @'flip' f@ takes its (first) two arguments in the reverse order of @f@.
 602 flip                    :: (a -> b -> c) -> b -> a -> c
 603 flip f x y              =  f y x
 604
 605 -- | Application operator.  This operator is redundant, since ordinary
 606 -- application @(f x)@ means the same as @(f '$' x)@. However, '$' has
 607 -- low, right-associative binding precedence, so it sometimes allows
 608 -- parentheses to be omitted; for example:
 609 --
 610 -- >     f $ g $ h x  =  f (g (h x))
 611 --
 612 -- It is also useful in higher-order situations, such as @'map' ('$' 0) xs@,
 613 -- or @'Data.List.zipWith' ('$') fs xs@.
 614 {-# INLINE ($) #-}
 615 ($)                     :: (a -> b) -> a -> b
 616 f $ x                   =  f x
 617
 618 -- | @'until' p f@ yields the result of applying @f@ until @p@ holds.
 619 until                   :: (a -> Bool) -> (a -> a) -> a -> a
 620 until p f x | p x       =  x
 621             | otherwise =  until p f (f x)
 622
 623 -- | 'asTypeOf' is a type-restricted version of 'const'.  It is usually
 624 -- used as an infix operator, and its typing forces its first argument
 625 -- (which is usually overloaded) to have the same type as the second.
 626 asTypeOf                :: a -> a -> a
 627 asTypeOf                =  const
 628 \end{code}
 629
 630 %*********************************************************
 631 %*                                                      *
 632 \subsection{@Functor@ and @Monad@ instances for @IO@}
 633 %*                                                      *
 634 %*********************************************************
 635
 636 \begin{code}
 637 instance  Functor IO where
 638    fmap f x = x >>= (return . f)
 639
 640 instance  Monad IO  where
 641     {-# INLINE return #-}
 642     {-# INLINE (>>)   #-}
 643     {-# INLINE (>>=)  #-}
 644     m >> k    = m >>= \ _ -> k
 645     return    = returnIO
 646     (>>=)     = bindIO
 647     fail s    = GHC.IO.failIO s
 648
 649 returnIO :: a -> IO a
 650 returnIO x = IO $ \ s -> (# s, x #)
 651
 652 bindIO :: IO a -> (a -> IO b) -> IO b
 653 bindIO (IO m) k = IO $ \ s -> case m s of (# new_s, a #) -> unIO (k a) new_s
 654
 655 thenIO :: IO a -> IO b -> IO b
 656 thenIO (IO m) k = IO $ \ s -> case m s of (# new_s, _ #) -> unIO k new_s
 657
 658 unIO :: IO a -> (State# RealWorld -> (# State# RealWorld, a #))
 659 unIO (IO a) = a
 660 \end{code}
 661
 662 %*********************************************************
 663 %*                                                      *
 664 \subsection{@getTag@}
 665 %*                                                      *
 666 %*********************************************************
 667
 668 Returns the 'tag' of a constructor application; this function is used
 669 by the deriving code for Eq, Ord and Enum.
 670
 671 The primitive dataToTag# requires an evaluated constructor application
 672 as its argument, so we provide getTag as a wrapper that performs the
 673 evaluation before calling dataToTag#.  We could have dataToTag#
 674 evaluate its argument, but we prefer to do it this way because (a)
 675 dataToTag# can be an inline primop if it doesn't need to do any
 676 evaluation, and (b) we want to expose the evaluation to the
 677 simplifier, because it might be possible to eliminate the evaluation
 678 in the case when the argument is already known to be evaluated.
 679
 680 \begin{code}
 681 {-# INLINE getTag #-}
 682 getTag :: a -> Int#
 683 getTag x = x `seq` dataToTag# x
 684 \end{code}
 685
 686 %*********************************************************
 687 %*                                                      *
 688 \subsection{Numeric primops}
 689 %*                                                      *
 690 %*********************************************************
 691
 692 \begin{code}
 693 divInt# :: Int# -> Int# -> Int#
 694 x# `divInt#` y#
 695         -- Be careful NOT to overflow if we do any additional arithmetic
 696         -- on the arguments...  the following  previous version of this
 697         -- code has problems with overflow:
 698 --    | (x# ># 0#) && (y# <# 0#) = ((x# -# y#) -# 1#) `quotInt#` y#
 699 --    | (x# <# 0#) && (y# ># 0#) = ((x# -# y#) +# 1#) `quotInt#` y#
 700     | (x# ># 0#) && (y# <# 0#) = ((x# -# 1#) `quotInt#` y#) -# 1#
 701     | (x# <# 0#) && (y# ># 0#) = ((x# +# 1#) `quotInt#` y#) -# 1#
 702     | otherwise                = x# `quotInt#` y#
 703
 704 modInt# :: Int# -> Int# -> Int#
 705 x# `modInt#` y#
 706     | (x# ># 0#) && (y# <# 0#) ||
 707       (x# <# 0#) && (y# ># 0#)    = if r# /=# 0# then r# +# y# else 0#
 708     | otherwise                   = r#
 709     where
 710     !r# = x# `remInt#` y#
 711 \end{code}
 712
 713 Definitions of the boxed PrimOps; these will be
 714 used in the case of partial applications, etc.
 715
 716 \begin{code}
 717 {-# INLINE eqInt #-}
 718 {-# INLINE neInt #-}
 719 {-# INLINE gtInt #-}
 720 {-# INLINE geInt #-}
 721 {-# INLINE ltInt #-}
 722 {-# INLINE leInt #-}
 723 {-# INLINE plusInt #-}
 724 {-# INLINE minusInt #-}
 725 {-# INLINE timesInt #-}
 726 {-# INLINE quotInt #-}
 727 {-# INLINE remInt #-}
 728 {-# INLINE negateInt #-}
 729
 730 plusInt, minusInt, timesInt, quotInt, remInt, divInt, modInt :: Int -> Int -> Int
 731 (I# x) `plusInt`  (I# y) = I# (x +# y)
 732 (I# x) `minusInt` (I# y) = I# (x -# y)
 733 (I# x) `timesInt` (I# y) = I# (x *# y)
 734 (I# x) `quotInt`  (I# y) = I# (x `quotInt#` y)
 735 (I# x) `remInt`   (I# y) = I# (x `remInt#`  y)
 736 (I# x) `divInt`   (I# y) = I# (x `divInt#`  y)
 737 (I# x) `modInt`   (I# y) = I# (x `modInt#`  y)
 738
 739 {-# RULES
 740 "x# +# 0#" forall x#. x# +# 0# = x#
 741 "0# +# x#" forall x#. 0# +# x# = x#
 742 "x# -# 0#" forall x#. x# -# 0# = x#
 743 "x# -# x#" forall x#. x# -# x# = 0#
 744 "x# *# 0#" forall x#. x# *# 0# = 0#
 745 "0# *# x#" forall x#. 0# *# x# = 0#
 746 "x# *# 1#" forall x#. x# *# 1# = x#
 747 "1# *# x#" forall x#. 1# *# x# = x#
 748   #-}
 749
 750 negateInt :: Int -> Int
 751 negateInt (I# x) = I# (negateInt# x)
 752
 753 gtInt, geInt, eqInt, neInt, ltInt, leInt :: Int -> Int -> Bool
 754 (I# x) `gtInt` (I# y) = x >#  y
 755 (I# x) `geInt` (I# y) = x >=# y
 756 (I# x) `eqInt` (I# y) = x ==# y
 757 (I# x) `neInt` (I# y) = x /=# y
 758 (I# x) `ltInt` (I# y) = x <#  y
 759 (I# x) `leInt` (I# y) = x <=# y
 760
 761 {-# RULES
 762 "x# ># x#"  forall x#. x# >#  x# = False
 763 "x# >=# x#" forall x#. x# >=# x# = True
 764 "x# ==# x#" forall x#. x# ==# x# = True
 765 "x# /=# x#" forall x#. x# /=# x# = False
 766 "x# <# x#"  forall x#. x# <#  x# = False
 767 "x# <=# x#" forall x#. x# <=# x# = True
 768   #-}
 769
 770 {-# RULES
 771 "plusFloat x 0.0"   forall x#. plusFloat#  x#   0.0# = x#
 772 "plusFloat 0.0 x"   forall x#. plusFloat#  0.0# x#   = x#
 773 "minusFloat x 0.0"  forall x#. minusFloat# x#   0.0# = x#
 774 "minusFloat x x"    forall x#. minusFloat# x#   x#   = 0.0#
 775 "timesFloat x 0.0"  forall x#. timesFloat# x#   0.0# = 0.0#
 776 "timesFloat0.0 x"   forall x#. timesFloat# 0.0# x#   = 0.0#
 777 "timesFloat x 1.0"  forall x#. timesFloat# x#   1.0# = x#
 778 "timesFloat 1.0 x"  forall x#. timesFloat# 1.0# x#   = x#
 779 "divideFloat x 1.0" forall x#. divideFloat# x#  1.0# = x#
 780   #-}
 781
 782 {-# RULES
 783 "plusDouble x 0.0"   forall x#. (+##) x#    0.0## = x#
 784 "plusDouble 0.0 x"   forall x#. (+##) 0.0## x#    = x#
 785 "minusDouble x 0.0"  forall x#. (-##) x#    0.0## = x#
 786 "timesDouble x 1.0"  forall x#. (*##) x#    1.0## = x#
 787 "timesDouble 1.0 x"  forall x#. (*##) 1.0## x#    = x#
 788 "divideDouble x 1.0" forall x#. (/##) x#    1.0## = x#
 789   #-}
 790
 791 {-
 792 We'd like to have more rules, but for example:
 793
 794 This gives wrong answer (0) for NaN - NaN (should be NaN):
 795     "minusDouble x x"    forall x#. (-##) x#    x#    = 0.0##
 796
 797 This gives wrong answer (0) for 0 * NaN (should be NaN):
 798     "timesDouble 0.0 x"  forall x#. (*##) 0.0## x#    = 0.0##
 799
 800 This gives wrong answer (0) for NaN * 0 (should be NaN):
 801     "timesDouble x 0.0"  forall x#. (*##) x#    0.0## = 0.0##
 802
 803 These are tested by num014.
 804 -}
 805
 806 -- Wrappers for the shift operations.  The uncheckedShift# family are
 807 -- undefined when the amount being shifted by is greater than the size
 808 -- in bits of Int#, so these wrappers perform a check and return
 809 -- either zero or -1 appropriately.
 810 --
 811 -- Note that these wrappers still produce undefined results when the
 812 -- second argument (the shift amount) is negative.
 813
 814 -- | Shift the argument left by the specified number of bits
 815 -- (which must be non-negative).
 816 shiftL# :: Word# -> Int# -> Word#
 817 a `shiftL#` b   | b >=# WORD_SIZE_IN_BITS# = int2Word# 0#
 818                 | otherwise                = a `uncheckedShiftL#` b
 819
 820 -- | Shift the argument right by the specified number of bits
 821 -- (which must be non-negative).
 822 shiftRL# :: Word# -> Int# -> Word#
 823 a `shiftRL#` b  | b >=# WORD_SIZE_IN_BITS# = int2Word# 0#
 824                 | otherwise                = a `uncheckedShiftRL#` b
 825
 826 -- | Shift the argument left by the specified number of bits
 827 -- (which must be non-negative).
 828 iShiftL# :: Int# -> Int# -> Int#
 829 a `iShiftL#` b  | b >=# WORD_SIZE_IN_BITS# = 0#
 830                 | otherwise                = a `uncheckedIShiftL#` b
 831
 832 -- | Shift the argument right (signed) by the specified number of bits
 833 -- (which must be non-negative).
 834 iShiftRA# :: Int# -> Int# -> Int#
 835 a `iShiftRA#` b | b >=# WORD_SIZE_IN_BITS# = if a <# 0# then (-1#) else 0#
 836                 | otherwise                = a `uncheckedIShiftRA#` b
 837
 838 -- | Shift the argument right (unsigned) by the specified number of bits
 839 -- (which must be non-negative).
 840 iShiftRL# :: Int# -> Int# -> Int#
 841 a `iShiftRL#` b | b >=# WORD_SIZE_IN_BITS# = 0#
 842                 | otherwise                = a `uncheckedIShiftRL#` b
 843
 844 #if WORD_SIZE_IN_BITS == 32
 845 {-# RULES
 846 "narrow32Int#"  forall x#. narrow32Int#   x# = x#
 847 "narrow32Word#" forall x#. narrow32Word#   x# = x#
 848    #-}
 849 #endif
 850
 851 {-# RULES
 852 "int2Word2Int"  forall x#. int2Word# (word2Int# x#) = x#
 853 "word2Int2Word" forall x#. word2Int# (int2Word# x#) = x#
 854   #-}
 855 \end{code}
 856
 857
 858 %********************************************************
 859 %*                                                      *
 860 \subsection{Unpacking C strings}
 861 %*                                                      *
 862 %********************************************************
 863
 864 This code is needed for virtually all programs, since it's used for
 865 unpacking the strings of error messages.
 866
 867 \begin{code}
 868 unpackCString# :: Addr# -> [Char]
 869 {-# NOINLINE unpackCString# #-}
 870     -- There's really no point in inlining this, ever, cos
 871     -- the loop doesn't specialise in an interesting
 872     -- But it's pretty small, so there's a danger that
 873     -- it'll be inlined at every literal, which is a waste
 874 unpackCString# addr
 875   = unpack 0#
 876   where
 877     unpack nh
 878       | ch `eqChar#` '\0'# = []
 879       | otherwise          = C# ch : unpack (nh +# 1#)
 880       where
 881         !ch = indexCharOffAddr# addr nh
 882
 883 unpackAppendCString# :: Addr# -> [Char] -> [Char]
 884 {-# NOINLINE unpackAppendCString# #-}
 885      -- See the NOINLINE note on unpackCString#
 886 unpackAppendCString# addr rest
 887   = unpack 0#
 888   where
 889     unpack nh
 890       | ch `eqChar#` '\0'# = rest
 891       | otherwise          = C# ch : unpack (nh +# 1#)
 892       where
 893         !ch = indexCharOffAddr# addr nh
 894
 895 unpackFoldrCString# :: Addr# -> (Char  -> a -> a) -> a -> a
 896
 897 -- Usually the unpack-list rule turns unpackFoldrCString# into unpackCString#
 898
 899 -- It also has a BuiltInRule in PrelRules.lhs:
 900 --      unpackFoldrCString# "foo" c (unpackFoldrCString# "baz" c n)
 901 --        =  unpackFoldrCString# "foobaz" c n
 902
 903 {-# NOINLINE unpackFoldrCString# #-}
 904 -- At one stage I had NOINLINE [0] on the grounds that, unlike
 905 -- unpackCString#, there *is* some point in inlining
 906 -- unpackFoldrCString#, because we get better code for the
 907 -- higher-order function call.  BUT there may be a lot of
 908 -- literal strings, and making a separate 'unpack' loop for
 909 -- each is highly gratuitous.  See nofib/real/anna/PrettyPrint.
 910
 911 unpackFoldrCString# addr f z
 912   = unpack 0#
 913   where
 914     unpack nh
 915       | ch `eqChar#` '\0'# = z
 916       | otherwise          = C# ch `f` unpack (nh +# 1#)
 917       where
 918         !ch = indexCharOffAddr# addr nh
 919
 920 unpackCStringUtf8# :: Addr# -> [Char]
 921 unpackCStringUtf8# addr
 922   = unpack 0#
 923   where
 924     unpack nh
 925       | ch `eqChar#` '\0'#   = []
 926       | ch `leChar#` '\x7F'# = C# ch : unpack (nh +# 1#)
 927       | ch `leChar#` '\xDF'# =
 928           C# (chr# (((ord# ch                                  -# 0xC0#) `uncheckedIShiftL#`  6#) +#
 929                      (ord# (indexCharOffAddr# addr (nh +# 1#)) -# 0x80#))) :
 930           unpack (nh +# 2#)
 931       | ch `leChar#` '\xEF'# =
 932           C# (chr# (((ord# ch                                  -# 0xE0#) `uncheckedIShiftL#` 12#) +#
 933                     ((ord# (indexCharOffAddr# addr (nh +# 1#)) -# 0x80#) `uncheckedIShiftL#`  6#) +#
 934                      (ord# (indexCharOffAddr# addr (nh +# 2#)) -# 0x80#))) :
 935           unpack (nh +# 3#)
 936       | otherwise            =
 937           C# (chr# (((ord# ch                                  -# 0xF0#) `uncheckedIShiftL#` 18#) +#
 938                     ((ord# (indexCharOffAddr# addr (nh +# 1#)) -# 0x80#) `uncheckedIShiftL#` 12#) +#
 939                     ((ord# (indexCharOffAddr# addr (nh +# 2#)) -# 0x80#) `uncheckedIShiftL#`  6#) +#
 940                      (ord# (indexCharOffAddr# addr (nh +# 3#)) -# 0x80#))) :
 941           unpack (nh +# 4#)
 942       where
 943         !ch = indexCharOffAddr# addr nh
 944
 945 unpackNBytes# :: Addr# -> Int# -> [Char]
 946 unpackNBytes# _addr 0#   = []
 947 unpackNBytes#  addr len# = unpack [] (len# -# 1#)
 948     where
 949      unpack acc i#
 950       | i# <# 0#  = acc
 951       | otherwise =
 952          case indexCharOffAddr# addr i# of
 953             ch -> unpack (C# ch : acc) (i# -# 1#)
 954
 955 {-# RULES
 956 "unpack"       [~1] forall a   . unpackCString# a             = build (unpackFoldrCString# a)
 957 "unpack-list"  [1]  forall a   . unpackFoldrCString# a (:) [] = unpackCString# a
 958 "unpack-append"     forall a n . unpackFoldrCString# a (:) n  = unpackAppendCString# a n
 959
 960 -- There's a built-in rule (in PrelRules.lhs) for
 961 --      unpackFoldr "foo" c (unpackFoldr "baz" c n)  =  unpackFoldr "foobaz" c n
 962
 963   #-}
 964 \end{code}
 965
 966 #ifdef __HADDOCK__
 967 \begin{code}
 968 -- | A special argument for the 'Control.Monad.ST.ST' type constructor,
 969 -- indexing a state embedded in the 'Prelude.IO' monad by
 970 -- 'Control.Monad.ST.stToIO'.
 971 data RealWorld
 972 \end{code}
 973 #endif