GHC/Base.lhs

   1 \section[GHC.Base]{Module @GHC.Base@}
   2
   3 The overall structure of the GHC Prelude is a bit tricky.
   4
   5   a) We want to avoid "orphan modules", i.e. ones with instance
   6         decls that don't belong either to a tycon or a class
   7         defined in the same module
   8
   9   b) We want to avoid giant modules
  10
  11 So the rough structure is as follows, in (linearised) dependency order
  12
  13
  14 GHC.Prim                Has no implementation.  It defines built-in things, and
  15                 by importing it you bring them into scope.
  16                 The source file is GHC.Prim.hi-boot, which is just
  17                 copied to make GHC.Prim.hi
  18
  19 GHC.Base        Classes: Eq, Ord, Functor, Monad
  20                 Types:   list, (), Int, Bool, Ordering, Char, String
  21
  22 Data.Tup        Types: tuples, plus instances for GHC.Base classes
  23
  24 GHC.Show        Class: Show, plus instances for GHC.Base/GHC.Tup types
  25
  26 GHC.Enum        Class: Enum,  plus instances for GHC.Base/GHC.Tup types
  27
  28 Data.Maybe      Type: Maybe, plus instances for GHC.Base classes
  29
  30 GHC.Num         Class: Num, plus instances for Int
  31                 Type:  Integer, plus instances for all classes so far (Eq, Ord, Num, Show)
  32
  33                 Integer is needed here because it is mentioned in the signature
  34                 of 'fromInteger' in class Num
  35
  36 GHC.Real        Classes: Real, Integral, Fractional, RealFrac
  37                          plus instances for Int, Integer
  38                 Types:  Ratio, Rational
  39                         plus intances for classes so far
  40
  41                 Rational is needed here because it is mentioned in the signature
  42                 of 'toRational' in class Real
  43
  44 Ix              Classes: Ix, plus instances for Int, Bool, Char, Integer, Ordering, tuples
  45
  46 GHC.Arr         Types: Array, MutableArray, MutableVar
  47
  48                 Does *not* contain any ByteArray stuff (see GHC.ByteArr)
  49                 Arrays are used by a function in GHC.Float
  50
  51 GHC.Float       Classes: Floating, RealFloat
  52                 Types:   Float, Double, plus instances of all classes so far
  53
  54                 This module contains everything to do with floating point.
  55                 It is a big module (900 lines)
  56                 With a bit of luck, many modules can be compiled without ever reading GHC.Float.hi
  57
  58 GHC.ByteArr     Types: ByteArray, MutableByteArray
  59
  60                 We want this one to be after GHC.Float, because it defines arrays
  61                 of unboxed floats.
  62
  63
  64 Other Prelude modules are much easier with fewer complex dependencies.
  65
  66 \begin{code}
  67 {-# OPTIONS_GHC -fno-implicit-prelude #-}
  68 -----------------------------------------------------------------------------
  69 -- |
  70 -- Module      :  GHC.Base
  71 -- Copyright   :  (c) The University of Glasgow, 1992-2002
  72 -- License     :  see libraries/base/LICENSE
  73 --
  74 -- Maintainer  :  cvs-ghc@haskell.org
  75 -- Stability   :  internal
  76 -- Portability :  non-portable (GHC extensions)
  77 --
  78 -- Basic data types and classes.
  79 --
  80 -----------------------------------------------------------------------------
  81
  82 #include "MachDeps.h"
  83
  84 -- #hide
  85 module GHC.Base
  86         (
  87         module GHC.Base,
  88         module GHC.Prim,        -- Re-export GHC.Prim and GHC.Err, to avoid lots
  89         module GHC.Err          -- of people having to import it explicitly
  90   )
  91         where
  92
  93 import GHC.Prim
  94 import {-# SOURCE #-} GHC.Err
  95
  96 infixr 9  .
  97 infixr 5  ++, :
  98 infix  4  ==, /=, <, <=, >=, >
  99 infixr 3  &&
 100 infixr 2  ||
 101 infixl 1  >>, >>=
 102 infixr 0  $
 103
 104 default ()              -- Double isn't available yet
 105 \end{code}
 106
 107
 108 %*********************************************************
 109 %*                                                      *
 110 \subsection{DEBUGGING STUFF}
 111 %*  (for use when compiling GHC.Base itself doesn't work)
 112 %*                                                      *
 113 %*********************************************************
 114
 115 \begin{code}
 116 {-
 117 data  Bool  =  False | True
 118 data Ordering = LT | EQ | GT
 119 data Char = C# Char#
 120 type  String = [Char]
 121 data Int = I# Int#
 122 data  ()  =  ()
 123 data [] a = MkNil
 124
 125 not True = False
 126 (&&) True True = True
 127 otherwise = True
 128
 129 build = error "urk"
 130 foldr = error "urk"
 131
 132 unpackCString# :: Addr# -> [Char]
 133 unpackFoldrCString# :: Addr# -> (Char  -> a -> a) -> a -> a
 134 unpackAppendCString# :: Addr# -> [Char] -> [Char]
 135 unpackCStringUtf8# :: Addr# -> [Char]
 136 unpackCString# a = error "urk"
 137 unpackFoldrCString# a = error "urk"
 138 unpackAppendCString# a = error "urk"
 139 unpackCStringUtf8# a = error "urk"
 140 -}
 141 \end{code}
 142
 143
 144 %*********************************************************
 145 %*                                                      *
 146 \subsection{Standard classes @Eq@, @Ord@}
 147 %*                                                      *
 148 %*********************************************************
 149
 150 \begin{code}
 151
 152 -- | The 'Eq' class defines equality ('==') and inequality ('/=').
 153 -- All the basic datatypes exported by the "Prelude" are instances of 'Eq',
 154 -- and 'Eq' may be derived for any datatype whose constituents are also
 155 -- instances of 'Eq'.
 156 --
 157 -- Minimal complete definition: either '==' or '/='.
 158 --
 159 class  Eq a  where
 160     (==), (/=)           :: a -> a -> Bool
 161
 162     x /= y               = not (x == y)
 163     x == y               = not (x /= y)
 164
 165 -- | The 'Ord' class is used for totally ordered datatypes.
 166 --
 167 -- Instances of 'Ord' can be derived for any user-defined
 168 -- datatype whose constituent types are in 'Ord'.  The declared order
 169 -- of the constructors in the data declaration determines the ordering
 170 -- in derived 'Ord' instances.  The 'Ordering' datatype allows a single
 171 -- comparison to determine the precise ordering of two objects.
 172 --
 173 -- Minimal complete definition: either 'compare' or '<='.
 174 -- Using 'compare' can be more efficient for complex types.
 175 --
 176 class  (Eq a) => Ord a  where
 177     compare              :: a -> a -> Ordering
 178     (<), (<=), (>), (>=) :: a -> a -> Bool
 179     max, min             :: a -> a -> a
 180
 181     compare x y
 182         | x == y    = EQ
 183         | x <= y    = LT        -- NB: must be '<=' not '<' to validate the
 184                                 -- above claim about the minimal things that
 185                                 -- can be defined for an instance of Ord
 186         | otherwise = GT
 187
 188     x <  y = case compare x y of { LT -> True;  _other -> False }
 189     x <= y = case compare x y of { GT -> False; _other -> True }
 190     x >  y = case compare x y of { GT -> True;  _other -> False }
 191     x >= y = case compare x y of { LT -> False; _other -> True }
 192
 193         -- These two default methods use '<=' rather than 'compare'
 194         -- because the latter is often more expensive
 195     max x y = if x <= y then y else x
 196     min x y = if x <= y then x else y
 197 \end{code}
 198
 199 %*********************************************************
 200 %*                                                      *
 201 \subsection{Monadic classes @Functor@, @Monad@ }
 202 %*                                                      *
 203 %*********************************************************
 204
 205 \begin{code}
 206 {- | The 'Functor' class is used for types that can be mapped over.
 207 Instances of 'Functor' should satisfy the following laws:
 208
 209 > fmap id  ==  id
 210 > fmap (f . g)  ==  fmap f . fmap g
 211
 212 The instances of 'Functor' for lists, 'Data.Maybe.Maybe' and 'System.IO.IO'
 213 defined in the "Prelude" satisfy these laws.
 214 -}
 215
 216 class  Functor f  where
 217     fmap        :: (a -> b) -> f a -> f b
 218
 219 {- | The 'Monad' class defines the basic operations over a /monad/,
 220 a concept from a branch of mathematics known as /category theory/.
 221 From the perspective of a Haskell programmer, however, it is best to
 222 think of a monad as an /abstract datatype/ of actions.
 223 Haskell's @do@ expressions provide a convenient syntax for writing
 224 monadic expressions.
 225
 226 Minimal complete definition: '>>=' and 'return'.
 227
 228 Instances of 'Monad' should satisfy the following laws:
 229
 230 > return a >>= k  ==  k a
 231 > m >>= return  ==  m
 232 > m >>= (\x -> k x >>= h)  ==  (m >>= k) >>= h
 233
 234 Instances of both 'Monad' and 'Functor' should additionally satisfy the law:
 235
 236 > fmap f xs  ==  xs >>= return . f
 237
 238 The instances of 'Monad' for lists, 'Data.Maybe.Maybe' and 'System.IO.IO'
 239 defined in the "Prelude" satisfy these laws.
 240 -}
 241
 242 class  Monad m  where
 243     -- | Sequentially compose two actions, passing any value produced
 244     -- by the first as an argument to the second.
 245     (>>=)       :: forall a b. m a -> (a -> m b) -> m b
 246     -- | Sequentially compose two actions, discarding any value produced
 247     -- by the first, like sequencing operators (such as the semicolon)
 248     -- in imperative languages.
 249     (>>)        :: forall a b. m a -> m b -> m b
 250         -- Explicit for-alls so that we know what order to
 251         -- give type arguments when desugaring
 252
 253     -- | Inject a value into the monadic type.
 254     return      :: a -> m a
 255     -- | Fail with a message.  This operation is not part of the
 256     -- mathematical definition of a monad, but is invoked on pattern-match
 257     -- failure in a @do@ expression.
 258     fail        :: String -> m a
 259
 260     m >> k      = m >>= \_ -> k
 261     fail s      = error s
 262 \end{code}
 263
 264
 265 %*********************************************************
 266 %*                                                      *
 267 \subsection{The list type}
 268 %*                                                      *
 269 %*********************************************************
 270
 271 \begin{code}
 272 data [] a = [] | a : [a]  -- do explicitly: deriving (Eq, Ord)
 273                           -- to avoid weird names like con2tag_[]#
 274
 275
 276 instance (Eq a) => Eq [a] where
 277     {-# SPECIALISE instance Eq [Char] #-}
 278     []     == []     = True
 279     (x:xs) == (y:ys) = x == y && xs == ys
 280     _xs    == _ys    = False
 281
 282 instance (Ord a) => Ord [a] where
 283     {-# SPECIALISE instance Ord [Char] #-}
 284     compare []     []     = EQ
 285     compare []     (_:_)  = LT
 286     compare (_:_)  []     = GT
 287     compare (x:xs) (y:ys) = case compare x y of
 288                                 EQ    -> compare xs ys
 289                                 other -> other
 290
 291 instance Functor [] where
 292     fmap = map
 293
 294 instance  Monad []  where
 295     m >>= k             = foldr ((++) . k) [] m
 296     m >> k              = foldr ((++) . (\ _ -> k)) [] m
 297     return x            = [x]
 298     fail _              = []
 299 \end{code}
 300
 301 A few list functions that appear here because they are used here.
 302 The rest of the prelude list functions are in GHC.List.
 303
 304 ----------------------------------------------
 305 --      foldr/build/augment
 306 ----------------------------------------------
 307
 308 \begin{code}
 309 -- | 'foldr', applied to a binary operator, a starting value (typically
 310 -- the right-identity of the operator), and a list, reduces the list
 311 -- using the binary operator, from right to left:
 312 --
 313 -- > foldr f z [x1, x2, ..., xn] == x1 `f` (x2 `f` ... (xn `f` z)...)
 314
 315 foldr            :: (a -> b -> b) -> b -> [a] -> b
 316 -- foldr _ z []     =  z
 317 -- foldr f z (x:xs) =  f x (foldr f z xs)
 318 {-# INLINE [0] foldr #-}
 319 -- Inline only in the final stage, after the foldr/cons rule has had a chance
 320 foldr k z xs = go xs
 321              where
 322                go []     = z
 323                go (y:ys) = y `k` go ys
 324
 325 -- | A list producer that can be fused with 'foldr'.
 326 -- This function is merely
 327 --
 328 -- >    build g = g (:) []
 329 --
 330 -- but GHC's simplifier will transform an expression of the form
 331 -- @'foldr' k z ('build' g)@, which may arise after inlining, to @g k z@,
 332 -- which avoids producing an intermediate list.
 333
 334 build   :: forall a. (forall b. (a -> b -> b) -> b -> b) -> [a]
 335 {-# INLINE [1] build #-}
 336         -- The INLINE is important, even though build is tiny,
 337         -- because it prevents [] getting inlined in the version that
 338         -- appears in the interface file.  If [] *is* inlined, it
 339         -- won't match with [] appearing in rules in an importing module.
 340         --
 341         -- The "1" says to inline in phase 1
 342
 343 build g = g (:) []
 344
 345 -- | A list producer that can be fused with 'foldr'.
 346 -- This function is merely
 347 --
 348 -- >    augment g xs = g (:) xs
 349 --
 350 -- but GHC's simplifier will transform an expression of the form
 351 -- @'foldr' k z ('augment' g xs)@, which may arise after inlining, to
 352 -- @g k ('foldr' k z xs)@, which avoids producing an intermediate list.
 353
 354 augment :: forall a. (forall b. (a->b->b) -> b -> b) -> [a] -> [a]
 355 {-# INLINE [1] augment #-}
 356 augment g xs = g (:) xs
 357
 358 {-# RULES
 359 "fold/build"    forall k z (g::forall b. (a->b->b) -> b -> b) .
 360                 foldr k z (build g) = g k z
 361
 362 "foldr/augment" forall k z xs (g::forall b. (a->b->b) -> b -> b) .
 363                 foldr k z (augment g xs) = g k (foldr k z xs)
 364
 365 "foldr/id"                        foldr (:) [] = \x->x
 366 "foldr/app"     [1] forall xs ys. foldr (:) ys xs = xs ++ ys
 367         -- Only activate this from phase 1, because that's
 368         -- when we disable the rule that expands (++) into foldr
 369
 370 -- The foldr/cons rule looks nice, but it can give disastrously
 371 -- bloated code when commpiling
 372 --      array (a,b) [(1,2), (2,2), (3,2), ...very long list... ]
 373 -- i.e. when there are very very long literal lists
 374 -- So I've disabled it for now. We could have special cases
 375 -- for short lists, I suppose.
 376 -- "foldr/cons" forall k z x xs. foldr k z (x:xs) = k x (foldr k z xs)
 377
 378 "foldr/single"  forall k z x. foldr k z [x] = k x z
 379 "foldr/nil"     forall k z.   foldr k z []  = z
 380
 381 "augment/build" forall (g::forall b. (a->b->b) -> b -> b)
 382                        (h::forall b. (a->b->b) -> b -> b) .
 383                        augment g (build h) = build (\c n -> g c (h c n))
 384 "augment/nil"   forall (g::forall b. (a->b->b) -> b -> b) .
 385                         augment g [] = build g
 386  #-}
 387
 388 -- This rule is true, but not (I think) useful:
 389 --      augment g (augment h t) = augment (\cn -> g c (h c n)) t
 390 \end{code}
 391
 392
 393 ----------------------------------------------
 394 --              map
 395 ----------------------------------------------
 396
 397 \begin{code}
 398 -- | 'map' @f xs@ is the list obtained by applying @f@ to each element
 399 -- of @xs@, i.e.,
 400 --
 401 -- > map f [x1, x2, ..., xn] == [f x1, f x2, ..., f xn]
 402 -- > map f [x1, x2, ...] == [f x1, f x2, ...]
 403
 404 map :: (a -> b) -> [a] -> [b]
 405 map _ []     = []
 406 map f (x:xs) = f x : map f xs
 407
 408 -- Note eta expanded
 409 mapFB ::  (elt -> lst -> lst) -> (a -> elt) -> a -> lst -> lst
 410 {-# INLINE [0] mapFB #-}
 411 mapFB c f x ys = c (f x) ys
 412
 413 -- The rules for map work like this.
 414 --
 415 -- Up to (but not including) phase 1, we use the "map" rule to
 416 -- rewrite all saturated applications of map with its build/fold
 417 -- form, hoping for fusion to happen.
 418 -- In phase 1 and 0, we switch off that rule, inline build, and
 419 -- switch on the "mapList" rule, which rewrites the foldr/mapFB
 420 -- thing back into plain map.
 421 --
 422 -- It's important that these two rules aren't both active at once
 423 -- (along with build's unfolding) else we'd get an infinite loop
 424 -- in the rules.  Hence the activation control below.
 425 --
 426 -- The "mapFB" rule optimises compositions of map.
 427 --
 428 -- This same pattern is followed by many other functions:
 429 -- e.g. append, filter, iterate, repeat, etc.
 430
 431 {-# RULES
 432 "map"       [~1] forall f xs.   map f xs                = build (\c n -> foldr (mapFB c f) n xs)
 433 "mapList"   [1]  forall f.      foldr (mapFB (:) f) []  = map f
 434 "mapFB"     forall c f g.       mapFB (mapFB c f) g     = mapFB c (f.g)
 435   #-}
 436 \end{code}
 437
 438
 439 ----------------------------------------------
 440 --              append
 441 ----------------------------------------------
 442 \begin{code}
 443 -- | Append two lists, i.e.,
 444 --
 445 -- > [x1, ..., xm] ++ [y1, ..., yn] == [x1, ..., xm, y1, ..., yn]
 446 -- > [x1, ..., xm] ++ [y1, ...] == [x1, ..., xm, y1, ...]
 447 --
 448 -- If the first list is not finite, the result is the first list.
 449
 450 (++) :: [a] -> [a] -> [a]
 451 (++) []     ys = ys
 452 (++) (x:xs) ys = x : xs ++ ys
 453
 454 {-# RULES
 455 "++"    [~1] forall xs ys. xs ++ ys = augment (\c n -> foldr c n xs) ys
 456   #-}
 457
 458 \end{code}
 459
 460
 461 %*********************************************************
 462 %*                                                      *
 463 \subsection{Type @Bool@}
 464 %*                                                      *
 465 %*********************************************************
 466
 467 \begin{code}
 468 -- |The 'Bool' type is an enumeration.  It is defined with 'False'
 469 -- first so that the corresponding 'Prelude.Enum' instance will give
 470 -- 'Prelude.fromEnum' 'False' the value zero, and
 471 -- 'Prelude.fromEnum' 'True' the value 1.
 472 data  Bool  =  False | True  deriving (Eq, Ord)
 473         -- Read in GHC.Read, Show in GHC.Show
 474
 475 -- Boolean functions
 476
 477 -- | Boolean \"and\"
 478 (&&)                    :: Bool -> Bool -> Bool
 479 True  && x              =  x
 480 False && _              =  False
 481
 482 -- | Boolean \"or\"
 483 (||)                    :: Bool -> Bool -> Bool
 484 True  || _              =  True
 485 False || x              =  x
 486
 487 -- | Boolean \"not\"
 488 not                     :: Bool -> Bool
 489 not True                =  False
 490 not False               =  True
 491
 492 -- |'otherwise' is defined as the value 'True'.  It helps to make
 493 -- guards more readable.  eg.
 494 --
 495 -- >  f x | x < 0     = ...
 496 -- >      | otherwise = ...
 497 otherwise               :: Bool
 498 otherwise               =  True
 499 \end{code}
 500
 501
 502 %*********************************************************
 503 %*                                                      *
 504 \subsection{The @()@ type}
 505 %*                                                      *
 506 %*********************************************************
 507
 508 The Unit type is here because virtually any program needs it (whereas
 509 some programs may get away without consulting GHC.Tup).  Furthermore,
 510 the renamer currently *always* asks for () to be in scope, so that
 511 ccalls can use () as their default type; so when compiling GHC.Base we
 512 need ().  (We could arrange suck in () only if -fglasgow-exts, but putting
 513 it here seems more direct.)
 514
 515 \begin{code}
 516 -- | The unit datatype @()@ has one non-undefined member, the nullary
 517 -- constructor @()@.
 518 data () = ()
 519
 520 instance Eq () where
 521     () == () = True
 522     () /= () = False
 523
 524 instance Ord () where
 525     () <= () = True
 526     () <  () = False
 527     () >= () = True
 528     () >  () = False
 529     max () () = ()
 530     min () () = ()
 531     compare () () = EQ
 532 \end{code}
 533
 534
 535 %*********************************************************
 536 %*                                                      *
 537 \subsection{Type @Ordering@}
 538 %*                                                      *
 539 %*********************************************************
 540
 541 \begin{code}
 542 -- | Represents an ordering relationship between two values: less
 543 -- than, equal to, or greater than.  An 'Ordering' is returned by
 544 -- 'compare'.
 545 data Ordering = LT | EQ | GT deriving (Eq, Ord)
 546         -- Read in GHC.Read, Show in GHC.Show
 547 \end{code}
 548
 549
 550 %*********************************************************
 551 %*                                                      *
 552 \subsection{Type @Char@ and @String@}
 553 %*                                                      *
 554 %*********************************************************
 555
 556 \begin{code}
 557 -- | A 'String' is a list of characters.  String constants in Haskell are values
 558 -- of type 'String'.
 559 --
 560 type String = [Char]
 561
 562 {-| The character type 'Char' is an enumeration whose values represent
 563 Unicode (or equivalently ISO 10646) characters.
 564 This set extends the ISO 8859-1 (Latin-1) character set
 565 (the first 256 charachers), which is itself an extension of the ASCII
 566 character set (the first 128 characters).
 567 A character literal in Haskell has type 'Char'.
 568
 569 To convert a 'Char' to or from the corresponding 'Int' value defined
 570 by Unicode, use 'Prelude.toEnum' and 'Prelude.fromEnum' from the
 571 'Prelude.Enum' class respectively (or equivalently 'ord' and 'chr').
 572 -}
 573 data Char = C# Char#
 574
 575 -- We don't use deriving for Eq and Ord, because for Ord the derived
 576 -- instance defines only compare, which takes two primops.  Then
 577 -- '>' uses compare, and therefore takes two primops instead of one.
 578
 579 instance Eq Char where
 580     (C# c1) == (C# c2) = c1 `eqChar#` c2
 581     (C# c1) /= (C# c2) = c1 `neChar#` c2
 582
 583 instance Ord Char where
 584     (C# c1) >  (C# c2) = c1 `gtChar#` c2
 585     (C# c1) >= (C# c2) = c1 `geChar#` c2
 586     (C# c1) <= (C# c2) = c1 `leChar#` c2
 587     (C# c1) <  (C# c2) = c1 `ltChar#` c2
 588
 589 {-# RULES
 590 "x# `eqChar#` x#" forall x#. x# `eqChar#` x# = True
 591 "x# `neChar#` x#" forall x#. x# `neChar#` x# = False
 592 "x# `gtChar#` x#" forall x#. x# `gtChar#` x# = False
 593 "x# `geChar#` x#" forall x#. x# `geChar#` x# = True
 594 "x# `leChar#` x#" forall x#. x# `leChar#` x# = True
 595 "x# `ltChar#` x#" forall x#. x# `ltChar#` x# = False
 596   #-}
 597
 598 -- | The 'Prelude.toEnum' method restricted to the type 'Data.Char.Char'.
 599 chr :: Int -> Char
 600 chr (I# i#) | int2Word# i# `leWord#` int2Word# 0x10FFFF# = C# (chr# i#)
 601             | otherwise                                  = error "Prelude.chr: bad argument"
 602
 603 unsafeChr :: Int -> Char
 604 unsafeChr (I# i#) = C# (chr# i#)
 605
 606 -- | The 'Prelude.fromEnum' method restricted to the type 'Data.Char.Char'.
 607 ord :: Char -> Int
 608 ord (C# c#) = I# (ord# c#)
 609 \end{code}
 610
 611 String equality is used when desugaring pattern-matches against strings.
 612
 613 \begin{code}
 614 eqString :: String -> String -> Bool
 615 eqString []       []       = True
 616 eqString (c1:cs1) (c2:cs2) = c1 == c2 && cs1 `eqString` cs2
 617 eqString cs1      cs2      = False
 618
 619 {-# RULES "eqString" (==) = eqString #-}
 620 \end{code}
 621
 622
 623 %*********************************************************
 624 %*                                                      *
 625 \subsection{Type @Int@}
 626 %*                                                      *
 627 %*********************************************************
 628
 629 \begin{code}
 630 data Int = I# Int#
 631 -- ^A fixed-precision integer type with at least the range @[-2^29 .. 2^29-1]@.
 632 -- The exact range for a given implementation can be determined by using
 633 -- 'Prelude.minBound' and 'Prelude.maxBound' from the 'Prelude.Bounded' class.
 634
 635 zeroInt, oneInt, twoInt, maxInt, minInt :: Int
 636 zeroInt = I# 0#
 637 oneInt  = I# 1#
 638 twoInt  = I# 2#
 639
 640 {- Seems clumsy. Should perhaps put minInt and MaxInt directly into MachDeps.h -}
 641 #if WORD_SIZE_IN_BITS == 31
 642 minInt  = I# (-0x40000000#)
 643 maxInt  = I# 0x3FFFFFFF#
 644 #elif WORD_SIZE_IN_BITS == 32
 645 minInt  = I# (-0x80000000#)
 646 maxInt  = I# 0x7FFFFFFF#
 647 #else
 648 minInt  = I# (-0x8000000000000000#)
 649 maxInt  = I# 0x7FFFFFFFFFFFFFFF#
 650 #endif
 651
 652 instance Eq Int where
 653     (==) = eqInt
 654     (/=) = neInt
 655
 656 instance Ord Int where
 657     compare = compareInt
 658     (<)     = ltInt
 659     (<=)    = leInt
 660     (>=)    = geInt
 661     (>)     = gtInt
 662
 663 compareInt :: Int -> Int -> Ordering
 664 (I# x#) `compareInt` (I# y#) = compareInt# x# y#
 665
 666 compareInt# :: Int# -> Int# -> Ordering
 667 compareInt# x# y#
 668     | x# <#  y# = LT
 669     | x# ==# y# = EQ
 670     | otherwise = GT
 671 \end{code}
 672
 673
 674 %*********************************************************
 675 %*                                                      *
 676 \subsection{The function type}
 677 %*                                                      *
 678 %*********************************************************
 679
 680 \begin{code}
 681 -- | Identity function.
 682 id                      :: a -> a
 683 id x                    =  x
 684
 685 -- lazy function; this is just the same as id, but its unfolding
 686 -- and strictness are over-ridden by the definition in MkId.lhs
 687 -- That way, it does not get inlined, and the strictness analyser
 688 -- sees it as lazy.  Then the worker/wrapper phase inlines it.
 689 -- Result: happiness
 690 lazy :: a -> a
 691 lazy x = x
 692
 693 -- Assertion function.  This simply ignores its boolean argument.
 694 -- The compiler may rewrite it to @('assertError' line)@.
 695
 696 -- | If the first argument evaluates to 'True', then the result is the
 697 -- second argument.  Otherwise an 'AssertionFailed' exception is raised,
 698 -- containing a 'String' with the source file and line number of the
 699 -- call to 'assert'.
 700 --
 701 -- Assertions can normally be turned on or off with a compiler flag
 702 -- (for GHC, assertions are normally on unless the @-fignore-asserts@
 703 -- option is given).  When assertions are turned off, the first
 704 -- argument to 'assert' is ignored, and the second argument is
 705 -- returned as the result.
 706
 707 --      SLPJ: in 5.04 etc 'assert' is in GHC.Prim,
 708 --      but from Template Haskell onwards it's simply
 709 --      defined here in Base.lhs
 710 assert :: Bool -> a -> a
 711 assert pred r = r
 712
 713 -- | Constant function.
 714 const                   :: a -> b -> a
 715 const x _               =  x
 716
 717 -- | Function composition.
 718 {-# INLINE (.) #-}
 719 (.)       :: (b -> c) -> (a -> b) -> a -> c
 720 (.) f g x = f (g x)
 721
 722 -- | @'flip' f@ takes its (first) two arguments in the reverse order of @f@.
 723 flip                    :: (a -> b -> c) -> b -> a -> c
 724 flip f x y              =  f y x
 725
 726 -- | Application operator.  This operator is redundant, since ordinary
 727 -- application @(f x)@ means the same as @(f '$' x)@. However, '$' has
 728 -- low, right-associative binding precedence, so it sometimes allows
 729 -- parentheses to be omitted; for example:
 730 --
 731 -- >     f $ g $ h x  =  f (g (h x))
 732 --
 733 -- It is also useful in higher-order situations, such as @'map' ('$' 0) xs@,
 734 -- or @'Data.List.zipWith' ('$') fs xs@.
 735 {-# INLINE ($) #-}
 736 ($)                     :: (a -> b) -> a -> b
 737 f $ x                   =  f x
 738
 739 -- | @'until' p f@ yields the result of applying @f@ until @p@ holds.
 740 until                   :: (a -> Bool) -> (a -> a) -> a -> a
 741 until p f x | p x       =  x
 742             | otherwise =  until p f (f x)
 743
 744 -- | 'asTypeOf' is a type-restricted version of 'const'.  It is usually
 745 -- used as an infix operator, and its typing forces its first argument
 746 -- (which is usually overloaded) to have the same type as the second.
 747 asTypeOf                :: a -> a -> a
 748 asTypeOf                =  const
 749 \end{code}
 750
 751 %*********************************************************
 752 %*                                                      *
 753 \subsection{Generics}
 754 %*                                                      *
 755 %*********************************************************
 756
 757 \begin{code}
 758 data Unit = Unit
 759 #ifndef __HADDOCK__
 760 data (:+:) a b = Inl a | Inr b
 761 data (:*:) a b = a :*: b
 762 #endif
 763 \end{code}
 764
 765 %*********************************************************
 766 %*                                                      *
 767 \subsection{@getTag@}
 768 %*                                                      *
 769 %*********************************************************
 770
 771 Returns the 'tag' of a constructor application; this function is used
 772 by the deriving code for Eq, Ord and Enum.
 773
 774 The primitive dataToTag# requires an evaluated constructor application
 775 as its argument, so we provide getTag as a wrapper that performs the
 776 evaluation before calling dataToTag#.  We could have dataToTag#
 777 evaluate its argument, but we prefer to do it this way because (a)
 778 dataToTag# can be an inline primop if it doesn't need to do any
 779 evaluation, and (b) we want to expose the evaluation to the
 780 simplifier, because it might be possible to eliminate the evaluation
 781 in the case when the argument is already known to be evaluated.
 782
 783 \begin{code}
 784 {-# INLINE getTag #-}
 785 getTag :: a -> Int#
 786 getTag x = x `seq` dataToTag# x
 787 \end{code}
 788
 789 %*********************************************************
 790 %*                                                      *
 791 \subsection{Numeric primops}
 792 %*                                                      *
 793 %*********************************************************
 794
 795 \begin{code}
 796 divInt# :: Int# -> Int# -> Int#
 797 x# `divInt#` y#
 798         -- Be careful NOT to overflow if we do any additional arithmetic
 799         -- on the arguments...  the following  previous version of this
 800         -- code has problems with overflow:
 801 --    | (x# ># 0#) && (y# <# 0#) = ((x# -# y#) -# 1#) `quotInt#` y#
 802 --    | (x# <# 0#) && (y# ># 0#) = ((x# -# y#) +# 1#) `quotInt#` y#
 803     | (x# ># 0#) && (y# <# 0#) = ((x# -# 1#) `quotInt#` y#) -# 1#
 804     | (x# <# 0#) && (y# ># 0#) = ((x# +# 1#) `quotInt#` y#) -# 1#
 805     | otherwise                = x# `quotInt#` y#
 806
 807 modInt# :: Int# -> Int# -> Int#
 808 x# `modInt#` y#
 809     | (x# ># 0#) && (y# <# 0#) ||
 810       (x# <# 0#) && (y# ># 0#)    = if r# /=# 0# then r# +# y# else 0#
 811     | otherwise                   = r#
 812     where
 813     r# = x# `remInt#` y#
 814 \end{code}
 815
 816 Definitions of the boxed PrimOps; these will be
 817 used in the case of partial applications, etc.
 818
 819 \begin{code}
 820 {-# INLINE eqInt #-}
 821 {-# INLINE neInt #-}
 822 {-# INLINE gtInt #-}
 823 {-# INLINE geInt #-}
 824 {-# INLINE ltInt #-}
 825 {-# INLINE leInt #-}
 826 {-# INLINE plusInt #-}
 827 {-# INLINE minusInt #-}
 828 {-# INLINE timesInt #-}
 829 {-# INLINE quotInt #-}
 830 {-# INLINE remInt #-}
 831 {-# INLINE negateInt #-}
 832
 833 plusInt, minusInt, timesInt, quotInt, remInt, divInt, modInt, gcdInt :: Int -> Int -> Int
 834 (I# x) `plusInt`  (I# y) = I# (x +# y)
 835 (I# x) `minusInt` (I# y) = I# (x -# y)
 836 (I# x) `timesInt` (I# y) = I# (x *# y)
 837 (I# x) `quotInt`  (I# y) = I# (x `quotInt#` y)
 838 (I# x) `remInt`   (I# y) = I# (x `remInt#`  y)
 839 (I# x) `divInt`   (I# y) = I# (x `divInt#`  y)
 840 (I# x) `modInt`   (I# y) = I# (x `modInt#`  y)
 841
 842 {-# RULES
 843 "x# +# 0#" forall x#. x# +# 0# = x#
 844 "0# +# x#" forall x#. 0# +# x# = x#
 845 "x# -# 0#" forall x#. x# -# 0# = x#
 846 "x# -# x#" forall x#. x# -# x# = 0#
 847 "x# *# 0#" forall x#. x# *# 0# = 0#
 848 "0# *# x#" forall x#. 0# *# x# = 0#
 849 "x# *# 1#" forall x#. x# *# 1# = x#
 850 "1# *# x#" forall x#. 1# *# x# = x#
 851   #-}
 852
 853 gcdInt (I# a) (I# b) = g a b
 854    where g 0# 0# = error "GHC.Base.gcdInt: gcd 0 0 is undefined"
 855          g 0# _  = I# absB
 856          g _  0# = I# absA
 857          g _  _  = I# (gcdInt# absA absB)
 858
 859          absInt x = if x <# 0# then negateInt# x else x
 860
 861          absA     = absInt a
 862          absB     = absInt b
 863
 864 negateInt :: Int -> Int
 865 negateInt (I# x) = I# (negateInt# x)
 866
 867 gtInt, geInt, eqInt, neInt, ltInt, leInt :: Int -> Int -> Bool
 868 (I# x) `gtInt` (I# y) = x >#  y
 869 (I# x) `geInt` (I# y) = x >=# y
 870 (I# x) `eqInt` (I# y) = x ==# y
 871 (I# x) `neInt` (I# y) = x /=# y
 872 (I# x) `ltInt` (I# y) = x <#  y
 873 (I# x) `leInt` (I# y) = x <=# y
 874
 875 {-# RULES
 876 "x# ># x#"  forall x#. x# >#  x# = False
 877 "x# >=# x#" forall x#. x# >=# x# = True
 878 "x# ==# x#" forall x#. x# ==# x# = True
 879 "x# /=# x#" forall x#. x# /=# x# = False
 880 "x# <# x#"  forall x#. x# <#  x# = False
 881 "x# <=# x#" forall x#. x# <=# x# = True
 882   #-}
 883
 884 {-# RULES
 885 "plusFloat x 0.0"   forall x#. plusFloat#  x#   0.0# = x#
 886 "plusFloat 0.0 x"   forall x#. plusFloat#  0.0# x#   = x#
 887 "minusFloat x 0.0"  forall x#. minusFloat# x#   0.0# = x#
 888 "minusFloat x x"    forall x#. minusFloat# x#   x#   = 0.0#
 889 "timesFloat x 0.0"  forall x#. timesFloat# x#   0.0# = 0.0#
 890 "timesFloat0.0 x"   forall x#. timesFloat# 0.0# x#   = 0.0#
 891 "timesFloat x 1.0"  forall x#. timesFloat# x#   1.0# = x#
 892 "timesFloat 1.0 x"  forall x#. timesFloat# 1.0# x#   = x#
 893 "divideFloat x 1.0" forall x#. divideFloat# x#  1.0# = x#
 894   #-}
 895
 896 {-# RULES
 897 "plusDouble x 0.0"   forall x#. (+##) x#    0.0## = x#
 898 "plusDouble 0.0 x"   forall x#. (+##) 0.0## x#    = x#
 899 "minusDouble x 0.0"  forall x#. (-##) x#    0.0## = x#
 900 "minusDouble x x"    forall x#. (-##) x#    x#    = 0.0##
 901 "timesDouble x 0.0"  forall x#. (*##) x#    0.0## = 0.0##
 902 "timesDouble 0.0 x"  forall x#. (*##) 0.0## x#    = 0.0##
 903 "timesDouble x 1.0"  forall x#. (*##) x#    1.0## = x#
 904 "timesDouble 1.0 x"  forall x#. (*##) 1.0## x#    = x#
 905 "divideDouble x 1.0" forall x#. (/##) x#    1.0## = x#
 906   #-}
 907
 908 -- Wrappers for the shift operations.  The uncheckedShift# family are
 909 -- undefined when the amount being shifted by is greater than the size
 910 -- in bits of Int#, so these wrappers perform a check and return
 911 -- either zero or -1 appropriately.
 912 --
 913 -- Note that these wrappers still produce undefined results when the
 914 -- second argument (the shift amount) is negative.
 915
 916 -- | Shift the argument left by the specified number of bits
 917 -- (which must be non-negative).
 918 shiftL# :: Word# -> Int# -> Word#
 919 a `shiftL#` b   | b >=# WORD_SIZE_IN_BITS# = int2Word# 0#
 920                 | otherwise                = a `uncheckedShiftL#` b
 921
 922 -- | Shift the argument right by the specified number of bits
 923 -- (which must be non-negative).
 924 shiftRL# :: Word# -> Int# -> Word#
 925 a `shiftRL#` b  | b >=# WORD_SIZE_IN_BITS# = int2Word# 0#
 926                 | otherwise                = a `uncheckedShiftRL#` b
 927
 928 -- | Shift the argument left by the specified number of bits
 929 -- (which must be non-negative).
 930 iShiftL# :: Int# -> Int# -> Int#
 931 a `iShiftL#` b  | b >=# WORD_SIZE_IN_BITS# = 0#
 932                 | otherwise                = a `uncheckedIShiftL#` b
 933
 934 -- | Shift the argument right (signed) by the specified number of bits
 935 -- (which must be non-negative).
 936 iShiftRA# :: Int# -> Int# -> Int#
 937 a `iShiftRA#` b | b >=# WORD_SIZE_IN_BITS# = if a <# 0# then (-1#) else 0#
 938                 | otherwise                = a `uncheckedIShiftRA#` b
 939
 940 -- | Shift the argument right (unsigned) by the specified number of bits
 941 -- (which must be non-negative).
 942 iShiftRL# :: Int# -> Int# -> Int#
 943 a `iShiftRL#` b | b >=# WORD_SIZE_IN_BITS# = 0#
 944                 | otherwise                = a `uncheckedIShiftRL#` b
 945
 946 #if WORD_SIZE_IN_BITS == 32
 947 {-# RULES
 948 "narrow32Int#"  forall x#. narrow32Int#   x# = x#
 949 "narrow32Word#" forall x#. narrow32Word#   x# = x#
 950    #-}
 951 #endif
 952
 953 {-# RULES
 954 "int2Word2Int"  forall x#. int2Word# (word2Int# x#) = x#
 955 "word2Int2Word" forall x#. word2Int# (int2Word# x#) = x#
 956   #-}
 957 \end{code}
 958
 959
 960 %********************************************************
 961 %*                                                      *
 962 \subsection{Unpacking C strings}
 963 %*                                                      *
 964 %********************************************************
 965
 966 This code is needed for virtually all programs, since it's used for
 967 unpacking the strings of error messages.
 968
 969 \begin{code}
 970 unpackCString# :: Addr# -> [Char]
 971 {-# NOINLINE [1] unpackCString# #-}
 972 unpackCString# addr
 973   = unpack 0#
 974   where
 975     unpack nh
 976       | ch `eqChar#` '\0'# = []
 977       | otherwise          = C# ch : unpack (nh +# 1#)
 978       where
 979         ch = indexCharOffAddr# addr nh
 980
 981 unpackAppendCString# :: Addr# -> [Char] -> [Char]
 982 unpackAppendCString# addr rest
 983   = unpack 0#
 984   where
 985     unpack nh
 986       | ch `eqChar#` '\0'# = rest
 987       | otherwise          = C# ch : unpack (nh +# 1#)
 988       where
 989         ch = indexCharOffAddr# addr nh
 990
 991 unpackFoldrCString# :: Addr# -> (Char  -> a -> a) -> a -> a
 992 {-# NOINLINE [0] unpackFoldrCString# #-}
 993 -- Don't inline till right at the end;
 994 -- usually the unpack-list rule turns it into unpackCStringList
 995 unpackFoldrCString# addr f z
 996   = unpack 0#
 997   where
 998     unpack nh
 999       | ch `eqChar#` '\0'# = z
1000       | otherwise          = C# ch `f` unpack (nh +# 1#)
1001       where
1002         ch = indexCharOffAddr# addr nh
1003
1004 unpackCStringUtf8# :: Addr# -> [Char]
1005 unpackCStringUtf8# addr
1006   = unpack 0#
1007   where
1008     unpack nh
1009       | ch `eqChar#` '\0'#   = []
1010       | ch `leChar#` '\x7F'# = C# ch : unpack (nh +# 1#)
1011       | ch `leChar#` '\xDF'# =
1012           C# (chr# (((ord# ch                                  -# 0xC0#) `uncheckedIShiftL#`  6#) +#
1013                      (ord# (indexCharOffAddr# addr (nh +# 1#)) -# 0x80#))) :
1014           unpack (nh +# 2#)
1015       | ch `leChar#` '\xEF'# =
1016           C# (chr# (((ord# ch                                  -# 0xE0#) `uncheckedIShiftL#` 12#) +#
1017                     ((ord# (indexCharOffAddr# addr (nh +# 1#)) -# 0x80#) `uncheckedIShiftL#`  6#) +#
1018                      (ord# (indexCharOffAddr# addr (nh +# 2#)) -# 0x80#))) :
1019           unpack (nh +# 3#)
1020       | otherwise            =
1021           C# (chr# (((ord# ch                                  -# 0xF0#) `uncheckedIShiftL#` 18#) +#
1022                     ((ord# (indexCharOffAddr# addr (nh +# 1#)) -# 0x80#) `uncheckedIShiftL#` 12#) +#
1023                     ((ord# (indexCharOffAddr# addr (nh +# 2#)) -# 0x80#) `uncheckedIShiftL#`  6#) +#
1024                      (ord# (indexCharOffAddr# addr (nh +# 3#)) -# 0x80#))) :
1025           unpack (nh +# 4#)
1026       where
1027         ch = indexCharOffAddr# addr nh
1028
1029 unpackNBytes# :: Addr# -> Int# -> [Char]
1030 unpackNBytes# _addr 0#   = []
1031 unpackNBytes#  addr len# = unpack [] (len# -# 1#)
1032     where
1033      unpack acc i#
1034       | i# <# 0#  = acc
1035       | otherwise =
1036          case indexCharOffAddr# addr i# of
1037             ch -> unpack (C# ch : acc) (i# -# 1#)
1038
1039 {-# RULES
1040 "unpack"       [~1] forall a   . unpackCString# a                  = build (unpackFoldrCString# a)
1041 "unpack-list"  [1]  forall a   . unpackFoldrCString# a (:) [] = unpackCString# a
1042 "unpack-append"     forall a n . unpackFoldrCString# a (:) n  = unpackAppendCString# a n
1043
1044 -- There's a built-in rule (in PrelRules.lhs) for
1045 --      unpackFoldr "foo" c (unpackFoldr "baz" c n)  =  unpackFoldr "foobaz" c n
1046
1047   #-}
1048 \end{code}
1049
1050 #ifdef __HADDOCK__
1051 \begin{code}
1052 -- | A special argument for the 'Control.Monad.ST.ST' type constructor,
1053 -- indexing a state embedded in the 'Prelude.IO' monad by
1054 -- 'Control.Monad.ST.stToIO'.
1055 data RealWorld
1056 \end{code}
1057 #endif