GHC/Base.lhs

   1 \section[GHC.Base]{Module @GHC.Base@}
   2
   3 The overall structure of the GHC Prelude is a bit tricky.
   4
   5   a) We want to avoid "orphan modules", i.e. ones with instance
   6         decls that don't belong either to a tycon or a class
   7         defined in the same module
   8
   9   b) We want to avoid giant modules
  10
  11 So the rough structure is as follows, in (linearised) dependency order
  12
  13
  14 GHC.Prim                Has no implementation.  It defines built-in things, and
  15                 by importing it you bring them into scope.
  16                 The source file is GHC.Prim.hi-boot, which is just
  17                 copied to make GHC.Prim.hi
  18
  19 GHC.Base        Classes: Eq, Ord, Functor, Monad
  20                 Types:   list, (), Int, Bool, Ordering, Char, String
  21
  22 Data.Tuple      Types: tuples, plus instances for GHC.Base classes
  23
  24 GHC.Show        Class: Show, plus instances for GHC.Base/GHC.Tup types
  25
  26 GHC.Enum        Class: Enum,  plus instances for GHC.Base/GHC.Tup types
  27
  28 Data.Maybe      Type: Maybe, plus instances for GHC.Base classes
  29
  30 GHC.List        List functions
  31
  32 GHC.Num         Class: Num, plus instances for Int
  33                 Type:  Integer, plus instances for all classes so far (Eq, Ord, Num, Show)
  34
  35                 Integer is needed here because it is mentioned in the signature
  36                 of 'fromInteger' in class Num
  37
  38 GHC.Real        Classes: Real, Integral, Fractional, RealFrac
  39                          plus instances for Int, Integer
  40                 Types:  Ratio, Rational
  41                         plus intances for classes so far
  42
  43                 Rational is needed here because it is mentioned in the signature
  44                 of 'toRational' in class Real
  45
  46 GHC.ST  The ST monad, instances and a few helper functions
  47
  48 Ix              Classes: Ix, plus instances for Int, Bool, Char, Integer, Ordering, tuples
  49
  50 GHC.Arr         Types: Array, MutableArray, MutableVar
  51
  52                 Arrays are used by a function in GHC.Float
  53
  54 GHC.Float       Classes: Floating, RealFloat
  55                 Types:   Float, Double, plus instances of all classes so far
  56
  57                 This module contains everything to do with floating point.
  58                 It is a big module (900 lines)
  59                 With a bit of luck, many modules can be compiled without ever reading GHC.Float.hi
  60
  61
  62 Other Prelude modules are much easier with fewer complex dependencies.
  63
  64 \begin{code}
  65 {-# OPTIONS_GHC -XNoImplicitPrelude #-}
  66 {-# OPTIONS_GHC -fno-warn-orphans #-}
  67 {-# OPTIONS_HADDOCK hide #-}
  68 -----------------------------------------------------------------------------
  69 -- |
  70 -- Module      :  GHC.Base
  71 -- Copyright   :  (c) The University of Glasgow, 1992-2002
  72 -- License     :  see libraries/base/LICENSE
  73 --
  74 -- Maintainer  :  cvs-ghc@haskell.org
  75 -- Stability   :  internal
  76 -- Portability :  non-portable (GHC extensions)
  77 --
  78 -- Basic data types and classes.
  79 --
  80 -----------------------------------------------------------------------------
  81
  82 #include "MachDeps.h"
  83
  84 -- #hide
  85 module GHC.Base
  86         (
  87         module GHC.Base,
  88         module GHC.Bool,
  89         module GHC.Classes,
  90         module GHC.Generics,
  91         module GHC.Ordering,
  92         module GHC.Types,
  93         module GHC.Prim,        -- Re-export GHC.Prim and GHC.Err, to avoid lots
  94         module GHC.Err          -- of people having to import it explicitly
  95   )
  96         where
  97
  98 import GHC.Types
  99 import GHC.Bool
 100 import GHC.Classes
 101 import GHC.Generics
 102 import GHC.Ordering
 103 import GHC.Prim
 104 import {-# SOURCE #-} GHC.Show
 105 import {-# SOURCE #-} GHC.Err
 106 import {-# SOURCE #-} GHC.IO (failIO)
 107
 108 -- These two are not strictly speaking required by this module, but they are
 109 -- implicit dependencies whenever () or tuples are mentioned, so adding them
 110 -- as imports here helps to get the dependencies right in the new build system.
 111 import GHC.Tuple ()
 112 import GHC.Unit ()
 113
 114 infixr 9  .
 115 infixr 5  ++
 116 infixl 4  <$
 117 infixl 1  >>, >>=
 118 infixr 0  $
 119
 120 default ()              -- Double isn't available yet
 121 \end{code}
 122
 123
 124 %*********************************************************
 125 %*                                                      *
 126 \subsection{DEBUGGING STUFF}
 127 %*  (for use when compiling GHC.Base itself doesn't work)
 128 %*                                                      *
 129 %*********************************************************
 130
 131 \begin{code}
 132 {-
 133 data  Bool  =  False | True
 134 data Ordering = LT | EQ | GT
 135 data Char = C# Char#
 136 type  String = [Char]
 137 data Int = I# Int#
 138 data  ()  =  ()
 139 data [] a = MkNil
 140
 141 not True = False
 142 (&&) True True = True
 143 otherwise = True
 144
 145 build = error "urk"
 146 foldr = error "urk"
 147
 148 unpackCString# :: Addr# -> [Char]
 149 unpackFoldrCString# :: Addr# -> (Char  -> a -> a) -> a -> a
 150 unpackAppendCString# :: Addr# -> [Char] -> [Char]
 151 unpackCStringUtf8# :: Addr# -> [Char]
 152 unpackCString# a = error "urk"
 153 unpackFoldrCString# a = error "urk"
 154 unpackAppendCString# a = error "urk"
 155 unpackCStringUtf8# a = error "urk"
 156 -}
 157 \end{code}
 158
 159
 160 %*********************************************************
 161 %*                                                      *
 162 \subsection{Monadic classes @Functor@, @Monad@ }
 163 %*                                                      *
 164 %*********************************************************
 165
 166 \begin{code}
 167 {- | The 'Functor' class is used for types that can be mapped over.
 168 Instances of 'Functor' should satisfy the following laws:
 169
 170 > fmap id  ==  id
 171 > fmap (f . g)  ==  fmap f . fmap g
 172
 173 The instances of 'Functor' for lists, 'Data.Maybe.Maybe' and 'System.IO.IO'
 174 defined in the "Prelude" satisfy these laws.
 175 -}
 176
 177 class  Functor f  where
 178     fmap        :: (a -> b) -> f a -> f b
 179
 180     -- | Replace all locations in the input with the same value.
 181     -- The default definition is @'fmap' . 'const'@, but this may be
 182     -- overridden with a more efficient version.
 183     (<$)        :: a -> f b -> f a
 184     (<$)        =  fmap . const
 185
 186 {- | The 'Monad' class defines the basic operations over a /monad/,
 187 a concept from a branch of mathematics known as /category theory/.
 188 From the perspective of a Haskell programmer, however, it is best to
 189 think of a monad as an /abstract datatype/ of actions.
 190 Haskell's @do@ expressions provide a convenient syntax for writing
 191 monadic expressions.
 192
 193 Minimal complete definition: '>>=' and 'return'.
 194
 195 Instances of 'Monad' should satisfy the following laws:
 196
 197 > return a >>= k  ==  k a
 198 > m >>= return  ==  m
 199 > m >>= (\x -> k x >>= h)  ==  (m >>= k) >>= h
 200
 201 Instances of both 'Monad' and 'Functor' should additionally satisfy the law:
 202
 203 > fmap f xs  ==  xs >>= return . f
 204
 205 The instances of 'Monad' for lists, 'Data.Maybe.Maybe' and 'System.IO.IO'
 206 defined in the "Prelude" satisfy these laws.
 207 -}
 208
 209 class  Monad m  where
 210     -- | Sequentially compose two actions, passing any value produced
 211     -- by the first as an argument to the second.
 212     (>>=)       :: forall a b. m a -> (a -> m b) -> m b
 213     -- | Sequentially compose two actions, discarding any value produced
 214     -- by the first, like sequencing operators (such as the semicolon)
 215     -- in imperative languages.
 216     (>>)        :: forall a b. m a -> m b -> m b
 217         -- Explicit for-alls so that we know what order to
 218         -- give type arguments when desugaring
 219
 220     -- | Inject a value into the monadic type.
 221     return      :: a -> m a
 222     -- | Fail with a message.  This operation is not part of the
 223     -- mathematical definition of a monad, but is invoked on pattern-match
 224     -- failure in a @do@ expression.
 225     fail        :: String -> m a
 226
 227     {-# INLINE (>>) #-}
 228     m >> k      = m >>= \_ -> k
 229     fail s      = error s
 230 \end{code}
 231
 232
 233 %*********************************************************
 234 %*                                                      *
 235 \subsection{The list type}
 236 %*                                                      *
 237 %*********************************************************
 238
 239 \begin{code}
 240 -- do explicitly: deriving (Eq, Ord)
 241 -- to avoid weird names like con2tag_[]#
 242
 243 instance (Eq a) => Eq [a] where
 244     {-# SPECIALISE instance Eq [Char] #-}
 245     []     == []     = True
 246     (x:xs) == (y:ys) = x == y && xs == ys
 247     _xs    == _ys    = False
 248
 249 instance (Ord a) => Ord [a] where
 250     {-# SPECIALISE instance Ord [Char] #-}
 251     compare []     []     = EQ
 252     compare []     (_:_)  = LT
 253     compare (_:_)  []     = GT
 254     compare (x:xs) (y:ys) = case compare x y of
 255                                 EQ    -> compare xs ys
 256                                 other -> other
 257
 258 instance Functor [] where
 259     fmap = map
 260
 261 instance  Monad []  where
 262     m >>= k             = foldr ((++) . k) [] m
 263     m >> k              = foldr ((++) . (\ _ -> k)) [] m
 264     return x            = [x]
 265     fail _              = []
 266 \end{code}
 267
 268 A few list functions that appear here because they are used here.
 269 The rest of the prelude list functions are in GHC.List.
 270
 271 ----------------------------------------------
 272 --      foldr/build/augment
 273 ----------------------------------------------
 274
 275 \begin{code}
 276 -- | 'foldr', applied to a binary operator, a starting value (typically
 277 -- the right-identity of the operator), and a list, reduces the list
 278 -- using the binary operator, from right to left:
 279 --
 280 -- > foldr f z [x1, x2, ..., xn] == x1 `f` (x2 `f` ... (xn `f` z)...)
 281
 282 foldr            :: (a -> b -> b) -> b -> [a] -> b
 283 -- foldr _ z []     =  z
 284 -- foldr f z (x:xs) =  f x (foldr f z xs)
 285 {-# INLINE [0] foldr #-}
 286 -- Inline only in the final stage, after the foldr/cons rule has had a chance
 287 -- Also note that we inline it when it has *two* parameters, which are the
 288 -- ones we are keen about specialising!
 289 foldr k z = go
 290           where
 291             go []     = z
 292             go (y:ys) = y `k` go ys
 293
 294 -- | A list producer that can be fused with 'foldr'.
 295 -- This function is merely
 296 --
 297 -- >    build g = g (:) []
 298 --
 299 -- but GHC's simplifier will transform an expression of the form
 300 -- @'foldr' k z ('build' g)@, which may arise after inlining, to @g k z@,
 301 -- which avoids producing an intermediate list.
 302
 303 build   :: forall a. (forall b. (a -> b -> b) -> b -> b) -> [a]
 304 {-# INLINE [1] build #-}
 305         -- The INLINE is important, even though build is tiny,
 306         -- because it prevents [] getting inlined in the version that
 307         -- appears in the interface file.  If [] *is* inlined, it
 308         -- won't match with [] appearing in rules in an importing module.
 309         --
 310         -- The "1" says to inline in phase 1
 311
 312 build g = g (:) []
 313
 314 -- | A list producer that can be fused with 'foldr'.
 315 -- This function is merely
 316 --
 317 -- >    augment g xs = g (:) xs
 318 --
 319 -- but GHC's simplifier will transform an expression of the form
 320 -- @'foldr' k z ('augment' g xs)@, which may arise after inlining, to
 321 -- @g k ('foldr' k z xs)@, which avoids producing an intermediate list.
 322
 323 augment :: forall a. (forall b. (a->b->b) -> b -> b) -> [a] -> [a]
 324 {-# INLINE [1] augment #-}
 325 augment g xs = g (:) xs
 326
 327 {-# RULES
 328 "fold/build"    forall k z (g::forall b. (a->b->b) -> b -> b) .
 329                 foldr k z (build g) = g k z
 330
 331 "foldr/augment" forall k z xs (g::forall b. (a->b->b) -> b -> b) .
 332                 foldr k z (augment g xs) = g k (foldr k z xs)
 333
 334 "foldr/id"                        foldr (:) [] = \x  -> x
 335 "foldr/app"     [1] forall ys. foldr (:) ys = \xs -> xs ++ ys
 336         -- Only activate this from phase 1, because that's
 337         -- when we disable the rule that expands (++) into foldr
 338
 339 -- The foldr/cons rule looks nice, but it can give disastrously
 340 -- bloated code when commpiling
 341 --      array (a,b) [(1,2), (2,2), (3,2), ...very long list... ]
 342 -- i.e. when there are very very long literal lists
 343 -- So I've disabled it for now. We could have special cases
 344 -- for short lists, I suppose.
 345 -- "foldr/cons" forall k z x xs. foldr k z (x:xs) = k x (foldr k z xs)
 346
 347 "foldr/single"  forall k z x. foldr k z [x] = k x z
 348 "foldr/nil"     forall k z.   foldr k z []  = z
 349
 350 "augment/build" forall (g::forall b. (a->b->b) -> b -> b)
 351                        (h::forall b. (a->b->b) -> b -> b) .
 352                        augment g (build h) = build (\c n -> g c (h c n))
 353 "augment/nil"   forall (g::forall b. (a->b->b) -> b -> b) .
 354                         augment g [] = build g
 355  #-}
 356
 357 -- This rule is true, but not (I think) useful:
 358 --      augment g (augment h t) = augment (\cn -> g c (h c n)) t
 359 \end{code}
 360
 361
 362 ----------------------------------------------
 363 --              map
 364 ----------------------------------------------
 365
 366 \begin{code}
 367 -- | 'map' @f xs@ is the list obtained by applying @f@ to each element
 368 -- of @xs@, i.e.,
 369 --
 370 -- > map f [x1, x2, ..., xn] == [f x1, f x2, ..., f xn]
 371 -- > map f [x1, x2, ...] == [f x1, f x2, ...]
 372
 373 map :: (a -> b) -> [a] -> [b]
 374 map _ []     = []
 375 map f (x:xs) = f x : map f xs
 376
 377 -- Note eta expanded
 378 mapFB ::  (elt -> lst -> lst) -> (a -> elt) -> a -> lst -> lst
 379 {-# INLINE [0] mapFB #-}
 380 mapFB c f x ys = c (f x) ys
 381
 382 -- The rules for map work like this.
 383 --
 384 -- Up to (but not including) phase 1, we use the "map" rule to
 385 -- rewrite all saturated applications of map with its build/fold
 386 -- form, hoping for fusion to happen.
 387 -- In phase 1 and 0, we switch off that rule, inline build, and
 388 -- switch on the "mapList" rule, which rewrites the foldr/mapFB
 389 -- thing back into plain map.
 390 --
 391 -- It's important that these two rules aren't both active at once
 392 -- (along with build's unfolding) else we'd get an infinite loop
 393 -- in the rules.  Hence the activation control below.
 394 --
 395 -- The "mapFB" rule optimises compositions of map.
 396 --
 397 -- This same pattern is followed by many other functions:
 398 -- e.g. append, filter, iterate, repeat, etc.
 399
 400 {-# RULES
 401 "map"       [~1] forall f xs.   map f xs                = build (\c n -> foldr (mapFB c f) n xs)
 402 "mapList"   [1]  forall f.      foldr (mapFB (:) f) []  = map f
 403 "mapFB"     forall c f g.       mapFB (mapFB c f) g     = mapFB c (f.g)
 404   #-}
 405 \end{code}
 406
 407
 408 ----------------------------------------------
 409 --              append
 410 ----------------------------------------------
 411 \begin{code}
 412 -- | Append two lists, i.e.,
 413 --
 414 -- > [x1, ..., xm] ++ [y1, ..., yn] == [x1, ..., xm, y1, ..., yn]
 415 -- > [x1, ..., xm] ++ [y1, ...] == [x1, ..., xm, y1, ...]
 416 --
 417 -- If the first list is not finite, the result is the first list.
 418
 419 (++) :: [a] -> [a] -> [a]
 420 (++) []     ys = ys
 421 (++) (x:xs) ys = x : xs ++ ys
 422
 423 {-# RULES
 424 "++"    [~1] forall xs ys. xs ++ ys = augment (\c n -> foldr c n xs) ys
 425   #-}
 426
 427 \end{code}
 428
 429
 430 %*********************************************************
 431 %*                                                      *
 432 \subsection{Type @Bool@}
 433 %*                                                      *
 434 %*********************************************************
 435
 436 \begin{code}
 437 -- |'otherwise' is defined as the value 'True'.  It helps to make
 438 -- guards more readable.  eg.
 439 --
 440 -- >  f x | x < 0     = ...
 441 -- >      | otherwise = ...
 442 otherwise               :: Bool
 443 otherwise               =  True
 444 \end{code}
 445
 446 %*********************************************************
 447 %*                                                      *
 448 \subsection{Type @Char@ and @String@}
 449 %*                                                      *
 450 %*********************************************************
 451
 452 \begin{code}
 453 -- | A 'String' is a list of characters.  String constants in Haskell are values
 454 -- of type 'String'.
 455 --
 456 type String = [Char]
 457
 458 {-| The character type 'Char' is an enumeration whose values represent
 459 Unicode (or equivalently ISO\/IEC 10646) characters
 460 (see <http://www.unicode.org/> for details).
 461 This set extends the ISO 8859-1 (Latin-1) character set
 462 (the first 256 charachers), which is itself an extension of the ASCII
 463 character set (the first 128 characters).
 464 A character literal in Haskell has type 'Char'.
 465
 466 To convert a 'Char' to or from the corresponding 'Int' value defined
 467 by Unicode, use 'Prelude.toEnum' and 'Prelude.fromEnum' from the
 468 'Prelude.Enum' class respectively (or equivalently 'ord' and 'chr').
 469 -}
 470
 471 {-# RULES
 472 "x# `eqChar#` x#" forall x#. x# `eqChar#` x# = True
 473 "x# `neChar#` x#" forall x#. x# `neChar#` x# = False
 474 "x# `gtChar#` x#" forall x#. x# `gtChar#` x# = False
 475 "x# `geChar#` x#" forall x#. x# `geChar#` x# = True
 476 "x# `leChar#` x#" forall x#. x# `leChar#` x# = True
 477 "x# `ltChar#` x#" forall x#. x# `ltChar#` x# = False
 478   #-}
 479
 480 -- | The 'Prelude.toEnum' method restricted to the type 'Data.Char.Char'.
 481 chr :: Int -> Char
 482 chr i@(I# i#)
 483  | int2Word# i# `leWord#` int2Word# 0x10FFFF# = C# (chr# i#)
 484  | otherwise
 485     = error ("Prelude.chr: bad argument: " ++ showSignedInt (I# 9#) i "")
 486
 487 unsafeChr :: Int -> Char
 488 unsafeChr (I# i#) = C# (chr# i#)
 489
 490 -- | The 'Prelude.fromEnum' method restricted to the type 'Data.Char.Char'.
 491 ord :: Char -> Int
 492 ord (C# c#) = I# (ord# c#)
 493 \end{code}
 494
 495 String equality is used when desugaring pattern-matches against strings.
 496
 497 \begin{code}
 498 eqString :: String -> String -> Bool
 499 eqString []       []       = True
 500 eqString (c1:cs1) (c2:cs2) = c1 == c2 && cs1 `eqString` cs2
 501 eqString _        _        = False
 502
 503 {-# RULES "eqString" (==) = eqString #-}
 504 -- eqString also has a BuiltInRule in PrelRules.lhs:
 505 --      eqString (unpackCString# (Lit s1)) (unpackCString# (Lit s2) = s1==s2
 506 \end{code}
 507
 508
 509 %*********************************************************
 510 %*                                                      *
 511 \subsection{Type @Int@}
 512 %*                                                      *
 513 %*********************************************************
 514
 515 \begin{code}
 516 zeroInt, oneInt, twoInt, maxInt, minInt :: Int
 517 zeroInt = I# 0#
 518 oneInt  = I# 1#
 519 twoInt  = I# 2#
 520
 521 {- Seems clumsy. Should perhaps put minInt and MaxInt directly into MachDeps.h -}
 522 #if WORD_SIZE_IN_BITS == 31
 523 minInt  = I# (-0x40000000#)
 524 maxInt  = I# 0x3FFFFFFF#
 525 #elif WORD_SIZE_IN_BITS == 32
 526 minInt  = I# (-0x80000000#)
 527 maxInt  = I# 0x7FFFFFFF#
 528 #else
 529 minInt  = I# (-0x8000000000000000#)
 530 maxInt  = I# 0x7FFFFFFFFFFFFFFF#
 531 #endif
 532
 533 instance Eq Int where
 534     (==) = eqInt
 535     (/=) = neInt
 536
 537 instance Ord Int where
 538     compare = compareInt
 539     (<)     = ltInt
 540     (<=)    = leInt
 541     (>=)    = geInt
 542     (>)     = gtInt
 543
 544 compareInt :: Int -> Int -> Ordering
 545 (I# x#) `compareInt` (I# y#) = compareInt# x# y#
 546
 547 compareInt# :: Int# -> Int# -> Ordering
 548 compareInt# x# y#
 549     | x# <#  y# = LT
 550     | x# ==# y# = EQ
 551     | otherwise = GT
 552 \end{code}
 553
 554
 555 %*********************************************************
 556 %*                                                      *
 557 \subsection{The function type}
 558 %*                                                      *
 559 %*********************************************************
 560
 561 \begin{code}
 562 -- | Identity function.
 563 id                      :: a -> a
 564 id x                    =  x
 565
 566 -- | The call '(lazy e)' means the same as 'e', but 'lazy' has a
 567 -- magical strictness property: it is lazy in its first argument,
 568 -- even though its semantics is strict.
 569 lazy :: a -> a
 570 lazy x = x
 571 -- Implementation note: its strictness and unfolding are over-ridden
 572 -- by the definition in MkId.lhs; in both cases to nothing at all.
 573 -- That way, 'lazy' does not get inlined, and the strictness analyser
 574 -- sees it as lazy.  Then the worker/wrapper phase inlines it.
 575 -- Result: happiness
 576
 577 -- Assertion function.  This simply ignores its boolean argument.
 578 -- The compiler may rewrite it to @('assertError' line)@.
 579
 580 -- | If the first argument evaluates to 'True', then the result is the
 581 -- second argument.  Otherwise an 'AssertionFailed' exception is raised,
 582 -- containing a 'String' with the source file and line number of the
 583 -- call to 'assert'.
 584 --
 585 -- Assertions can normally be turned on or off with a compiler flag
 586 -- (for GHC, assertions are normally on unless optimisation is turned on
 587 -- with @-O@ or the @-fignore-asserts@
 588 -- option is given).  When assertions are turned off, the first
 589 -- argument to 'assert' is ignored, and the second argument is
 590 -- returned as the result.
 591
 592 --      SLPJ: in 5.04 etc 'assert' is in GHC.Prim,
 593 --      but from Template Haskell onwards it's simply
 594 --      defined here in Base.lhs
 595 assert :: Bool -> a -> a
 596 assert _pred r = r
 597
 598 breakpoint :: a -> a
 599 breakpoint r = r
 600
 601 breakpointCond :: Bool -> a -> a
 602 breakpointCond _ r = r
 603
 604 data Opaque = forall a. O a
 605
 606 -- | Constant function.
 607 const                   :: a -> b -> a
 608 const x _               =  x
 609
 610 -- | Function composition.
 611 {-# INLINE (.) #-}
 612 -- Make sure it has TWO args only on the left, so that it inlines
 613 -- when applied to two functions, even if there is no final argument
 614 (.)    :: (b -> c) -> (a -> b) -> a -> c
 615 (.) f g = \x -> f (g x)
 616
 617 -- | @'flip' f@ takes its (first) two arguments in the reverse order of @f@.
 618 flip                    :: (a -> b -> c) -> b -> a -> c
 619 flip f x y              =  f y x
 620
 621 -- | Application operator.  This operator is redundant, since ordinary
 622 -- application @(f x)@ means the same as @(f '$' x)@. However, '$' has
 623 -- low, right-associative binding precedence, so it sometimes allows
 624 -- parentheses to be omitted; for example:
 625 --
 626 -- >     f $ g $ h x  =  f (g (h x))
 627 --
 628 -- It is also useful in higher-order situations, such as @'map' ('$' 0) xs@,
 629 -- or @'Data.List.zipWith' ('$') fs xs@.
 630 {-# INLINE ($) #-}
 631 ($)                     :: (a -> b) -> a -> b
 632 f $ x                   =  f x
 633
 634 -- | @'until' p f@ yields the result of applying @f@ until @p@ holds.
 635 until                   :: (a -> Bool) -> (a -> a) -> a -> a
 636 until p f x | p x       =  x
 637             | otherwise =  until p f (f x)
 638
 639 -- | 'asTypeOf' is a type-restricted version of 'const'.  It is usually
 640 -- used as an infix operator, and its typing forces its first argument
 641 -- (which is usually overloaded) to have the same type as the second.
 642 asTypeOf                :: a -> a -> a
 643 asTypeOf                =  const
 644 \end{code}
 645
 646 %*********************************************************
 647 %*                                                      *
 648 \subsection{@Functor@ and @Monad@ instances for @IO@}
 649 %*                                                      *
 650 %*********************************************************
 651
 652 \begin{code}
 653 instance  Functor IO where
 654    fmap f x = x >>= (return . f)
 655
 656 instance  Monad IO  where
 657     {-# INLINE return #-}
 658     {-# INLINE (>>)   #-}
 659     {-# INLINE (>>=)  #-}
 660     m >> k    = m >>= \ _ -> k
 661     return    = returnIO
 662     (>>=)     = bindIO
 663     fail s    = GHC.IO.failIO s
 664
 665 returnIO :: a -> IO a
 666 returnIO x = IO $ \ s -> (# s, x #)
 667
 668 bindIO :: IO a -> (a -> IO b) -> IO b
 669 bindIO (IO m) k = IO $ \ s -> case m s of (# new_s, a #) -> unIO (k a) new_s
 670
 671 thenIO :: IO a -> IO b -> IO b
 672 thenIO (IO m) k = IO $ \ s -> case m s of (# new_s, _ #) -> unIO k new_s
 673
 674 unIO :: IO a -> (State# RealWorld -> (# State# RealWorld, a #))
 675 unIO (IO a) = a
 676 \end{code}
 677
 678 %*********************************************************
 679 %*                                                      *
 680 \subsection{@getTag@}
 681 %*                                                      *
 682 %*********************************************************
 683
 684 Returns the 'tag' of a constructor application; this function is used
 685 by the deriving code for Eq, Ord and Enum.
 686
 687 The primitive dataToTag# requires an evaluated constructor application
 688 as its argument, so we provide getTag as a wrapper that performs the
 689 evaluation before calling dataToTag#.  We could have dataToTag#
 690 evaluate its argument, but we prefer to do it this way because (a)
 691 dataToTag# can be an inline primop if it doesn't need to do any
 692 evaluation, and (b) we want to expose the evaluation to the
 693 simplifier, because it might be possible to eliminate the evaluation
 694 in the case when the argument is already known to be evaluated.
 695
 696 \begin{code}
 697 {-# INLINE getTag #-}
 698 getTag :: a -> Int#
 699 getTag x = x `seq` dataToTag# x
 700 \end{code}
 701
 702 %*********************************************************
 703 %*                                                      *
 704 \subsection{Numeric primops}
 705 %*                                                      *
 706 %*********************************************************
 707
 708 \begin{code}
 709 divInt# :: Int# -> Int# -> Int#
 710 x# `divInt#` y#
 711         -- Be careful NOT to overflow if we do any additional arithmetic
 712         -- on the arguments...  the following  previous version of this
 713         -- code has problems with overflow:
 714 --    | (x# ># 0#) && (y# <# 0#) = ((x# -# y#) -# 1#) `quotInt#` y#
 715 --    | (x# <# 0#) && (y# ># 0#) = ((x# -# y#) +# 1#) `quotInt#` y#
 716     | (x# ># 0#) && (y# <# 0#) = ((x# -# 1#) `quotInt#` y#) -# 1#
 717     | (x# <# 0#) && (y# ># 0#) = ((x# +# 1#) `quotInt#` y#) -# 1#
 718     | otherwise                = x# `quotInt#` y#
 719
 720 modInt# :: Int# -> Int# -> Int#
 721 x# `modInt#` y#
 722     | (x# ># 0#) && (y# <# 0#) ||
 723       (x# <# 0#) && (y# ># 0#)    = if r# /=# 0# then r# +# y# else 0#
 724     | otherwise                   = r#
 725     where
 726     !r# = x# `remInt#` y#
 727 \end{code}
 728
 729 Definitions of the boxed PrimOps; these will be
 730 used in the case of partial applications, etc.
 731
 732 \begin{code}
 733 {-# INLINE eqInt #-}
 734 {-# INLINE neInt #-}
 735 {-# INLINE gtInt #-}
 736 {-# INLINE geInt #-}
 737 {-# INLINE ltInt #-}
 738 {-# INLINE leInt #-}
 739 {-# INLINE plusInt #-}
 740 {-# INLINE minusInt #-}
 741 {-# INLINE timesInt #-}
 742 {-# INLINE quotInt #-}
 743 {-# INLINE remInt #-}
 744 {-# INLINE negateInt #-}
 745
 746 plusInt, minusInt, timesInt, quotInt, remInt, divInt, modInt :: Int -> Int -> Int
 747 (I# x) `plusInt`  (I# y) = I# (x +# y)
 748 (I# x) `minusInt` (I# y) = I# (x -# y)
 749 (I# x) `timesInt` (I# y) = I# (x *# y)
 750 (I# x) `quotInt`  (I# y) = I# (x `quotInt#` y)
 751 (I# x) `remInt`   (I# y) = I# (x `remInt#`  y)
 752 (I# x) `divInt`   (I# y) = I# (x `divInt#`  y)
 753 (I# x) `modInt`   (I# y) = I# (x `modInt#`  y)
 754
 755 {-# RULES
 756 "x# +# 0#" forall x#. x# +# 0# = x#
 757 "0# +# x#" forall x#. 0# +# x# = x#
 758 "x# -# 0#" forall x#. x# -# 0# = x#
 759 "x# -# x#" forall x#. x# -# x# = 0#
 760 "x# *# 0#" forall x#. x# *# 0# = 0#
 761 "0# *# x#" forall x#. 0# *# x# = 0#
 762 "x# *# 1#" forall x#. x# *# 1# = x#
 763 "1# *# x#" forall x#. 1# *# x# = x#
 764   #-}
 765
 766 negateInt :: Int -> Int
 767 negateInt (I# x) = I# (negateInt# x)
 768
 769 gtInt, geInt, eqInt, neInt, ltInt, leInt :: Int -> Int -> Bool
 770 (I# x) `gtInt` (I# y) = x >#  y
 771 (I# x) `geInt` (I# y) = x >=# y
 772 (I# x) `eqInt` (I# y) = x ==# y
 773 (I# x) `neInt` (I# y) = x /=# y
 774 (I# x) `ltInt` (I# y) = x <#  y
 775 (I# x) `leInt` (I# y) = x <=# y
 776
 777 {-# RULES
 778 "x# ># x#"  forall x#. x# >#  x# = False
 779 "x# >=# x#" forall x#. x# >=# x# = True
 780 "x# ==# x#" forall x#. x# ==# x# = True
 781 "x# /=# x#" forall x#. x# /=# x# = False
 782 "x# <# x#"  forall x#. x# <#  x# = False
 783 "x# <=# x#" forall x#. x# <=# x# = True
 784   #-}
 785
 786 {-# RULES
 787 "plusFloat x 0.0"   forall x#. plusFloat#  x#   0.0# = x#
 788 "plusFloat 0.0 x"   forall x#. plusFloat#  0.0# x#   = x#
 789 "minusFloat x 0.0"  forall x#. minusFloat# x#   0.0# = x#
 790 "minusFloat x x"    forall x#. minusFloat# x#   x#   = 0.0#
 791 "timesFloat x 0.0"  forall x#. timesFloat# x#   0.0# = 0.0#
 792 "timesFloat0.0 x"   forall x#. timesFloat# 0.0# x#   = 0.0#
 793 "timesFloat x 1.0"  forall x#. timesFloat# x#   1.0# = x#
 794 "timesFloat 1.0 x"  forall x#. timesFloat# 1.0# x#   = x#
 795 "divideFloat x 1.0" forall x#. divideFloat# x#  1.0# = x#
 796   #-}
 797
 798 {-# RULES
 799 "plusDouble x 0.0"   forall x#. (+##) x#    0.0## = x#
 800 "plusDouble 0.0 x"   forall x#. (+##) 0.0## x#    = x#
 801 "minusDouble x 0.0"  forall x#. (-##) x#    0.0## = x#
 802 "timesDouble x 1.0"  forall x#. (*##) x#    1.0## = x#
 803 "timesDouble 1.0 x"  forall x#. (*##) 1.0## x#    = x#
 804 "divideDouble x 1.0" forall x#. (/##) x#    1.0## = x#
 805   #-}
 806
 807 {-
 808 We'd like to have more rules, but for example:
 809
 810 This gives wrong answer (0) for NaN - NaN (should be NaN):
 811     "minusDouble x x"    forall x#. (-##) x#    x#    = 0.0##
 812
 813 This gives wrong answer (0) for 0 * NaN (should be NaN):
 814     "timesDouble 0.0 x"  forall x#. (*##) 0.0## x#    = 0.0##
 815
 816 This gives wrong answer (0) for NaN * 0 (should be NaN):
 817     "timesDouble x 0.0"  forall x#. (*##) x#    0.0## = 0.0##
 818
 819 These are tested by num014.
 820 -}
 821
 822 -- Wrappers for the shift operations.  The uncheckedShift# family are
 823 -- undefined when the amount being shifted by is greater than the size
 824 -- in bits of Int#, so these wrappers perform a check and return
 825 -- either zero or -1 appropriately.
 826 --
 827 -- Note that these wrappers still produce undefined results when the
 828 -- second argument (the shift amount) is negative.
 829
 830 -- | Shift the argument left by the specified number of bits
 831 -- (which must be non-negative).
 832 shiftL# :: Word# -> Int# -> Word#
 833 a `shiftL#` b   | b >=# WORD_SIZE_IN_BITS# = int2Word# 0#
 834                 | otherwise                = a `uncheckedShiftL#` b
 835
 836 -- | Shift the argument right by the specified number of bits
 837 -- (which must be non-negative).
 838 shiftRL# :: Word# -> Int# -> Word#
 839 a `shiftRL#` b  | b >=# WORD_SIZE_IN_BITS# = int2Word# 0#
 840                 | otherwise                = a `uncheckedShiftRL#` b
 841
 842 -- | Shift the argument left by the specified number of bits
 843 -- (which must be non-negative).
 844 iShiftL# :: Int# -> Int# -> Int#
 845 a `iShiftL#` b  | b >=# WORD_SIZE_IN_BITS# = 0#
 846                 | otherwise                = a `uncheckedIShiftL#` b
 847
 848 -- | Shift the argument right (signed) by the specified number of bits
 849 -- (which must be non-negative).
 850 iShiftRA# :: Int# -> Int# -> Int#
 851 a `iShiftRA#` b | b >=# WORD_SIZE_IN_BITS# = if a <# 0# then (-1#) else 0#
 852                 | otherwise                = a `uncheckedIShiftRA#` b
 853
 854 -- | Shift the argument right (unsigned) by the specified number of bits
 855 -- (which must be non-negative).
 856 iShiftRL# :: Int# -> Int# -> Int#
 857 a `iShiftRL#` b | b >=# WORD_SIZE_IN_BITS# = 0#
 858                 | otherwise                = a `uncheckedIShiftRL#` b
 859
 860 #if WORD_SIZE_IN_BITS == 32
 861 {-# RULES
 862 "narrow32Int#"  forall x#. narrow32Int#   x# = x#
 863 "narrow32Word#" forall x#. narrow32Word#   x# = x#
 864    #-}
 865 #endif
 866
 867 {-# RULES
 868 "int2Word2Int"  forall x#. int2Word# (word2Int# x#) = x#
 869 "word2Int2Word" forall x#. word2Int# (int2Word# x#) = x#
 870   #-}
 871 \end{code}
 872
 873
 874 %********************************************************
 875 %*                                                      *
 876 \subsection{Unpacking C strings}
 877 %*                                                      *
 878 %********************************************************
 879
 880 This code is needed for virtually all programs, since it's used for
 881 unpacking the strings of error messages.
 882
 883 \begin{code}
 884 unpackCString# :: Addr# -> [Char]
 885 {-# NOINLINE unpackCString# #-}
 886     -- There's really no point in inlining this, ever, cos
 887     -- the loop doesn't specialise in an interesting
 888     -- But it's pretty small, so there's a danger that
 889     -- it'll be inlined at every literal, which is a waste
 890 unpackCString# addr
 891   = unpack 0#
 892   where
 893     unpack nh
 894       | ch `eqChar#` '\0'# = []
 895       | otherwise          = C# ch : unpack (nh +# 1#)
 896       where
 897         !ch = indexCharOffAddr# addr nh
 898
 899 unpackAppendCString# :: Addr# -> [Char] -> [Char]
 900 {-# NOINLINE unpackAppendCString# #-}
 901      -- See the NOINLINE note on unpackCString#
 902 unpackAppendCString# addr rest
 903   = unpack 0#
 904   where
 905     unpack nh
 906       | ch `eqChar#` '\0'# = rest
 907       | otherwise          = C# ch : unpack (nh +# 1#)
 908       where
 909         !ch = indexCharOffAddr# addr nh
 910
 911 unpackFoldrCString# :: Addr# -> (Char  -> a -> a) -> a -> a
 912
 913 -- Usually the unpack-list rule turns unpackFoldrCString# into unpackCString#
 914
 915 -- It also has a BuiltInRule in PrelRules.lhs:
 916 --      unpackFoldrCString# "foo" c (unpackFoldrCString# "baz" c n)
 917 --        =  unpackFoldrCString# "foobaz" c n
 918
 919 {-# NOINLINE unpackFoldrCString# #-}
 920 -- At one stage I had NOINLINE [0] on the grounds that, unlike
 921 -- unpackCString#, there *is* some point in inlining
 922 -- unpackFoldrCString#, because we get better code for the
 923 -- higher-order function call.  BUT there may be a lot of
 924 -- literal strings, and making a separate 'unpack' loop for
 925 -- each is highly gratuitous.  See nofib/real/anna/PrettyPrint.
 926
 927 unpackFoldrCString# addr f z
 928   = unpack 0#
 929   where
 930     unpack nh
 931       | ch `eqChar#` '\0'# = z
 932       | otherwise          = C# ch `f` unpack (nh +# 1#)
 933       where
 934         !ch = indexCharOffAddr# addr nh
 935
 936 unpackCStringUtf8# :: Addr# -> [Char]
 937 unpackCStringUtf8# addr
 938   = unpack 0#
 939   where
 940     unpack nh
 941       | ch `eqChar#` '\0'#   = []
 942       | ch `leChar#` '\x7F'# = C# ch : unpack (nh +# 1#)
 943       | ch `leChar#` '\xDF'# =
 944           C# (chr# (((ord# ch                                  -# 0xC0#) `uncheckedIShiftL#`  6#) +#
 945                      (ord# (indexCharOffAddr# addr (nh +# 1#)) -# 0x80#))) :
 946           unpack (nh +# 2#)
 947       | ch `leChar#` '\xEF'# =
 948           C# (chr# (((ord# ch                                  -# 0xE0#) `uncheckedIShiftL#` 12#) +#
 949                     ((ord# (indexCharOffAddr# addr (nh +# 1#)) -# 0x80#) `uncheckedIShiftL#`  6#) +#
 950                      (ord# (indexCharOffAddr# addr (nh +# 2#)) -# 0x80#))) :
 951           unpack (nh +# 3#)
 952       | otherwise            =
 953           C# (chr# (((ord# ch                                  -# 0xF0#) `uncheckedIShiftL#` 18#) +#
 954                     ((ord# (indexCharOffAddr# addr (nh +# 1#)) -# 0x80#) `uncheckedIShiftL#` 12#) +#
 955                     ((ord# (indexCharOffAddr# addr (nh +# 2#)) -# 0x80#) `uncheckedIShiftL#`  6#) +#
 956                      (ord# (indexCharOffAddr# addr (nh +# 3#)) -# 0x80#))) :
 957           unpack (nh +# 4#)
 958       where
 959         !ch = indexCharOffAddr# addr nh
 960
 961 unpackNBytes# :: Addr# -> Int# -> [Char]
 962 unpackNBytes# _addr 0#   = []
 963 unpackNBytes#  addr len# = unpack [] (len# -# 1#)
 964     where
 965      unpack acc i#
 966       | i# <# 0#  = acc
 967       | otherwise =
 968          case indexCharOffAddr# addr i# of
 969             ch -> unpack (C# ch : acc) (i# -# 1#)
 970
 971 {-# RULES
 972 "unpack"       [~1] forall a   . unpackCString# a             = build (unpackFoldrCString# a)
 973 "unpack-list"  [1]  forall a   . unpackFoldrCString# a (:) [] = unpackCString# a
 974 "unpack-append"     forall a n . unpackFoldrCString# a (:) n  = unpackAppendCString# a n
 975
 976 -- There's a built-in rule (in PrelRules.lhs) for
 977 --      unpackFoldr "foo" c (unpackFoldr "baz" c n)  =  unpackFoldr "foobaz" c n
 978
 979   #-}
 980 \end{code}
 981
 982 #ifdef __HADDOCK__
 983 \begin{code}
 984 -- | A special argument for the 'Control.Monad.ST.ST' type constructor,
 985 -- indexing a state embedded in the 'Prelude.IO' monad by
 986 -- 'Control.Monad.ST.stToIO'.
 987 data RealWorld
 988 \end{code}
 989 #endif