GHC/Base.lhs

   1 \section[GHC.Base]{Module @GHC.Base@}
   2
   3 The overall structure of the GHC Prelude is a bit tricky.
   4
   5   a) We want to avoid "orphan modules", i.e. ones with instance
   6         decls that don't belong either to a tycon or a class
   7         defined in the same module
   8
   9   b) We want to avoid giant modules
  10
  11 So the rough structure is as follows, in (linearised) dependency order
  12
  13
  14 GHC.Prim                Has no implementation.  It defines built-in things, and
  15                 by importing it you bring them into scope.
  16                 The source file is GHC.Prim.hi-boot, which is just
  17                 copied to make GHC.Prim.hi
  18
  19                 Classes: CCallable, CReturnable
  20
  21 GHC.Base        Classes: Eq, Ord, Functor, Monad
  22                 Types:   list, (), Int, Bool, Ordering, Char, String
  23
  24 Data.Tup        Types: tuples, plus instances for GHC.Base classes
  25
  26 GHC.Show        Class: Show, plus instances for GHC.Base/GHC.Tup types
  27
  28 GHC.Enum        Class: Enum,  plus instances for GHC.Base/GHC.Tup types
  29
  30 Data.Maybe      Type: Maybe, plus instances for GHC.Base classes
  31
  32 GHC.Num         Class: Num, plus instances for Int
  33                 Type:  Integer, plus instances for all classes so far (Eq, Ord, Num, Show)
  34
  35                 Integer is needed here because it is mentioned in the signature
  36                 of 'fromInteger' in class Num
  37
  38 GHC.Real        Classes: Real, Integral, Fractional, RealFrac
  39                          plus instances for Int, Integer
  40                 Types:  Ratio, Rational
  41                         plus intances for classes so far
  42
  43                 Rational is needed here because it is mentioned in the signature
  44                 of 'toRational' in class Real
  45
  46 Ix              Classes: Ix, plus instances for Int, Bool, Char, Integer, Ordering, tuples
  47
  48 GHC.Arr         Types: Array, MutableArray, MutableVar
  49
  50                 Does *not* contain any ByteArray stuff (see GHC.ByteArr)
  51                 Arrays are used by a function in GHC.Float
  52
  53 GHC.Float       Classes: Floating, RealFloat
  54                 Types:   Float, Double, plus instances of all classes so far
  55
  56                 This module contains everything to do with floating point.
  57                 It is a big module (900 lines)
  58                 With a bit of luck, many modules can be compiled without ever reading GHC.Float.hi
  59
  60 GHC.ByteArr     Types: ByteArray, MutableByteArray
  61
  62                 We want this one to be after GHC.Float, because it defines arrays
  63                 of unboxed floats.
  64
  65
  66 Other Prelude modules are much easier with fewer complex dependencies.
  67
  68 \begin{code}
  69 {-# OPTIONS -fno-implicit-prelude #-}
  70 -----------------------------------------------------------------------------
  71 -- |
  72 -- Module      :  GHC.Base
  73 -- Copyright   :  (c) The University of Glasgow, 1992-2002
  74 -- License     :  see libraries/base/LICENSE
  75 --
  76 -- Maintainer  :  cvs-ghc@haskell.org
  77 -- Stability   :  internal
  78 -- Portability :  non-portable (GHC extensions)
  79 --
  80 -- Basic data types and classes.
  81 --
  82 -----------------------------------------------------------------------------
  83
  84 #include "MachDeps.h"
  85
  86 module GHC.Base
  87         (
  88         module GHC.Base,
  89         module GHC.Prim,                -- Re-export GHC.Prim and GHC.Err, to avoid lots
  90         module GHC.Err          -- of people having to import it explicitly
  91   )
  92         where
  93
  94 import GHC.Prim
  95 import {-# SOURCE #-} GHC.Err
  96
  97 infixr 9  .
  98 infixr 5  ++, :
  99 infix  4  ==, /=, <, <=, >=, >
 100 infixr 3  &&
 101 infixr 2  ||
 102 infixl 1  >>, >>=
 103 infixr 0  $
 104
 105 default ()              -- Double isn't available yet
 106 \end{code}
 107
 108
 109 %*********************************************************
 110 %*                                                      *
 111 \subsection{DEBUGGING STUFF}
 112 %*  (for use when compiling GHC.Base itself doesn't work)
 113 %*                                                      *
 114 %*********************************************************
 115
 116 \begin{code}
 117 {-
 118 data  Bool  =  False | True
 119 data Ordering = LT | EQ | GT
 120 data Char = C# Char#
 121 type  String = [Char]
 122 data Int = I# Int#
 123 data  ()  =  ()
 124 data [] a = MkNil
 125
 126 not True = False
 127 (&&) True True = True
 128 otherwise = True
 129
 130 build = error "urk"
 131 foldr = error "urk"
 132
 133 unpackCString# :: Addr# -> [Char]
 134 unpackFoldrCString# :: Addr# -> (Char  -> a -> a) -> a -> a
 135 unpackAppendCString# :: Addr# -> [Char] -> [Char]
 136 unpackCStringUtf8# :: Addr# -> [Char]
 137 unpackCString# a = error "urk"
 138 unpackFoldrCString# a = error "urk"
 139 unpackAppendCString# a = error "urk"
 140 unpackCStringUtf8# a = error "urk"
 141 -}
 142 \end{code}
 143
 144
 145 %*********************************************************
 146 %*                                                      *
 147 \subsection{Standard classes @Eq@, @Ord@}
 148 %*                                                      *
 149 %*********************************************************
 150
 151 \begin{code}
 152
 153 -- | The 'Eq' class defines equality ('==') and inequality ('/=').
 154 -- All the basic datatypes exported by the "Prelude" are instances of 'Eq',
 155 -- and 'Eq' may be derived for any datatype whose constituents are also
 156 -- instances of 'Eq'.
 157 --
 158 -- Minimal complete definition: either '==' or '/='.
 159 --
 160 class  Eq a  where
 161     (==), (/=)           :: a -> a -> Bool
 162
 163     x /= y               = not (x == y)
 164     x == y               = not (x /= y)
 165
 166 class  (Eq a) => Ord a  where
 167     compare              :: a -> a -> Ordering
 168     (<), (<=), (>), (>=) :: a -> a -> Bool
 169     max, min             :: a -> a -> a
 170
 171     -- An instance of Ord should define either 'compare' or '<='.
 172     -- Using 'compare' can be more efficient for complex types.
 173
 174     compare x y
 175         | x == y    = EQ
 176         | x <= y    = LT        -- NB: must be '<=' not '<' to validate the
 177                                 -- above claim about the minimal things that
 178                                 -- can be defined for an instance of Ord
 179         | otherwise = GT
 180
 181     x <  y = case compare x y of { LT -> True;  _other -> False }
 182     x <= y = case compare x y of { GT -> False; _other -> True }
 183     x >  y = case compare x y of { GT -> True;  _other -> False }
 184     x >= y = case compare x y of { LT -> False; _other -> True }
 185
 186         -- These two default methods use '<=' rather than 'compare'
 187         -- because the latter is often more expensive
 188     max x y = if x <= y then y else x
 189     min x y = if x <= y then x else y
 190 \end{code}
 191
 192 %*********************************************************
 193 %*                                                      *
 194 \subsection{Monadic classes @Functor@, @Monad@ }
 195 %*                                                      *
 196 %*********************************************************
 197
 198 \begin{code}
 199 class  Functor f  where
 200     fmap        :: (a -> b) -> f a -> f b
 201
 202 class  Monad m  where
 203     (>>=)       :: m a -> (a -> m b) -> m b
 204     (>>)        :: m a -> m b -> m b
 205     return      :: a -> m a
 206     fail        :: String -> m a
 207
 208     m >> k      = m >>= \_ -> k
 209     fail s      = error s
 210 \end{code}
 211
 212
 213 %*********************************************************
 214 %*                                                      *
 215 \subsection{The list type}
 216 %*                                                      *
 217 %*********************************************************
 218
 219 \begin{code}
 220 data [] a = [] | a : [a]  -- do explicitly: deriving (Eq, Ord)
 221                           -- to avoid weird names like con2tag_[]#
 222
 223
 224 instance (Eq a) => Eq [a] where
 225     {-# SPECIALISE instance Eq [Char] #-}
 226     []     == []     = True
 227     (x:xs) == (y:ys) = x == y && xs == ys
 228     _xs    == _ys    = False
 229
 230 instance (Ord a) => Ord [a] where
 231     {-# SPECIALISE instance Ord [Char] #-}
 232     compare []     []     = EQ
 233     compare []     (_:_)  = LT
 234     compare (_:_)  []     = GT
 235     compare (x:xs) (y:ys) = case compare x y of
 236                                 EQ    -> compare xs ys
 237                                 other -> other
 238
 239 instance Functor [] where
 240     fmap = map
 241
 242 instance  Monad []  where
 243     m >>= k             = foldr ((++) . k) [] m
 244     m >> k              = foldr ((++) . (\ _ -> k)) [] m
 245     return x            = [x]
 246     fail _              = []
 247 \end{code}
 248
 249 A few list functions that appear here because they are used here.
 250 The rest of the prelude list functions are in GHC.List.
 251
 252 ----------------------------------------------
 253 --      foldr/build/augment
 254 ----------------------------------------------
 255
 256 \begin{code}
 257 foldr            :: (a -> b -> b) -> b -> [a] -> b
 258 -- foldr _ z []     =  z
 259 -- foldr f z (x:xs) =  f x (foldr f z xs)
 260 {-# INLINE [0] foldr #-}
 261 -- Inline only in the final stage, after the foldr/cons rule has had a chance
 262 foldr k z xs = go xs
 263              where
 264                go []     = z
 265                go (y:ys) = y `k` go ys
 266
 267 build   :: forall a. (forall b. (a -> b -> b) -> b -> b) -> [a]
 268 {-# INLINE [1] build #-}
 269         -- The INLINE is important, even though build is tiny,
 270         -- because it prevents [] getting inlined in the version that
 271         -- appears in the interface file.  If [] *is* inlined, it
 272         -- won't match with [] appearing in rules in an importing module.
 273         --
 274         -- The "1" says to inline in phase 1
 275
 276 build g = g (:) []
 277
 278 augment :: forall a. (forall b. (a->b->b) -> b -> b) -> [a] -> [a]
 279 {-# INLINE [1] augment #-}
 280 augment g xs = g (:) xs
 281
 282 {-# RULES
 283 "fold/build"    forall k z (g::forall b. (a->b->b) -> b -> b) .
 284                 foldr k z (build g) = g k z
 285
 286 "foldr/augment" forall k z xs (g::forall b. (a->b->b) -> b -> b) .
 287                 foldr k z (augment g xs) = g k (foldr k z xs)
 288
 289 "foldr/id"                        foldr (:) [] = \x->x
 290 "foldr/app"     [1] forall xs ys. foldr (:) ys xs = xs ++ ys
 291         -- Only activate this from phase 1, because that's
 292         -- when we disable the rule that expands (++) into foldr
 293
 294 -- The foldr/cons rule looks nice, but it can give disastrously
 295 -- bloated code when commpiling
 296 --      array (a,b) [(1,2), (2,2), (3,2), ...very long list... ]
 297 -- i.e. when there are very very long literal lists
 298 -- So I've disabled it for now. We could have special cases
 299 -- for short lists, I suppose.
 300 -- "foldr/cons" forall k z x xs. foldr k z (x:xs) = k x (foldr k z xs)
 301
 302 "foldr/single"  forall k z x. foldr k z [x] = k x z
 303 "foldr/nil"     forall k z.   foldr k z []  = z
 304
 305 "augment/build" forall (g::forall b. (a->b->b) -> b -> b)
 306                        (h::forall b. (a->b->b) -> b -> b) .
 307                        augment g (build h) = build (\c n -> g c (h c n))
 308 "augment/nil"   forall (g::forall b. (a->b->b) -> b -> b) .
 309                         augment g [] = build g
 310  #-}
 311
 312 -- This rule is true, but not (I think) useful:
 313 --      augment g (augment h t) = augment (\cn -> g c (h c n)) t
 314 \end{code}
 315
 316
 317 ----------------------------------------------
 318 --              map
 319 ----------------------------------------------
 320
 321 \begin{code}
 322 map :: (a -> b) -> [a] -> [b]
 323 map _ []     = []
 324 map f (x:xs) = f x : map f xs
 325
 326 -- Note eta expanded
 327 mapFB ::  (elt -> lst -> lst) -> (a -> elt) -> a -> lst -> lst
 328 {-# INLINE [0] mapFB #-}
 329 mapFB c f x ys = c (f x) ys
 330
 331 -- The rules for map work like this.
 332 --
 333 -- Up to (but not including) phase 1, we use the "map" rule to
 334 -- rewrite all saturated applications of map with its build/fold
 335 -- form, hoping for fusion to happen.
 336 -- In phase 1 and 0, we switch off that rule, inline build, and
 337 -- switch on the "mapList" rule, which rewrites the foldr/mapFB
 338 -- thing back into plain map.
 339 --
 340 -- It's important that these two rules aren't both active at once
 341 -- (along with build's unfolding) else we'd get an infinite loop
 342 -- in the rules.  Hence the activation control below.
 343 --
 344 -- The "mapFB" rule optimises compositions of map.
 345 --
 346 -- This same pattern is followed by many other functions:
 347 -- e.g. append, filter, iterate, repeat, etc.
 348
 349 {-# RULES
 350 "map"       [~1] forall f xs.   map f xs                = build (\c n -> foldr (mapFB c f) n xs)
 351 "mapList"   [1]  forall f.      foldr (mapFB (:) f) []  = map f
 352 "mapFB"     forall c f g.       mapFB (mapFB c f) g     = mapFB c (f.g)
 353   #-}
 354 \end{code}
 355
 356
 357 ----------------------------------------------
 358 --              append
 359 ----------------------------------------------
 360 \begin{code}
 361 (++) :: [a] -> [a] -> [a]
 362 (++) []     ys = ys
 363 (++) (x:xs) ys = x : xs ++ ys
 364
 365 {-# RULES
 366 "++"    [~1] forall xs ys. xs ++ ys = augment (\c n -> foldr c n xs) ys
 367   #-}
 368
 369 \end{code}
 370
 371
 372 %*********************************************************
 373 %*                                                      *
 374 \subsection{Type @Bool@}
 375 %*                                                      *
 376 %*********************************************************
 377
 378 \begin{code}
 379 -- |The 'Bool' type is an enumeration.  It is defined with 'False'
 380 -- first so that the corresponding 'Enum' instance will give @'fromEnum'
 381 -- False@ the value zero, and @'fromEnum' True@ the value 1.
 382 data  Bool  =  False | True  deriving (Eq, Ord)
 383         -- Read in GHC.Read, Show in GHC.Show
 384
 385 -- Boolean functions
 386
 387 -- | Boolean \"and\"
 388 (&&)                    :: Bool -> Bool -> Bool
 389 True  && x              =  x
 390 False && _              =  False
 391
 392 -- | Boolean \"or\"
 393 (||)                    :: Bool -> Bool -> Bool
 394 True  || _              =  True
 395 False || x              =  x
 396
 397 -- | Boolean \"not\"
 398 not                     :: Bool -> Bool
 399 not True                =  False
 400 not False               =  True
 401
 402 -- |'otherwise' is defined as the value 'True'; it helps to make
 403 -- guards more readable.  eg.
 404 --
 405 -- >  f x | x \< 0     = ...
 406 -- >      | otherwise = ...
 407 otherwise               :: Bool
 408 otherwise               =  True
 409 \end{code}
 410
 411
 412 %*********************************************************
 413 %*                                                      *
 414 \subsection{The @()@ type}
 415 %*                                                      *
 416 %*********************************************************
 417
 418 The Unit type is here because virtually any program needs it (whereas
 419 some programs may get away without consulting GHC.Tup).  Furthermore,
 420 the renamer currently *always* asks for () to be in scope, so that
 421 ccalls can use () as their default type; so when compiling GHC.Base we
 422 need ().  (We could arrange suck in () only if -fglasgow-exts, but putting
 423 it here seems more direct.)
 424
 425 \begin{code}
 426 -- | The unit datatype @()@ has one non-undefined member, the nullary
 427 -- constructor @()@.
 428 data () = ()
 429
 430 instance Eq () where
 431     () == () = True
 432     () /= () = False
 433
 434 instance Ord () where
 435     () <= () = True
 436     () <  () = False
 437     () >= () = True
 438     () >  () = False
 439     max () () = ()
 440     min () () = ()
 441     compare () () = EQ
 442 \end{code}
 443
 444
 445 %*********************************************************
 446 %*                                                      *
 447 \subsection{Type @Ordering@}
 448 %*                                                      *
 449 %*********************************************************
 450
 451 \begin{code}
 452 -- | Represents an ordering relationship between two values: less
 453 -- than, equal to, or greater than.  An 'Ordering' is returned by
 454 -- 'compare'.
 455 data Ordering = LT | EQ | GT deriving (Eq, Ord)
 456         -- Read in GHC.Read, Show in GHC.Show
 457 \end{code}
 458
 459
 460 %*********************************************************
 461 %*                                                      *
 462 \subsection{Type @Char@ and @String@}
 463 %*                                                      *
 464 %*********************************************************
 465
 466 \begin{code}
 467 -- | A 'String' is a list of characters.  String constants in Haskell are values
 468 -- of type 'String'.
 469 --
 470 type String = [Char]
 471
 472 {-| The character type 'Char' is an enumeration whose values represent
 473 Unicode characters.  A character literal in Haskell has type 'Char'.
 474
 475 To convert a 'Char' to or from an 'Int', use 'Prelude.toEnum' and
 476 'Prelude.fromEnum' from the 'Enum' class respectively (equivalently
 477 'ord' and 'chr' also do the trick).
 478 -}
 479 data Char = C# Char#
 480
 481 -- We don't use deriving for Eq and Ord, because for Ord the derived
 482 -- instance defines only compare, which takes two primops.  Then
 483 -- '>' uses compare, and therefore takes two primops instead of one.
 484
 485 instance Eq Char where
 486     (C# c1) == (C# c2) = c1 `eqChar#` c2
 487     (C# c1) /= (C# c2) = c1 `neChar#` c2
 488
 489 instance Ord Char where
 490     (C# c1) >  (C# c2) = c1 `gtChar#` c2
 491     (C# c1) >= (C# c2) = c1 `geChar#` c2
 492     (C# c1) <= (C# c2) = c1 `leChar#` c2
 493     (C# c1) <  (C# c2) = c1 `ltChar#` c2
 494
 495 {-# RULES
 496 "x# `eqChar#` x#" forall x#. x# `eqChar#` x# = True
 497 "x# `neChar#` x#" forall x#. x# `neChar#` x# = False
 498 "x# `gtChar#` x#" forall x#. x# `gtChar#` x# = False
 499 "x# `geChar#` x#" forall x#. x# `geChar#` x# = True
 500 "x# `leChar#` x#" forall x#. x# `leChar#` x# = True
 501 "x# `ltChar#` x#" forall x#. x# `ltChar#` x# = False
 502   #-}
 503
 504 chr :: Int -> Char
 505 chr (I# i#) | int2Word# i# `leWord#` int2Word# 0x10FFFF# = C# (chr# i#)
 506             | otherwise                                  = error "Prelude.chr: bad argument"
 507
 508 unsafeChr :: Int -> Char
 509 unsafeChr (I# i#) = C# (chr# i#)
 510
 511 ord :: Char -> Int
 512 ord (C# c#) = I# (ord# c#)
 513 \end{code}
 514
 515 String equality is used when desugaring pattern-matches against strings.
 516
 517 \begin{code}
 518 eqString :: String -> String -> Bool
 519 eqString []       []       = True
 520 eqString (c1:cs1) (c2:cs2) = c1 == c2 && cs1 `eqString` cs2
 521 eqString cs1      cs2      = False
 522
 523 {-# RULES "eqString" (==) = eqString #-}
 524 \end{code}
 525
 526
 527 %*********************************************************
 528 %*                                                      *
 529 \subsection{Type @Int@}
 530 %*                                                      *
 531 %*********************************************************
 532
 533 \begin{code}
 534 data Int = I# Int#
 535 -- ^A fixed-precision integer type with at least the range @[-2^29
 536 -- .. 2^29-1]@.  The exact range for a given implementation can be
 537 -- determined by using 'minBound' and 'maxBound' from the 'Bounded'
 538 -- class.
 539
 540 zeroInt, oneInt, twoInt, maxInt, minInt :: Int
 541 zeroInt = I# 0#
 542 oneInt  = I# 1#
 543 twoInt  = I# 2#
 544
 545 {- Seems clumsy. Should perhaps put minInt and MaxInt directly into MachDeps.h -}
 546 #if WORD_SIZE_IN_BITS == 31
 547 minInt  = I# (-0x40000000#)
 548 maxInt  = I# 0x3FFFFFFF#
 549 #elif WORD_SIZE_IN_BITS == 32
 550 minInt  = I# (-0x80000000#)
 551 maxInt  = I# 0x7FFFFFFF#
 552 #else
 553 minInt  = I# (-0x8000000000000000#)
 554 maxInt  = I# 0x7FFFFFFFFFFFFFFF#
 555 #endif
 556
 557 instance Eq Int where
 558     (==) = eqInt
 559     (/=) = neInt
 560
 561 instance Ord Int where
 562     compare = compareInt
 563     (<)     = ltInt
 564     (<=)    = leInt
 565     (>=)    = geInt
 566     (>)     = gtInt
 567
 568 compareInt :: Int -> Int -> Ordering
 569 (I# x#) `compareInt` (I# y#) = compareInt# x# y#
 570
 571 compareInt# :: Int# -> Int# -> Ordering
 572 compareInt# x# y#
 573     | x# <#  y# = LT
 574     | x# ==# y# = EQ
 575     | otherwise = GT
 576 \end{code}
 577
 578
 579 %*********************************************************
 580 %*                                                      *
 581 \subsection{The function type}
 582 %*                                                      *
 583 %*********************************************************
 584
 585 \begin{code}
 586 -- identity function
 587 id                      :: a -> a
 588 id x                    =  x
 589
 590 -- lazy function; this is just the same as id, but its unfolding
 591 -- and strictness are over-ridden by the definition in MkId.lhs
 592 -- That way, it does not get inlined, and the strictness analyser
 593 -- sees it as lazy.  Then the worker/wrapper phase inlines it.
 594 -- Result: happiness
 595 lazy :: a -> a
 596 lazy x = x
 597
 598 -- constant function
 599 const                   :: a -> b -> a
 600 const x _               =  x
 601
 602 -- function composition
 603 {-# INLINE (.) #-}
 604 (.)       :: (b -> c) -> (a -> b) -> a -> c
 605 (.) f g x = f (g x)
 606
 607 -- flip f  takes its (first) two arguments in the reverse order of f.
 608 flip                    :: (a -> b -> c) -> b -> a -> c
 609 flip f x y              =  f y x
 610
 611 -- right-associating infix application operator (useful in continuation-
 612 -- passing style)
 613 {-# INLINE ($) #-}
 614 ($)                     :: (a -> b) -> a -> b
 615 f $ x                   =  f x
 616
 617 -- until p f  yields the result of applying f until p holds.
 618 until                   :: (a -> Bool) -> (a -> a) -> a -> a
 619 until p f x | p x       =  x
 620             | otherwise =  until p f (f x)
 621
 622 -- asTypeOf is a type-restricted version of const.  It is usually used
 623 -- as an infix operator, and its typing forces its first argument
 624 -- (which is usually overloaded) to have the same type as the second.
 625 asTypeOf                :: a -> a -> a
 626 asTypeOf                =  const
 627 \end{code}
 628
 629 %*********************************************************
 630 %*                                                      *
 631 \subsection{CCallable instances}
 632 %*                                                      *
 633 %*********************************************************
 634
 635 Defined here to avoid orphans
 636
 637 \begin{code}
 638 instance CCallable Char
 639 instance CReturnable Char
 640
 641 instance CCallable   Int
 642 instance CReturnable Int
 643
 644 instance CReturnable () -- Why, exactly?
 645 \end{code}
 646
 647
 648 %*********************************************************
 649 %*                                                      *
 650 \subsection{Generics}
 651 %*                                                      *
 652 %*********************************************************
 653
 654 \begin{code}
 655 data Unit = Unit
 656 #ifndef __HADDOCK__
 657 data (:+:) a b = Inl a | Inr b
 658 data (:*:) a b = a :*: b
 659 #endif
 660 \end{code}
 661
 662
 663 %*********************************************************
 664 %*                                                      *
 665 \subsection{Numeric primops}
 666 %*                                                      *
 667 %*********************************************************
 668
 669 \begin{code}
 670 divInt# :: Int# -> Int# -> Int#
 671 x# `divInt#` y#
 672         -- careful NOT to overflow if we do any additional arithmetic
 673         -- on the arguments...  the following  previous version of this
 674         -- code has problems with overflow:
 675 --    | (x# ># 0#) && (y# <# 0#) = ((x# -# y#) -# 1#) `quotInt#` y#
 676 --    | (x# <# 0#) && (y# ># 0#) = ((x# -# y#) +# 1#) `quotInt#` y#
 677     | (x# ># 0#) && (y# <# 0#) = (x# -# 1#) `quotInt#` y# -# 1#
 678     | (x# <# 0#) && (y# ># 0#) = (x# +# 1#) `quotInt#` y# -# 1#
 679     | otherwise                = x# `quotInt#` y#
 680
 681 modInt# :: Int# -> Int# -> Int#
 682 x# `modInt#` y#
 683     | (x# ># 0#) && (y# <# 0#) ||
 684       (x# <# 0#) && (y# ># 0#)    = if r# /=# 0# then r# +# y# else 0#
 685     | otherwise                   = r#
 686     where
 687     r# = x# `remInt#` y#
 688 \end{code}
 689
 690 Definitions of the boxed PrimOps; these will be
 691 used in the case of partial applications, etc.
 692
 693 \begin{code}
 694 {-# INLINE eqInt #-}
 695 {-# INLINE neInt #-}
 696 {-# INLINE gtInt #-}
 697 {-# INLINE geInt #-}
 698 {-# INLINE ltInt #-}
 699 {-# INLINE leInt #-}
 700 {-# INLINE plusInt #-}
 701 {-# INLINE minusInt #-}
 702 {-# INLINE timesInt #-}
 703 {-# INLINE quotInt #-}
 704 {-# INLINE remInt #-}
 705 {-# INLINE negateInt #-}
 706
 707 plusInt, minusInt, timesInt, quotInt, remInt, divInt, modInt, gcdInt :: Int -> Int -> Int
 708 (I# x) `plusInt`  (I# y) = I# (x +# y)
 709 (I# x) `minusInt` (I# y) = I# (x -# y)
 710 (I# x) `timesInt` (I# y) = I# (x *# y)
 711 (I# x) `quotInt`  (I# y) = I# (x `quotInt#` y)
 712 (I# x) `remInt`   (I# y) = I# (x `remInt#`  y)
 713 (I# x) `divInt`   (I# y) = I# (x `divInt#`  y)
 714 (I# x) `modInt`   (I# y) = I# (x `modInt#`  y)
 715
 716 {-# RULES
 717 "x# +# 0#" forall x#. x# +# 0# = x#
 718 "0# +# x#" forall x#. 0# +# x# = x#
 719 "x# -# 0#" forall x#. x# -# 0# = x#
 720 "x# -# x#" forall x#. x# -# x# = 0#
 721 "x# *# 0#" forall x#. x# *# 0# = 0#
 722 "0# *# x#" forall x#. 0# *# x# = 0#
 723 "x# *# 1#" forall x#. x# *# 1# = x#
 724 "1# *# x#" forall x#. 1# *# x# = x#
 725   #-}
 726
 727 gcdInt (I# a) (I# b) = g a b
 728    where g 0# 0# = error "GHC.Base.gcdInt: gcd 0 0 is undefined"
 729          g 0# _  = I# absB
 730          g _  0# = I# absA
 731          g _  _  = I# (gcdInt# absA absB)
 732
 733          absInt x = if x <# 0# then negateInt# x else x
 734
 735          absA     = absInt a
 736          absB     = absInt b
 737
 738 negateInt :: Int -> Int
 739 negateInt (I# x) = I# (negateInt# x)
 740
 741 gtInt, geInt, eqInt, neInt, ltInt, leInt :: Int -> Int -> Bool
 742 (I# x) `gtInt` (I# y) = x >#  y
 743 (I# x) `geInt` (I# y) = x >=# y
 744 (I# x) `eqInt` (I# y) = x ==# y
 745 (I# x) `neInt` (I# y) = x /=# y
 746 (I# x) `ltInt` (I# y) = x <#  y
 747 (I# x) `leInt` (I# y) = x <=# y
 748
 749 {-# RULES
 750 "x# ># x#"  forall x#. x# >#  x# = False
 751 "x# >=# x#" forall x#. x# >=# x# = True
 752 "x# ==# x#" forall x#. x# ==# x# = True
 753 "x# /=# x#" forall x#. x# /=# x# = False
 754 "x# <# x#"  forall x#. x# <#  x# = False
 755 "x# <=# x#" forall x#. x# <=# x# = True
 756   #-}
 757
 758 {-# RULES
 759 "plusFloat x 0.0"   forall x#. plusFloat#  x#   0.0# = x#
 760 "plusFloat 0.0 x"   forall x#. plusFloat#  0.0# x#   = x#
 761 "minusFloat x 0.0"  forall x#. minusFloat# x#   0.0# = x#
 762 "minusFloat x x"    forall x#. minusFloat# x#   x#   = 0.0#
 763 "timesFloat x 0.0"  forall x#. timesFloat# x#   0.0# = 0.0#
 764 "timesFloat0.0 x"   forall x#. timesFloat# 0.0# x#   = 0.0#
 765 "timesFloat x 1.0"  forall x#. timesFloat# x#   1.0# = x#
 766 "timesFloat 1.0 x"  forall x#. timesFloat# 1.0# x#   = x#
 767 "divideFloat x 1.0" forall x#. divideFloat# x#  1.0# = x#
 768   #-}
 769
 770 {-# RULES
 771 "plusDouble x 0.0"   forall x#. (+##) x#    0.0## = x#
 772 "plusDouble 0.0 x"   forall x#. (+##) 0.0## x#    = x#
 773 "minusDouble x 0.0"  forall x#. (-##) x#    0.0## = x#
 774 "minusDouble x x"    forall x#. (-##) x#    x#    = 0.0##
 775 "timesDouble x 0.0"  forall x#. (*##) x#    0.0## = 0.0##
 776 "timesDouble 0.0 x"  forall x#. (*##) 0.0## x#    = 0.0##
 777 "timesDouble x 1.0"  forall x#. (*##) x#    1.0## = x#
 778 "timesDouble 1.0 x"  forall x#. (*##) 1.0## x#    = x#
 779 "divideDouble x 1.0" forall x#. (/##) x#    1.0## = x#
 780   #-}
 781
 782 -- Wrappers for the shift operations.  The uncheckedShift# family are
 783 -- undefined when the amount being shifted by is greater than the size
 784 -- in bits of Int#, so these wrappers perform a check and return
 785 -- either zero or -1 appropriately.
 786 --
 787 -- Note that these wrappers still produce undefined results when the
 788 -- second argument (the shift amount) is negative.
 789
 790 shiftL#, shiftRL# :: Word# -> Int# -> Word#
 791
 792 a `shiftL#` b   | b >=# WORD_SIZE_IN_BITS# = int2Word# 0#
 793                 | otherwise                = a `uncheckedShiftL#` b
 794
 795 a `shiftRL#` b  | b >=# WORD_SIZE_IN_BITS# = int2Word# 0#
 796                 | otherwise                = a `uncheckedShiftRL#` b
 797
 798 iShiftL#, iShiftRA#, iShiftRL# :: Int# -> Int# -> Int#
 799
 800 a `iShiftL#` b  | b >=# WORD_SIZE_IN_BITS# = 0#
 801                 | otherwise                = a `uncheckedIShiftL#` b
 802
 803 a `iShiftRA#` b | b >=# WORD_SIZE_IN_BITS# = if a <# 0# then (-1#) else 0#
 804                 | otherwise                = a `uncheckedIShiftRA#` b
 805
 806 a `iShiftRL#` b | b >=# WORD_SIZE_IN_BITS# = 0#
 807                 | otherwise                = a `uncheckedIShiftRL#` b
 808
 809 #if WORD_SIZE_IN_BITS == 32
 810 {-# RULES
 811 "narrow32Int#"  forall x#. narrow32Int#   x# = x#
 812 "narrow32Word#" forall x#. narrow32Word#   x# = x#
 813    #-}
 814 #endif
 815
 816 {-# RULES
 817 "int2Word2Int"  forall x#. int2Word# (word2Int# x#) = x#
 818 "word2Int2Word" forall x#. word2Int# (int2Word# x#) = x#
 819   #-}
 820 \end{code}
 821
 822
 823 %********************************************************
 824 %*                                                      *
 825 \subsection{Unpacking C strings}
 826 %*                                                      *
 827 %********************************************************
 828
 829 This code is needed for virtually all programs, since it's used for
 830 unpacking the strings of error messages.
 831
 832 \begin{code}
 833 unpackCString# :: Addr# -> [Char]
 834 {-# NOINLINE [1] unpackCString# #-}
 835 unpackCString# addr
 836   = unpack 0#
 837   where
 838     unpack nh
 839       | ch `eqChar#` '\0'# = []
 840       | otherwise          = C# ch : unpack (nh +# 1#)
 841       where
 842         ch = indexCharOffAddr# addr nh
 843
 844 unpackAppendCString# :: Addr# -> [Char] -> [Char]
 845 unpackAppendCString# addr rest
 846   = unpack 0#
 847   where
 848     unpack nh
 849       | ch `eqChar#` '\0'# = rest
 850       | otherwise          = C# ch : unpack (nh +# 1#)
 851       where
 852         ch = indexCharOffAddr# addr nh
 853
 854 unpackFoldrCString# :: Addr# -> (Char  -> a -> a) -> a -> a
 855 {-# NOINLINE [0] unpackFoldrCString# #-}
 856 -- Don't inline till right at the end;
 857 -- usually the unpack-list rule turns it into unpackCStringList
 858 unpackFoldrCString# addr f z
 859   = unpack 0#
 860   where
 861     unpack nh
 862       | ch `eqChar#` '\0'# = z
 863       | otherwise          = C# ch `f` unpack (nh +# 1#)
 864       where
 865         ch = indexCharOffAddr# addr nh
 866
 867 unpackCStringUtf8# :: Addr# -> [Char]
 868 unpackCStringUtf8# addr
 869   = unpack 0#
 870   where
 871     unpack nh
 872       | ch `eqChar#` '\0'#   = []
 873       | ch `leChar#` '\x7F'# = C# ch : unpack (nh +# 1#)
 874       | ch `leChar#` '\xDF'# =
 875           C# (chr# ((ord# ch                                  -# 0xC0#) `uncheckedIShiftL#`  6# +#
 876                     (ord# (indexCharOffAddr# addr (nh +# 1#)) -# 0x80#))) :
 877           unpack (nh +# 2#)
 878       | ch `leChar#` '\xEF'# =
 879           C# (chr# ((ord# ch                                  -# 0xE0#) `uncheckedIShiftL#` 12# +#
 880                     (ord# (indexCharOffAddr# addr (nh +# 1#)) -# 0x80#) `uncheckedIShiftL#`  6# +#
 881                     (ord# (indexCharOffAddr# addr (nh +# 2#)) -# 0x80#))) :
 882           unpack (nh +# 3#)
 883       | otherwise            =
 884           C# (chr# ((ord# ch                                  -# 0xF0#) `uncheckedIShiftL#` 18# +#
 885                     (ord# (indexCharOffAddr# addr (nh +# 1#)) -# 0x80#) `uncheckedIShiftL#` 12# +#
 886                     (ord# (indexCharOffAddr# addr (nh +# 2#)) -# 0x80#) `uncheckedIShiftL#`  6# +#
 887                     (ord# (indexCharOffAddr# addr (nh +# 3#)) -# 0x80#))) :
 888           unpack (nh +# 4#)
 889       where
 890         ch = indexCharOffAddr# addr nh
 891
 892 unpackNBytes# :: Addr# -> Int# -> [Char]
 893 unpackNBytes# _addr 0#   = []
 894 unpackNBytes#  addr len# = unpack [] (len# -# 1#)
 895     where
 896      unpack acc i#
 897       | i# <# 0#  = acc
 898       | otherwise =
 899          case indexCharOffAddr# addr i# of
 900             ch -> unpack (C# ch : acc) (i# -# 1#)
 901
 902 {-# RULES
 903 "unpack"       [~1] forall a   . unpackCString# a                  = build (unpackFoldrCString# a)
 904 "unpack-list"  [1]  forall a   . unpackFoldrCString# a (:) [] = unpackCString# a
 905 "unpack-append"     forall a n . unpackFoldrCString# a (:) n  = unpackAppendCString# a n
 906
 907 -- There's a built-in rule (in PrelRules.lhs) for
 908 --      unpackFoldr "foo" c (unpackFoldr "baz" c n)  =  unpackFoldr "foobaz" c n
 909
 910   #-}
 911 \end{code}