GHC/Base.lhs

   1 \section[GHC.Base]{Module @GHC.Base@}
   2
   3 The overall structure of the GHC Prelude is a bit tricky.
   4
   5   a) We want to avoid "orphan modules", i.e. ones with instance
   6         decls that don't belong either to a tycon or a class
   7         defined in the same module
   8
   9   b) We want to avoid giant modules
  10
  11 So the rough structure is as follows, in (linearised) dependency order
  12
  13
  14 GHC.Prim                Has no implementation.  It defines built-in things, and
  15                 by importing it you bring them into scope.
  16                 The source file is GHC.Prim.hi-boot, which is just
  17                 copied to make GHC.Prim.hi
  18
  19 GHC.Base        Classes: Eq, Ord, Functor, Monad
  20                 Types:   list, (), Int, Bool, Ordering, Char, String
  21
  22 Data.Tuple      Types: tuples, plus instances for GHC.Base classes
  23
  24 GHC.Show        Class: Show, plus instances for GHC.Base/GHC.Tup types
  25
  26 GHC.Enum        Class: Enum,  plus instances for GHC.Base/GHC.Tup types
  27
  28 Data.Maybe      Type: Maybe, plus instances for GHC.Base classes
  29
  30 GHC.List        List functions
  31
  32 GHC.Num         Class: Num, plus instances for Int
  33                 Type:  Integer, plus instances for all classes so far (Eq, Ord, Num, Show)
  34
  35                 Integer is needed here because it is mentioned in the signature
  36                 of 'fromInteger' in class Num
  37
  38 GHC.Real        Classes: Real, Integral, Fractional, RealFrac
  39                          plus instances for Int, Integer
  40                 Types:  Ratio, Rational
  41                         plus intances for classes so far
  42
  43                 Rational is needed here because it is mentioned in the signature
  44                 of 'toRational' in class Real
  45
  46 GHC.ST  The ST monad, instances and a few helper functions
  47
  48 Ix              Classes: Ix, plus instances for Int, Bool, Char, Integer, Ordering, tuples
  49
  50 GHC.Arr         Types: Array, MutableArray, MutableVar
  51
  52                 Arrays are used by a function in GHC.Float
  53
  54 GHC.Float       Classes: Floating, RealFloat
  55                 Types:   Float, Double, plus instances of all classes so far
  56
  57                 This module contains everything to do with floating point.
  58                 It is a big module (900 lines)
  59                 With a bit of luck, many modules can be compiled without ever reading GHC.Float.hi
  60
  61
  62 Other Prelude modules are much easier with fewer complex dependencies.
  63
  64 \begin{code}
  65 {-# OPTIONS_GHC -XNoImplicitPrelude #-}
  66 {-# OPTIONS_GHC -fno-warn-orphans #-}
  67 {-# OPTIONS_HADDOCK hide #-}
  68 -----------------------------------------------------------------------------
  69 -- |
  70 -- Module      :  GHC.Base
  71 -- Copyright   :  (c) The University of Glasgow, 1992-2002
  72 -- License     :  see libraries/base/LICENSE
  73 --
  74 -- Maintainer  :  cvs-ghc@haskell.org
  75 -- Stability   :  internal
  76 -- Portability :  non-portable (GHC extensions)
  77 --
  78 -- Basic data types and classes.
  79 --
  80 -----------------------------------------------------------------------------
  81
  82 #include "MachDeps.h"
  83
  84 -- #hide
  85 module GHC.Base
  86         (
  87         module GHC.Base,
  88         module GHC.Bool,
  89         module GHC.Classes,
  90         module GHC.Generics,
  91         module GHC.Ordering,
  92         module GHC.Types,
  93         module GHC.Prim,        -- Re-export GHC.Prim and GHC.Err, to avoid lots
  94         module GHC.Err          -- of people having to import it explicitly
  95   )
  96         where
  97
  98 import GHC.Types
  99 import GHC.Bool
 100 import GHC.Classes
 101 import GHC.Generics
 102 import GHC.Ordering
 103 import GHC.Prim
 104 import {-# SOURCE #-} GHC.Err
 105
 106 infixr 9  .
 107 infixr 5  ++
 108 infixl 1  >>, >>=
 109 infixr 0  $
 110
 111 default ()              -- Double isn't available yet
 112 \end{code}
 113
 114
 115 %*********************************************************
 116 %*                                                      *
 117 \subsection{DEBUGGING STUFF}
 118 %*  (for use when compiling GHC.Base itself doesn't work)
 119 %*                                                      *
 120 %*********************************************************
 121
 122 \begin{code}
 123 {-
 124 data  Bool  =  False | True
 125 data Ordering = LT | EQ | GT
 126 data Char = C# Char#
 127 type  String = [Char]
 128 data Int = I# Int#
 129 data  ()  =  ()
 130 data [] a = MkNil
 131
 132 not True = False
 133 (&&) True True = True
 134 otherwise = True
 135
 136 build = error "urk"
 137 foldr = error "urk"
 138
 139 unpackCString# :: Addr# -> [Char]
 140 unpackFoldrCString# :: Addr# -> (Char  -> a -> a) -> a -> a
 141 unpackAppendCString# :: Addr# -> [Char] -> [Char]
 142 unpackCStringUtf8# :: Addr# -> [Char]
 143 unpackCString# a = error "urk"
 144 unpackFoldrCString# a = error "urk"
 145 unpackAppendCString# a = error "urk"
 146 unpackCStringUtf8# a = error "urk"
 147 -}
 148 \end{code}
 149
 150
 151 %*********************************************************
 152 %*                                                      *
 153 \subsection{Monadic classes @Functor@, @Monad@ }
 154 %*                                                      *
 155 %*********************************************************
 156
 157 \begin{code}
 158 {- | The 'Functor' class is used for types that can be mapped over.
 159 Instances of 'Functor' should satisfy the following laws:
 160
 161 > fmap id  ==  id
 162 > fmap (f . g)  ==  fmap f . fmap g
 163
 164 The instances of 'Functor' for lists, 'Data.Maybe.Maybe' and 'System.IO.IO'
 165 defined in the "Prelude" satisfy these laws.
 166 -}
 167
 168 class  Functor f  where
 169     fmap        :: (a -> b) -> f a -> f b
 170
 171 {- | The 'Monad' class defines the basic operations over a /monad/,
 172 a concept from a branch of mathematics known as /category theory/.
 173 From the perspective of a Haskell programmer, however, it is best to
 174 think of a monad as an /abstract datatype/ of actions.
 175 Haskell's @do@ expressions provide a convenient syntax for writing
 176 monadic expressions.
 177
 178 Minimal complete definition: '>>=' and 'return'.
 179
 180 Instances of 'Monad' should satisfy the following laws:
 181
 182 > return a >>= k  ==  k a
 183 > m >>= return  ==  m
 184 > m >>= (\x -> k x >>= h)  ==  (m >>= k) >>= h
 185
 186 Instances of both 'Monad' and 'Functor' should additionally satisfy the law:
 187
 188 > fmap f xs  ==  xs >>= return . f
 189
 190 The instances of 'Monad' for lists, 'Data.Maybe.Maybe' and 'System.IO.IO'
 191 defined in the "Prelude" satisfy these laws.
 192 -}
 193
 194 class  Monad m  where
 195     -- | Sequentially compose two actions, passing any value produced
 196     -- by the first as an argument to the second.
 197     (>>=)       :: forall a b. m a -> (a -> m b) -> m b
 198     -- | Sequentially compose two actions, discarding any value produced
 199     -- by the first, like sequencing operators (such as the semicolon)
 200     -- in imperative languages.
 201     (>>)        :: forall a b. m a -> m b -> m b
 202         -- Explicit for-alls so that we know what order to
 203         -- give type arguments when desugaring
 204
 205     -- | Inject a value into the monadic type.
 206     return      :: a -> m a
 207     -- | Fail with a message.  This operation is not part of the
 208     -- mathematical definition of a monad, but is invoked on pattern-match
 209     -- failure in a @do@ expression.
 210     fail        :: String -> m a
 211
 212     m >> k      = m >>= \_ -> k
 213     fail s      = error s
 214 \end{code}
 215
 216
 217 %*********************************************************
 218 %*                                                      *
 219 \subsection{The list type}
 220 %*                                                      *
 221 %*********************************************************
 222
 223 \begin{code}
 224 -- do explicitly: deriving (Eq, Ord)
 225 -- to avoid weird names like con2tag_[]#
 226
 227 instance (Eq a) => Eq [a] where
 228     {-# SPECIALISE instance Eq [Char] #-}
 229     []     == []     = True
 230     (x:xs) == (y:ys) = x == y && xs == ys
 231     _xs    == _ys    = False
 232
 233 instance (Ord a) => Ord [a] where
 234     {-# SPECIALISE instance Ord [Char] #-}
 235     compare []     []     = EQ
 236     compare []     (_:_)  = LT
 237     compare (_:_)  []     = GT
 238     compare (x:xs) (y:ys) = case compare x y of
 239                                 EQ    -> compare xs ys
 240                                 other -> other
 241
 242 instance Functor [] where
 243     fmap = map
 244
 245 instance  Monad []  where
 246     m >>= k             = foldr ((++) . k) [] m
 247     m >> k              = foldr ((++) . (\ _ -> k)) [] m
 248     return x            = [x]
 249     fail _              = []
 250 \end{code}
 251
 252 A few list functions that appear here because they are used here.
 253 The rest of the prelude list functions are in GHC.List.
 254
 255 ----------------------------------------------
 256 --      foldr/build/augment
 257 ----------------------------------------------
 258
 259 Note [Inlining for foldr]
 260 ~~~~~~~~~~~~~~~~~~~~~~~~~
 261 Inline foldr only in the final stage (0), after the foldr rules
 262 have had a chance
 263
 264 Notice that we write foldr with just *two* arguments so that it'll inline
 265 when given just those two arguments.  Those are the ones that allow it to
 266 be specialised for its argument functions.  If you give it *three* args
 267 then a definition like
 268    unpack = foldr unpk_fn unpk_arg
 269 does not get foldr inlined.  But now 'unpack' will probably be inlined at
 270 every call site (being small and arity 1), and *that* will make foldr inline!
 271 So we get a copy of foldr at every call of unpack. This is particularly
 272 bad for literal strings.
 273
 274 \begin{code}
 275 -- | 'foldr', applied to a binary operator, a starting value (typically
 276 -- the right-identity of the operator), and a list, reduces the list
 277 -- using the binary operator, from right to left:
 278 --
 279 -- > foldr f z [x1, x2, ..., xn] == x1 `f` (x2 `f` ... (xn `f` z)...)
 280
 281 foldr            :: (a -> b -> b) -> b -> [a] -> b
 282 -- foldr _ z []     =  z
 283 -- foldr f z (x:xs) =  f x (foldr f z xs)
 284 {-# INLINE [0] foldr #-}    -- See Note [Inlining for foldr]
 285 foldr k z = go
 286           where
 287                go []     = z
 288                go (y:ys) = y `k` go ys
 289
 290 -- | A list producer that can be fused with 'foldr'.
 291 -- This function is merely
 292 --
 293 -- >    build g = g (:) []
 294 --
 295 -- but GHC's simplifier will transform an expression of the form
 296 -- @'foldr' k z ('build' g)@, which may arise after inlining, to @g k z@,
 297 -- which avoids producing an intermediate list.
 298
 299 build   :: forall a. (forall b. (a -> b -> b) -> b -> b) -> [a]
 300 {-# INLINE [1] build #-}
 301         -- The INLINE is important, even though build is tiny,
 302         -- because it prevents [] getting inlined in the version that
 303         -- appears in the interface file.  If [] *is* inlined, it
 304         -- won't match with [] appearing in rules in an importing module.
 305         --
 306         -- The "1" says to inline in phase 1
 307
 308 build g = g (:) []
 309
 310 -- | A list producer that can be fused with 'foldr'.
 311 -- This function is merely
 312 --
 313 -- >    augment g xs = g (:) xs
 314 --
 315 -- but GHC's simplifier will transform an expression of the form
 316 -- @'foldr' k z ('augment' g xs)@, which may arise after inlining, to
 317 -- @g k ('foldr' k z xs)@, which avoids producing an intermediate list.
 318
 319 augment :: forall a. (forall b. (a->b->b) -> b -> b) -> [a] -> [a]
 320 {-# INLINE [1] augment #-}
 321 augment g xs = g (:) xs
 322
 323 {-# RULES
 324 "fold/build"    forall k z (g::forall b. (a->b->b) -> b -> b) .
 325                 foldr k z (build g) = g k z
 326
 327 "foldr/augment" forall k z xs (g::forall b. (a->b->b) -> b -> b) .
 328                 foldr k z (augment g xs) = g k (foldr k z xs)
 329
 330 "foldr/id"                        foldr (:) [] = \x  -> x
 331 "foldr/app"     [1] forall ys. foldr (:) ys = \xs -> xs ++ ys
 332         -- Only activate this from phase 1, because that's
 333         -- when we disable the rule that expands (++) into foldr
 334
 335 -- The foldr/cons rule looks nice, but it can give disastrously
 336 -- bloated code when commpiling
 337 --      array (a,b) [(1,2), (2,2), (3,2), ...very long list... ]
 338 -- i.e. when there are very very long literal lists
 339 -- So I've disabled it for now. We could have special cases
 340 -- for short lists, I suppose.
 341 -- "foldr/cons" forall k z x xs. foldr k z (x:xs) = k x (foldr k z xs)
 342
 343 "foldr/single"  forall k z x. foldr k z [x] = k x z
 344 "foldr/nil"     forall k z.   foldr k z []  = z
 345
 346 "augment/build" forall (g::forall b. (a->b->b) -> b -> b)
 347                        (h::forall b. (a->b->b) -> b -> b) .
 348                        augment g (build h) = build (\c n -> g c (h c n))
 349 "augment/nil"   forall (g::forall b. (a->b->b) -> b -> b) .
 350                         augment g [] = build g
 351  #-}
 352
 353 -- This rule is true, but not (I think) useful:
 354 --      augment g (augment h t) = augment (\cn -> g c (h c n)) t
 355 \end{code}
 356
 357
 358 ----------------------------------------------
 359 --              map
 360 ----------------------------------------------
 361
 362 \begin{code}
 363 -- | 'map' @f xs@ is the list obtained by applying @f@ to each element
 364 -- of @xs@, i.e.,
 365 --
 366 -- > map f [x1, x2, ..., xn] == [f x1, f x2, ..., f xn]
 367 -- > map f [x1, x2, ...] == [f x1, f x2, ...]
 368
 369 map :: (a -> b) -> [a] -> [b]
 370 map _ []     = []
 371 map f (x:xs) = f x : map f xs
 372
 373 -- Note eta expanded
 374 mapFB ::  (elt -> lst -> lst) -> (a -> elt) -> a -> lst -> lst
 375 {-# INLINE [0] mapFB #-}
 376 mapFB c f x ys = c (f x) ys
 377
 378 -- The rules for map work like this.
 379 --
 380 -- Up to (but not including) phase 1, we use the "map" rule to
 381 -- rewrite all saturated applications of map with its build/fold
 382 -- form, hoping for fusion to happen.
 383 -- In phase 1 and 0, we switch off that rule, inline build, and
 384 -- switch on the "mapList" rule, which rewrites the foldr/mapFB
 385 -- thing back into plain map.
 386 --
 387 -- It's important that these two rules aren't both active at once
 388 -- (along with build's unfolding) else we'd get an infinite loop
 389 -- in the rules.  Hence the activation control below.
 390 --
 391 -- The "mapFB" rule optimises compositions of map.
 392 --
 393 -- This same pattern is followed by many other functions:
 394 -- e.g. append, filter, iterate, repeat, etc.
 395
 396 {-# RULES
 397 "map"       [~1] forall f xs.   map f xs                = build (\c n -> foldr (mapFB c f) n xs)
 398 "mapList"   [1]  forall f.      foldr (mapFB (:) f) []  = map f
 399 "mapFB"     forall c f g.       mapFB (mapFB c f) g     = mapFB c (f.g)
 400   #-}
 401 \end{code}
 402
 403
 404 ----------------------------------------------
 405 --              append
 406 ----------------------------------------------
 407 \begin{code}
 408 -- | Append two lists, i.e.,
 409 --
 410 -- > [x1, ..., xm] ++ [y1, ..., yn] == [x1, ..., xm, y1, ..., yn]
 411 -- > [x1, ..., xm] ++ [y1, ...] == [x1, ..., xm, y1, ...]
 412 --
 413 -- If the first list is not finite, the result is the first list.
 414
 415 (++) :: [a] -> [a] -> [a]
 416 (++) []     ys = ys
 417 (++) (x:xs) ys = x : xs ++ ys
 418
 419 {-# RULES
 420 "++"    [~1] forall xs ys. xs ++ ys = augment (\c n -> foldr c n xs) ys
 421   #-}
 422
 423 \end{code}
 424
 425
 426 %*********************************************************
 427 %*                                                      *
 428 \subsection{Type @Bool@}
 429 %*                                                      *
 430 %*********************************************************
 431
 432 \begin{code}
 433 -- |The 'Bool' type is an enumeration.  It is defined with 'False'
 434 -- first so that the corresponding 'Prelude.Enum' instance will give
 435 -- 'Prelude.fromEnum' 'False' the value zero, and
 436 -- 'Prelude.fromEnum' 'True' the value 1.
 437 -- The actual definition is in the ghc-prim package.
 438
 439 -- XXX These don't work:
 440 -- deriving instance Eq Bool
 441 -- deriving instance Ord Bool
 442 -- <wired into compiler>:
 443 --     Illegal binding of built-in syntax: con2tag_Bool#
 444
 445 instance Eq Bool where
 446     True  == True  = True
 447     False == False = True
 448     _     == _     = False
 449
 450 instance Ord Bool where
 451     compare False True  = LT
 452     compare True  False = GT
 453     compare _     _     = EQ
 454
 455 -- Read is in GHC.Read, Show in GHC.Show
 456
 457 -- |'otherwise' is defined as the value 'True'.  It helps to make
 458 -- guards more readable.  eg.
 459 --
 460 -- >  f x | x < 0     = ...
 461 -- >      | otherwise = ...
 462 otherwise               :: Bool
 463 otherwise               =  True
 464 \end{code}
 465
 466 %*********************************************************
 467 %*                                                      *
 468 \subsection{Type @Ordering@}
 469 %*                                                      *
 470 %*********************************************************
 471
 472 \begin{code}
 473 -- | Represents an ordering relationship between two values: less
 474 -- than, equal to, or greater than.  An 'Ordering' is returned by
 475 -- 'compare'.
 476 -- XXX These don't work:
 477 -- deriving instance Eq Ordering
 478 -- deriving instance Ord Ordering
 479 -- Illegal binding of built-in syntax: con2tag_Ordering#
 480 instance Eq Ordering where
 481     EQ == EQ = True
 482     LT == LT = True
 483     GT == GT = True
 484     _  == _  = False
 485         -- Read in GHC.Read, Show in GHC.Show
 486
 487 instance Ord Ordering where
 488     LT <= _  = True
 489     _  <= LT = False
 490     EQ <= _  = True
 491     _  <= EQ = False
 492     GT <= GT = True
 493 \end{code}
 494
 495
 496 %*********************************************************
 497 %*                                                      *
 498 \subsection{Type @Char@ and @String@}
 499 %*                                                      *
 500 %*********************************************************
 501
 502 \begin{code}
 503 -- | A 'String' is a list of characters.  String constants in Haskell are values
 504 -- of type 'String'.
 505 --
 506 type String = [Char]
 507
 508 {-| The character type 'Char' is an enumeration whose values represent
 509 Unicode (or equivalently ISO\/IEC 10646) characters
 510 (see <http://www.unicode.org/> for details).
 511 This set extends the ISO 8859-1 (Latin-1) character set
 512 (the first 256 charachers), which is itself an extension of the ASCII
 513 character set (the first 128 characters).
 514 A character literal in Haskell has type 'Char'.
 515
 516 To convert a 'Char' to or from the corresponding 'Int' value defined
 517 by Unicode, use 'Prelude.toEnum' and 'Prelude.fromEnum' from the
 518 'Prelude.Enum' class respectively (or equivalently 'ord' and 'chr').
 519 -}
 520
 521 -- We don't use deriving for Eq and Ord, because for Ord the derived
 522 -- instance defines only compare, which takes two primops.  Then
 523 -- '>' uses compare, and therefore takes two primops instead of one.
 524
 525 instance Eq Char where
 526     (C# c1) == (C# c2) = c1 `eqChar#` c2
 527     (C# c1) /= (C# c2) = c1 `neChar#` c2
 528
 529 instance Ord Char where
 530     (C# c1) >  (C# c2) = c1 `gtChar#` c2
 531     (C# c1) >= (C# c2) = c1 `geChar#` c2
 532     (C# c1) <= (C# c2) = c1 `leChar#` c2
 533     (C# c1) <  (C# c2) = c1 `ltChar#` c2
 534
 535 {-# RULES
 536 "x# `eqChar#` x#" forall x#. x# `eqChar#` x# = True
 537 "x# `neChar#` x#" forall x#. x# `neChar#` x# = False
 538 "x# `gtChar#` x#" forall x#. x# `gtChar#` x# = False
 539 "x# `geChar#` x#" forall x#. x# `geChar#` x# = True
 540 "x# `leChar#` x#" forall x#. x# `leChar#` x# = True
 541 "x# `ltChar#` x#" forall x#. x# `ltChar#` x# = False
 542   #-}
 543
 544 -- | The 'Prelude.toEnum' method restricted to the type 'Data.Char.Char'.
 545 chr :: Int -> Char
 546 chr (I# i#) | int2Word# i# `leWord#` int2Word# 0x10FFFF# = C# (chr# i#)
 547             | otherwise                                  = error "Prelude.chr: bad argument"
 548
 549 unsafeChr :: Int -> Char
 550 unsafeChr (I# i#) = C# (chr# i#)
 551
 552 -- | The 'Prelude.fromEnum' method restricted to the type 'Data.Char.Char'.
 553 ord :: Char -> Int
 554 ord (C# c#) = I# (ord# c#)
 555 \end{code}
 556
 557 String equality is used when desugaring pattern-matches against strings.
 558
 559 \begin{code}
 560 eqString :: String -> String -> Bool
 561 eqString []       []       = True
 562 eqString (c1:cs1) (c2:cs2) = c1 == c2 && cs1 `eqString` cs2
 563 eqString _        _        = False
 564
 565 {-# RULES "eqString" (==) = eqString #-}
 566 -- eqString also has a BuiltInRule in PrelRules.lhs:
 567 --      eqString (unpackCString# (Lit s1)) (unpackCString# (Lit s2) = s1==s2
 568 \end{code}
 569
 570
 571 %*********************************************************
 572 %*                                                      *
 573 \subsection{Type @Int@}
 574 %*                                                      *
 575 %*********************************************************
 576
 577 \begin{code}
 578 zeroInt, oneInt, twoInt, maxInt, minInt :: Int
 579 zeroInt = I# 0#
 580 oneInt  = I# 1#
 581 twoInt  = I# 2#
 582
 583 {- Seems clumsy. Should perhaps put minInt and MaxInt directly into MachDeps.h -}
 584 #if WORD_SIZE_IN_BITS == 31
 585 minInt  = I# (-0x40000000#)
 586 maxInt  = I# 0x3FFFFFFF#
 587 #elif WORD_SIZE_IN_BITS == 32
 588 minInt  = I# (-0x80000000#)
 589 maxInt  = I# 0x7FFFFFFF#
 590 #else
 591 minInt  = I# (-0x8000000000000000#)
 592 maxInt  = I# 0x7FFFFFFFFFFFFFFF#
 593 #endif
 594
 595 instance Eq Int where
 596     (==) = eqInt
 597     (/=) = neInt
 598
 599 instance Ord Int where
 600     compare = compareInt
 601     (<)     = ltInt
 602     (<=)    = leInt
 603     (>=)    = geInt
 604     (>)     = gtInt
 605
 606 compareInt :: Int -> Int -> Ordering
 607 (I# x#) `compareInt` (I# y#) = compareInt# x# y#
 608
 609 compareInt# :: Int# -> Int# -> Ordering
 610 compareInt# x# y#
 611     | x# <#  y# = LT
 612     | x# ==# y# = EQ
 613     | otherwise = GT
 614 \end{code}
 615
 616
 617 %*********************************************************
 618 %*                                                      *
 619 \subsection{The function type}
 620 %*                                                      *
 621 %*********************************************************
 622
 623 \begin{code}
 624 -- | Identity function.
 625 id                      :: a -> a
 626 id x                    =  x
 627
 628 -- | The call '(lazy e)' means the same as 'e', but 'lazy' has a
 629 -- magical strictness property: it is lazy in its first argument,
 630 -- even though its semantics is strict.
 631 lazy :: a -> a
 632 lazy x = x
 633 -- Implementation note: its strictness and unfolding are over-ridden
 634 -- by the definition in MkId.lhs; in both cases to nothing at all.
 635 -- That way, 'lazy' does not get inlined, and the strictness analyser
 636 -- sees it as lazy.  Then the worker/wrapper phase inlines it.
 637 -- Result: happiness
 638
 639
 640 -- | The call '(inline f)' reduces to 'f', but 'inline' has a BuiltInRule
 641 -- that tries to inline 'f' (if it has an unfolding) unconditionally
 642 -- The 'NOINLINE' pragma arranges that inline only gets inlined (and
 643 -- hence eliminated) late in compilation, after the rule has had
 644 -- a god chance to fire.
 645 inline :: a -> a
 646 {-# NOINLINE[0] inline #-}
 647 inline x = x
 648
 649 -- Assertion function.  This simply ignores its boolean argument.
 650 -- The compiler may rewrite it to @('assertError' line)@.
 651
 652 -- | If the first argument evaluates to 'True', then the result is the
 653 -- second argument.  Otherwise an 'AssertionFailed' exception is raised,
 654 -- containing a 'String' with the source file and line number of the
 655 -- call to 'assert'.
 656 --
 657 -- Assertions can normally be turned on or off with a compiler flag
 658 -- (for GHC, assertions are normally on unless optimisation is turned on
 659 -- with @-O@ or the @-fignore-asserts@
 660 -- option is given).  When assertions are turned off, the first
 661 -- argument to 'assert' is ignored, and the second argument is
 662 -- returned as the result.
 663
 664 --      SLPJ: in 5.04 etc 'assert' is in GHC.Prim,
 665 --      but from Template Haskell onwards it's simply
 666 --      defined here in Base.lhs
 667 assert :: Bool -> a -> a
 668 assert _pred r = r
 669
 670 breakpoint :: a -> a
 671 breakpoint r = r
 672
 673 breakpointCond :: Bool -> a -> a
 674 breakpointCond _ r = r
 675
 676 data Opaque = forall a. O a
 677
 678 -- | Constant function.
 679 const                   :: a -> b -> a
 680 const x _               =  x
 681
 682 -- | Function composition.
 683 {-# INLINE (.) #-}
 684 (.)       :: (b -> c) -> (a -> b) -> a -> c
 685 (.) f g = \x -> f (g x)
 686
 687 -- | @'flip' f@ takes its (first) two arguments in the reverse order of @f@.
 688 flip                    :: (a -> b -> c) -> b -> a -> c
 689 flip f x y              =  f y x
 690
 691 -- | Application operator.  This operator is redundant, since ordinary
 692 -- application @(f x)@ means the same as @(f '$' x)@. However, '$' has
 693 -- low, right-associative binding precedence, so it sometimes allows
 694 -- parentheses to be omitted; for example:
 695 --
 696 -- >     f $ g $ h x  =  f (g (h x))
 697 --
 698 -- It is also useful in higher-order situations, such as @'map' ('$' 0) xs@,
 699 -- or @'Data.List.zipWith' ('$') fs xs@.
 700 {-# INLINE ($) #-}
 701 ($)                     :: (a -> b) -> a -> b
 702 f $ x                   =  f x
 703
 704 -- | @'until' p f@ yields the result of applying @f@ until @p@ holds.
 705 until                   :: (a -> Bool) -> (a -> a) -> a -> a
 706 until p f x | p x       =  x
 707             | otherwise =  until p f (f x)
 708
 709 -- | 'asTypeOf' is a type-restricted version of 'const'.  It is usually
 710 -- used as an infix operator, and its typing forces its first argument
 711 -- (which is usually overloaded) to have the same type as the second.
 712 asTypeOf                :: a -> a -> a
 713 asTypeOf                =  const
 714 \end{code}
 715
 716 %*********************************************************
 717 %*                                                      *
 718 \subsection{@getTag@}
 719 %*                                                      *
 720 %*********************************************************
 721
 722 Returns the 'tag' of a constructor application; this function is used
 723 by the deriving code for Eq, Ord and Enum.
 724
 725 The primitive dataToTag# requires an evaluated constructor application
 726 as its argument, so we provide getTag as a wrapper that performs the
 727 evaluation before calling dataToTag#.  We could have dataToTag#
 728 evaluate its argument, but we prefer to do it this way because (a)
 729 dataToTag# can be an inline primop if it doesn't need to do any
 730 evaluation, and (b) we want to expose the evaluation to the
 731 simplifier, because it might be possible to eliminate the evaluation
 732 in the case when the argument is already known to be evaluated.
 733
 734 \begin{code}
 735 {-# INLINE getTag #-}
 736 getTag :: a -> Int#
 737 getTag x = x `seq` dataToTag# x
 738 \end{code}
 739
 740 %*********************************************************
 741 %*                                                      *
 742 \subsection{Numeric primops}
 743 %*                                                      *
 744 %*********************************************************
 745
 746 \begin{code}
 747 divInt# :: Int# -> Int# -> Int#
 748 x# `divInt#` y#
 749         -- Be careful NOT to overflow if we do any additional arithmetic
 750         -- on the arguments...  the following  previous version of this
 751         -- code has problems with overflow:
 752 --    | (x# ># 0#) && (y# <# 0#) = ((x# -# y#) -# 1#) `quotInt#` y#
 753 --    | (x# <# 0#) && (y# ># 0#) = ((x# -# y#) +# 1#) `quotInt#` y#
 754     | (x# ># 0#) && (y# <# 0#) = ((x# -# 1#) `quotInt#` y#) -# 1#
 755     | (x# <# 0#) && (y# ># 0#) = ((x# +# 1#) `quotInt#` y#) -# 1#
 756     | otherwise                = x# `quotInt#` y#
 757
 758 modInt# :: Int# -> Int# -> Int#
 759 x# `modInt#` y#
 760     | (x# ># 0#) && (y# <# 0#) ||
 761       (x# <# 0#) && (y# ># 0#)    = if r# /=# 0# then r# +# y# else 0#
 762     | otherwise                   = r#
 763     where
 764     r# = x# `remInt#` y#
 765 \end{code}
 766
 767 Definitions of the boxed PrimOps; these will be
 768 used in the case of partial applications, etc.
 769
 770 \begin{code}
 771 {-# INLINE eqInt #-}
 772 {-# INLINE neInt #-}
 773 {-# INLINE gtInt #-}
 774 {-# INLINE geInt #-}
 775 {-# INLINE ltInt #-}
 776 {-# INLINE leInt #-}
 777 {-# INLINE plusInt #-}
 778 {-# INLINE minusInt #-}
 779 {-# INLINE timesInt #-}
 780 {-# INLINE quotInt #-}
 781 {-# INLINE remInt #-}
 782 {-# INLINE negateInt #-}
 783
 784 plusInt, minusInt, timesInt, quotInt, remInt, divInt, modInt, gcdInt :: Int -> Int -> Int
 785 (I# x) `plusInt`  (I# y) = I# (x +# y)
 786 (I# x) `minusInt` (I# y) = I# (x -# y)
 787 (I# x) `timesInt` (I# y) = I# (x *# y)
 788 (I# x) `quotInt`  (I# y) = I# (x `quotInt#` y)
 789 (I# x) `remInt`   (I# y) = I# (x `remInt#`  y)
 790 (I# x) `divInt`   (I# y) = I# (x `divInt#`  y)
 791 (I# x) `modInt`   (I# y) = I# (x `modInt#`  y)
 792
 793 {-# RULES
 794 "x# +# 0#" forall x#. x# +# 0# = x#
 795 "0# +# x#" forall x#. 0# +# x# = x#
 796 "x# -# 0#" forall x#. x# -# 0# = x#
 797 "x# -# x#" forall x#. x# -# x# = 0#
 798 "x# *# 0#" forall x#. x# *# 0# = 0#
 799 "0# *# x#" forall x#. 0# *# x# = 0#
 800 "x# *# 1#" forall x#. x# *# 1# = x#
 801 "1# *# x#" forall x#. 1# *# x# = x#
 802   #-}
 803
 804 gcdInt (I# a) (I# b) = g a b
 805    where g 0# 0# = error "GHC.Base.gcdInt: gcd 0 0 is undefined"
 806          g 0# _  = I# absB
 807          g _  0# = I# absA
 808          g _  _  = I# (gcdInt# absA absB)
 809
 810          absInt x = if x <# 0# then negateInt# x else x
 811
 812          absA     = absInt a
 813          absB     = absInt b
 814
 815 negateInt :: Int -> Int
 816 negateInt (I# x) = I# (negateInt# x)
 817
 818 gtInt, geInt, eqInt, neInt, ltInt, leInt :: Int -> Int -> Bool
 819 (I# x) `gtInt` (I# y) = x >#  y
 820 (I# x) `geInt` (I# y) = x >=# y
 821 (I# x) `eqInt` (I# y) = x ==# y
 822 (I# x) `neInt` (I# y) = x /=# y
 823 (I# x) `ltInt` (I# y) = x <#  y
 824 (I# x) `leInt` (I# y) = x <=# y
 825
 826 {-# RULES
 827 "x# ># x#"  forall x#. x# >#  x# = False
 828 "x# >=# x#" forall x#. x# >=# x# = True
 829 "x# ==# x#" forall x#. x# ==# x# = True
 830 "x# /=# x#" forall x#. x# /=# x# = False
 831 "x# <# x#"  forall x#. x# <#  x# = False
 832 "x# <=# x#" forall x#. x# <=# x# = True
 833   #-}
 834
 835 {-# RULES
 836 "plusFloat x 0.0"   forall x#. plusFloat#  x#   0.0# = x#
 837 "plusFloat 0.0 x"   forall x#. plusFloat#  0.0# x#   = x#
 838 "minusFloat x 0.0"  forall x#. minusFloat# x#   0.0# = x#
 839 "minusFloat x x"    forall x#. minusFloat# x#   x#   = 0.0#
 840 "timesFloat x 0.0"  forall x#. timesFloat# x#   0.0# = 0.0#
 841 "timesFloat0.0 x"   forall x#. timesFloat# 0.0# x#   = 0.0#
 842 "timesFloat x 1.0"  forall x#. timesFloat# x#   1.0# = x#
 843 "timesFloat 1.0 x"  forall x#. timesFloat# 1.0# x#   = x#
 844 "divideFloat x 1.0" forall x#. divideFloat# x#  1.0# = x#
 845   #-}
 846
 847 {-# RULES
 848 "plusDouble x 0.0"   forall x#. (+##) x#    0.0## = x#
 849 "plusDouble 0.0 x"   forall x#. (+##) 0.0## x#    = x#
 850 "minusDouble x 0.0"  forall x#. (-##) x#    0.0## = x#
 851 "timesDouble x 1.0"  forall x#. (*##) x#    1.0## = x#
 852 "timesDouble 1.0 x"  forall x#. (*##) 1.0## x#    = x#
 853 "divideDouble x 1.0" forall x#. (/##) x#    1.0## = x#
 854   #-}
 855
 856 {-
 857 We'd like to have more rules, but for example:
 858
 859 This gives wrong answer (0) for NaN - NaN (should be NaN):
 860     "minusDouble x x"    forall x#. (-##) x#    x#    = 0.0##
 861
 862 This gives wrong answer (0) for 0 * NaN (should be NaN):
 863     "timesDouble 0.0 x"  forall x#. (*##) 0.0## x#    = 0.0##
 864
 865 This gives wrong answer (0) for NaN * 0 (should be NaN):
 866     "timesDouble x 0.0"  forall x#. (*##) x#    0.0## = 0.0##
 867
 868 These are tested by num014.
 869 -}
 870
 871 -- Wrappers for the shift operations.  The uncheckedShift# family are
 872 -- undefined when the amount being shifted by is greater than the size
 873 -- in bits of Int#, so these wrappers perform a check and return
 874 -- either zero or -1 appropriately.
 875 --
 876 -- Note that these wrappers still produce undefined results when the
 877 -- second argument (the shift amount) is negative.
 878
 879 -- | Shift the argument left by the specified number of bits
 880 -- (which must be non-negative).
 881 shiftL# :: Word# -> Int# -> Word#
 882 a `shiftL#` b   | b >=# WORD_SIZE_IN_BITS# = int2Word# 0#
 883                 | otherwise                = a `uncheckedShiftL#` b
 884
 885 -- | Shift the argument right by the specified number of bits
 886 -- (which must be non-negative).
 887 shiftRL# :: Word# -> Int# -> Word#
 888 a `shiftRL#` b  | b >=# WORD_SIZE_IN_BITS# = int2Word# 0#
 889                 | otherwise                = a `uncheckedShiftRL#` b
 890
 891 -- | Shift the argument left by the specified number of bits
 892 -- (which must be non-negative).
 893 iShiftL# :: Int# -> Int# -> Int#
 894 a `iShiftL#` b  | b >=# WORD_SIZE_IN_BITS# = 0#
 895                 | otherwise                = a `uncheckedIShiftL#` b
 896
 897 -- | Shift the argument right (signed) by the specified number of bits
 898 -- (which must be non-negative).
 899 iShiftRA# :: Int# -> Int# -> Int#
 900 a `iShiftRA#` b | b >=# WORD_SIZE_IN_BITS# = if a <# 0# then (-1#) else 0#
 901                 | otherwise                = a `uncheckedIShiftRA#` b
 902
 903 -- | Shift the argument right (unsigned) by the specified number of bits
 904 -- (which must be non-negative).
 905 iShiftRL# :: Int# -> Int# -> Int#
 906 a `iShiftRL#` b | b >=# WORD_SIZE_IN_BITS# = 0#
 907                 | otherwise                = a `uncheckedIShiftRL#` b
 908
 909 #if WORD_SIZE_IN_BITS == 32
 910 {-# RULES
 911 "narrow32Int#"  forall x#. narrow32Int#   x# = x#
 912 "narrow32Word#" forall x#. narrow32Word#   x# = x#
 913    #-}
 914 #endif
 915
 916 {-# RULES
 917 "int2Word2Int"  forall x#. int2Word# (word2Int# x#) = x#
 918 "word2Int2Word" forall x#. word2Int# (int2Word# x#) = x#
 919   #-}
 920 \end{code}
 921
 922
 923 %********************************************************
 924 %*                                                      *
 925 \subsection{Unpacking C strings}
 926 %*                                                      *
 927 %********************************************************
 928
 929 This code is needed for virtually all programs, since it's used for
 930 unpacking the strings of error messages.
 931
 932 Note [Inlining for unpacking C strings]
 933 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 934 We use NOINLINE on unpackCString# and unpackFoldrCString# because
 935 there is little or no gain from inlining them -- and there may be a
 936 lot of calls (one for each literal string).
 937
 938 \begin{code}
 939 unpackCString# :: Addr# -> [Char]
 940 {-# NOINLINE unpackCString# #-}
 941 -- See Note [Inlining for unpacking C strings]
 942 unpackCString# addr
 943   = unpack 0#
 944   where
 945     unpack nh
 946       | ch `eqChar#` '\0'# = []
 947       | otherwise          = C# ch : unpack (nh +# 1#)
 948       where
 949         ch = indexCharOffAddr# addr nh
 950
 951 unpackAppendCString# :: Addr# -> [Char] -> [Char]
 952 unpackAppendCString# addr rest
 953   = unpack 0#
 954   where
 955     unpack nh
 956       | ch `eqChar#` '\0'# = rest
 957       | otherwise          = C# ch : unpack (nh +# 1#)
 958       where
 959         ch = indexCharOffAddr# addr nh
 960
 961 unpackFoldrCString# :: Addr# -> (Char  -> a -> a) -> a -> a
 962 {-# NOINLINE unpackFoldrCString# #-}
 963 -- See Note [Inlining for unpacking C strings]
 964 -- Usually the unpack-list rule turns it into unpackCString#
 965 -- It also has a BuiltInRule in PrelRules.lhs:
 966 --      unpackFoldrCString# "foo" c (unpackFoldrCString# "baz" c n)
 967 --        =  unpackFoldrCString# "foobaz" c n
 968 unpackFoldrCString# addr f z
 969   = unpack 0#
 970   where
 971     unpack nh
 972       | ch `eqChar#` '\0'# = z
 973       | otherwise          = C# ch `f` unpack (nh +# 1#)
 974       where
 975         ch = indexCharOffAddr# addr nh
 976
 977 unpackCStringUtf8# :: Addr# -> [Char]
 978 unpackCStringUtf8# addr
 979   = unpack 0#
 980   where
 981     unpack nh
 982       | ch `eqChar#` '\0'#   = []
 983       | ch `leChar#` '\x7F'# = C# ch : unpack (nh +# 1#)
 984       | ch `leChar#` '\xDF'# =
 985           C# (chr# (((ord# ch                                  -# 0xC0#) `uncheckedIShiftL#`  6#) +#
 986                      (ord# (indexCharOffAddr# addr (nh +# 1#)) -# 0x80#))) :
 987           unpack (nh +# 2#)
 988       | ch `leChar#` '\xEF'# =
 989           C# (chr# (((ord# ch                                  -# 0xE0#) `uncheckedIShiftL#` 12#) +#
 990                     ((ord# (indexCharOffAddr# addr (nh +# 1#)) -# 0x80#) `uncheckedIShiftL#`  6#) +#
 991                      (ord# (indexCharOffAddr# addr (nh +# 2#)) -# 0x80#))) :
 992           unpack (nh +# 3#)
 993       | otherwise            =
 994           C# (chr# (((ord# ch                                  -# 0xF0#) `uncheckedIShiftL#` 18#) +#
 995                     ((ord# (indexCharOffAddr# addr (nh +# 1#)) -# 0x80#) `uncheckedIShiftL#` 12#) +#
 996                     ((ord# (indexCharOffAddr# addr (nh +# 2#)) -# 0x80#) `uncheckedIShiftL#`  6#) +#
 997                      (ord# (indexCharOffAddr# addr (nh +# 3#)) -# 0x80#))) :
 998           unpack (nh +# 4#)
 999       where
1000         ch = indexCharOffAddr# addr nh
1001
1002 unpackNBytes# :: Addr# -> Int# -> [Char]
1003 unpackNBytes# _addr 0#   = []
1004 unpackNBytes#  addr len# = unpack [] (len# -# 1#)
1005     where
1006      unpack acc i#
1007       | i# <# 0#  = acc
1008       | otherwise =
1009          case indexCharOffAddr# addr i# of
1010             ch -> unpack (C# ch : acc) (i# -# 1#)
1011
1012 {-# RULES
1013 "unpack"       [~1] forall a   . unpackCString# a             = build (unpackFoldrCString# a)
1014 "unpack-list"  [1]  forall a   . unpackFoldrCString# a (:) [] = unpackCString# a
1015 "unpack-append"     forall a n . unpackFoldrCString# a (:) n  = unpackAppendCString# a n
1016
1017 -- There's a built-in rule (in PrelRules.lhs) for
1018 --      unpackFoldr "foo" c (unpackFoldr "baz" c n)  =  unpackFoldr "foobaz" c n
1019
1020   #-}
1021 \end{code}
1022
1023 #ifdef __HADDOCK__
1024 \begin{code}
1025 -- | A special argument for the 'Control.Monad.ST.ST' type constructor,
1026 -- indexing a state embedded in the 'Prelude.IO' monad by
1027 -- 'Control.Monad.ST.stToIO'.
1028 data RealWorld
1029 \end{code}
1030 #endif