GHC/Base.lhs

   1 \section[GHC.Base]{Module @GHC.Base@}
   2
   3 The overall structure of the GHC Prelude is a bit tricky.
   4
   5   a) We want to avoid "orphan modules", i.e. ones with instance
   6         decls that don't belong either to a tycon or a class
   7         defined in the same module
   8
   9   b) We want to avoid giant modules
  10
  11 So the rough structure is as follows, in (linearised) dependency order
  12
  13
  14 GHC.Prim                Has no implementation.  It defines built-in things, and
  15                 by importing it you bring them into scope.
  16                 The source file is GHC.Prim.hi-boot, which is just
  17                 copied to make GHC.Prim.hi
  18
  19                 Classes: CCallable, CReturnable
  20
  21 GHC.Base        Classes: Eq, Ord, Functor, Monad
  22                 Types:   list, (), Int, Bool, Ordering, Char, String
  23
  24 Data.Tup        Types: tuples, plus instances for GHC.Base classes
  25
  26 GHC.Show        Class: Show, plus instances for GHC.Base/GHC.Tup types
  27
  28 GHC.Enum        Class: Enum,  plus instances for GHC.Base/GHC.Tup types
  29
  30 Data.Maybe      Type: Maybe, plus instances for GHC.Base classes
  31
  32 GHC.Num         Class: Num, plus instances for Int
  33                 Type:  Integer, plus instances for all classes so far (Eq, Ord, Num, Show)
  34
  35                 Integer is needed here because it is mentioned in the signature
  36                 of 'fromInteger' in class Num
  37
  38 GHC.Real        Classes: Real, Integral, Fractional, RealFrac
  39                          plus instances for Int, Integer
  40                 Types:  Ratio, Rational
  41                         plus intances for classes so far
  42
  43                 Rational is needed here because it is mentioned in the signature
  44                 of 'toRational' in class Real
  45
  46 Ix              Classes: Ix, plus instances for Int, Bool, Char, Integer, Ordering, tuples
  47
  48 GHC.Arr         Types: Array, MutableArray, MutableVar
  49
  50                 Does *not* contain any ByteArray stuff (see GHC.ByteArr)
  51                 Arrays are used by a function in GHC.Float
  52
  53 GHC.Float       Classes: Floating, RealFloat
  54                 Types:   Float, Double, plus instances of all classes so far
  55
  56                 This module contains everything to do with floating point.
  57                 It is a big module (900 lines)
  58                 With a bit of luck, many modules can be compiled without ever reading GHC.Float.hi
  59
  60 GHC.ByteArr     Types: ByteArray, MutableByteArray
  61
  62                 We want this one to be after GHC.Float, because it defines arrays
  63                 of unboxed floats.
  64
  65
  66 Other Prelude modules are much easier with fewer complex dependencies.
  67
  68 \begin{code}
  69 {-# OPTIONS -fno-implicit-prelude #-}
  70 -----------------------------------------------------------------------------
  71 -- |
  72 -- Module      :  GHC.Base
  73 -- Copyright   :  (c) The University of Glasgow, 1992-2002
  74 -- License     :  see libraries/base/LICENSE
  75 --
  76 -- Maintainer  :  cvs-ghc@haskell.org
  77 -- Stability   :  internal
  78 -- Portability :  non-portable (GHC extensions)
  79 --
  80 -- Basic data types and classes.
  81 --
  82 -----------------------------------------------------------------------------
  83
  84 #include "MachDeps.h"
  85
  86 module GHC.Base
  87         (
  88         module GHC.Base,
  89         module GHC.Prim,        -- Re-export GHC.Prim and GHC.Err, to avoid lots
  90         module GHC.Err          -- of people having to import it explicitly
  91   )
  92         where
  93
  94 import GHC.Prim
  95 import {-# SOURCE #-} GHC.Err
  96
  97 infixr 9  .
  98 infixr 5  ++, :
  99 infix  4  ==, /=, <, <=, >=, >
 100 infixr 3  &&
 101 infixr 2  ||
 102 infixl 1  >>, >>=
 103 infixr 0  $
 104
 105 default ()              -- Double isn't available yet
 106 \end{code}
 107
 108
 109 %*********************************************************
 110 %*                                                      *
 111 \subsection{DEBUGGING STUFF}
 112 %*  (for use when compiling GHC.Base itself doesn't work)
 113 %*                                                      *
 114 %*********************************************************
 115
 116 \begin{code}
 117 {-
 118 data  Bool  =  False | True
 119 data Ordering = LT | EQ | GT
 120 data Char = C# Char#
 121 type  String = [Char]
 122 data Int = I# Int#
 123 data  ()  =  ()
 124 data [] a = MkNil
 125
 126 not True = False
 127 (&&) True True = True
 128 otherwise = True
 129
 130 build = error "urk"
 131 foldr = error "urk"
 132
 133 unpackCString# :: Addr# -> [Char]
 134 unpackFoldrCString# :: Addr# -> (Char  -> a -> a) -> a -> a
 135 unpackAppendCString# :: Addr# -> [Char] -> [Char]
 136 unpackCStringUtf8# :: Addr# -> [Char]
 137 unpackCString# a = error "urk"
 138 unpackFoldrCString# a = error "urk"
 139 unpackAppendCString# a = error "urk"
 140 unpackCStringUtf8# a = error "urk"
 141 -}
 142 \end{code}
 143
 144
 145 %*********************************************************
 146 %*                                                      *
 147 \subsection{Standard classes @Eq@, @Ord@}
 148 %*                                                      *
 149 %*********************************************************
 150
 151 \begin{code}
 152
 153 -- | The 'Eq' class defines equality ('==') and inequality ('/=').
 154 -- All the basic datatypes exported by the "Prelude" are instances of 'Eq',
 155 -- and 'Eq' may be derived for any datatype whose constituents are also
 156 -- instances of 'Eq'.
 157 --
 158 -- Minimal complete definition: either '==' or '/='.
 159 --
 160 class  Eq a  where
 161     (==), (/=)           :: a -> a -> Bool
 162
 163     x /= y               = not (x == y)
 164     x == y               = not (x /= y)
 165
 166 class  (Eq a) => Ord a  where
 167     compare              :: a -> a -> Ordering
 168     (<), (<=), (>), (>=) :: a -> a -> Bool
 169     max, min             :: a -> a -> a
 170
 171     -- An instance of Ord should define either 'compare' or '<='.
 172     -- Using 'compare' can be more efficient for complex types.
 173
 174     compare x y
 175         | x == y    = EQ
 176         | x <= y    = LT        -- NB: must be '<=' not '<' to validate the
 177                                 -- above claim about the minimal things that
 178                                 -- can be defined for an instance of Ord
 179         | otherwise = GT
 180
 181     x <  y = case compare x y of { LT -> True;  _other -> False }
 182     x <= y = case compare x y of { GT -> False; _other -> True }
 183     x >  y = case compare x y of { GT -> True;  _other -> False }
 184     x >= y = case compare x y of { LT -> False; _other -> True }
 185
 186         -- These two default methods use '<=' rather than 'compare'
 187         -- because the latter is often more expensive
 188     max x y = if x <= y then y else x
 189     min x y = if x <= y then x else y
 190 \end{code}
 191
 192 %*********************************************************
 193 %*                                                      *
 194 \subsection{Monadic classes @Functor@, @Monad@ }
 195 %*                                                      *
 196 %*********************************************************
 197
 198 \begin{code}
 199 {- | The 'Functor' class is used for types that can be mapped over.
 200 Instances of 'Functor' should satisfy the following laws:
 201
 202 > fmap id  ==  id
 203 > fmap (f . g)  ==  fmap f . fmap g
 204
 205 The instances of 'Functor' for lists, 'Maybe' and 'IO' defined in the "Prelude"
 206 satisfy these laws.
 207 -}
 208
 209 class  Functor f  where
 210     fmap        :: (a -> b) -> f a -> f b
 211
 212 {- | The 'Monad' class defines the basic operations over a /monad/.
 213 Instances of 'Monad' should satisfy the following laws:
 214
 215 > return a >>= k  ==  k a
 216 > m >>= return  ==  m
 217 > m >>= (\x -> k x >>= h)  ==  (m >>= k) >>= h
 218
 219 Instances of both 'Monad' and 'Functor' should additionally satisfy the law:
 220
 221 > fmap f xs  ==  xs >>= return . f
 222
 223 The instances of 'Monad' for lists, 'Maybe' and 'IO' defined in the "Prelude"
 224 satisfy these laws.
 225 -}
 226
 227 class  Monad m  where
 228     (>>=)       :: m a -> (a -> m b) -> m b
 229     (>>)        :: m a -> m b -> m b
 230     return      :: a -> m a
 231     fail        :: String -> m a
 232
 233     m >> k      = m >>= \_ -> k
 234     fail s      = error s
 235 \end{code}
 236
 237
 238 %*********************************************************
 239 %*                                                      *
 240 \subsection{The list type}
 241 %*                                                      *
 242 %*********************************************************
 243
 244 \begin{code}
 245 data [] a = [] | a : [a]  -- do explicitly: deriving (Eq, Ord)
 246                           -- to avoid weird names like con2tag_[]#
 247
 248
 249 instance (Eq a) => Eq [a] where
 250     {-# SPECIALISE instance Eq [Char] #-}
 251     []     == []     = True
 252     (x:xs) == (y:ys) = x == y && xs == ys
 253     _xs    == _ys    = False
 254
 255 instance (Ord a) => Ord [a] where
 256     {-# SPECIALISE instance Ord [Char] #-}
 257     compare []     []     = EQ
 258     compare []     (_:_)  = LT
 259     compare (_:_)  []     = GT
 260     compare (x:xs) (y:ys) = case compare x y of
 261                                 EQ    -> compare xs ys
 262                                 other -> other
 263
 264 instance Functor [] where
 265     fmap = map
 266
 267 instance  Monad []  where
 268     m >>= k             = foldr ((++) . k) [] m
 269     m >> k              = foldr ((++) . (\ _ -> k)) [] m
 270     return x            = [x]
 271     fail _              = []
 272 \end{code}
 273
 274 A few list functions that appear here because they are used here.
 275 The rest of the prelude list functions are in GHC.List.
 276
 277 ----------------------------------------------
 278 --      foldr/build/augment
 279 ----------------------------------------------
 280
 281 \begin{code}
 282 foldr            :: (a -> b -> b) -> b -> [a] -> b
 283 -- foldr _ z []     =  z
 284 -- foldr f z (x:xs) =  f x (foldr f z xs)
 285 {-# INLINE [0] foldr #-}
 286 -- Inline only in the final stage, after the foldr/cons rule has had a chance
 287 foldr k z xs = go xs
 288              where
 289                go []     = z
 290                go (y:ys) = y `k` go ys
 291
 292 build   :: forall a. (forall b. (a -> b -> b) -> b -> b) -> [a]
 293 {-# INLINE [1] build #-}
 294         -- The INLINE is important, even though build is tiny,
 295         -- because it prevents [] getting inlined in the version that
 296         -- appears in the interface file.  If [] *is* inlined, it
 297         -- won't match with [] appearing in rules in an importing module.
 298         --
 299         -- The "1" says to inline in phase 1
 300
 301 build g = g (:) []
 302
 303 augment :: forall a. (forall b. (a->b->b) -> b -> b) -> [a] -> [a]
 304 {-# INLINE [1] augment #-}
 305 augment g xs = g (:) xs
 306
 307 {-# RULES
 308 "fold/build"    forall k z (g::forall b. (a->b->b) -> b -> b) .
 309                 foldr k z (build g) = g k z
 310
 311 "foldr/augment" forall k z xs (g::forall b. (a->b->b) -> b -> b) .
 312                 foldr k z (augment g xs) = g k (foldr k z xs)
 313
 314 "foldr/id"                        foldr (:) [] = \x->x
 315 "foldr/app"     [1] forall xs ys. foldr (:) ys xs = xs ++ ys
 316         -- Only activate this from phase 1, because that's
 317         -- when we disable the rule that expands (++) into foldr
 318
 319 -- The foldr/cons rule looks nice, but it can give disastrously
 320 -- bloated code when commpiling
 321 --      array (a,b) [(1,2), (2,2), (3,2), ...very long list... ]
 322 -- i.e. when there are very very long literal lists
 323 -- So I've disabled it for now. We could have special cases
 324 -- for short lists, I suppose.
 325 -- "foldr/cons" forall k z x xs. foldr k z (x:xs) = k x (foldr k z xs)
 326
 327 "foldr/single"  forall k z x. foldr k z [x] = k x z
 328 "foldr/nil"     forall k z.   foldr k z []  = z
 329
 330 "augment/build" forall (g::forall b. (a->b->b) -> b -> b)
 331                        (h::forall b. (a->b->b) -> b -> b) .
 332                        augment g (build h) = build (\c n -> g c (h c n))
 333 "augment/nil"   forall (g::forall b. (a->b->b) -> b -> b) .
 334                         augment g [] = build g
 335  #-}
 336
 337 -- This rule is true, but not (I think) useful:
 338 --      augment g (augment h t) = augment (\cn -> g c (h c n)) t
 339 \end{code}
 340
 341
 342 ----------------------------------------------
 343 --              map
 344 ----------------------------------------------
 345
 346 \begin{code}
 347 map :: (a -> b) -> [a] -> [b]
 348 map _ []     = []
 349 map f (x:xs) = f x : map f xs
 350
 351 -- Note eta expanded
 352 mapFB ::  (elt -> lst -> lst) -> (a -> elt) -> a -> lst -> lst
 353 {-# INLINE [0] mapFB #-}
 354 mapFB c f x ys = c (f x) ys
 355
 356 -- The rules for map work like this.
 357 --
 358 -- Up to (but not including) phase 1, we use the "map" rule to
 359 -- rewrite all saturated applications of map with its build/fold
 360 -- form, hoping for fusion to happen.
 361 -- In phase 1 and 0, we switch off that rule, inline build, and
 362 -- switch on the "mapList" rule, which rewrites the foldr/mapFB
 363 -- thing back into plain map.
 364 --
 365 -- It's important that these two rules aren't both active at once
 366 -- (along with build's unfolding) else we'd get an infinite loop
 367 -- in the rules.  Hence the activation control below.
 368 --
 369 -- The "mapFB" rule optimises compositions of map.
 370 --
 371 -- This same pattern is followed by many other functions:
 372 -- e.g. append, filter, iterate, repeat, etc.
 373
 374 {-# RULES
 375 "map"       [~1] forall f xs.   map f xs                = build (\c n -> foldr (mapFB c f) n xs)
 376 "mapList"   [1]  forall f.      foldr (mapFB (:) f) []  = map f
 377 "mapFB"     forall c f g.       mapFB (mapFB c f) g     = mapFB c (f.g)
 378   #-}
 379 \end{code}
 380
 381
 382 ----------------------------------------------
 383 --              append
 384 ----------------------------------------------
 385 \begin{code}
 386 (++) :: [a] -> [a] -> [a]
 387 (++) []     ys = ys
 388 (++) (x:xs) ys = x : xs ++ ys
 389
 390 {-# RULES
 391 "++"    [~1] forall xs ys. xs ++ ys = augment (\c n -> foldr c n xs) ys
 392   #-}
 393
 394 \end{code}
 395
 396
 397 %*********************************************************
 398 %*                                                      *
 399 \subsection{Type @Bool@}
 400 %*                                                      *
 401 %*********************************************************
 402
 403 \begin{code}
 404 -- |The 'Bool' type is an enumeration.  It is defined with 'False'
 405 -- first so that the corresponding 'Prelude.Enum' instance will give
 406 -- 'Prelude.fromEnum' 'False' the value zero, and
 407 -- 'Prelude.fromEnum' 'True' the value 1.
 408 data  Bool  =  False | True  deriving (Eq, Ord)
 409         -- Read in GHC.Read, Show in GHC.Show
 410
 411 -- Boolean functions
 412
 413 -- | Boolean \"and\"
 414 (&&)                    :: Bool -> Bool -> Bool
 415 True  && x              =  x
 416 False && _              =  False
 417
 418 -- | Boolean \"or\"
 419 (||)                    :: Bool -> Bool -> Bool
 420 True  || _              =  True
 421 False || x              =  x
 422
 423 -- | Boolean \"not\"
 424 not                     :: Bool -> Bool
 425 not True                =  False
 426 not False               =  True
 427
 428 -- |'otherwise' is defined as the value 'True'.  It helps to make
 429 -- guards more readable.  eg.
 430 --
 431 -- >  f x | x < 0     = ...
 432 -- >      | otherwise = ...
 433 otherwise               :: Bool
 434 otherwise               =  True
 435 \end{code}
 436
 437
 438 %*********************************************************
 439 %*                                                      *
 440 \subsection{The @()@ type}
 441 %*                                                      *
 442 %*********************************************************
 443
 444 The Unit type is here because virtually any program needs it (whereas
 445 some programs may get away without consulting GHC.Tup).  Furthermore,
 446 the renamer currently *always* asks for () to be in scope, so that
 447 ccalls can use () as their default type; so when compiling GHC.Base we
 448 need ().  (We could arrange suck in () only if -fglasgow-exts, but putting
 449 it here seems more direct.)
 450
 451 \begin{code}
 452 -- | The unit datatype @()@ has one non-undefined member, the nullary
 453 -- constructor @()@.
 454 data () = ()
 455
 456 instance Eq () where
 457     () == () = True
 458     () /= () = False
 459
 460 instance Ord () where
 461     () <= () = True
 462     () <  () = False
 463     () >= () = True
 464     () >  () = False
 465     max () () = ()
 466     min () () = ()
 467     compare () () = EQ
 468 \end{code}
 469
 470
 471 %*********************************************************
 472 %*                                                      *
 473 \subsection{Type @Ordering@}
 474 %*                                                      *
 475 %*********************************************************
 476
 477 \begin{code}
 478 -- | Represents an ordering relationship between two values: less
 479 -- than, equal to, or greater than.  An 'Ordering' is returned by
 480 -- 'compare'.
 481 data Ordering = LT | EQ | GT deriving (Eq, Ord)
 482         -- Read in GHC.Read, Show in GHC.Show
 483 \end{code}
 484
 485
 486 %*********************************************************
 487 %*                                                      *
 488 \subsection{Type @Char@ and @String@}
 489 %*                                                      *
 490 %*********************************************************
 491
 492 \begin{code}
 493 -- | A 'String' is a list of characters.  String constants in Haskell are values
 494 -- of type 'String'.
 495 --
 496 type String = [Char]
 497
 498 {-| The character type 'Char' is an enumeration whose values represent
 499 Unicode (or equivalently ISO 10646) characters.
 500 This set extends the ISO 8859-1 (Latin-1) character set
 501 (the first 256 charachers), which is itself an extension of the ASCII
 502 character set (the first 128 characters).
 503 A character literal in Haskell has type 'Char'.
 504
 505 To convert a 'Char' to or from the corresponding 'Int' value defined
 506 by Unicode, use 'Prelude.toEnum' and 'Prelude.fromEnum' from the
 507 'Prelude.Enum' class respectively (or equivalently 'ord' and 'chr').
 508 -}
 509 data Char = C# Char#
 510
 511 -- We don't use deriving for Eq and Ord, because for Ord the derived
 512 -- instance defines only compare, which takes two primops.  Then
 513 -- '>' uses compare, and therefore takes two primops instead of one.
 514
 515 instance Eq Char where
 516     (C# c1) == (C# c2) = c1 `eqChar#` c2
 517     (C# c1) /= (C# c2) = c1 `neChar#` c2
 518
 519 instance Ord Char where
 520     (C# c1) >  (C# c2) = c1 `gtChar#` c2
 521     (C# c1) >= (C# c2) = c1 `geChar#` c2
 522     (C# c1) <= (C# c2) = c1 `leChar#` c2
 523     (C# c1) <  (C# c2) = c1 `ltChar#` c2
 524
 525 {-# RULES
 526 "x# `eqChar#` x#" forall x#. x# `eqChar#` x# = True
 527 "x# `neChar#` x#" forall x#. x# `neChar#` x# = False
 528 "x# `gtChar#` x#" forall x#. x# `gtChar#` x# = False
 529 "x# `geChar#` x#" forall x#. x# `geChar#` x# = True
 530 "x# `leChar#` x#" forall x#. x# `leChar#` x# = True
 531 "x# `ltChar#` x#" forall x#. x# `ltChar#` x# = False
 532   #-}
 533
 534 -- | The 'Prelude.toEnum' method restricted to the type 'Data.Char.Char'.
 535 chr :: Int -> Char
 536 chr (I# i#) | int2Word# i# `leWord#` int2Word# 0x10FFFF# = C# (chr# i#)
 537             | otherwise                                  = error "Prelude.chr: bad argument"
 538
 539 unsafeChr :: Int -> Char
 540 unsafeChr (I# i#) = C# (chr# i#)
 541
 542 -- | The 'Prelude.fromEnum' method restricted to the type 'Data.Char.Char'.
 543 ord :: Char -> Int
 544 ord (C# c#) = I# (ord# c#)
 545 \end{code}
 546
 547 String equality is used when desugaring pattern-matches against strings.
 548
 549 \begin{code}
 550 eqString :: String -> String -> Bool
 551 eqString []       []       = True
 552 eqString (c1:cs1) (c2:cs2) = c1 == c2 && cs1 `eqString` cs2
 553 eqString cs1      cs2      = False
 554
 555 {-# RULES "eqString" (==) = eqString #-}
 556 \end{code}
 557
 558
 559 %*********************************************************
 560 %*                                                      *
 561 \subsection{Type @Int@}
 562 %*                                                      *
 563 %*********************************************************
 564
 565 \begin{code}
 566 data Int = I# Int#
 567 -- ^A fixed-precision integer type with at least the range @[-2^29
 568 -- .. 2^29-1]@.  The exact range for a given implementation can be
 569 -- determined by using 'minBound' and 'maxBound' from the 'Bounded'
 570 -- class.
 571
 572 zeroInt, oneInt, twoInt, maxInt, minInt :: Int
 573 zeroInt = I# 0#
 574 oneInt  = I# 1#
 575 twoInt  = I# 2#
 576
 577 {- Seems clumsy. Should perhaps put minInt and MaxInt directly into MachDeps.h -}
 578 #if WORD_SIZE_IN_BITS == 31
 579 minInt  = I# (-0x40000000#)
 580 maxInt  = I# 0x3FFFFFFF#
 581 #elif WORD_SIZE_IN_BITS == 32
 582 minInt  = I# (-0x80000000#)
 583 maxInt  = I# 0x7FFFFFFF#
 584 #else
 585 minInt  = I# (-0x8000000000000000#)
 586 maxInt  = I# 0x7FFFFFFFFFFFFFFF#
 587 #endif
 588
 589 instance Eq Int where
 590     (==) = eqInt
 591     (/=) = neInt
 592
 593 instance Ord Int where
 594     compare = compareInt
 595     (<)     = ltInt
 596     (<=)    = leInt
 597     (>=)    = geInt
 598     (>)     = gtInt
 599
 600 compareInt :: Int -> Int -> Ordering
 601 (I# x#) `compareInt` (I# y#) = compareInt# x# y#
 602
 603 compareInt# :: Int# -> Int# -> Ordering
 604 compareInt# x# y#
 605     | x# <#  y# = LT
 606     | x# ==# y# = EQ
 607     | otherwise = GT
 608 \end{code}
 609
 610
 611 %*********************************************************
 612 %*                                                      *
 613 \subsection{The function type}
 614 %*                                                      *
 615 %*********************************************************
 616
 617 \begin{code}
 618 -- identity function
 619 id                      :: a -> a
 620 id x                    =  x
 621
 622 -- lazy function; this is just the same as id, but its unfolding
 623 -- and strictness are over-ridden by the definition in MkId.lhs
 624 -- That way, it does not get inlined, and the strictness analyser
 625 -- sees it as lazy.  Then the worker/wrapper phase inlines it.
 626 -- Result: happiness
 627 lazy :: a -> a
 628 lazy x = x
 629
 630 -- Assertion function. This simply ignores its boolean argument.
 631 -- The compiler may rewrite it to (assertError line)
 632 --      SLPJ: in 5.04 etc 'assert' is in GHC.Prim,
 633 --      but from Template Haskell onwards it's simply
 634 --      defined here in Base.lhs
 635 assert :: Bool -> a -> a
 636 assert pred r = r
 637
 638 -- constant function
 639 const                   :: a -> b -> a
 640 const x _               =  x
 641
 642 -- function composition
 643 {-# INLINE (.) #-}
 644 (.)       :: (b -> c) -> (a -> b) -> a -> c
 645 (.) f g x = f (g x)
 646
 647 -- flip f  takes its (first) two arguments in the reverse order of f.
 648 flip                    :: (a -> b -> c) -> b -> a -> c
 649 flip f x y              =  f y x
 650
 651 -- right-associating infix application operator (useful in continuation-
 652 -- passing style)
 653 {-# INLINE ($) #-}
 654 ($)                     :: (a -> b) -> a -> b
 655 f $ x                   =  f x
 656
 657 -- until p f  yields the result of applying f until p holds.
 658 until                   :: (a -> Bool) -> (a -> a) -> a -> a
 659 until p f x | p x       =  x
 660             | otherwise =  until p f (f x)
 661
 662 -- asTypeOf is a type-restricted version of const.  It is usually used
 663 -- as an infix operator, and its typing forces its first argument
 664 -- (which is usually overloaded) to have the same type as the second.
 665 asTypeOf                :: a -> a -> a
 666 asTypeOf                =  const
 667 \end{code}
 668
 669 %*********************************************************
 670 %*                                                      *
 671 \subsection{CCallable instances}
 672 %*                                                      *
 673 %*********************************************************
 674
 675 Defined here to avoid orphans
 676
 677 \begin{code}
 678 instance CCallable Char
 679 instance CReturnable Char
 680
 681 instance CCallable   Int
 682 instance CReturnable Int
 683
 684 instance CReturnable () -- Why, exactly?
 685 \end{code}
 686
 687
 688 %*********************************************************
 689 %*                                                      *
 690 \subsection{Generics}
 691 %*                                                      *
 692 %*********************************************************
 693
 694 \begin{code}
 695 data Unit = Unit
 696 #ifndef __HADDOCK__
 697 data (:+:) a b = Inl a | Inr b
 698 data (:*:) a b = a :*: b
 699 #endif
 700 \end{code}
 701
 702 %*********************************************************
 703 %*                                                      *
 704 \subsection{@getTag@}
 705 %*                                                      *
 706 %*********************************************************
 707
 708 Returns the 'tag' of a constructor application; this function is used
 709 by the deriving code for Eq, Ord and Enum.
 710
 711 The primitive dataToTag# requires an evaluated constructor application
 712 as its argument, so we provide getTag as a wrapper that performs the
 713 evaluation before calling dataToTag#.  We could have dataToTag#
 714 evaluate its argument, but we prefer to do it this way because (a)
 715 dataToTag# can be an inline primop if it doesn't need to do any
 716 evaluation, and (b) we want to expose the evaluation to the
 717 simplifier, because it might be possible to eliminate the evaluation
 718 in the case when the argument is already known to be evaluated.
 719
 720 \begin{code}
 721 {-# INLINE getTag #-}
 722 getTag :: a -> Int#
 723 getTag x = x `seq` dataToTag# x
 724 \end{code}
 725
 726 %*********************************************************
 727 %*                                                      *
 728 \subsection{Numeric primops}
 729 %*                                                      *
 730 %*********************************************************
 731
 732 \begin{code}
 733 divInt# :: Int# -> Int# -> Int#
 734 x# `divInt#` y#
 735         -- Be careful NOT to overflow if we do any additional arithmetic
 736         -- on the arguments...  the following  previous version of this
 737         -- code has problems with overflow:
 738 --    | (x# ># 0#) && (y# <# 0#) = ((x# -# y#) -# 1#) `quotInt#` y#
 739 --    | (x# <# 0#) && (y# ># 0#) = ((x# -# y#) +# 1#) `quotInt#` y#
 740     | (x# ># 0#) && (y# <# 0#) = ((x# -# 1#) `quotInt#` y#) -# 1#
 741     | (x# <# 0#) && (y# ># 0#) = ((x# +# 1#) `quotInt#` y#) -# 1#
 742     | otherwise                = x# `quotInt#` y#
 743
 744 modInt# :: Int# -> Int# -> Int#
 745 x# `modInt#` y#
 746     | (x# ># 0#) && (y# <# 0#) ||
 747       (x# <# 0#) && (y# ># 0#)    = if r# /=# 0# then r# +# y# else 0#
 748     | otherwise                   = r#
 749     where
 750     r# = x# `remInt#` y#
 751 \end{code}
 752
 753 Definitions of the boxed PrimOps; these will be
 754 used in the case of partial applications, etc.
 755
 756 \begin{code}
 757 {-# INLINE eqInt #-}
 758 {-# INLINE neInt #-}
 759 {-# INLINE gtInt #-}
 760 {-# INLINE geInt #-}
 761 {-# INLINE ltInt #-}
 762 {-# INLINE leInt #-}
 763 {-# INLINE plusInt #-}
 764 {-# INLINE minusInt #-}
 765 {-# INLINE timesInt #-}
 766 {-# INLINE quotInt #-}
 767 {-# INLINE remInt #-}
 768 {-# INLINE negateInt #-}
 769
 770 plusInt, minusInt, timesInt, quotInt, remInt, divInt, modInt, gcdInt :: Int -> Int -> Int
 771 (I# x) `plusInt`  (I# y) = I# (x +# y)
 772 (I# x) `minusInt` (I# y) = I# (x -# y)
 773 (I# x) `timesInt` (I# y) = I# (x *# y)
 774 (I# x) `quotInt`  (I# y) = I# (x `quotInt#` y)
 775 (I# x) `remInt`   (I# y) = I# (x `remInt#`  y)
 776 (I# x) `divInt`   (I# y) = I# (x `divInt#`  y)
 777 (I# x) `modInt`   (I# y) = I# (x `modInt#`  y)
 778
 779 {-# RULES
 780 "x# +# 0#" forall x#. x# +# 0# = x#
 781 "0# +# x#" forall x#. 0# +# x# = x#
 782 "x# -# 0#" forall x#. x# -# 0# = x#
 783 "x# -# x#" forall x#. x# -# x# = 0#
 784 "x# *# 0#" forall x#. x# *# 0# = 0#
 785 "0# *# x#" forall x#. 0# *# x# = 0#
 786 "x# *# 1#" forall x#. x# *# 1# = x#
 787 "1# *# x#" forall x#. 1# *# x# = x#
 788   #-}
 789
 790 gcdInt (I# a) (I# b) = g a b
 791    where g 0# 0# = error "GHC.Base.gcdInt: gcd 0 0 is undefined"
 792          g 0# _  = I# absB
 793          g _  0# = I# absA
 794          g _  _  = I# (gcdInt# absA absB)
 795
 796          absInt x = if x <# 0# then negateInt# x else x
 797
 798          absA     = absInt a
 799          absB     = absInt b
 800
 801 negateInt :: Int -> Int
 802 negateInt (I# x) = I# (negateInt# x)
 803
 804 gtInt, geInt, eqInt, neInt, ltInt, leInt :: Int -> Int -> Bool
 805 (I# x) `gtInt` (I# y) = x >#  y
 806 (I# x) `geInt` (I# y) = x >=# y
 807 (I# x) `eqInt` (I# y) = x ==# y
 808 (I# x) `neInt` (I# y) = x /=# y
 809 (I# x) `ltInt` (I# y) = x <#  y
 810 (I# x) `leInt` (I# y) = x <=# y
 811
 812 {-# RULES
 813 "x# ># x#"  forall x#. x# >#  x# = False
 814 "x# >=# x#" forall x#. x# >=# x# = True
 815 "x# ==# x#" forall x#. x# ==# x# = True
 816 "x# /=# x#" forall x#. x# /=# x# = False
 817 "x# <# x#"  forall x#. x# <#  x# = False
 818 "x# <=# x#" forall x#. x# <=# x# = True
 819   #-}
 820
 821 {-# RULES
 822 "plusFloat x 0.0"   forall x#. plusFloat#  x#   0.0# = x#
 823 "plusFloat 0.0 x"   forall x#. plusFloat#  0.0# x#   = x#
 824 "minusFloat x 0.0"  forall x#. minusFloat# x#   0.0# = x#
 825 "minusFloat x x"    forall x#. minusFloat# x#   x#   = 0.0#
 826 "timesFloat x 0.0"  forall x#. timesFloat# x#   0.0# = 0.0#
 827 "timesFloat0.0 x"   forall x#. timesFloat# 0.0# x#   = 0.0#
 828 "timesFloat x 1.0"  forall x#. timesFloat# x#   1.0# = x#
 829 "timesFloat 1.0 x"  forall x#. timesFloat# 1.0# x#   = x#
 830 "divideFloat x 1.0" forall x#. divideFloat# x#  1.0# = x#
 831   #-}
 832
 833 {-# RULES
 834 "plusDouble x 0.0"   forall x#. (+##) x#    0.0## = x#
 835 "plusDouble 0.0 x"   forall x#. (+##) 0.0## x#    = x#
 836 "minusDouble x 0.0"  forall x#. (-##) x#    0.0## = x#
 837 "minusDouble x x"    forall x#. (-##) x#    x#    = 0.0##
 838 "timesDouble x 0.0"  forall x#. (*##) x#    0.0## = 0.0##
 839 "timesDouble 0.0 x"  forall x#. (*##) 0.0## x#    = 0.0##
 840 "timesDouble x 1.0"  forall x#. (*##) x#    1.0## = x#
 841 "timesDouble 1.0 x"  forall x#. (*##) 1.0## x#    = x#
 842 "divideDouble x 1.0" forall x#. (/##) x#    1.0## = x#
 843   #-}
 844
 845 -- Wrappers for the shift operations.  The uncheckedShift# family are
 846 -- undefined when the amount being shifted by is greater than the size
 847 -- in bits of Int#, so these wrappers perform a check and return
 848 -- either zero or -1 appropriately.
 849 --
 850 -- Note that these wrappers still produce undefined results when the
 851 -- second argument (the shift amount) is negative.
 852
 853 shiftL#, shiftRL# :: Word# -> Int# -> Word#
 854
 855 a `shiftL#` b   | b >=# WORD_SIZE_IN_BITS# = int2Word# 0#
 856                 | otherwise                = a `uncheckedShiftL#` b
 857
 858 a `shiftRL#` b  | b >=# WORD_SIZE_IN_BITS# = int2Word# 0#
 859                 | otherwise                = a `uncheckedShiftRL#` b
 860
 861 iShiftL#, iShiftRA#, iShiftRL# :: Int# -> Int# -> Int#
 862
 863 a `iShiftL#` b  | b >=# WORD_SIZE_IN_BITS# = 0#
 864                 | otherwise                = a `uncheckedIShiftL#` b
 865
 866 a `iShiftRA#` b | b >=# WORD_SIZE_IN_BITS# = if a <# 0# then (-1#) else 0#
 867                 | otherwise                = a `uncheckedIShiftRA#` b
 868
 869 a `iShiftRL#` b | b >=# WORD_SIZE_IN_BITS# = 0#
 870                 | otherwise                = a `uncheckedIShiftRL#` b
 871
 872 #if WORD_SIZE_IN_BITS == 32
 873 {-# RULES
 874 "narrow32Int#"  forall x#. narrow32Int#   x# = x#
 875 "narrow32Word#" forall x#. narrow32Word#   x# = x#
 876    #-}
 877 #endif
 878
 879 {-# RULES
 880 "int2Word2Int"  forall x#. int2Word# (word2Int# x#) = x#
 881 "word2Int2Word" forall x#. word2Int# (int2Word# x#) = x#
 882   #-}
 883 \end{code}
 884
 885
 886 %********************************************************
 887 %*                                                      *
 888 \subsection{Unpacking C strings}
 889 %*                                                      *
 890 %********************************************************
 891
 892 This code is needed for virtually all programs, since it's used for
 893 unpacking the strings of error messages.
 894
 895 \begin{code}
 896 unpackCString# :: Addr# -> [Char]
 897 {-# NOINLINE [1] unpackCString# #-}
 898 unpackCString# addr
 899   = unpack 0#
 900   where
 901     unpack nh
 902       | ch `eqChar#` '\0'# = []
 903       | otherwise          = C# ch : unpack (nh +# 1#)
 904       where
 905         ch = indexCharOffAddr# addr nh
 906
 907 unpackAppendCString# :: Addr# -> [Char] -> [Char]
 908 unpackAppendCString# addr rest
 909   = unpack 0#
 910   where
 911     unpack nh
 912       | ch `eqChar#` '\0'# = rest
 913       | otherwise          = C# ch : unpack (nh +# 1#)
 914       where
 915         ch = indexCharOffAddr# addr nh
 916
 917 unpackFoldrCString# :: Addr# -> (Char  -> a -> a) -> a -> a
 918 {-# NOINLINE [0] unpackFoldrCString# #-}
 919 -- Don't inline till right at the end;
 920 -- usually the unpack-list rule turns it into unpackCStringList
 921 unpackFoldrCString# addr f z
 922   = unpack 0#
 923   where
 924     unpack nh
 925       | ch `eqChar#` '\0'# = z
 926       | otherwise          = C# ch `f` unpack (nh +# 1#)
 927       where
 928         ch = indexCharOffAddr# addr nh
 929
 930 unpackCStringUtf8# :: Addr# -> [Char]
 931 unpackCStringUtf8# addr
 932   = unpack 0#
 933   where
 934     unpack nh
 935       | ch `eqChar#` '\0'#   = []
 936       | ch `leChar#` '\x7F'# = C# ch : unpack (nh +# 1#)
 937       | ch `leChar#` '\xDF'# =
 938           C# (chr# (((ord# ch                                  -# 0xC0#) `uncheckedIShiftL#`  6#) +#
 939                      (ord# (indexCharOffAddr# addr (nh +# 1#)) -# 0x80#))) :
 940           unpack (nh +# 2#)
 941       | ch `leChar#` '\xEF'# =
 942           C# (chr# (((ord# ch                                  -# 0xE0#) `uncheckedIShiftL#` 12#) +#
 943                     ((ord# (indexCharOffAddr# addr (nh +# 1#)) -# 0x80#) `uncheckedIShiftL#`  6#) +#
 944                      (ord# (indexCharOffAddr# addr (nh +# 2#)) -# 0x80#))) :
 945           unpack (nh +# 3#)
 946       | otherwise            =
 947           C# (chr# (((ord# ch                                  -# 0xF0#) `uncheckedIShiftL#` 18#) +#
 948                     ((ord# (indexCharOffAddr# addr (nh +# 1#)) -# 0x80#) `uncheckedIShiftL#` 12#) +#
 949                     ((ord# (indexCharOffAddr# addr (nh +# 2#)) -# 0x80#) `uncheckedIShiftL#`  6#) +#
 950                      (ord# (indexCharOffAddr# addr (nh +# 3#)) -# 0x80#))) :
 951           unpack (nh +# 4#)
 952       where
 953         ch = indexCharOffAddr# addr nh
 954
 955 unpackNBytes# :: Addr# -> Int# -> [Char]
 956 unpackNBytes# _addr 0#   = []
 957 unpackNBytes#  addr len# = unpack [] (len# -# 1#)
 958     where
 959      unpack acc i#
 960       | i# <# 0#  = acc
 961       | otherwise =
 962          case indexCharOffAddr# addr i# of
 963             ch -> unpack (C# ch : acc) (i# -# 1#)
 964
 965 {-# RULES
 966 "unpack"       [~1] forall a   . unpackCString# a                  = build (unpackFoldrCString# a)
 967 "unpack-list"  [1]  forall a   . unpackFoldrCString# a (:) [] = unpackCString# a
 968 "unpack-append"     forall a n . unpackFoldrCString# a (:) n  = unpackAppendCString# a n
 969
 970 -- There's a built-in rule (in PrelRules.lhs) for
 971 --      unpackFoldr "foo" c (unpackFoldr "baz" c n)  =  unpackFoldr "foobaz" c n
 972
 973   #-}
 974 \end{code}