GHC/Base.lhs

   1 \section[GHC.Base]{Module @GHC.Base@}
   2
   3 The overall structure of the GHC Prelude is a bit tricky.
   4
   5   a) We want to avoid "orphan modules", i.e. ones with instance
   6         decls that don't belong either to a tycon or a class
   7         defined in the same module
   8
   9   b) We want to avoid giant modules
  10
  11 So the rough structure is as follows, in (linearised) dependency order
  12
  13
  14 GHC.Prim                Has no implementation.  It defines built-in things, and
  15                 by importing it you bring them into scope.
  16                 The source file is GHC.Prim.hi-boot, which is just
  17                 copied to make GHC.Prim.hi
  18
  19 GHC.Base        Classes: Eq, Ord, Functor, Monad
  20                 Types:   list, (), Int, Bool, Ordering, Char, String
  21
  22 Data.Tuple      Types: tuples, plus instances for GHC.Base classes
  23
  24 GHC.Show        Class: Show, plus instances for GHC.Base/GHC.Tup types
  25
  26 GHC.Enum        Class: Enum,  plus instances for GHC.Base/GHC.Tup types
  27
  28 Data.Maybe      Type: Maybe, plus instances for GHC.Base classes
  29
  30 GHC.List        List functions
  31
  32 GHC.Num         Class: Num, plus instances for Int
  33                 Type:  Integer, plus instances for all classes so far (Eq, Ord, Num, Show)
  34
  35                 Integer is needed here because it is mentioned in the signature
  36                 of 'fromInteger' in class Num
  37
  38 GHC.Real        Classes: Real, Integral, Fractional, RealFrac
  39                          plus instances for Int, Integer
  40                 Types:  Ratio, Rational
  41                         plus intances for classes so far
  42
  43                 Rational is needed here because it is mentioned in the signature
  44                 of 'toRational' in class Real
  45
  46 GHC.ST  The ST monad, instances and a few helper functions
  47
  48 Ix              Classes: Ix, plus instances for Int, Bool, Char, Integer, Ordering, tuples
  49
  50 GHC.Arr         Types: Array, MutableArray, MutableVar
  51
  52                 Arrays are used by a function in GHC.Float
  53
  54 GHC.Float       Classes: Floating, RealFloat
  55                 Types:   Float, Double, plus instances of all classes so far
  56
  57                 This module contains everything to do with floating point.
  58                 It is a big module (900 lines)
  59                 With a bit of luck, many modules can be compiled without ever reading GHC.Float.hi
  60
  61
  62 Other Prelude modules are much easier with fewer complex dependencies.
  63
  64 \begin{code}
  65 {-# OPTIONS_GHC -fno-implicit-prelude #-}
  66 -----------------------------------------------------------------------------
  67 -- |
  68 -- Module      :  GHC.Base
  69 -- Copyright   :  (c) The University of Glasgow, 1992-2002
  70 -- License     :  see libraries/base/LICENSE
  71 --
  72 -- Maintainer  :  cvs-ghc@haskell.org
  73 -- Stability   :  internal
  74 -- Portability :  non-portable (GHC extensions)
  75 --
  76 -- Basic data types and classes.
  77 --
  78 -----------------------------------------------------------------------------
  79
  80 #include "MachDeps.h"
  81
  82 -- #hide
  83 module GHC.Base
  84         (
  85         module GHC.Base,
  86         module GHC.Prim,        -- Re-export GHC.Prim and GHC.Err, to avoid lots
  87         module GHC.Err          -- of people having to import it explicitly
  88   )
  89         where
  90
  91 import GHC.Prim
  92 import {-# SOURCE #-} GHC.Err
  93
  94 infixr 9  .
  95 infixr 5  ++, :
  96 infix  4  ==, /=, <, <=, >=, >
  97 infixr 3  &&
  98 infixr 2  ||
  99 infixl 1  >>, >>=
 100 infixr 0  $
 101
 102 default ()              -- Double isn't available yet
 103 \end{code}
 104
 105
 106 %*********************************************************
 107 %*                                                      *
 108 \subsection{DEBUGGING STUFF}
 109 %*  (for use when compiling GHC.Base itself doesn't work)
 110 %*                                                      *
 111 %*********************************************************
 112
 113 \begin{code}
 114 {-
 115 data  Bool  =  False | True
 116 data Ordering = LT | EQ | GT
 117 data Char = C# Char#
 118 type  String = [Char]
 119 data Int = I# Int#
 120 data  ()  =  ()
 121 data [] a = MkNil
 122
 123 not True = False
 124 (&&) True True = True
 125 otherwise = True
 126
 127 build = error "urk"
 128 foldr = error "urk"
 129
 130 unpackCString# :: Addr# -> [Char]
 131 unpackFoldrCString# :: Addr# -> (Char  -> a -> a) -> a -> a
 132 unpackAppendCString# :: Addr# -> [Char] -> [Char]
 133 unpackCStringUtf8# :: Addr# -> [Char]
 134 unpackCString# a = error "urk"
 135 unpackFoldrCString# a = error "urk"
 136 unpackAppendCString# a = error "urk"
 137 unpackCStringUtf8# a = error "urk"
 138 -}
 139 \end{code}
 140
 141
 142 %*********************************************************
 143 %*                                                      *
 144 \subsection{Standard classes @Eq@, @Ord@}
 145 %*                                                      *
 146 %*********************************************************
 147
 148 \begin{code}
 149
 150 -- | The 'Eq' class defines equality ('==') and inequality ('/=').
 151 -- All the basic datatypes exported by the "Prelude" are instances of 'Eq',
 152 -- and 'Eq' may be derived for any datatype whose constituents are also
 153 -- instances of 'Eq'.
 154 --
 155 -- Minimal complete definition: either '==' or '/='.
 156 --
 157 class  Eq a  where
 158     (==), (/=)           :: a -> a -> Bool
 159
 160     x /= y               = not (x == y)
 161     x == y               = not (x /= y)
 162
 163 -- | The 'Ord' class is used for totally ordered datatypes.
 164 --
 165 -- Instances of 'Ord' can be derived for any user-defined
 166 -- datatype whose constituent types are in 'Ord'.  The declared order
 167 -- of the constructors in the data declaration determines the ordering
 168 -- in derived 'Ord' instances.  The 'Ordering' datatype allows a single
 169 -- comparison to determine the precise ordering of two objects.
 170 --
 171 -- Minimal complete definition: either 'compare' or '<='.
 172 -- Using 'compare' can be more efficient for complex types.
 173 --
 174 class  (Eq a) => Ord a  where
 175     compare              :: a -> a -> Ordering
 176     (<), (<=), (>), (>=) :: a -> a -> Bool
 177     max, min             :: a -> a -> a
 178
 179     compare x y
 180         | x == y    = EQ
 181         | x <= y    = LT        -- NB: must be '<=' not '<' to validate the
 182                                 -- above claim about the minimal things that
 183                                 -- can be defined for an instance of Ord
 184         | otherwise = GT
 185
 186     x <  y = case compare x y of { LT -> True;  _other -> False }
 187     x <= y = case compare x y of { GT -> False; _other -> True }
 188     x >  y = case compare x y of { GT -> True;  _other -> False }
 189     x >= y = case compare x y of { LT -> False; _other -> True }
 190
 191         -- These two default methods use '<=' rather than 'compare'
 192         -- because the latter is often more expensive
 193     max x y = if x <= y then y else x
 194     min x y = if x <= y then x else y
 195 \end{code}
 196
 197 %*********************************************************
 198 %*                                                      *
 199 \subsection{Monadic classes @Functor@, @Monad@ }
 200 %*                                                      *
 201 %*********************************************************
 202
 203 \begin{code}
 204 {- | The 'Functor' class is used for types that can be mapped over.
 205 Instances of 'Functor' should satisfy the following laws:
 206
 207 > fmap id  ==  id
 208 > fmap (f . g)  ==  fmap f . fmap g
 209
 210 The instances of 'Functor' for lists, 'Data.Maybe.Maybe' and 'System.IO.IO'
 211 defined in the "Prelude" satisfy these laws.
 212 -}
 213
 214 class  Functor f  where
 215     fmap        :: (a -> b) -> f a -> f b
 216
 217 {- | The 'Monad' class defines the basic operations over a /monad/,
 218 a concept from a branch of mathematics known as /category theory/.
 219 From the perspective of a Haskell programmer, however, it is best to
 220 think of a monad as an /abstract datatype/ of actions.
 221 Haskell's @do@ expressions provide a convenient syntax for writing
 222 monadic expressions.
 223
 224 Minimal complete definition: '>>=' and 'return'.
 225
 226 Instances of 'Monad' should satisfy the following laws:
 227
 228 > return a >>= k  ==  k a
 229 > m >>= return  ==  m
 230 > m >>= (\x -> k x >>= h)  ==  (m >>= k) >>= h
 231
 232 Instances of both 'Monad' and 'Functor' should additionally satisfy the law:
 233
 234 > fmap f xs  ==  xs >>= return . f
 235
 236 The instances of 'Monad' for lists, 'Data.Maybe.Maybe' and 'System.IO.IO'
 237 defined in the "Prelude" satisfy these laws.
 238 -}
 239
 240 class  Monad m  where
 241     -- | Sequentially compose two actions, passing any value produced
 242     -- by the first as an argument to the second.
 243     (>>=)       :: forall a b. m a -> (a -> m b) -> m b
 244     -- | Sequentially compose two actions, discarding any value produced
 245     -- by the first, like sequencing operators (such as the semicolon)
 246     -- in imperative languages.
 247     (>>)        :: forall a b. m a -> m b -> m b
 248         -- Explicit for-alls so that we know what order to
 249         -- give type arguments when desugaring
 250
 251     -- | Inject a value into the monadic type.
 252     return      :: a -> m a
 253     -- | Fail with a message.  This operation is not part of the
 254     -- mathematical definition of a monad, but is invoked on pattern-match
 255     -- failure in a @do@ expression.
 256     fail        :: String -> m a
 257
 258     m >> k      = m >>= \_ -> k
 259     fail s      = error s
 260 \end{code}
 261
 262
 263 %*********************************************************
 264 %*                                                      *
 265 \subsection{The list type}
 266 %*                                                      *
 267 %*********************************************************
 268
 269 \begin{code}
 270 data [] a = [] | a : [a]  -- do explicitly: deriving (Eq, Ord)
 271                           -- to avoid weird names like con2tag_[]#
 272
 273
 274 instance (Eq a) => Eq [a] where
 275     {-# SPECIALISE instance Eq [Char] #-}
 276     []     == []     = True
 277     (x:xs) == (y:ys) = x == y && xs == ys
 278     _xs    == _ys    = False
 279
 280 instance (Ord a) => Ord [a] where
 281     {-# SPECIALISE instance Ord [Char] #-}
 282     compare []     []     = EQ
 283     compare []     (_:_)  = LT
 284     compare (_:_)  []     = GT
 285     compare (x:xs) (y:ys) = case compare x y of
 286                                 EQ    -> compare xs ys
 287                                 other -> other
 288
 289 instance Functor [] where
 290     fmap = map
 291
 292 instance  Monad []  where
 293     m >>= k             = foldr ((++) . k) [] m
 294     m >> k              = foldr ((++) . (\ _ -> k)) [] m
 295     return x            = [x]
 296     fail _              = []
 297 \end{code}
 298
 299 A few list functions that appear here because they are used here.
 300 The rest of the prelude list functions are in GHC.List.
 301
 302 ----------------------------------------------
 303 --      foldr/build/augment
 304 ----------------------------------------------
 305
 306 \begin{code}
 307 -- | 'foldr', applied to a binary operator, a starting value (typically
 308 -- the right-identity of the operator), and a list, reduces the list
 309 -- using the binary operator, from right to left:
 310 --
 311 -- > foldr f z [x1, x2, ..., xn] == x1 `f` (x2 `f` ... (xn `f` z)...)
 312
 313 foldr            :: (a -> b -> b) -> b -> [a] -> b
 314 -- foldr _ z []     =  z
 315 -- foldr f z (x:xs) =  f x (foldr f z xs)
 316 {-# INLINE [0] foldr #-}
 317 -- Inline only in the final stage, after the foldr/cons rule has had a chance
 318 foldr k z xs = go xs
 319              where
 320                go []     = z
 321                go (y:ys) = y `k` go ys
 322
 323 -- | A list producer that can be fused with 'foldr'.
 324 -- This function is merely
 325 --
 326 -- >    build g = g (:) []
 327 --
 328 -- but GHC's simplifier will transform an expression of the form
 329 -- @'foldr' k z ('build' g)@, which may arise after inlining, to @g k z@,
 330 -- which avoids producing an intermediate list.
 331
 332 build   :: forall a. (forall b. (a -> b -> b) -> b -> b) -> [a]
 333 {-# INLINE [1] build #-}
 334         -- The INLINE is important, even though build is tiny,
 335         -- because it prevents [] getting inlined in the version that
 336         -- appears in the interface file.  If [] *is* inlined, it
 337         -- won't match with [] appearing in rules in an importing module.
 338         --
 339         -- The "1" says to inline in phase 1
 340
 341 build g = g (:) []
 342
 343 -- | A list producer that can be fused with 'foldr'.
 344 -- This function is merely
 345 --
 346 -- >    augment g xs = g (:) xs
 347 --
 348 -- but GHC's simplifier will transform an expression of the form
 349 -- @'foldr' k z ('augment' g xs)@, which may arise after inlining, to
 350 -- @g k ('foldr' k z xs)@, which avoids producing an intermediate list.
 351
 352 augment :: forall a. (forall b. (a->b->b) -> b -> b) -> [a] -> [a]
 353 {-# INLINE [1] augment #-}
 354 augment g xs = g (:) xs
 355
 356 {-# RULES
 357 "fold/build"    forall k z (g::forall b. (a->b->b) -> b -> b) .
 358                 foldr k z (build g) = g k z
 359
 360 "foldr/augment" forall k z xs (g::forall b. (a->b->b) -> b -> b) .
 361                 foldr k z (augment g xs) = g k (foldr k z xs)
 362
 363 "foldr/id"                        foldr (:) [] = \x  -> x
 364 "foldr/app"     [1] forall ys. foldr (:) ys = \xs -> xs ++ ys
 365         -- Only activate this from phase 1, because that's
 366         -- when we disable the rule that expands (++) into foldr
 367
 368 -- The foldr/cons rule looks nice, but it can give disastrously
 369 -- bloated code when commpiling
 370 --      array (a,b) [(1,2), (2,2), (3,2), ...very long list... ]
 371 -- i.e. when there are very very long literal lists
 372 -- So I've disabled it for now. We could have special cases
 373 -- for short lists, I suppose.
 374 -- "foldr/cons" forall k z x xs. foldr k z (x:xs) = k x (foldr k z xs)
 375
 376 "foldr/single"  forall k z x. foldr k z [x] = k x z
 377 "foldr/nil"     forall k z.   foldr k z []  = z
 378
 379 "augment/build" forall (g::forall b. (a->b->b) -> b -> b)
 380                        (h::forall b. (a->b->b) -> b -> b) .
 381                        augment g (build h) = build (\c n -> g c (h c n))
 382 "augment/nil"   forall (g::forall b. (a->b->b) -> b -> b) .
 383                         augment g [] = build g
 384  #-}
 385
 386 -- This rule is true, but not (I think) useful:
 387 --      augment g (augment h t) = augment (\cn -> g c (h c n)) t
 388 \end{code}
 389
 390
 391 ----------------------------------------------
 392 --              map
 393 ----------------------------------------------
 394
 395 \begin{code}
 396 -- | 'map' @f xs@ is the list obtained by applying @f@ to each element
 397 -- of @xs@, i.e.,
 398 --
 399 -- > map f [x1, x2, ..., xn] == [f x1, f x2, ..., f xn]
 400 -- > map f [x1, x2, ...] == [f x1, f x2, ...]
 401
 402 map :: (a -> b) -> [a] -> [b]
 403 map _ []     = []
 404 map f (x:xs) = f x : map f xs
 405
 406 -- Note eta expanded
 407 mapFB ::  (elt -> lst -> lst) -> (a -> elt) -> a -> lst -> lst
 408 {-# INLINE [0] mapFB #-}
 409 mapFB c f x ys = c (f x) ys
 410
 411 -- The rules for map work like this.
 412 --
 413 -- Up to (but not including) phase 1, we use the "map" rule to
 414 -- rewrite all saturated applications of map with its build/fold
 415 -- form, hoping for fusion to happen.
 416 -- In phase 1 and 0, we switch off that rule, inline build, and
 417 -- switch on the "mapList" rule, which rewrites the foldr/mapFB
 418 -- thing back into plain map.
 419 --
 420 -- It's important that these two rules aren't both active at once
 421 -- (along with build's unfolding) else we'd get an infinite loop
 422 -- in the rules.  Hence the activation control below.
 423 --
 424 -- The "mapFB" rule optimises compositions of map.
 425 --
 426 -- This same pattern is followed by many other functions:
 427 -- e.g. append, filter, iterate, repeat, etc.
 428
 429 {-# RULES
 430 "map"       [~1] forall f xs.   map f xs                = build (\c n -> foldr (mapFB c f) n xs)
 431 "mapList"   [1]  forall f.      foldr (mapFB (:) f) []  = map f
 432 "mapFB"     forall c f g.       mapFB (mapFB c f) g     = mapFB c (f.g)
 433   #-}
 434 \end{code}
 435
 436
 437 ----------------------------------------------
 438 --              append
 439 ----------------------------------------------
 440 \begin{code}
 441 -- | Append two lists, i.e.,
 442 --
 443 -- > [x1, ..., xm] ++ [y1, ..., yn] == [x1, ..., xm, y1, ..., yn]
 444 -- > [x1, ..., xm] ++ [y1, ...] == [x1, ..., xm, y1, ...]
 445 --
 446 -- If the first list is not finite, the result is the first list.
 447
 448 (++) :: [a] -> [a] -> [a]
 449 (++) []     ys = ys
 450 (++) (x:xs) ys = x : xs ++ ys
 451
 452 {-# RULES
 453 "++"    [~1] forall xs ys. xs ++ ys = augment (\c n -> foldr c n xs) ys
 454   #-}
 455
 456 \end{code}
 457
 458
 459 %*********************************************************
 460 %*                                                      *
 461 \subsection{Type @Bool@}
 462 %*                                                      *
 463 %*********************************************************
 464
 465 \begin{code}
 466 -- |The 'Bool' type is an enumeration.  It is defined with 'False'
 467 -- first so that the corresponding 'Prelude.Enum' instance will give
 468 -- 'Prelude.fromEnum' 'False' the value zero, and
 469 -- 'Prelude.fromEnum' 'True' the value 1.
 470 data  Bool  =  False | True  deriving (Eq, Ord)
 471         -- Read in GHC.Read, Show in GHC.Show
 472
 473 -- Boolean functions
 474
 475 -- | Boolean \"and\"
 476 (&&)                    :: Bool -> Bool -> Bool
 477 True  && x              =  x
 478 False && _              =  False
 479
 480 -- | Boolean \"or\"
 481 (||)                    :: Bool -> Bool -> Bool
 482 True  || _              =  True
 483 False || x              =  x
 484
 485 -- | Boolean \"not\"
 486 not                     :: Bool -> Bool
 487 not True                =  False
 488 not False               =  True
 489
 490 -- |'otherwise' is defined as the value 'True'.  It helps to make
 491 -- guards more readable.  eg.
 492 --
 493 -- >  f x | x < 0     = ...
 494 -- >      | otherwise = ...
 495 otherwise               :: Bool
 496 otherwise               =  True
 497 \end{code}
 498
 499 \begin{code}
 500 class IsString a where
 501     fromString :: String -> a
 502
 503 instance IsString [Char] where
 504     fromString xs = xs
 505 \end{code}
 506
 507
 508 %*********************************************************
 509 %*                                                      *
 510 \subsection{The @()@ type}
 511 %*                                                      *
 512 %*********************************************************
 513
 514 The Unit type is here because virtually any program needs it (whereas
 515 some programs may get away without consulting GHC.Tup).  Furthermore,
 516 the renamer currently *always* asks for () to be in scope, so that
 517 ccalls can use () as their default type; so when compiling GHC.Base we
 518 need ().  (We could arrange suck in () only if -fglasgow-exts, but putting
 519 it here seems more direct.)
 520
 521 \begin{code}
 522 -- | The unit datatype @()@ has one non-undefined member, the nullary
 523 -- constructor @()@.
 524 data () = ()
 525
 526 instance Eq () where
 527     () == () = True
 528     () /= () = False
 529
 530 instance Ord () where
 531     () <= () = True
 532     () <  () = False
 533     () >= () = True
 534     () >  () = False
 535     max () () = ()
 536     min () () = ()
 537     compare () () = EQ
 538 \end{code}
 539
 540
 541 %*********************************************************
 542 %*                                                      *
 543 \subsection{Type @Ordering@}
 544 %*                                                      *
 545 %*********************************************************
 546
 547 \begin{code}
 548 -- | Represents an ordering relationship between two values: less
 549 -- than, equal to, or greater than.  An 'Ordering' is returned by
 550 -- 'compare'.
 551 data Ordering = LT | EQ | GT deriving (Eq, Ord)
 552         -- Read in GHC.Read, Show in GHC.Show
 553 \end{code}
 554
 555
 556 %*********************************************************
 557 %*                                                      *
 558 \subsection{Type @Char@ and @String@}
 559 %*                                                      *
 560 %*********************************************************
 561
 562 \begin{code}
 563 -- | A 'String' is a list of characters.  String constants in Haskell are values
 564 -- of type 'String'.
 565 --
 566 type String = [Char]
 567
 568 {-| The character type 'Char' is an enumeration whose values represent
 569 Unicode (or equivalently ISO\/IEC 10646) characters
 570 (see <http://www.unicode.org/> for details).
 571 This set extends the ISO 8859-1 (Latin-1) character set
 572 (the first 256 charachers), which is itself an extension of the ASCII
 573 character set (the first 128 characters).
 574 A character literal in Haskell has type 'Char'.
 575
 576 To convert a 'Char' to or from the corresponding 'Int' value defined
 577 by Unicode, use 'Prelude.toEnum' and 'Prelude.fromEnum' from the
 578 'Prelude.Enum' class respectively (or equivalently 'ord' and 'chr').
 579 -}
 580 data Char = C# Char#
 581
 582 -- We don't use deriving for Eq and Ord, because for Ord the derived
 583 -- instance defines only compare, which takes two primops.  Then
 584 -- '>' uses compare, and therefore takes two primops instead of one.
 585
 586 instance Eq Char where
 587     (C# c1) == (C# c2) = c1 `eqChar#` c2
 588     (C# c1) /= (C# c2) = c1 `neChar#` c2
 589
 590 instance Ord Char where
 591     (C# c1) >  (C# c2) = c1 `gtChar#` c2
 592     (C# c1) >= (C# c2) = c1 `geChar#` c2
 593     (C# c1) <= (C# c2) = c1 `leChar#` c2
 594     (C# c1) <  (C# c2) = c1 `ltChar#` c2
 595
 596 {-# RULES
 597 "x# `eqChar#` x#" forall x#. x# `eqChar#` x# = True
 598 "x# `neChar#` x#" forall x#. x# `neChar#` x# = False
 599 "x# `gtChar#` x#" forall x#. x# `gtChar#` x# = False
 600 "x# `geChar#` x#" forall x#. x# `geChar#` x# = True
 601 "x# `leChar#` x#" forall x#. x# `leChar#` x# = True
 602 "x# `ltChar#` x#" forall x#. x# `ltChar#` x# = False
 603   #-}
 604
 605 -- | The 'Prelude.toEnum' method restricted to the type 'Data.Char.Char'.
 606 chr :: Int -> Char
 607 chr (I# i#) | int2Word# i# `leWord#` int2Word# 0x10FFFF# = C# (chr# i#)
 608             | otherwise                                  = error "Prelude.chr: bad argument"
 609
 610 unsafeChr :: Int -> Char
 611 unsafeChr (I# i#) = C# (chr# i#)
 612
 613 -- | The 'Prelude.fromEnum' method restricted to the type 'Data.Char.Char'.
 614 ord :: Char -> Int
 615 ord (C# c#) = I# (ord# c#)
 616 \end{code}
 617
 618 String equality is used when desugaring pattern-matches against strings.
 619
 620 \begin{code}
 621 eqString :: String -> String -> Bool
 622 eqString []       []       = True
 623 eqString (c1:cs1) (c2:cs2) = c1 == c2 && cs1 `eqString` cs2
 624 eqString cs1      cs2      = False
 625
 626 {-# RULES "eqString" (==) = eqString #-}
 627 -- eqString also has a BuiltInRule in PrelRules.lhs:
 628 --      eqString (unpackCString# (Lit s1)) (unpackCString# (Lit s2) = s1==s2
 629 \end{code}
 630
 631
 632 %*********************************************************
 633 %*                                                      *
 634 \subsection{Type @Int@}
 635 %*                                                      *
 636 %*********************************************************
 637
 638 \begin{code}
 639 data Int = I# Int#
 640 -- ^A fixed-precision integer type with at least the range @[-2^29 .. 2^29-1]@.
 641 -- The exact range for a given implementation can be determined by using
 642 -- 'Prelude.minBound' and 'Prelude.maxBound' from the 'Prelude.Bounded' class.
 643
 644 zeroInt, oneInt, twoInt, maxInt, minInt :: Int
 645 zeroInt = I# 0#
 646 oneInt  = I# 1#
 647 twoInt  = I# 2#
 648
 649 {- Seems clumsy. Should perhaps put minInt and MaxInt directly into MachDeps.h -}
 650 #if WORD_SIZE_IN_BITS == 31
 651 minInt  = I# (-0x40000000#)
 652 maxInt  = I# 0x3FFFFFFF#
 653 #elif WORD_SIZE_IN_BITS == 32
 654 minInt  = I# (-0x80000000#)
 655 maxInt  = I# 0x7FFFFFFF#
 656 #else
 657 minInt  = I# (-0x8000000000000000#)
 658 maxInt  = I# 0x7FFFFFFFFFFFFFFF#
 659 #endif
 660
 661 instance Eq Int where
 662     (==) = eqInt
 663     (/=) = neInt
 664
 665 instance Ord Int where
 666     compare = compareInt
 667     (<)     = ltInt
 668     (<=)    = leInt
 669     (>=)    = geInt
 670     (>)     = gtInt
 671
 672 compareInt :: Int -> Int -> Ordering
 673 (I# x#) `compareInt` (I# y#) = compareInt# x# y#
 674
 675 compareInt# :: Int# -> Int# -> Ordering
 676 compareInt# x# y#
 677     | x# <#  y# = LT
 678     | x# ==# y# = EQ
 679     | otherwise = GT
 680 \end{code}
 681
 682
 683 %*********************************************************
 684 %*                                                      *
 685 \subsection{The function type}
 686 %*                                                      *
 687 %*********************************************************
 688
 689 \begin{code}
 690 -- | Identity function.
 691 id                      :: a -> a
 692 id x                    =  x
 693
 694 -- | The call '(lazy e)' means the same as 'e', but 'lazy' has a
 695 -- magical strictness property: it is lazy in its first argument,
 696 -- even though its semantics is strict.
 697 lazy :: a -> a
 698 lazy x = x
 699 -- Implementation note: its strictness and unfolding are over-ridden
 700 -- by the definition in MkId.lhs; in both cases to nothing at all.
 701 -- That way, 'lazy' does not get inlined, and the strictness analyser
 702 -- sees it as lazy.  Then the worker/wrapper phase inlines it.
 703 -- Result: happiness
 704
 705
 706 -- | The call '(inline f)' reduces to 'f', but 'inline' has a BuiltInRule
 707 -- that tries to inline 'f' (if it has an unfolding) unconditionally
 708 -- The 'NOINLINE' pragma arranges that inline only gets inlined (and
 709 -- hence eliminated) late in compilation, after the rule has had
 710 -- a god chance to fire.
 711 inline :: a -> a
 712 {-# NOINLINE[0] inline #-}
 713 inline x = x
 714
 715 -- Assertion function.  This simply ignores its boolean argument.
 716 -- The compiler may rewrite it to @('assertError' line)@.
 717
 718 -- | If the first argument evaluates to 'True', then the result is the
 719 -- second argument.  Otherwise an 'AssertionFailed' exception is raised,
 720 -- containing a 'String' with the source file and line number of the
 721 -- call to 'assert'.
 722 --
 723 -- Assertions can normally be turned on or off with a compiler flag
 724 -- (for GHC, assertions are normally on unless optimisation is turned on
 725 -- with @-O@ or the @-fignore-asserts@
 726 -- option is given).  When assertions are turned off, the first
 727 -- argument to 'assert' is ignored, and the second argument is
 728 -- returned as the result.
 729
 730 --      SLPJ: in 5.04 etc 'assert' is in GHC.Prim,
 731 --      but from Template Haskell onwards it's simply
 732 --      defined here in Base.lhs
 733 assert :: Bool -> a -> a
 734 assert pred r = r
 735
 736 breakpoint :: a -> a
 737 breakpoint r = r
 738
 739 breakpointCond :: Bool -> a -> a
 740 breakpointCond _ r = r
 741
 742 data Unknown
 743 data Unknown1 a
 744 data Unknown2 a b
 745 data Unknown3 a b c
 746 data Unknown4 a b c d
 747
 748 data Opaque = forall a. O a
 749
 750 -- | Constant function.
 751 const                   :: a -> b -> a
 752 const x _               =  x
 753
 754 -- | Function composition.
 755 {-# INLINE (.) #-}
 756 (.)       :: (b -> c) -> (a -> b) -> a -> c
 757 (.) f g x = f (g x)
 758
 759 -- | @'flip' f@ takes its (first) two arguments in the reverse order of @f@.
 760 flip                    :: (a -> b -> c) -> b -> a -> c
 761 flip f x y              =  f y x
 762
 763 -- | Application operator.  This operator is redundant, since ordinary
 764 -- application @(f x)@ means the same as @(f '$' x)@. However, '$' has
 765 -- low, right-associative binding precedence, so it sometimes allows
 766 -- parentheses to be omitted; for example:
 767 --
 768 -- >     f $ g $ h x  =  f (g (h x))
 769 --
 770 -- It is also useful in higher-order situations, such as @'map' ('$' 0) xs@,
 771 -- or @'Data.List.zipWith' ('$') fs xs@.
 772 {-# INLINE ($) #-}
 773 ($)                     :: (a -> b) -> a -> b
 774 f $ x                   =  f x
 775
 776 -- | @'until' p f@ yields the result of applying @f@ until @p@ holds.
 777 until                   :: (a -> Bool) -> (a -> a) -> a -> a
 778 until p f x | p x       =  x
 779             | otherwise =  until p f (f x)
 780
 781 -- | 'asTypeOf' is a type-restricted version of 'const'.  It is usually
 782 -- used as an infix operator, and its typing forces its first argument
 783 -- (which is usually overloaded) to have the same type as the second.
 784 asTypeOf                :: a -> a -> a
 785 asTypeOf                =  const
 786 \end{code}
 787
 788 %*********************************************************
 789 %*                                                      *
 790 \subsection{Generics}
 791 %*                                                      *
 792 %*********************************************************
 793
 794 \begin{code}
 795 data Unit = Unit
 796 #ifndef __HADDOCK__
 797 data (:+:) a b = Inl a | Inr b
 798 data (:*:) a b = a :*: b
 799 #endif
 800 \end{code}
 801
 802 %*********************************************************
 803 %*                                                      *
 804 \subsection{@getTag@}
 805 %*                                                      *
 806 %*********************************************************
 807
 808 Returns the 'tag' of a constructor application; this function is used
 809 by the deriving code for Eq, Ord and Enum.
 810
 811 The primitive dataToTag# requires an evaluated constructor application
 812 as its argument, so we provide getTag as a wrapper that performs the
 813 evaluation before calling dataToTag#.  We could have dataToTag#
 814 evaluate its argument, but we prefer to do it this way because (a)
 815 dataToTag# can be an inline primop if it doesn't need to do any
 816 evaluation, and (b) we want to expose the evaluation to the
 817 simplifier, because it might be possible to eliminate the evaluation
 818 in the case when the argument is already known to be evaluated.
 819
 820 \begin{code}
 821 {-# INLINE getTag #-}
 822 getTag :: a -> Int#
 823 getTag x = x `seq` dataToTag# x
 824 \end{code}
 825
 826 %*********************************************************
 827 %*                                                      *
 828 \subsection{Numeric primops}
 829 %*                                                      *
 830 %*********************************************************
 831
 832 \begin{code}
 833 divInt# :: Int# -> Int# -> Int#
 834 x# `divInt#` y#
 835         -- Be careful NOT to overflow if we do any additional arithmetic
 836         -- on the arguments...  the following  previous version of this
 837         -- code has problems with overflow:
 838 --    | (x# ># 0#) && (y# <# 0#) = ((x# -# y#) -# 1#) `quotInt#` y#
 839 --    | (x# <# 0#) && (y# ># 0#) = ((x# -# y#) +# 1#) `quotInt#` y#
 840     | (x# ># 0#) && (y# <# 0#) = ((x# -# 1#) `quotInt#` y#) -# 1#
 841     | (x# <# 0#) && (y# ># 0#) = ((x# +# 1#) `quotInt#` y#) -# 1#
 842     | otherwise                = x# `quotInt#` y#
 843
 844 modInt# :: Int# -> Int# -> Int#
 845 x# `modInt#` y#
 846     | (x# ># 0#) && (y# <# 0#) ||
 847       (x# <# 0#) && (y# ># 0#)    = if r# /=# 0# then r# +# y# else 0#
 848     | otherwise                   = r#
 849     where
 850     r# = x# `remInt#` y#
 851 \end{code}
 852
 853 Definitions of the boxed PrimOps; these will be
 854 used in the case of partial applications, etc.
 855
 856 \begin{code}
 857 {-# INLINE eqInt #-}
 858 {-# INLINE neInt #-}
 859 {-# INLINE gtInt #-}
 860 {-# INLINE geInt #-}
 861 {-# INLINE ltInt #-}
 862 {-# INLINE leInt #-}
 863 {-# INLINE plusInt #-}
 864 {-# INLINE minusInt #-}
 865 {-# INLINE timesInt #-}
 866 {-# INLINE quotInt #-}
 867 {-# INLINE remInt #-}
 868 {-# INLINE negateInt #-}
 869
 870 plusInt, minusInt, timesInt, quotInt, remInt, divInt, modInt, gcdInt :: Int -> Int -> Int
 871 (I# x) `plusInt`  (I# y) = I# (x +# y)
 872 (I# x) `minusInt` (I# y) = I# (x -# y)
 873 (I# x) `timesInt` (I# y) = I# (x *# y)
 874 (I# x) `quotInt`  (I# y) = I# (x `quotInt#` y)
 875 (I# x) `remInt`   (I# y) = I# (x `remInt#`  y)
 876 (I# x) `divInt`   (I# y) = I# (x `divInt#`  y)
 877 (I# x) `modInt`   (I# y) = I# (x `modInt#`  y)
 878
 879 {-# RULES
 880 "x# +# 0#" forall x#. x# +# 0# = x#
 881 "0# +# x#" forall x#. 0# +# x# = x#
 882 "x# -# 0#" forall x#. x# -# 0# = x#
 883 "x# -# x#" forall x#. x# -# x# = 0#
 884 "x# *# 0#" forall x#. x# *# 0# = 0#
 885 "0# *# x#" forall x#. 0# *# x# = 0#
 886 "x# *# 1#" forall x#. x# *# 1# = x#
 887 "1# *# x#" forall x#. 1# *# x# = x#
 888   #-}
 889
 890 gcdInt (I# a) (I# b) = g a b
 891    where g 0# 0# = error "GHC.Base.gcdInt: gcd 0 0 is undefined"
 892          g 0# _  = I# absB
 893          g _  0# = I# absA
 894          g _  _  = I# (gcdInt# absA absB)
 895
 896          absInt x = if x <# 0# then negateInt# x else x
 897
 898          absA     = absInt a
 899          absB     = absInt b
 900
 901 negateInt :: Int -> Int
 902 negateInt (I# x) = I# (negateInt# x)
 903
 904 gtInt, geInt, eqInt, neInt, ltInt, leInt :: Int -> Int -> Bool
 905 (I# x) `gtInt` (I# y) = x >#  y
 906 (I# x) `geInt` (I# y) = x >=# y
 907 (I# x) `eqInt` (I# y) = x ==# y
 908 (I# x) `neInt` (I# y) = x /=# y
 909 (I# x) `ltInt` (I# y) = x <#  y
 910 (I# x) `leInt` (I# y) = x <=# y
 911
 912 {-# RULES
 913 "x# ># x#"  forall x#. x# >#  x# = False
 914 "x# >=# x#" forall x#. x# >=# x# = True
 915 "x# ==# x#" forall x#. x# ==# x# = True
 916 "x# /=# x#" forall x#. x# /=# x# = False
 917 "x# <# x#"  forall x#. x# <#  x# = False
 918 "x# <=# x#" forall x#. x# <=# x# = True
 919   #-}
 920
 921 {-# RULES
 922 "plusFloat x 0.0"   forall x#. plusFloat#  x#   0.0# = x#
 923 "plusFloat 0.0 x"   forall x#. plusFloat#  0.0# x#   = x#
 924 "minusFloat x 0.0"  forall x#. minusFloat# x#   0.0# = x#
 925 "minusFloat x x"    forall x#. minusFloat# x#   x#   = 0.0#
 926 "timesFloat x 0.0"  forall x#. timesFloat# x#   0.0# = 0.0#
 927 "timesFloat0.0 x"   forall x#. timesFloat# 0.0# x#   = 0.0#
 928 "timesFloat x 1.0"  forall x#. timesFloat# x#   1.0# = x#
 929 "timesFloat 1.0 x"  forall x#. timesFloat# 1.0# x#   = x#
 930 "divideFloat x 1.0" forall x#. divideFloat# x#  1.0# = x#
 931   #-}
 932
 933 {-# RULES
 934 "plusDouble x 0.0"   forall x#. (+##) x#    0.0## = x#
 935 "plusDouble 0.0 x"   forall x#. (+##) 0.0## x#    = x#
 936 "minusDouble x 0.0"  forall x#. (-##) x#    0.0## = x#
 937 "minusDouble x x"    forall x#. (-##) x#    x#    = 0.0##
 938 "timesDouble x 0.0"  forall x#. (*##) x#    0.0## = 0.0##
 939 "timesDouble 0.0 x"  forall x#. (*##) 0.0## x#    = 0.0##
 940 "timesDouble x 1.0"  forall x#. (*##) x#    1.0## = x#
 941 "timesDouble 1.0 x"  forall x#. (*##) 1.0## x#    = x#
 942 "divideDouble x 1.0" forall x#. (/##) x#    1.0## = x#
 943   #-}
 944
 945 -- Wrappers for the shift operations.  The uncheckedShift# family are
 946 -- undefined when the amount being shifted by is greater than the size
 947 -- in bits of Int#, so these wrappers perform a check and return
 948 -- either zero or -1 appropriately.
 949 --
 950 -- Note that these wrappers still produce undefined results when the
 951 -- second argument (the shift amount) is negative.
 952
 953 -- | Shift the argument left by the specified number of bits
 954 -- (which must be non-negative).
 955 shiftL# :: Word# -> Int# -> Word#
 956 a `shiftL#` b   | b >=# WORD_SIZE_IN_BITS# = int2Word# 0#
 957                 | otherwise                = a `uncheckedShiftL#` b
 958
 959 -- | Shift the argument right by the specified number of bits
 960 -- (which must be non-negative).
 961 shiftRL# :: Word# -> Int# -> Word#
 962 a `shiftRL#` b  | b >=# WORD_SIZE_IN_BITS# = int2Word# 0#
 963                 | otherwise                = a `uncheckedShiftRL#` b
 964
 965 -- | Shift the argument left by the specified number of bits
 966 -- (which must be non-negative).
 967 iShiftL# :: Int# -> Int# -> Int#
 968 a `iShiftL#` b  | b >=# WORD_SIZE_IN_BITS# = 0#
 969                 | otherwise                = a `uncheckedIShiftL#` b
 970
 971 -- | Shift the argument right (signed) by the specified number of bits
 972 -- (which must be non-negative).
 973 iShiftRA# :: Int# -> Int# -> Int#
 974 a `iShiftRA#` b | b >=# WORD_SIZE_IN_BITS# = if a <# 0# then (-1#) else 0#
 975                 | otherwise                = a `uncheckedIShiftRA#` b
 976
 977 -- | Shift the argument right (unsigned) by the specified number of bits
 978 -- (which must be non-negative).
 979 iShiftRL# :: Int# -> Int# -> Int#
 980 a `iShiftRL#` b | b >=# WORD_SIZE_IN_BITS# = 0#
 981                 | otherwise                = a `uncheckedIShiftRL#` b
 982
 983 #if WORD_SIZE_IN_BITS == 32
 984 {-# RULES
 985 "narrow32Int#"  forall x#. narrow32Int#   x# = x#
 986 "narrow32Word#" forall x#. narrow32Word#   x# = x#
 987    #-}
 988 #endif
 989
 990 {-# RULES
 991 "int2Word2Int"  forall x#. int2Word# (word2Int# x#) = x#
 992 "word2Int2Word" forall x#. word2Int# (int2Word# x#) = x#
 993   #-}
 994 \end{code}
 995
 996
 997 %********************************************************
 998 %*                                                      *
 999 \subsection{Unpacking C strings}
1000 %*                                                      *
1001 %********************************************************
1002
1003 This code is needed for virtually all programs, since it's used for
1004 unpacking the strings of error messages.
1005
1006 \begin{code}
1007 unpackCString# :: Addr# -> [Char]
1008 {-# NOINLINE [1] unpackCString# #-}
1009 unpackCString# addr
1010   = unpack 0#
1011   where
1012     unpack nh
1013       | ch `eqChar#` '\0'# = []
1014       | otherwise          = C# ch : unpack (nh +# 1#)
1015       where
1016         ch = indexCharOffAddr# addr nh
1017
1018 unpackAppendCString# :: Addr# -> [Char] -> [Char]
1019 unpackAppendCString# addr rest
1020   = unpack 0#
1021   where
1022     unpack nh
1023       | ch `eqChar#` '\0'# = rest
1024       | otherwise          = C# ch : unpack (nh +# 1#)
1025       where
1026         ch = indexCharOffAddr# addr nh
1027
1028 unpackFoldrCString# :: Addr# -> (Char  -> a -> a) -> a -> a
1029 {-# NOINLINE [0] unpackFoldrCString# #-}
1030 -- Don't inline till right at the end;
1031 -- usually the unpack-list rule turns it into unpackCStringList
1032 -- It also has a BuiltInRule in PrelRules.lhs:
1033 --      unpackFoldrCString# "foo" c (unpackFoldrCString# "baz" c n)
1034 --        =  unpackFoldrCString# "foobaz" c n
1035 unpackFoldrCString# addr f z
1036   = unpack 0#
1037   where
1038     unpack nh
1039       | ch `eqChar#` '\0'# = z
1040       | otherwise          = C# ch `f` unpack (nh +# 1#)
1041       where
1042         ch = indexCharOffAddr# addr nh
1043
1044 unpackCStringUtf8# :: Addr# -> [Char]
1045 unpackCStringUtf8# addr
1046   = unpack 0#
1047   where
1048     unpack nh
1049       | ch `eqChar#` '\0'#   = []
1050       | ch `leChar#` '\x7F'# = C# ch : unpack (nh +# 1#)
1051       | ch `leChar#` '\xDF'# =
1052           C# (chr# (((ord# ch                                  -# 0xC0#) `uncheckedIShiftL#`  6#) +#
1053                      (ord# (indexCharOffAddr# addr (nh +# 1#)) -# 0x80#))) :
1054           unpack (nh +# 2#)
1055       | ch `leChar#` '\xEF'# =
1056           C# (chr# (((ord# ch                                  -# 0xE0#) `uncheckedIShiftL#` 12#) +#
1057                     ((ord# (indexCharOffAddr# addr (nh +# 1#)) -# 0x80#) `uncheckedIShiftL#`  6#) +#
1058                      (ord# (indexCharOffAddr# addr (nh +# 2#)) -# 0x80#))) :
1059           unpack (nh +# 3#)
1060       | otherwise            =
1061           C# (chr# (((ord# ch                                  -# 0xF0#) `uncheckedIShiftL#` 18#) +#
1062                     ((ord# (indexCharOffAddr# addr (nh +# 1#)) -# 0x80#) `uncheckedIShiftL#` 12#) +#
1063                     ((ord# (indexCharOffAddr# addr (nh +# 2#)) -# 0x80#) `uncheckedIShiftL#`  6#) +#
1064                      (ord# (indexCharOffAddr# addr (nh +# 3#)) -# 0x80#))) :
1065           unpack (nh +# 4#)
1066       where
1067         ch = indexCharOffAddr# addr nh
1068
1069 unpackNBytes# :: Addr# -> Int# -> [Char]
1070 unpackNBytes# _addr 0#   = []
1071 unpackNBytes#  addr len# = unpack [] (len# -# 1#)
1072     where
1073      unpack acc i#
1074       | i# <# 0#  = acc
1075       | otherwise =
1076          case indexCharOffAddr# addr i# of
1077             ch -> unpack (C# ch : acc) (i# -# 1#)
1078
1079 {-# RULES
1080 "unpack"       [~1] forall a   . unpackCString# a                  = build (unpackFoldrCString# a)
1081 "unpack-list"  [1]  forall a   . unpackFoldrCString# a (:) [] = unpackCString# a
1082 "unpack-append"     forall a n . unpackFoldrCString# a (:) n  = unpackAppendCString# a n
1083
1084 -- There's a built-in rule (in PrelRules.lhs) for
1085 --      unpackFoldr "foo" c (unpackFoldr "baz" c n)  =  unpackFoldr "foobaz" c n
1086
1087   #-}
1088 \end{code}
1089
1090 #ifdef __HADDOCK__
1091 \begin{code}
1092 -- | A special argument for the 'Control.Monad.ST.ST' type constructor,
1093 -- indexing a state embedded in the 'Prelude.IO' monad by
1094 -- 'Control.Monad.ST.stToIO'.
1095 data RealWorld
1096 \end{code}
1097 #endif