GHC/Base.lhs

   1 \section[GHC.Base]{Module @GHC.Base@}
   2
   3 The overall structure of the GHC Prelude is a bit tricky.
   4
   5   a) We want to avoid "orphan modules", i.e. ones with instance
   6         decls that don't belong either to a tycon or a class
   7         defined in the same module
   8
   9   b) We want to avoid giant modules
  10
  11 So the rough structure is as follows, in (linearised) dependency order
  12
  13
  14 GHC.Prim                Has no implementation.  It defines built-in things, and
  15                 by importing it you bring them into scope.
  16                 The source file is GHC.Prim.hi-boot, which is just
  17                 copied to make GHC.Prim.hi
  18
  19                 Classes: CCallable, CReturnable
  20
  21 GHC.Base        Classes: Eq, Ord, Functor, Monad
  22                 Types:   list, (), Int, Bool, Ordering, Char, String
  23
  24 Data.Tup        Types: tuples, plus instances for GHC.Base classes
  25
  26 GHC.Show        Class: Show, plus instances for GHC.Base/GHC.Tup types
  27
  28 GHC.Enum        Class: Enum,  plus instances for GHC.Base/GHC.Tup types
  29
  30 Data.Maybe      Type: Maybe, plus instances for GHC.Base classes
  31
  32 GHC.Num         Class: Num, plus instances for Int
  33                 Type:  Integer, plus instances for all classes so far (Eq, Ord, Num, Show)
  34
  35                 Integer is needed here because it is mentioned in the signature
  36                 of 'fromInteger' in class Num
  37
  38 GHC.Real        Classes: Real, Integral, Fractional, RealFrac
  39                          plus instances for Int, Integer
  40                 Types:  Ratio, Rational
  41                         plus intances for classes so far
  42
  43                 Rational is needed here because it is mentioned in the signature
  44                 of 'toRational' in class Real
  45
  46 Ix              Classes: Ix, plus instances for Int, Bool, Char, Integer, Ordering, tuples
  47
  48 GHC.Arr         Types: Array, MutableArray, MutableVar
  49
  50                 Does *not* contain any ByteArray stuff (see GHC.ByteArr)
  51                 Arrays are used by a function in GHC.Float
  52
  53 GHC.Float       Classes: Floating, RealFloat
  54                 Types:   Float, Double, plus instances of all classes so far
  55
  56                 This module contains everything to do with floating point.
  57                 It is a big module (900 lines)
  58                 With a bit of luck, many modules can be compiled without ever reading GHC.Float.hi
  59
  60 GHC.ByteArr     Types: ByteArray, MutableByteArray
  61
  62                 We want this one to be after GHC.Float, because it defines arrays
  63                 of unboxed floats.
  64
  65
  66 Other Prelude modules are much easier with fewer complex dependencies.
  67
  68 \begin{code}
  69 {-# OPTIONS -fno-implicit-prelude #-}
  70 -----------------------------------------------------------------------------
  71 -- |
  72 -- Module      :  GHC.Base
  73 -- Copyright   :  (c) The University of Glasgow, 1992-2002
  74 -- License     :  see libraries/base/LICENSE
  75 --
  76 -- Maintainer  :  cvs-ghc@haskell.org
  77 -- Stability   :  internal
  78 -- Portability :  non-portable (GHC extensions)
  79 --
  80 -- Basic data types and classes.
  81 --
  82 -----------------------------------------------------------------------------
  83
  84 #include "MachDeps.h"
  85
  86 module GHC.Base
  87         (
  88         module GHC.Base,
  89         module GHC.Prim,        -- Re-export GHC.Prim and GHC.Err, to avoid lots
  90         module GHC.Err          -- of people having to import it explicitly
  91   )
  92         where
  93
  94 import GHC.Prim
  95 import {-# SOURCE #-} GHC.Err
  96
  97 infixr 9  .
  98 infixr 5  ++, :
  99 infix  4  ==, /=, <, <=, >=, >
 100 infixr 3  &&
 101 infixr 2  ||
 102 infixl 1  >>, >>=
 103 infixr 0  $
 104
 105 default ()              -- Double isn't available yet
 106 \end{code}
 107
 108
 109 %*********************************************************
 110 %*                                                      *
 111 \subsection{DEBUGGING STUFF}
 112 %*  (for use when compiling GHC.Base itself doesn't work)
 113 %*                                                      *
 114 %*********************************************************
 115
 116 \begin{code}
 117 {-
 118 data  Bool  =  False | True
 119 data Ordering = LT | EQ | GT
 120 data Char = C# Char#
 121 type  String = [Char]
 122 data Int = I# Int#
 123 data  ()  =  ()
 124 data [] a = MkNil
 125
 126 not True = False
 127 (&&) True True = True
 128 otherwise = True
 129
 130 build = error "urk"
 131 foldr = error "urk"
 132
 133 unpackCString# :: Addr# -> [Char]
 134 unpackFoldrCString# :: Addr# -> (Char  -> a -> a) -> a -> a
 135 unpackAppendCString# :: Addr# -> [Char] -> [Char]
 136 unpackCStringUtf8# :: Addr# -> [Char]
 137 unpackCString# a = error "urk"
 138 unpackFoldrCString# a = error "urk"
 139 unpackAppendCString# a = error "urk"
 140 unpackCStringUtf8# a = error "urk"
 141 -}
 142 \end{code}
 143
 144
 145 %*********************************************************
 146 %*                                                      *
 147 \subsection{Standard classes @Eq@, @Ord@}
 148 %*                                                      *
 149 %*********************************************************
 150
 151 \begin{code}
 152
 153 -- | The 'Eq' class defines equality ('==') and inequality ('/=').
 154 -- All the basic datatypes exported by the "Prelude" are instances of 'Eq',
 155 -- and 'Eq' may be derived for any datatype whose constituents are also
 156 -- instances of 'Eq'.
 157 --
 158 -- Minimal complete definition: either '==' or '/='.
 159 --
 160 class  Eq a  where
 161     (==), (/=)           :: a -> a -> Bool
 162
 163     x /= y               = not (x == y)
 164     x == y               = not (x /= y)
 165
 166 class  (Eq a) => Ord a  where
 167     compare              :: a -> a -> Ordering
 168     (<), (<=), (>), (>=) :: a -> a -> Bool
 169     max, min             :: a -> a -> a
 170
 171     -- An instance of Ord should define either 'compare' or '<='.
 172     -- Using 'compare' can be more efficient for complex types.
 173
 174     compare x y
 175         | x == y    = EQ
 176         | x <= y    = LT        -- NB: must be '<=' not '<' to validate the
 177                                 -- above claim about the minimal things that
 178                                 -- can be defined for an instance of Ord
 179         | otherwise = GT
 180
 181     x <  y = case compare x y of { LT -> True;  _other -> False }
 182     x <= y = case compare x y of { GT -> False; _other -> True }
 183     x >  y = case compare x y of { GT -> True;  _other -> False }
 184     x >= y = case compare x y of { LT -> False; _other -> True }
 185
 186         -- These two default methods use '<=' rather than 'compare'
 187         -- because the latter is often more expensive
 188     max x y = if x <= y then y else x
 189     min x y = if x <= y then x else y
 190 \end{code}
 191
 192 %*********************************************************
 193 %*                                                      *
 194 \subsection{Monadic classes @Functor@, @Monad@ }
 195 %*                                                      *
 196 %*********************************************************
 197
 198 \begin{code}
 199 class  Functor f  where
 200     fmap        :: (a -> b) -> f a -> f b
 201
 202 class  Monad m  where
 203     (>>=)       :: m a -> (a -> m b) -> m b
 204     (>>)        :: m a -> m b -> m b
 205     return      :: a -> m a
 206     fail        :: String -> m a
 207
 208     m >> k      = m >>= \_ -> k
 209     fail s      = error s
 210 \end{code}
 211
 212
 213 %*********************************************************
 214 %*                                                      *
 215 \subsection{The list type}
 216 %*                                                      *
 217 %*********************************************************
 218
 219 \begin{code}
 220 data [] a = [] | a : [a]  -- do explicitly: deriving (Eq, Ord)
 221                           -- to avoid weird names like con2tag_[]#
 222
 223
 224 instance (Eq a) => Eq [a] where
 225     {-# SPECIALISE instance Eq [Char] #-}
 226     []     == []     = True
 227     (x:xs) == (y:ys) = x == y && xs == ys
 228     _xs    == _ys    = False
 229
 230 instance (Ord a) => Ord [a] where
 231     {-# SPECIALISE instance Ord [Char] #-}
 232     compare []     []     = EQ
 233     compare []     (_:_)  = LT
 234     compare (_:_)  []     = GT
 235     compare (x:xs) (y:ys) = case compare x y of
 236                                 EQ    -> compare xs ys
 237                                 other -> other
 238
 239 instance Functor [] where
 240     fmap = map
 241
 242 instance  Monad []  where
 243     m >>= k             = foldr ((++) . k) [] m
 244     m >> k              = foldr ((++) . (\ _ -> k)) [] m
 245     return x            = [x]
 246     fail _              = []
 247 \end{code}
 248
 249 A few list functions that appear here because they are used here.
 250 The rest of the prelude list functions are in GHC.List.
 251
 252 ----------------------------------------------
 253 --      foldr/build/augment
 254 ----------------------------------------------
 255
 256 \begin{code}
 257 foldr            :: (a -> b -> b) -> b -> [a] -> b
 258 -- foldr _ z []     =  z
 259 -- foldr f z (x:xs) =  f x (foldr f z xs)
 260 {-# INLINE [0] foldr #-}
 261 -- Inline only in the final stage, after the foldr/cons rule has had a chance
 262 foldr k z xs = go xs
 263              where
 264                go []     = z
 265                go (y:ys) = y `k` go ys
 266
 267 build   :: forall a. (forall b. (a -> b -> b) -> b -> b) -> [a]
 268 {-# INLINE [1] build #-}
 269         -- The INLINE is important, even though build is tiny,
 270         -- because it prevents [] getting inlined in the version that
 271         -- appears in the interface file.  If [] *is* inlined, it
 272         -- won't match with [] appearing in rules in an importing module.
 273         --
 274         -- The "1" says to inline in phase 1
 275
 276 build g = g (:) []
 277
 278 augment :: forall a. (forall b. (a->b->b) -> b -> b) -> [a] -> [a]
 279 {-# INLINE [1] augment #-}
 280 augment g xs = g (:) xs
 281
 282 {-# RULES
 283 "fold/build"    forall k z (g::forall b. (a->b->b) -> b -> b) .
 284                 foldr k z (build g) = g k z
 285
 286 "foldr/augment" forall k z xs (g::forall b. (a->b->b) -> b -> b) .
 287                 foldr k z (augment g xs) = g k (foldr k z xs)
 288
 289 "foldr/id"                        foldr (:) [] = \x->x
 290 "foldr/app"     [1] forall xs ys. foldr (:) ys xs = xs ++ ys
 291         -- Only activate this from phase 1, because that's
 292         -- when we disable the rule that expands (++) into foldr
 293
 294 -- The foldr/cons rule looks nice, but it can give disastrously
 295 -- bloated code when commpiling
 296 --      array (a,b) [(1,2), (2,2), (3,2), ...very long list... ]
 297 -- i.e. when there are very very long literal lists
 298 -- So I've disabled it for now. We could have special cases
 299 -- for short lists, I suppose.
 300 -- "foldr/cons" forall k z x xs. foldr k z (x:xs) = k x (foldr k z xs)
 301
 302 "foldr/single"  forall k z x. foldr k z [x] = k x z
 303 "foldr/nil"     forall k z.   foldr k z []  = z
 304
 305 "augment/build" forall (g::forall b. (a->b->b) -> b -> b)
 306                        (h::forall b. (a->b->b) -> b -> b) .
 307                        augment g (build h) = build (\c n -> g c (h c n))
 308 "augment/nil"   forall (g::forall b. (a->b->b) -> b -> b) .
 309                         augment g [] = build g
 310  #-}
 311
 312 -- This rule is true, but not (I think) useful:
 313 --      augment g (augment h t) = augment (\cn -> g c (h c n)) t
 314 \end{code}
 315
 316
 317 ----------------------------------------------
 318 --              map
 319 ----------------------------------------------
 320
 321 \begin{code}
 322 map :: (a -> b) -> [a] -> [b]
 323 map _ []     = []
 324 map f (x:xs) = f x : map f xs
 325
 326 -- Note eta expanded
 327 mapFB ::  (elt -> lst -> lst) -> (a -> elt) -> a -> lst -> lst
 328 {-# INLINE [0] mapFB #-}
 329 mapFB c f x ys = c (f x) ys
 330
 331 -- The rules for map work like this.
 332 --
 333 -- Up to (but not including) phase 1, we use the "map" rule to
 334 -- rewrite all saturated applications of map with its build/fold
 335 -- form, hoping for fusion to happen.
 336 -- In phase 1 and 0, we switch off that rule, inline build, and
 337 -- switch on the "mapList" rule, which rewrites the foldr/mapFB
 338 -- thing back into plain map.
 339 --
 340 -- It's important that these two rules aren't both active at once
 341 -- (along with build's unfolding) else we'd get an infinite loop
 342 -- in the rules.  Hence the activation control below.
 343 --
 344 -- The "mapFB" rule optimises compositions of map.
 345 --
 346 -- This same pattern is followed by many other functions:
 347 -- e.g. append, filter, iterate, repeat, etc.
 348
 349 {-# RULES
 350 "map"       [~1] forall f xs.   map f xs                = build (\c n -> foldr (mapFB c f) n xs)
 351 "mapList"   [1]  forall f.      foldr (mapFB (:) f) []  = map f
 352 "mapFB"     forall c f g.       mapFB (mapFB c f) g     = mapFB c (f.g)
 353   #-}
 354 \end{code}
 355
 356
 357 ----------------------------------------------
 358 --              append
 359 ----------------------------------------------
 360 \begin{code}
 361 (++) :: [a] -> [a] -> [a]
 362 (++) []     ys = ys
 363 (++) (x:xs) ys = x : xs ++ ys
 364
 365 {-# RULES
 366 "++"    [~1] forall xs ys. xs ++ ys = augment (\c n -> foldr c n xs) ys
 367   #-}
 368
 369 \end{code}
 370
 371
 372 %*********************************************************
 373 %*                                                      *
 374 \subsection{Type @Bool@}
 375 %*                                                      *
 376 %*********************************************************
 377
 378 \begin{code}
 379 -- |The 'Bool' type is an enumeration.  It is defined with 'False'
 380 -- first so that the corresponding 'Enum' instance will give @'fromEnum'
 381 -- False@ the value zero, and @'fromEnum' True@ the value 1.
 382 data  Bool  =  False | True  deriving (Eq, Ord)
 383         -- Read in GHC.Read, Show in GHC.Show
 384
 385 -- Boolean functions
 386
 387 -- | Boolean \"and\"
 388 (&&)                    :: Bool -> Bool -> Bool
 389 True  && x              =  x
 390 False && _              =  False
 391
 392 -- | Boolean \"or\"
 393 (||)                    :: Bool -> Bool -> Bool
 394 True  || _              =  True
 395 False || x              =  x
 396
 397 -- | Boolean \"not\"
 398 not                     :: Bool -> Bool
 399 not True                =  False
 400 not False               =  True
 401
 402 -- |'otherwise' is defined as the value 'True'; it helps to make
 403 -- guards more readable.  eg.
 404 --
 405 -- >  f x | x \< 0     = ...
 406 -- >      | otherwise = ...
 407 otherwise               :: Bool
 408 otherwise               =  True
 409 \end{code}
 410
 411
 412 %*********************************************************
 413 %*                                                      *
 414 \subsection{The @()@ type}
 415 %*                                                      *
 416 %*********************************************************
 417
 418 The Unit type is here because virtually any program needs it (whereas
 419 some programs may get away without consulting GHC.Tup).  Furthermore,
 420 the renamer currently *always* asks for () to be in scope, so that
 421 ccalls can use () as their default type; so when compiling GHC.Base we
 422 need ().  (We could arrange suck in () only if -fglasgow-exts, but putting
 423 it here seems more direct.)
 424
 425 \begin{code}
 426 -- | The unit datatype @()@ has one non-undefined member, the nullary
 427 -- constructor @()@.
 428 data () = ()
 429
 430 instance Eq () where
 431     () == () = True
 432     () /= () = False
 433
 434 instance Ord () where
 435     () <= () = True
 436     () <  () = False
 437     () >= () = True
 438     () >  () = False
 439     max () () = ()
 440     min () () = ()
 441     compare () () = EQ
 442 \end{code}
 443
 444
 445 %*********************************************************
 446 %*                                                      *
 447 \subsection{Type @Ordering@}
 448 %*                                                      *
 449 %*********************************************************
 450
 451 \begin{code}
 452 -- | Represents an ordering relationship between two values: less
 453 -- than, equal to, or greater than.  An 'Ordering' is returned by
 454 -- 'compare'.
 455 data Ordering = LT | EQ | GT deriving (Eq, Ord)
 456         -- Read in GHC.Read, Show in GHC.Show
 457 \end{code}
 458
 459
 460 %*********************************************************
 461 %*                                                      *
 462 \subsection{Type @Char@ and @String@}
 463 %*                                                      *
 464 %*********************************************************
 465
 466 \begin{code}
 467 -- | A 'String' is a list of characters.  String constants in Haskell are values
 468 -- of type 'String'.
 469 --
 470 type String = [Char]
 471
 472 {-| The character type 'Char' is an enumeration whose values represent
 473 Unicode characters.  A character literal in Haskell has type 'Char'.
 474
 475 To convert a 'Char' to or from an 'Int', use 'Prelude.toEnum' and
 476 'Prelude.fromEnum' from the 'Enum' class respectively (equivalently
 477 'ord' and 'chr' also do the trick).
 478 -}
 479 data Char = C# Char#
 480
 481 -- We don't use deriving for Eq and Ord, because for Ord the derived
 482 -- instance defines only compare, which takes two primops.  Then
 483 -- '>' uses compare, and therefore takes two primops instead of one.
 484
 485 instance Eq Char where
 486     (C# c1) == (C# c2) = c1 `eqChar#` c2
 487     (C# c1) /= (C# c2) = c1 `neChar#` c2
 488
 489 instance Ord Char where
 490     (C# c1) >  (C# c2) = c1 `gtChar#` c2
 491     (C# c1) >= (C# c2) = c1 `geChar#` c2
 492     (C# c1) <= (C# c2) = c1 `leChar#` c2
 493     (C# c1) <  (C# c2) = c1 `ltChar#` c2
 494
 495 {-# RULES
 496 "x# `eqChar#` x#" forall x#. x# `eqChar#` x# = True
 497 "x# `neChar#` x#" forall x#. x# `neChar#` x# = False
 498 "x# `gtChar#` x#" forall x#. x# `gtChar#` x# = False
 499 "x# `geChar#` x#" forall x#. x# `geChar#` x# = True
 500 "x# `leChar#` x#" forall x#. x# `leChar#` x# = True
 501 "x# `ltChar#` x#" forall x#. x# `ltChar#` x# = False
 502   #-}
 503
 504 chr :: Int -> Char
 505 chr (I# i#) | int2Word# i# `leWord#` int2Word# 0x10FFFF# = C# (chr# i#)
 506             | otherwise                                  = error "Prelude.chr: bad argument"
 507
 508 unsafeChr :: Int -> Char
 509 unsafeChr (I# i#) = C# (chr# i#)
 510
 511 ord :: Char -> Int
 512 ord (C# c#) = I# (ord# c#)
 513 \end{code}
 514
 515 String equality is used when desugaring pattern-matches against strings.
 516
 517 \begin{code}
 518 eqString :: String -> String -> Bool
 519 eqString []       []       = True
 520 eqString (c1:cs1) (c2:cs2) = c1 == c2 && cs1 `eqString` cs2
 521 eqString cs1      cs2      = False
 522
 523 {-# RULES "eqString" (==) = eqString #-}
 524 \end{code}
 525
 526
 527 %*********************************************************
 528 %*                                                      *
 529 \subsection{Type @Int@}
 530 %*                                                      *
 531 %*********************************************************
 532
 533 \begin{code}
 534 data Int = I# Int#
 535 -- ^A fixed-precision integer type with at least the range @[-2^29
 536 -- .. 2^29-1]@.  The exact range for a given implementation can be
 537 -- determined by using 'minBound' and 'maxBound' from the 'Bounded'
 538 -- class.
 539
 540 zeroInt, oneInt, twoInt, maxInt, minInt :: Int
 541 zeroInt = I# 0#
 542 oneInt  = I# 1#
 543 twoInt  = I# 2#
 544
 545 {- Seems clumsy. Should perhaps put minInt and MaxInt directly into MachDeps.h -}
 546 #if WORD_SIZE_IN_BITS == 31
 547 minInt  = I# (-0x40000000#)
 548 maxInt  = I# 0x3FFFFFFF#
 549 #elif WORD_SIZE_IN_BITS == 32
 550 minInt  = I# (-0x80000000#)
 551 maxInt  = I# 0x7FFFFFFF#
 552 #else
 553 minInt  = I# (-0x8000000000000000#)
 554 maxInt  = I# 0x7FFFFFFFFFFFFFFF#
 555 #endif
 556
 557 instance Eq Int where
 558     (==) = eqInt
 559     (/=) = neInt
 560
 561 instance Ord Int where
 562     compare = compareInt
 563     (<)     = ltInt
 564     (<=)    = leInt
 565     (>=)    = geInt
 566     (>)     = gtInt
 567
 568 compareInt :: Int -> Int -> Ordering
 569 (I# x#) `compareInt` (I# y#) = compareInt# x# y#
 570
 571 compareInt# :: Int# -> Int# -> Ordering
 572 compareInt# x# y#
 573     | x# <#  y# = LT
 574     | x# ==# y# = EQ
 575     | otherwise = GT
 576 \end{code}
 577
 578
 579 %*********************************************************
 580 %*                                                      *
 581 \subsection{The function type}
 582 %*                                                      *
 583 %*********************************************************
 584
 585 \begin{code}
 586 -- identity function
 587 id                      :: a -> a
 588 id x                    =  x
 589
 590 -- lazy function; this is just the same as id, but its unfolding
 591 -- and strictness are over-ridden by the definition in MkId.lhs
 592 -- That way, it does not get inlined, and the strictness analyser
 593 -- sees it as lazy.  Then the worker/wrapper phase inlines it.
 594 -- Result: happiness
 595 lazy :: a -> a
 596 lazy x = x
 597
 598 -- Assertion function. This simply ignores its boolean argument.
 599 -- The compiler may rewrite it to (assertError line)
 600 assert :: Bool -> a -> a
 601 assert pred r = r
 602
 603 -- constant function
 604 const                   :: a -> b -> a
 605 const x _               =  x
 606
 607 -- function composition
 608 {-# INLINE (.) #-}
 609 (.)       :: (b -> c) -> (a -> b) -> a -> c
 610 (.) f g x = f (g x)
 611
 612 -- flip f  takes its (first) two arguments in the reverse order of f.
 613 flip                    :: (a -> b -> c) -> b -> a -> c
 614 flip f x y              =  f y x
 615
 616 -- right-associating infix application operator (useful in continuation-
 617 -- passing style)
 618 {-# INLINE ($) #-}
 619 ($)                     :: (a -> b) -> a -> b
 620 f $ x                   =  f x
 621
 622 -- until p f  yields the result of applying f until p holds.
 623 until                   :: (a -> Bool) -> (a -> a) -> a -> a
 624 until p f x | p x       =  x
 625             | otherwise =  until p f (f x)
 626
 627 -- asTypeOf is a type-restricted version of const.  It is usually used
 628 -- as an infix operator, and its typing forces its first argument
 629 -- (which is usually overloaded) to have the same type as the second.
 630 asTypeOf                :: a -> a -> a
 631 asTypeOf                =  const
 632 \end{code}
 633
 634 %*********************************************************
 635 %*                                                      *
 636 \subsection{CCallable instances}
 637 %*                                                      *
 638 %*********************************************************
 639
 640 Defined here to avoid orphans
 641
 642 \begin{code}
 643 instance CCallable Char
 644 instance CReturnable Char
 645
 646 instance CCallable   Int
 647 instance CReturnable Int
 648
 649 instance CReturnable () -- Why, exactly?
 650 \end{code}
 651
 652
 653 %*********************************************************
 654 %*                                                      *
 655 \subsection{Generics}
 656 %*                                                      *
 657 %*********************************************************
 658
 659 \begin{code}
 660 data Unit = Unit
 661 #ifndef __HADDOCK__
 662 data (:+:) a b = Inl a | Inr b
 663 data (:*:) a b = a :*: b
 664 #endif
 665 \end{code}
 666
 667
 668 %*********************************************************
 669 %*                                                      *
 670 \subsection{Numeric primops}
 671 %*                                                      *
 672 %*********************************************************
 673
 674 \begin{code}
 675 divInt# :: Int# -> Int# -> Int#
 676 x# `divInt#` y#
 677         -- Be careful NOT to overflow if we do any additional arithmetic
 678         -- on the arguments...  the following  previous version of this
 679         -- code has problems with overflow:
 680 --    | (x# ># 0#) && (y# <# 0#) = ((x# -# y#) -# 1#) `quotInt#` y#
 681 --    | (x# <# 0#) && (y# ># 0#) = ((x# -# y#) +# 1#) `quotInt#` y#
 682     | (x# ># 0#) && (y# <# 0#) = ((x# -# 1#) `quotInt#` y#) -# 1#
 683     | (x# <# 0#) && (y# ># 0#) = ((x# +# 1#) `quotInt#` y#) -# 1#
 684     | otherwise                = x# `quotInt#` y#
 685
 686 modInt# :: Int# -> Int# -> Int#
 687 x# `modInt#` y#
 688     | (x# ># 0#) && (y# <# 0#) ||
 689       (x# <# 0#) && (y# ># 0#)    = if r# /=# 0# then r# +# y# else 0#
 690     | otherwise                   = r#
 691     where
 692     r# = x# `remInt#` y#
 693 \end{code}
 694
 695 Definitions of the boxed PrimOps; these will be
 696 used in the case of partial applications, etc.
 697
 698 \begin{code}
 699 {-# INLINE eqInt #-}
 700 {-# INLINE neInt #-}
 701 {-# INLINE gtInt #-}
 702 {-# INLINE geInt #-}
 703 {-# INLINE ltInt #-}
 704 {-# INLINE leInt #-}
 705 {-# INLINE plusInt #-}
 706 {-# INLINE minusInt #-}
 707 {-# INLINE timesInt #-}
 708 {-# INLINE quotInt #-}
 709 {-# INLINE remInt #-}
 710 {-# INLINE negateInt #-}
 711
 712 plusInt, minusInt, timesInt, quotInt, remInt, divInt, modInt, gcdInt :: Int -> Int -> Int
 713 (I# x) `plusInt`  (I# y) = I# (x +# y)
 714 (I# x) `minusInt` (I# y) = I# (x -# y)
 715 (I# x) `timesInt` (I# y) = I# (x *# y)
 716 (I# x) `quotInt`  (I# y) = I# (x `quotInt#` y)
 717 (I# x) `remInt`   (I# y) = I# (x `remInt#`  y)
 718 (I# x) `divInt`   (I# y) = I# (x `divInt#`  y)
 719 (I# x) `modInt`   (I# y) = I# (x `modInt#`  y)
 720
 721 {-# RULES
 722 "x# +# 0#" forall x#. x# +# 0# = x#
 723 "0# +# x#" forall x#. 0# +# x# = x#
 724 "x# -# 0#" forall x#. x# -# 0# = x#
 725 "x# -# x#" forall x#. x# -# x# = 0#
 726 "x# *# 0#" forall x#. x# *# 0# = 0#
 727 "0# *# x#" forall x#. 0# *# x# = 0#
 728 "x# *# 1#" forall x#. x# *# 1# = x#
 729 "1# *# x#" forall x#. 1# *# x# = x#
 730   #-}
 731
 732 gcdInt (I# a) (I# b) = g a b
 733    where g 0# 0# = error "GHC.Base.gcdInt: gcd 0 0 is undefined"
 734          g 0# _  = I# absB
 735          g _  0# = I# absA
 736          g _  _  = I# (gcdInt# absA absB)
 737
 738          absInt x = if x <# 0# then negateInt# x else x
 739
 740          absA     = absInt a
 741          absB     = absInt b
 742
 743 negateInt :: Int -> Int
 744 negateInt (I# x) = I# (negateInt# x)
 745
 746 gtInt, geInt, eqInt, neInt, ltInt, leInt :: Int -> Int -> Bool
 747 (I# x) `gtInt` (I# y) = x >#  y
 748 (I# x) `geInt` (I# y) = x >=# y
 749 (I# x) `eqInt` (I# y) = x ==# y
 750 (I# x) `neInt` (I# y) = x /=# y
 751 (I# x) `ltInt` (I# y) = x <#  y
 752 (I# x) `leInt` (I# y) = x <=# y
 753
 754 {-# RULES
 755 "x# ># x#"  forall x#. x# >#  x# = False
 756 "x# >=# x#" forall x#. x# >=# x# = True
 757 "x# ==# x#" forall x#. x# ==# x# = True
 758 "x# /=# x#" forall x#. x# /=# x# = False
 759 "x# <# x#"  forall x#. x# <#  x# = False
 760 "x# <=# x#" forall x#. x# <=# x# = True
 761   #-}
 762
 763 {-# RULES
 764 "plusFloat x 0.0"   forall x#. plusFloat#  x#   0.0# = x#
 765 "plusFloat 0.0 x"   forall x#. plusFloat#  0.0# x#   = x#
 766 "minusFloat x 0.0"  forall x#. minusFloat# x#   0.0# = x#
 767 "minusFloat x x"    forall x#. minusFloat# x#   x#   = 0.0#
 768 "timesFloat x 0.0"  forall x#. timesFloat# x#   0.0# = 0.0#
 769 "timesFloat0.0 x"   forall x#. timesFloat# 0.0# x#   = 0.0#
 770 "timesFloat x 1.0"  forall x#. timesFloat# x#   1.0# = x#
 771 "timesFloat 1.0 x"  forall x#. timesFloat# 1.0# x#   = x#
 772 "divideFloat x 1.0" forall x#. divideFloat# x#  1.0# = x#
 773   #-}
 774
 775 {-# RULES
 776 "plusDouble x 0.0"   forall x#. (+##) x#    0.0## = x#
 777 "plusDouble 0.0 x"   forall x#. (+##) 0.0## x#    = x#
 778 "minusDouble x 0.0"  forall x#. (-##) x#    0.0## = x#
 779 "minusDouble x x"    forall x#. (-##) x#    x#    = 0.0##
 780 "timesDouble x 0.0"  forall x#. (*##) x#    0.0## = 0.0##
 781 "timesDouble 0.0 x"  forall x#. (*##) 0.0## x#    = 0.0##
 782 "timesDouble x 1.0"  forall x#. (*##) x#    1.0## = x#
 783 "timesDouble 1.0 x"  forall x#. (*##) 1.0## x#    = x#
 784 "divideDouble x 1.0" forall x#. (/##) x#    1.0## = x#
 785   #-}
 786
 787 -- Wrappers for the shift operations.  The uncheckedShift# family are
 788 -- undefined when the amount being shifted by is greater than the size
 789 -- in bits of Int#, so these wrappers perform a check and return
 790 -- either zero or -1 appropriately.
 791 --
 792 -- Note that these wrappers still produce undefined results when the
 793 -- second argument (the shift amount) is negative.
 794
 795 shiftL#, shiftRL# :: Word# -> Int# -> Word#
 796
 797 a `shiftL#` b   | b >=# WORD_SIZE_IN_BITS# = int2Word# 0#
 798                 | otherwise                = a `uncheckedShiftL#` b
 799
 800 a `shiftRL#` b  | b >=# WORD_SIZE_IN_BITS# = int2Word# 0#
 801                 | otherwise                = a `uncheckedShiftRL#` b
 802
 803 iShiftL#, iShiftRA#, iShiftRL# :: Int# -> Int# -> Int#
 804
 805 a `iShiftL#` b  | b >=# WORD_SIZE_IN_BITS# = 0#
 806                 | otherwise                = a `uncheckedIShiftL#` b
 807
 808 a `iShiftRA#` b | b >=# WORD_SIZE_IN_BITS# = if a <# 0# then (-1#) else 0#
 809                 | otherwise                = a `uncheckedIShiftRA#` b
 810
 811 a `iShiftRL#` b | b >=# WORD_SIZE_IN_BITS# = 0#
 812                 | otherwise                = a `uncheckedIShiftRL#` b
 813
 814 #if WORD_SIZE_IN_BITS == 32
 815 {-# RULES
 816 "narrow32Int#"  forall x#. narrow32Int#   x# = x#
 817 "narrow32Word#" forall x#. narrow32Word#   x# = x#
 818    #-}
 819 #endif
 820
 821 {-# RULES
 822 "int2Word2Int"  forall x#. int2Word# (word2Int# x#) = x#
 823 "word2Int2Word" forall x#. word2Int# (int2Word# x#) = x#
 824   #-}
 825 \end{code}
 826
 827
 828 %********************************************************
 829 %*                                                      *
 830 \subsection{Unpacking C strings}
 831 %*                                                      *
 832 %********************************************************
 833
 834 This code is needed for virtually all programs, since it's used for
 835 unpacking the strings of error messages.
 836
 837 \begin{code}
 838 unpackCString# :: Addr# -> [Char]
 839 {-# NOINLINE [1] unpackCString# #-}
 840 unpackCString# addr
 841   = unpack 0#
 842   where
 843     unpack nh
 844       | ch `eqChar#` '\0'# = []
 845       | otherwise          = C# ch : unpack (nh +# 1#)
 846       where
 847         ch = indexCharOffAddr# addr nh
 848
 849 unpackAppendCString# :: Addr# -> [Char] -> [Char]
 850 unpackAppendCString# addr rest
 851   = unpack 0#
 852   where
 853     unpack nh
 854       | ch `eqChar#` '\0'# = rest
 855       | otherwise          = C# ch : unpack (nh +# 1#)
 856       where
 857         ch = indexCharOffAddr# addr nh
 858
 859 unpackFoldrCString# :: Addr# -> (Char  -> a -> a) -> a -> a
 860 {-# NOINLINE [0] unpackFoldrCString# #-}
 861 -- Don't inline till right at the end;
 862 -- usually the unpack-list rule turns it into unpackCStringList
 863 unpackFoldrCString# addr f z
 864   = unpack 0#
 865   where
 866     unpack nh
 867       | ch `eqChar#` '\0'# = z
 868       | otherwise          = C# ch `f` unpack (nh +# 1#)
 869       where
 870         ch = indexCharOffAddr# addr nh
 871
 872 unpackCStringUtf8# :: Addr# -> [Char]
 873 unpackCStringUtf8# addr
 874   = unpack 0#
 875   where
 876     unpack nh
 877       | ch `eqChar#` '\0'#   = []
 878       | ch `leChar#` '\x7F'# = C# ch : unpack (nh +# 1#)
 879       | ch `leChar#` '\xDF'# =
 880           C# (chr# (((ord# ch                                  -# 0xC0#) `uncheckedIShiftL#`  6#) +#
 881                      (ord# (indexCharOffAddr# addr (nh +# 1#)) -# 0x80#))) :
 882           unpack (nh +# 2#)
 883       | ch `leChar#` '\xEF'# =
 884           C# (chr# (((ord# ch                                  -# 0xE0#) `uncheckedIShiftL#` 12#) +#
 885                     ((ord# (indexCharOffAddr# addr (nh +# 1#)) -# 0x80#) `uncheckedIShiftL#`  6#) +#
 886                      (ord# (indexCharOffAddr# addr (nh +# 2#)) -# 0x80#))) :
 887           unpack (nh +# 3#)
 888       | otherwise            =
 889           C# (chr# (((ord# ch                                  -# 0xF0#) `uncheckedIShiftL#` 18#) +#
 890                     ((ord# (indexCharOffAddr# addr (nh +# 1#)) -# 0x80#) `uncheckedIShiftL#` 12#) +#
 891                     ((ord# (indexCharOffAddr# addr (nh +# 2#)) -# 0x80#) `uncheckedIShiftL#`  6#) +#
 892                      (ord# (indexCharOffAddr# addr (nh +# 3#)) -# 0x80#))) :
 893           unpack (nh +# 4#)
 894       where
 895         ch = indexCharOffAddr# addr nh
 896
 897 unpackNBytes# :: Addr# -> Int# -> [Char]
 898 unpackNBytes# _addr 0#   = []
 899 unpackNBytes#  addr len# = unpack [] (len# -# 1#)
 900     where
 901      unpack acc i#
 902       | i# <# 0#  = acc
 903       | otherwise =
 904          case indexCharOffAddr# addr i# of
 905             ch -> unpack (C# ch : acc) (i# -# 1#)
 906
 907 {-# RULES
 908 "unpack"       [~1] forall a   . unpackCString# a                  = build (unpackFoldrCString# a)
 909 "unpack-list"  [1]  forall a   . unpackFoldrCString# a (:) [] = unpackCString# a
 910 "unpack-append"     forall a n . unpackFoldrCString# a (:) n  = unpackAppendCString# a n
 911
 912 -- There's a built-in rule (in PrelRules.lhs) for
 913 --      unpackFoldr "foo" c (unpackFoldr "baz" c n)  =  unpackFoldr "foobaz" c n
 914
 915   #-}
 916 \end{code}